LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ cggev3()

subroutine cggev3 ( character jobvl,
character jobvr,
integer n,
complex, dimension( lda, * ) a,
integer lda,
complex, dimension( ldb, * ) b,
integer ldb,
complex, dimension( * ) alpha,
complex, dimension( * ) beta,
complex, dimension( ldvl, * ) vl,
integer ldvl,
complex, dimension( ldvr, * ) vr,
integer ldvr,
complex, dimension( * ) work,
integer lwork,
real, dimension( * ) rwork,
integer info )

CGGEV3 computes the eigenvalues and, optionally, the left and/or right eigenvectors for GE matrices (blocked algorithm)

Download CGGEV3 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!> CGGEV3 computes for a pair of N-by-N complex nonsymmetric matrices
!> (A,B), the generalized eigenvalues, and optionally, the left and/or
!> right generalized eigenvectors.
!>
!> A generalized eigenvalue for a pair of matrices (A,B) is a scalar
!> lambda or a ratio alpha/beta = lambda, such that A - lambda*B is
!> singular. It is usually represented as the pair (alpha,beta), as
!> there is a reasonable interpretation for beta=0, and even for both
!> being zero.
!>
!> The right generalized eigenvector v(j) corresponding to the
!> generalized eigenvalue lambda(j) of (A,B) satisfies
!>
!>              A * v(j) = lambda(j) * B * v(j).
!>
!> The left generalized eigenvector u(j) corresponding to the
!> generalized eigenvalues lambda(j) of (A,B) satisfies
!>
!>              u(j)**H * A = lambda(j) * u(j)**H * B
!>
!> where u(j)**H is the conjugate-transpose of u(j).
!>
Parameters
[in]JOBVL
!>          JOBVL is CHARACTER*1
!>          = 'N':  do not compute the left generalized eigenvectors;
!>          = 'V':  compute the left generalized eigenvectors.
!>
[in]JOBVR
!>          JOBVR is CHARACTER*1
!>          = 'N':  do not compute the right generalized eigenvectors;
!>          = 'V':  compute the right generalized eigenvectors.
!>
[in]N
!>          N is INTEGER
!>          The order of the matrices A, B, VL, and VR.  N >= 0.
!>
[in,out]A
!>          A is COMPLEX array, dimension (LDA, N)
!>          On entry, the matrix A in the pair (A,B).
!>          On exit, A has been overwritten.
!>
[in]LDA
!>          LDA is INTEGER
!>          The leading dimension of A.  LDA >= max(1,N).
!>
[in,out]B
!>          B is COMPLEX array, dimension (LDB, N)
!>          On entry, the matrix B in the pair (A,B).
!>          On exit, B has been overwritten.
!>
[in]LDB
!>          LDB is INTEGER
!>          The leading dimension of B.  LDB >= max(1,N).
!>
[out]ALPHA
!>          ALPHA is COMPLEX array, dimension (N)
!>
[out]BETA
!>          BETA is COMPLEX array, dimension (N)
!>          On exit, ALPHA(j)/BETA(j), j=1,...,N, will be the
!>          generalized eigenvalues.
!>
!>          Note: the quotients ALPHA(j)/BETA(j) may easily over- or
!>          underflow, and BETA(j) may even be zero.  Thus, the user
!>          should avoid naively computing the ratio alpha/beta.
!>          However, ALPHA will be always less than and usually
!>          comparable with norm(A) in magnitude, and BETA always less
!>          than and usually comparable with norm(B).
!>
[out]VL
!>          VL is COMPLEX array, dimension (LDVL,N)
!>          If JOBVL = 'V', the left generalized eigenvectors u(j) are
!>          stored one after another in the columns of VL, in the same
!>          order as their eigenvalues.
!>          Each eigenvector is scaled so the largest component has
!>          abs(real part) + abs(imag. part) = 1.
!>          Not referenced if JOBVL = 'N'.
!>
[in]LDVL
!>          LDVL is INTEGER
!>          The leading dimension of the matrix VL. LDVL >= 1, and
!>          if JOBVL = 'V', LDVL >= N.
!>
[out]VR
!>          VR is COMPLEX array, dimension (LDVR,N)
!>          If JOBVR = 'V', the right generalized eigenvectors v(j) are
!>          stored one after another in the columns of VR, in the same
!>          order as their eigenvalues.
!>          Each eigenvector is scaled so the largest component has
!>          abs(real part) + abs(imag. part) = 1.
!>          Not referenced if JOBVR = 'N'.
!>
[in]LDVR
!>          LDVR is INTEGER
!>          The leading dimension of the matrix VR. LDVR >= 1, and
!>          if JOBVR = 'V', LDVR >= N.
!>
[out]WORK
!>          WORK is COMPLEX array, dimension (MAX(1,LWORK))
!>          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
!>
[in]LWORK
!>          LWORK is INTEGER
!>          The dimension of the array WORK. LWORK >= MAX(1,2*N).
!>          For good performance, LWORK must generally be larger.
!>
!>          If LWORK = -1, then a workspace query is assumed; the routine
!>          only calculates the optimal size of the WORK array, returns
!>          this value as the first entry of the WORK array, and no error
!>          message related to LWORK is issued by XERBLA.
!>
[out]RWORK
!>          RWORK is REAL array, dimension (8*N)
!>
[out]INFO
!>          INFO is INTEGER
!>          = 0:  successful exit
!>          < 0:  if INFO = -i, the i-th argument had an illegal value.
!>          =1,...,N:
!>                The QZ iteration failed.  No eigenvectors have been
!>                calculated, but ALPHA(j) and BETA(j) should be
!>                correct for j=INFO+1,...,N.
!>          > N:  =N+1: other then QZ iteration failed in CHGEQZ,
!>                =N+2: error return from CTGEVC.
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 213 of file cggev3.f.

216*
217* -- LAPACK driver routine --
218* -- LAPACK is a software package provided by Univ. of Tennessee, --
219* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
220*
221* .. Scalar Arguments ..
222 CHARACTER JOBVL, JOBVR
223 INTEGER INFO, LDA, LDB, LDVL, LDVR, LWORK, N
224* ..
225* .. Array Arguments ..
226 REAL RWORK( * )
227 COMPLEX A( LDA, * ), ALPHA( * ), B( LDB, * ),
228 $ BETA( * ), VL( LDVL, * ), VR( LDVR, * ),
229 $ WORK( * )
230* ..
231*
232* =====================================================================
233*
234* .. Parameters ..
235 REAL ZERO, ONE
236 parameter( zero = 0.0e0, one = 1.0e0 )
237 COMPLEX CZERO, CONE
238 parameter( czero = ( 0.0e0, 0.0e0 ),
239 $ cone = ( 1.0e0, 0.0e0 ) )
240* ..
241* .. Local Scalars ..
242 LOGICAL ILASCL, ILBSCL, ILV, ILVL, ILVR, LQUERY
243 CHARACTER CHTEMP
244 INTEGER ICOLS, IERR, IHI, IJOBVL, IJOBVR, ILEFT, ILO,
245 $ IN, IRIGHT, IROWS, IRWRK, ITAU, IWRK, JC, JR,
246 $ LWKOPT, LWKMIN
247 REAL ANRM, ANRMTO, BIGNUM, BNRM, BNRMTO, EPS,
248 $ SMLNUM, TEMP
249 COMPLEX X
250* ..
251* .. Local Arrays ..
252 LOGICAL LDUMMA( 1 )
253* ..
254* .. External Subroutines ..
255 EXTERNAL cgeqrf, cggbak, cggbal, cgghd3, claqz0,
256 $ clacpy,
257 $ clascl, claset, ctgevc, cungqr, cunmqr, xerbla
258* ..
259* .. External Functions ..
260 LOGICAL LSAME
261 REAL CLANGE, SLAMCH, SROUNDUP_LWORK
262 EXTERNAL lsame, clange, slamch,
263 $ sroundup_lwork
264* ..
265* .. Intrinsic Functions ..
266 INTRINSIC abs, aimag, max, real, sqrt
267* ..
268* .. Statement Functions ..
269 REAL ABS1
270* ..
271* .. Statement Function definitions ..
272 abs1( x ) = abs( real( x ) ) + abs( aimag( x ) )
273* ..
274* .. Executable Statements ..
275*
276* Decode the input arguments
277*
278 IF( lsame( jobvl, 'N' ) ) THEN
279 ijobvl = 1
280 ilvl = .false.
281 ELSE IF( lsame( jobvl, 'V' ) ) THEN
282 ijobvl = 2
283 ilvl = .true.
284 ELSE
285 ijobvl = -1
286 ilvl = .false.
287 END IF
288*
289 IF( lsame( jobvr, 'N' ) ) THEN
290 ijobvr = 1
291 ilvr = .false.
292 ELSE IF( lsame( jobvr, 'V' ) ) THEN
293 ijobvr = 2
294 ilvr = .true.
295 ELSE
296 ijobvr = -1
297 ilvr = .false.
298 END IF
299 ilv = ilvl .OR. ilvr
300*
301* Test the input arguments
302*
303 info = 0
304 lquery = ( lwork.EQ.-1 )
305 lwkmin = max( 1, 2*n )
306 IF( ijobvl.LE.0 ) THEN
307 info = -1
308 ELSE IF( ijobvr.LE.0 ) THEN
309 info = -2
310 ELSE IF( n.LT.0 ) THEN
311 info = -3
312 ELSE IF( lda.LT.max( 1, n ) ) THEN
313 info = -5
314 ELSE IF( ldb.LT.max( 1, n ) ) THEN
315 info = -7
316 ELSE IF( ldvl.LT.1 .OR. ( ilvl .AND. ldvl.LT.n ) ) THEN
317 info = -11
318 ELSE IF( ldvr.LT.1 .OR. ( ilvr .AND. ldvr.LT.n ) ) THEN
319 info = -13
320 ELSE IF( lwork.LT.lwkmin .AND. .NOT.lquery ) THEN
321 info = -15
322 END IF
323*
324* Compute workspace
325*
326 IF( info.EQ.0 ) THEN
327 CALL cgeqrf( n, n, b, ldb, work, work, -1, ierr )
328 lwkopt = max( lwkmin, n+int( work( 1 ) ) )
329 CALL cunmqr( 'L', 'C', n, n, n, b, ldb, work, a, lda, work,
330 $ -1, ierr )
331 lwkopt = max( lwkopt, n+int( work( 1 ) ) )
332 IF( ilvl ) THEN
333 CALL cungqr( n, n, n, vl, ldvl, work, work, -1, ierr )
334 lwkopt = max( lwkopt, n+int( work( 1 ) ) )
335 END IF
336 IF( ilv ) THEN
337 CALL cgghd3( jobvl, jobvr, n, 1, n, a, lda, b, ldb, vl,
338 $ ldvl, vr, ldvr, work, -1, ierr )
339 lwkopt = max( lwkopt, n+int( work( 1 ) ) )
340 CALL claqz0( 'S', jobvl, jobvr, n, 1, n, a, lda, b, ldb,
341 $ alpha, beta, vl, ldvl, vr, ldvr, work, -1,
342 $ rwork, 0, ierr )
343 lwkopt = max( lwkopt, n+int( work( 1 ) ) )
344 ELSE
345 CALL cgghd3( 'N', 'N', n, 1, n, a, lda, b, ldb, vl, ldvl,
346 $ vr, ldvr, work, -1, ierr )
347 lwkopt = max( lwkopt, n+int( work( 1 ) ) )
348 CALL claqz0( 'E', jobvl, jobvr, n, 1, n, a, lda, b, ldb,
349 $ alpha, beta, vl, ldvl, vr, ldvr, work, -1,
350 $ rwork, 0, ierr )
351 lwkopt = max( lwkopt, n+int( work( 1 ) ) )
352 END IF
353 IF( n.EQ.0 ) THEN
354 work( 1 ) = 1
355 ELSE
356 work( 1 ) = sroundup_lwork( lwkopt )
357 END IF
358 END IF
359*
360 IF( info.NE.0 ) THEN
361 CALL xerbla( 'CGGEV3 ', -info )
362 RETURN
363 ELSE IF( lquery ) THEN
364 RETURN
365 END IF
366*
367* Quick return if possible
368*
369 IF( n.EQ.0 )
370 $ RETURN
371*
372* Get machine constants
373*
374 eps = slamch( 'E' )*slamch( 'B' )
375 smlnum = slamch( 'S' )
376 bignum = one / smlnum
377 smlnum = sqrt( smlnum ) / eps
378 bignum = one / smlnum
379*
380* Scale A if max element outside range [SMLNUM,BIGNUM]
381*
382 anrm = clange( 'M', n, n, a, lda, rwork )
383 ilascl = .false.
384 IF( anrm.GT.zero .AND. anrm.LT.smlnum ) THEN
385 anrmto = smlnum
386 ilascl = .true.
387 ELSE IF( anrm.GT.bignum ) THEN
388 anrmto = bignum
389 ilascl = .true.
390 END IF
391 IF( ilascl )
392 $ CALL clascl( 'G', 0, 0, anrm, anrmto, n, n, a, lda, ierr )
393*
394* Scale B if max element outside range [SMLNUM,BIGNUM]
395*
396 bnrm = clange( 'M', n, n, b, ldb, rwork )
397 ilbscl = .false.
398 IF( bnrm.GT.zero .AND. bnrm.LT.smlnum ) THEN
399 bnrmto = smlnum
400 ilbscl = .true.
401 ELSE IF( bnrm.GT.bignum ) THEN
402 bnrmto = bignum
403 ilbscl = .true.
404 END IF
405 IF( ilbscl )
406 $ CALL clascl( 'G', 0, 0, bnrm, bnrmto, n, n, b, ldb, ierr )
407*
408* Permute the matrices A, B to isolate eigenvalues if possible
409*
410 ileft = 1
411 iright = n + 1
412 irwrk = iright + n
413 CALL cggbal( 'P', n, a, lda, b, ldb, ilo, ihi, rwork( ileft ),
414 $ rwork( iright ), rwork( irwrk ), ierr )
415*
416* Reduce B to triangular form (QR decomposition of B)
417*
418 irows = ihi + 1 - ilo
419 IF( ilv ) THEN
420 icols = n + 1 - ilo
421 ELSE
422 icols = irows
423 END IF
424 itau = 1
425 iwrk = itau + irows
426 CALL cgeqrf( irows, icols, b( ilo, ilo ), ldb, work( itau ),
427 $ work( iwrk ), lwork+1-iwrk, ierr )
428*
429* Apply the orthogonal transformation to matrix A
430*
431 CALL cunmqr( 'L', 'C', irows, icols, irows, b( ilo, ilo ), ldb,
432 $ work( itau ), a( ilo, ilo ), lda, work( iwrk ),
433 $ lwork+1-iwrk, ierr )
434*
435* Initialize VL
436*
437 IF( ilvl ) THEN
438 CALL claset( 'Full', n, n, czero, cone, vl, ldvl )
439 IF( irows.GT.1 ) THEN
440 CALL clacpy( 'L', irows-1, irows-1, b( ilo+1, ilo ), ldb,
441 $ vl( ilo+1, ilo ), ldvl )
442 END IF
443 CALL cungqr( irows, irows, irows, vl( ilo, ilo ), ldvl,
444 $ work( itau ), work( iwrk ), lwork+1-iwrk, ierr )
445 END IF
446*
447* Initialize VR
448*
449 IF( ilvr )
450 $ CALL claset( 'Full', n, n, czero, cone, vr, ldvr )
451*
452* Reduce to generalized Hessenberg form
453*
454 IF( ilv ) THEN
455*
456* Eigenvectors requested -- work on whole matrix.
457*
458 CALL cgghd3( jobvl, jobvr, n, ilo, ihi, a, lda, b, ldb, vl,
459 $ ldvl, vr, ldvr, work( iwrk ), lwork+1-iwrk,
460 $ ierr )
461 ELSE
462 CALL cgghd3( 'N', 'N', irows, 1, irows, a( ilo, ilo ), lda,
463 $ b( ilo, ilo ), ldb, vl, ldvl, vr, ldvr,
464 $ work( iwrk ), lwork+1-iwrk, ierr )
465 END IF
466*
467* Perform QZ algorithm (Compute eigenvalues, and optionally, the
468* Schur form and Schur vectors)
469*
470 iwrk = itau
471 IF( ilv ) THEN
472 chtemp = 'S'
473 ELSE
474 chtemp = 'E'
475 END IF
476 CALL claqz0( chtemp, jobvl, jobvr, n, ilo, ihi, a, lda, b, ldb,
477 $ alpha, beta, vl, ldvl, vr, ldvr, work( iwrk ),
478 $ lwork+1-iwrk, rwork( irwrk ), 0, ierr )
479 IF( ierr.NE.0 ) THEN
480 IF( ierr.GT.0 .AND. ierr.LE.n ) THEN
481 info = ierr
482 ELSE IF( ierr.GT.n .AND. ierr.LE.2*n ) THEN
483 info = ierr - n
484 ELSE
485 info = n + 1
486 END IF
487 GO TO 70
488 END IF
489*
490* Compute Eigenvectors
491*
492 IF( ilv ) THEN
493 IF( ilvl ) THEN
494 IF( ilvr ) THEN
495 chtemp = 'B'
496 ELSE
497 chtemp = 'L'
498 END IF
499 ELSE
500 chtemp = 'R'
501 END IF
502*
503 CALL ctgevc( chtemp, 'B', ldumma, n, a, lda, b, ldb, vl,
504 $ ldvl,
505 $ vr, ldvr, n, in, work( iwrk ), rwork( irwrk ),
506 $ ierr )
507 IF( ierr.NE.0 ) THEN
508 info = n + 2
509 GO TO 70
510 END IF
511*
512* Undo balancing on VL and VR and normalization
513*
514 IF( ilvl ) THEN
515 CALL cggbak( 'P', 'L', n, ilo, ihi, rwork( ileft ),
516 $ rwork( iright ), n, vl, ldvl, ierr )
517 DO 30 jc = 1, n
518 temp = zero
519 DO 10 jr = 1, n
520 temp = max( temp, abs1( vl( jr, jc ) ) )
521 10 CONTINUE
522 IF( temp.LT.smlnum )
523 $ GO TO 30
524 temp = one / temp
525 DO 20 jr = 1, n
526 vl( jr, jc ) = vl( jr, jc )*temp
527 20 CONTINUE
528 30 CONTINUE
529 END IF
530 IF( ilvr ) THEN
531 CALL cggbak( 'P', 'R', n, ilo, ihi, rwork( ileft ),
532 $ rwork( iright ), n, vr, ldvr, ierr )
533 DO 60 jc = 1, n
534 temp = zero
535 DO 40 jr = 1, n
536 temp = max( temp, abs1( vr( jr, jc ) ) )
537 40 CONTINUE
538 IF( temp.LT.smlnum )
539 $ GO TO 60
540 temp = one / temp
541 DO 50 jr = 1, n
542 vr( jr, jc ) = vr( jr, jc )*temp
543 50 CONTINUE
544 60 CONTINUE
545 END IF
546 END IF
547*
548* Undo scaling if necessary
549*
550 70 CONTINUE
551*
552 IF( ilascl )
553 $ CALL clascl( 'G', 0, 0, anrmto, anrm, n, 1, alpha, n, ierr )
554*
555 IF( ilbscl )
556 $ CALL clascl( 'G', 0, 0, bnrmto, bnrm, n, 1, beta, n, ierr )
557*
558 work( 1 ) = sroundup_lwork( lwkopt )
559 RETURN
560*
561* End of CGGEV3
562*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
cgeqrf
subroutine cgeqrf(m, n, a, lda, tau, work, lwork, info)
CGEQRF
Definition cgeqrf.f:144
cggbak
subroutine cggbak(job, side, n, ilo, ihi, lscale, rscale, m, v, ldv, info)
CGGBAK
Definition cggbak.f:147
cggbal
subroutine cggbal(job, n, a, lda, b, ldb, ilo, ihi, lscale, rscale, work, info)
CGGBAL
Definition cggbal.f:175
cgghd3
subroutine cgghd3(compq, compz, n, ilo, ihi, a, lda, b, ldb, q, ldq, z, ldz, work, lwork, info)
CGGHD3
Definition cgghd3.f:230
clacpy
subroutine clacpy(uplo, m, n, a, lda, b, ldb)
CLACPY copies all or part of one two-dimensional array to another.
Definition clacpy.f:101
slamch
real function slamch(cmach)
SLAMCH
Definition slamch.f:68
clange
real function clange(norm, m, n, a, lda, work)
CLANGE returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition clange.f:113
claqz0
recursive subroutine claqz0(wants, wantq, wantz, n, ilo, ihi, a, lda, b, ldb, alpha, beta, q, ldq, z, ldz, work, lwork, rwork, rec, info)
CLAQZ0
Definition claqz0.f:283
clascl
subroutine clascl(type, kl, ku, cfrom, cto, m, n, a, lda, info)
CLASCL multiplies a general rectangular matrix by a real scalar defined as cto/cfrom.
Definition clascl.f:142
claset
subroutine claset(uplo, m, n, alpha, beta, a, lda)
CLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values.
Definition claset.f:104
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
sroundup_lwork
real function sroundup_lwork(lwork)
SROUNDUP_LWORK
Definition sroundup_lwork.f:59
ctgevc
subroutine ctgevc(side, howmny, select, n, s, lds, p, ldp, vl, ldvl, vr, ldvr, mm, m, work, rwork, info)
CTGEVC
Definition ctgevc.f:217
cungqr
subroutine cungqr(m, n, k, a, lda, tau, work, lwork, info)
CUNGQR
Definition cungqr.f:126
cunmqr
subroutine cunmqr(side, trans, m, n, k, a, lda, tau, c, ldc, work, lwork, info)
CUNMQR
Definition cunmqr.f:166
Here is the call graph for this function:
Here is the caller graph for this function: