dlqt02()

subroutine dlqt02	(	integer	m,
		integer	n,
		integer	k,
		double precision, dimension( lda, * )	a,
		double precision, dimension( lda, * )	af,
		double precision, dimension( lda, * )	q,
		double precision, dimension( lda, * )	l,
		integer	lda,
		double precision, dimension( * )	tau,
		double precision, dimension( lwork )	work,
		integer	lwork,
		double precision, dimension( * )	rwork,
		double precision, dimension( * )	result )

DLQT02

Purpose:

!>
!> DLQT02 tests DORGLQ, which generates an m-by-n matrix Q with
!> orthonormal rows that is defined as the product of k elementary
!> reflectors.
!>
!> Given the LQ factorization of an m-by-n matrix A, DLQT02 generates
!> the orthogonal matrix Q defined by the factorization of the first k
!> rows of A; it compares L(1:k,1:m) with A(1:k,1:n)*Q(1:m,1:n)', and
!> checks that the rows of Q are orthonormal.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrix Q to be generated. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix Q to be generated. !> N >= M >= 0. !>
[in]	K	!> K is INTEGER !> The number of elementary reflectors whose product defines the !> matrix Q. M >= K >= 0. !>
[in]	A	!> A is DOUBLE PRECISION array, dimension (LDA,N) !> The m-by-n matrix A which was factorized by DLQT01. !>
[in]	AF	!> AF is DOUBLE PRECISION array, dimension (LDA,N) !> Details of the LQ factorization of A, as returned by DGELQF. !> See DGELQF for further details. !>
[out]	Q	!> Q is DOUBLE PRECISION array, dimension (LDA,N) !>
[out]	L	!> L is DOUBLE PRECISION array, dimension (LDA,M) !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the arrays A, AF, Q and L. LDA >= N. !>
[in]	TAU	!> TAU is DOUBLE PRECISION array, dimension (M) !> The scalar factors of the elementary reflectors corresponding !> to the LQ factorization in AF. !>
[out]	WORK	!> WORK is DOUBLE PRECISION array, dimension (LWORK) !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. !>
[out]	RWORK	!> RWORK is DOUBLE PRECISION array, dimension (M) !>
[out]	RESULT	!> RESULT is DOUBLE PRECISION array, dimension (2) !> The test ratios: !> RESULT(1) = norm( L - A*Q' ) / ( N * norm(A) * EPS ) !> RESULT(2) = norm( I - Q*Q' ) / ( N * EPS ) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 133 of file dlqt02.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            K, LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), AF( LDA, * ), L( LDA, * ),
     $                   Q( LDA, * ), RESULT( * ), RWORK( * ), TAU( * ),
     $                   WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
      DOUBLE PRECISION   ROGUE
      parameter( rogue = -1.0d+10 )
*     ..
*     .. Local Scalars ..
      INTEGER            INFO
      DOUBLE PRECISION   ANORM, EPS, RESID
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, DLANGE, DLANSY
      EXTERNAL           dlamch, dlange, dlansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgemm, dlacpy, dlaset, dorglq, dsyrk
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       SRNAMT
*     ..
*     .. Common blocks ..
      COMMON             / srnamc / srnamt
*     ..
*     .. Executable Statements ..
*
      eps = dlamch( 'Epsilon' )
*
*     Copy the first k rows of the factorization to the array Q
*
      CALL dlaset( 'Full', m, n, rogue, rogue, q, lda )
      CALL dlacpy( 'Upper', k, n-1, af( 1, 2 ), lda, q( 1, 2 ), lda )
*
*     Generate the first n columns of the matrix Q
*
      srnamt = 'DORGLQ'
      CALL dorglq( m, n, k, q, lda, tau, work, lwork, info )
*
*     Copy L(1:k,1:m)
*
      CALL dlaset( 'Full', k, m, zero, zero, l, lda )
      CALL dlacpy( 'Lower', k, m, af, lda, l, lda )
*
*     Compute L(1:k,1:m) - A(1:k,1:n) * Q(1:m,1:n)'
*
      CALL dgemm( 'No transpose', 'Transpose', k, m, n, -one, a, lda, q,
     $            lda, one, l, lda )
*
*     Compute norm( L - A*Q' ) / ( N * norm(A) * EPS ) .
*
      anorm = dlange( '1', k, n, a, lda, rwork )
      resid = dlange( '1', k, m, l, lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / dble( max( 1, n ) ) ) / anorm ) / eps
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute I - Q*Q'
*
      CALL dlaset( 'Full', m, m, zero, one, l, lda )
      CALL dsyrk( 'Upper', 'No transpose', m, n, -one, q, lda, one, l,
     $            lda )
*
*     Compute norm( I - Q*Q' ) / ( N * EPS ) .
*
      resid = dlansy( '1', 'Upper', m, l, lda, rwork )
*
      result( 2 ) = ( resid / dble( max( 1, n ) ) ) / eps
*
      RETURN
*
*     End of DLQT02
*

Here is the call graph for this function:

Here is the caller graph for this function: