cggbak()

subroutine cggbak	(	character	job,
		character	side,
		integer	n,
		integer	ilo,
		integer	ihi,
		real, dimension( * )	lscale,
		real, dimension( * )	rscale,
		integer	m,
		complex, dimension( ldv, * )	v,
		integer	ldv,
		integer	info )

CGGBAK

Download CGGBAK + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CGGBAK forms the right or left eigenvectors of a complex generalized
!> eigenvalue problem A*x = lambda*B*x, by backward transformation on
!> the computed eigenvectors of the balanced pair of matrices output by
!> CGGBAL.
!> 

Parameters

[in]	JOB	!> JOB is CHARACTER*1 !> Specifies the type of backward transformation required: !> = 'N': do nothing, return immediately; !> = 'P': do backward transformation for permutation only; !> = 'S': do backward transformation for scaling only; !> = 'B': do backward transformations for both permutation and !> scaling. !> JOB must be the same as the argument JOB supplied to CGGBAL. !>
[in]	SIDE	!> SIDE is CHARACTER*1 !> = 'R': V contains right eigenvectors; !> = 'L': V contains left eigenvectors. !>
[in]	N	!> N is INTEGER !> The number of rows of the matrix V. N >= 0. !>
[in]	ILO	!> ILO is INTEGER !>
[in]	IHI	!> IHI is INTEGER !> The integers ILO and IHI determined by CGGBAL. !> 1 <= ILO <= IHI <= N, if N > 0; ILO=1 and IHI=0, if N=0. !>
[in]	LSCALE	!> LSCALE is REAL array, dimension (N) !> Details of the permutations and/or scaling factors applied !> to the left side of A and B, as returned by CGGBAL. !>
[in]	RSCALE	!> RSCALE is REAL array, dimension (N) !> Details of the permutations and/or scaling factors applied !> to the right side of A and B, as returned by CGGBAL. !>
[in]	M	!> M is INTEGER !> The number of columns of the matrix V. M >= 0. !>
[in,out]	V	!> V is COMPLEX array, dimension (LDV,M) !> On entry, the matrix of right or left eigenvectors to be !> transformed, as returned by CTGEVC. !> On exit, V is overwritten by the transformed eigenvectors. !>
[in]	LDV	!> LDV is INTEGER !> The leading dimension of the matrix V. LDV >= max(1,N). !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit. !> < 0: if INFO = -i, the i-th argument had an illegal value. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>  See R.C. Ward, Balancing the generalized eigenvalue problem,
!>                 SIAM J. Sci. Stat. Comp. 2 (1981), 141-152.
!> 

Definition at line 144 of file cggbak.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          JOB, SIDE
      INTEGER            IHI, ILO, INFO, LDV, M, N
*     ..
*     .. Array Arguments ..
      REAL               LSCALE( * ), RSCALE( * )
      COMPLEX            V( LDV, * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      LOGICAL            LEFTV, RIGHTV
      INTEGER            I, K
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           csscal, cswap, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters
*
      rightv = lsame( side, 'R' )
      leftv = lsame( side, 'L' )
*
      info = 0
      IF( .NOT.lsame( job, 'N' ) .AND.
     $    .NOT.lsame( job, 'P' ) .AND.
     $    .NOT.lsame( job, 'S' ) .AND.
     $                .NOT.lsame( job, 'B' ) ) THEN
         info = -1
      ELSE IF( .NOT.rightv .AND. .NOT.leftv ) THEN
         info = -2
      ELSE IF( n.LT.0 ) THEN
         info = -3
      ELSE IF( ilo.LT.1 ) THEN
         info = -4
      ELSE IF( n.EQ.0 .AND. ihi.EQ.0 .AND. ilo.NE.1 ) THEN
         info = -4
      ELSE IF( n.GT.0 .AND. ( ihi.LT.ilo .OR. ihi.GT.max( 1, n ) ) )
     $   THEN
         info = -5
      ELSE IF( n.EQ.0 .AND. ilo.EQ.1 .AND. ihi.NE.0 ) THEN
         info = -5
      ELSE IF( m.LT.0 ) THEN
         info = -8
      ELSE IF( ldv.LT.max( 1, n ) ) THEN
         info = -10
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CGGBAK', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
      IF( m.EQ.0 )
     $   RETURN
      IF( lsame( job, 'N' ) )
     $   RETURN
*
      IF( ilo.EQ.ihi )
     $   GO TO 30
*
*     Backward balance
*
      IF( lsame( job, 'S' ) .OR. lsame( job, 'B' ) ) THEN
*
*        Backward transformation on right eigenvectors
*
         IF( rightv ) THEN
            DO 10 i = ilo, ihi
               CALL csscal( m, rscale( i ), v( i, 1 ), ldv )
   10       CONTINUE
         END IF
*
*        Backward transformation on left eigenvectors
*
         IF( leftv ) THEN
            DO 20 i = ilo, ihi
               CALL csscal( m, lscale( i ), v( i, 1 ), ldv )
   20       CONTINUE
         END IF
      END IF
*
*     Backward permutation
*
   30 CONTINUE
      IF( lsame( job, 'P' ) .OR. lsame( job, 'B' ) ) THEN
*
*        Backward permutation on right eigenvectors
*
         IF( rightv ) THEN
            IF( ilo.EQ.1 )
     $         GO TO 50
            DO 40 i = ilo - 1, 1, -1
               k = int( rscale( i ) )
               IF( k.EQ.i )
     $            GO TO 40
               CALL cswap( m, v( i, 1 ), ldv, v( k, 1 ), ldv )
   40       CONTINUE
*
   50       CONTINUE
            IF( ihi.EQ.n )
     $         GO TO 70
            DO 60 i = ihi + 1, n
               k = int( rscale( i ) )
               IF( k.EQ.i )
     $            GO TO 60
               CALL cswap( m, v( i, 1 ), ldv, v( k, 1 ), ldv )
   60       CONTINUE
         END IF
*
*        Backward permutation on left eigenvectors
*
   70    CONTINUE
         IF( leftv ) THEN
            IF( ilo.EQ.1 )
     $         GO TO 90
            DO 80 i = ilo - 1, 1, -1
               k = int( lscale( i ) )
               IF( k.EQ.i )
     $            GO TO 80
               CALL cswap( m, v( i, 1 ), ldv, v( k, 1 ), ldv )
   80       CONTINUE
*
   90       CONTINUE
            IF( ihi.EQ.n )
     $         GO TO 110
            DO 100 i = ihi + 1, n
               k = int( lscale( i ) )
               IF( k.EQ.i )
     $            GO TO 100
               CALL cswap( m, v( i, 1 ), ldv, v( k, 1 ), ldv )
  100       CONTINUE
         END IF
      END IF
*
  110 CONTINUE
*
      RETURN
*
*     End of CGGBAK
*

Here is the call graph for this function:

Here is the caller graph for this function: