LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ ssygvx()

subroutine ssygvx ( integer itype,
character jobz,
character range,
character uplo,
integer n,
real, dimension( lda, * ) a,
integer lda,
real, dimension( ldb, * ) b,
integer ldb,
real vl,
real vu,
integer il,
integer iu,
real abstol,
integer m,
real, dimension( * ) w,
real, dimension( ldz, * ) z,
integer ldz,
real, dimension( * ) work,
integer lwork,
integer, dimension( * ) iwork,
integer, dimension( * ) ifail,
integer info )

SSYGVX

Download SSYGVX + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!> SSYGVX computes selected eigenvalues, and optionally, eigenvectors
!> of a real generalized symmetric-definite eigenproblem, of the form
!> A*x=(lambda)*B*x,  A*Bx=(lambda)*x,  or B*A*x=(lambda)*x.  Here A
!> and B are assumed to be symmetric and B is also positive definite.
!> Eigenvalues and eigenvectors can be selected by specifying either a
!> range of values or a range of indices for the desired eigenvalues.
!>
Parameters
[in]ITYPE
!>          ITYPE is INTEGER
!>          Specifies the problem type to be solved:
!>          = 1:  A*x = (lambda)*B*x
!>          = 2:  A*B*x = (lambda)*x
!>          = 3:  B*A*x = (lambda)*x
!>
[in]JOBZ
!>          JOBZ is CHARACTER*1
!>          = 'N':  Compute eigenvalues only;
!>          = 'V':  Compute eigenvalues and eigenvectors.
!>
[in]RANGE
!>          RANGE is CHARACTER*1
!>          = 'A': all eigenvalues will be found.
!>          = 'V': all eigenvalues in the half-open interval (VL,VU]
!>                 will be found.
!>          = 'I': the IL-th through IU-th eigenvalues will be found.
!>
[in]UPLO
!>          UPLO is CHARACTER*1
!>          = 'U':  Upper triangle of A and B are stored;
!>          = 'L':  Lower triangle of A and B are stored.
!>
[in]N
!>          N is INTEGER
!>          The order of the matrix pencil (A,B).  N >= 0.
!>
[in,out]A
!>          A is REAL array, dimension (LDA, N)
!>          On entry, the symmetric matrix A.  If UPLO = 'U', the
!>          leading N-by-N upper triangular part of A contains the
!>          upper triangular part of the matrix A.  If UPLO = 'L',
!>          the leading N-by-N lower triangular part of A contains
!>          the lower triangular part of the matrix A.
!>
!>          On exit, the lower triangle (if UPLO='L') or the upper
!>          triangle (if UPLO='U') of A, including the diagonal, is
!>          destroyed.
!>
[in]LDA
!>          LDA is INTEGER
!>          The leading dimension of the array A.  LDA >= max(1,N).
!>
[in,out]B
!>          B is REAL array, dimension (LDB, N)
!>          On entry, the symmetric matrix B.  If UPLO = 'U', the
!>          leading N-by-N upper triangular part of B contains the
!>          upper triangular part of the matrix B.  If UPLO = 'L',
!>          the leading N-by-N lower triangular part of B contains
!>          the lower triangular part of the matrix B.
!>
!>          On exit, if INFO <= N, the part of B containing the matrix is
!>          overwritten by the triangular factor U or L from the Cholesky
!>          factorization B = U**T*U or B = L*L**T.
!>
[in]LDB
!>          LDB is INTEGER
!>          The leading dimension of the array B.  LDB >= max(1,N).
!>
[in]VL
!>          VL is REAL
!>          If RANGE='V', the lower bound of the interval to
!>          be searched for eigenvalues. VL < VU.
!>          Not referenced if RANGE = 'A' or 'I'.
!>
[in]VU
!>          VU is REAL
!>          If RANGE='V', the upper bound of the interval to
!>          be searched for eigenvalues. VL < VU.
!>          Not referenced if RANGE = 'A' or 'I'.
!>
[in]IL
!>          IL is INTEGER
!>          If RANGE='I', the index of the
!>          smallest eigenvalue to be returned.
!>          1 <= IL <= IU <= N, if N > 0; IL = 1 and IU = 0 if N = 0.
!>          Not referenced if RANGE = 'A' or 'V'.
!>
[in]IU
!>          IU is INTEGER
!>          If RANGE='I', the index of the
!>          largest eigenvalue to be returned.
!>          1 <= IL <= IU <= N, if N > 0; IL = 1 and IU = 0 if N = 0.
!>          Not referenced if RANGE = 'A' or 'V'.
!>
[in]ABSTOL
!>          ABSTOL is REAL
!>          The absolute error tolerance for the eigenvalues.
!>          An approximate eigenvalue is accepted as converged
!>          when it is determined to lie in an interval [a,b]
!>          of width less than or equal to
!>
!>                  ABSTOL + EPS *   max( |a|,|b| ) ,
!>
!>          where EPS is the machine precision.  If ABSTOL is less than
!>          or equal to zero, then  EPS*|T|  will be used in its place,
!>          where |T| is the 1-norm of the tridiagonal matrix obtained
!>          by reducing C to tridiagonal form, where C is the symmetric
!>          matrix of the standard symmetric problem to which the
!>          generalized problem is transformed.
!>
!>          Eigenvalues will be computed most accurately when ABSTOL is
!>          set to twice the underflow threshold 2*DLAMCH('S'), not zero.
!>          If this routine returns with INFO>0, indicating that some
!>          eigenvectors did not converge, try setting ABSTOL to
!>          2*SLAMCH('S').
!>
[out]M
!>          M is INTEGER
!>          The total number of eigenvalues found.  0 <= M <= N.
!>          If RANGE = 'A', M = N, and if RANGE = 'I', M = IU-IL+1.
!>
[out]W
!>          W is REAL array, dimension (N)
!>          On normal exit, the first M elements contain the selected
!>          eigenvalues in ascending order.
!>
[out]Z
!>          Z is REAL array, dimension (LDZ, max(1,M))
!>          If JOBZ = 'N', then Z is not referenced.
!>          If JOBZ = 'V', then if INFO = 0, the first M columns of Z
!>          contain the orthonormal eigenvectors of the matrix A
!>          corresponding to the selected eigenvalues, with the i-th
!>          column of Z holding the eigenvector associated with W(i).
!>          The eigenvectors are normalized as follows:
!>          if ITYPE = 1 or 2, Z**T*B*Z = I;
!>          if ITYPE = 3, Z**T*inv(B)*Z = I.
!>
!>          If an eigenvector fails to converge, then that column of Z
!>          contains the latest approximation to the eigenvector, and the
!>          index of the eigenvector is returned in IFAIL.
!>          Note: the user must ensure that at least max(1,M) columns are
!>          supplied in the array Z; if RANGE = 'V', the exact value of M
!>          is not known in advance and an upper bound must be used.
!>
[in]LDZ
!>          LDZ is INTEGER
!>          The leading dimension of the array Z.  LDZ >= 1, and if
!>          JOBZ = 'V', LDZ >= max(1,N).
!>
[out]WORK
!>          WORK is REAL array, dimension (MAX(1,LWORK))
!>          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
!>
[in]LWORK
!>          LWORK is INTEGER
!>          The length of the array WORK.  LWORK >= max(1,8*N).
!>          For optimal efficiency, LWORK >= (NB+3)*N,
!>          where NB is the blocksize for SSYTRD returned by ILAENV.
!>
!>          If LWORK = -1, then a workspace query is assumed; the routine
!>          only calculates the optimal size of the WORK array, returns
!>          this value as the first entry of the WORK array, and no error
!>          message related to LWORK is issued by XERBLA.
!>
[out]IWORK
!>          IWORK is INTEGER array, dimension (5*N)
!>
[out]IFAIL
!>          IFAIL is INTEGER array, dimension (N)
!>          If JOBZ = 'V', then if INFO = 0, the first M elements of
!>          IFAIL are zero.  If INFO > 0, then IFAIL contains the
!>          indices of the eigenvectors that failed to converge.
!>          If JOBZ = 'N', then IFAIL is not referenced.
!>
[out]INFO
!>          INFO is INTEGER
!>          = 0:  successful exit
!>          < 0:  if INFO = -i, the i-th argument had an illegal value
!>          > 0:  SPOTRF or SSYEVX returned an error code:
!>             <= N:  if INFO = i, SSYEVX failed to converge;
!>                    i eigenvectors failed to converge.  Their indices
!>                    are stored in array IFAIL.
!>             > N:   if INFO = N + i, for 1 <= i <= N, then the leading
!>                    principal minor of order i of B is not positive.
!>                    The factorization of B could not be completed and
!>                    no eigenvalues or eigenvectors were computed.
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Contributors:
Mark Fahey, Department of Mathematics, Univ. of Kentucky, USA

Definition at line 292 of file ssygvx.f.

295*
296* -- LAPACK driver routine --
297* -- LAPACK is a software package provided by Univ. of Tennessee, --
298* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
299*
300* .. Scalar Arguments ..
301 CHARACTER JOBZ, RANGE, UPLO
302 INTEGER IL, INFO, ITYPE, IU, LDA, LDB, LDZ, LWORK, M, N
303 REAL ABSTOL, VL, VU
304* ..
305* .. Array Arguments ..
306 INTEGER IFAIL( * ), IWORK( * )
307 REAL A( LDA, * ), B( LDB, * ), W( * ), WORK( * ),
308 $ Z( LDZ, * )
309* ..
310*
311* =====================================================================
312*
313* .. Parameters ..
314 REAL ONE
315 parameter( one = 1.0e+0 )
316* ..
317* .. Local Scalars ..
318 LOGICAL ALLEIG, INDEIG, LQUERY, UPPER, VALEIG, WANTZ
319 CHARACTER TRANS
320 INTEGER LWKMIN, LWKOPT, NB
321* ..
322* .. External Functions ..
323 LOGICAL LSAME
324 INTEGER ILAENV
325 REAL SROUNDUP_LWORK
326 EXTERNAL ilaenv, lsame, sroundup_lwork
327* ..
328* .. External Subroutines ..
329 EXTERNAL spotrf, ssyevx, ssygst, strmm, strsm,
330 $ xerbla
331* ..
332* .. Intrinsic Functions ..
333 INTRINSIC max, min
334* ..
335* .. Executable Statements ..
336*
337* Test the input parameters.
338*
339 upper = lsame( uplo, 'U' )
340 wantz = lsame( jobz, 'V' )
341 alleig = lsame( range, 'A' )
342 valeig = lsame( range, 'V' )
343 indeig = lsame( range, 'I' )
344 lquery = ( lwork.EQ.-1 )
345*
346 info = 0
347 IF( itype.LT.1 .OR. itype.GT.3 ) THEN
348 info = -1
349 ELSE IF( .NOT.( wantz .OR. lsame( jobz, 'N' ) ) ) THEN
350 info = -2
351 ELSE IF( .NOT.( alleig .OR. valeig .OR. indeig ) ) THEN
352 info = -3
353 ELSE IF( .NOT.( upper .OR. lsame( uplo, 'L' ) ) ) THEN
354 info = -4
355 ELSE IF( n.LT.0 ) THEN
356 info = -5
357 ELSE IF( lda.LT.max( 1, n ) ) THEN
358 info = -7
359 ELSE IF( ldb.LT.max( 1, n ) ) THEN
360 info = -9
361 ELSE
362 IF( valeig ) THEN
363 IF( n.GT.0 .AND. vu.LE.vl )
364 $ info = -11
365 ELSE IF( indeig ) THEN
366 IF( il.LT.1 .OR. il.GT.max( 1, n ) ) THEN
367 info = -12
368 ELSE IF( iu.LT.min( n, il ) .OR. iu.GT.n ) THEN
369 info = -13
370 END IF
371 END IF
372 END IF
373 IF (info.EQ.0) THEN
374 IF (ldz.LT.1 .OR. (wantz .AND. ldz.LT.n)) THEN
375 info = -18
376 END IF
377 END IF
378*
379 IF( info.EQ.0 ) THEN
380 lwkmin = max( 1, 8*n )
381 nb = ilaenv( 1, 'SSYTRD', uplo, n, -1, -1, -1 )
382 lwkopt = max( lwkmin, ( nb + 3 )*n )
383 work( 1 ) = sroundup_lwork(lwkopt)
384*
385 IF( lwork.LT.lwkmin .AND. .NOT.lquery ) THEN
386 info = -20
387 END IF
388 END IF
389*
390 IF( info.NE.0 ) THEN
391 CALL xerbla( 'SSYGVX', -info )
392 RETURN
393 ELSE IF( lquery ) THEN
394 RETURN
395 END IF
396*
397* Quick return if possible
398*
399 m = 0
400 IF( n.EQ.0 ) THEN
401 RETURN
402 END IF
403*
404* Form a Cholesky factorization of B.
405*
406 CALL spotrf( uplo, n, b, ldb, info )
407 IF( info.NE.0 ) THEN
408 info = n + info
409 RETURN
410 END IF
411*
412* Transform problem to standard eigenvalue problem and solve.
413*
414 CALL ssygst( itype, uplo, n, a, lda, b, ldb, info )
415 CALL ssyevx( jobz, range, uplo, n, a, lda, vl, vu, il, iu,
416 $ abstol,
417 $ m, w, z, ldz, work, lwork, iwork, ifail, info )
418*
419 IF( wantz ) THEN
420*
421* Backtransform eigenvectors to the original problem.
422*
423 IF( info.GT.0 )
424 $ m = info - 1
425 IF( itype.EQ.1 .OR. itype.EQ.2 ) THEN
426*
427* For A*x=(lambda)*B*x and A*B*x=(lambda)*x;
428* backtransform eigenvectors: x = inv(L)**T*y or inv(U)*y
429*
430 IF( upper ) THEN
431 trans = 'N'
432 ELSE
433 trans = 'T'
434 END IF
435*
436 CALL strsm( 'Left', uplo, trans, 'Non-unit', n, m, one,
437 $ b,
438 $ ldb, z, ldz )
439*
440 ELSE IF( itype.EQ.3 ) THEN
441*
442* For B*A*x=(lambda)*x;
443* backtransform eigenvectors: x = L*y or U**T*y
444*
445 IF( upper ) THEN
446 trans = 'T'
447 ELSE
448 trans = 'N'
449 END IF
450*
451 CALL strmm( 'Left', uplo, trans, 'Non-unit', n, m, one,
452 $ b,
453 $ ldb, z, ldz )
454 END IF
455 END IF
456*
457* Set WORK(1) to optimal workspace size.
458*
459 work( 1 ) = sroundup_lwork(lwkopt)
460*
461 RETURN
462*
463* End of SSYGVX
464*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
ssyevx
subroutine ssyevx(jobz, range, uplo, n, a, lda, vl, vu, il, iu, abstol, m, w, z, ldz, work, lwork, iwork, ifail, info)
SSYEVX computes the eigenvalues and, optionally, the left and/or right eigenvectors for SY matrices
Definition ssyevx.f:252
ssygst
subroutine ssygst(itype, uplo, n, a, lda, b, ldb, info)
SSYGST
Definition ssygst.f:125
ilaenv
integer function ilaenv(ispec, name, opts, n1, n2, n3, n4)
ILAENV
Definition ilaenv.f:160
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
spotrf
subroutine spotrf(uplo, n, a, lda, info)
SPOTRF
Definition spotrf.f:105
sroundup_lwork
real function sroundup_lwork(lwork)
SROUNDUP_LWORK
Definition sroundup_lwork.f:59
strmm
subroutine strmm(side, uplo, transa, diag, m, n, alpha, a, lda, b, ldb)
STRMM
Definition strmm.f:177
strsm
subroutine strsm(side, uplo, transa, diag, m, n, alpha, a, lda, b, ldb)
STRSM
Definition strsm.f:181
Here is the call graph for this function:
Here is the caller graph for this function: