zqrt14()

double precision function zqrt14	(	character	trans,
		integer	m,
		integer	n,
		integer	nrhs,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		complex*16, dimension( ldx, * )	x,
		integer	ldx,
		complex*16, dimension( lwork )	work,
		integer	lwork
	)

ZQRT14

Purpose:

 ZQRT14 checks whether X is in the row space of A or A'.  It does so
 by scaling both X and A such that their norms are in the range
 [sqrt(eps), 1/sqrt(eps)], then computing a QR factorization of [A,X]
 (if TRANS = 'C') or an LQ factorization of [A',X]' (if TRANS = 'N'),
 and returning the norm of the trailing triangle, scaled by
 MAX(M,N,NRHS)*eps.

Parameters

[in]	TRANS	TRANS is CHARACTER*1 = 'N': No transpose, check for X in the row space of A = 'C': Conjugate transpose, check for X in row space of A'.
[in]	M	M is INTEGER The number of rows of the matrix A.
[in]	N	N is INTEGER The number of columns of the matrix A.
[in]	NRHS	NRHS is INTEGER The number of right hand sides, i.e., the number of columns of X.
[in]	A	A is COMPLEX*16 array, dimension (LDA,N) The M-by-N matrix A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A.
[in]	X	X is COMPLEX*16 array, dimension (LDX,NRHS) If TRANS = 'N', the N-by-NRHS matrix X. IF TRANS = 'C', the M-by-NRHS matrix X.
[in]	LDX	LDX is INTEGER The leading dimension of the array X.
[out]	WORK	WORK is COMPLEX*16 array dimension (LWORK)
[in]	LWORK	LWORK is INTEGER length of workspace array required If TRANS = 'N', LWORK >= (M+NRHS)*(N+2); if TRANS = 'C', LWORK >= (N+NRHS)*(M+2).

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 114 of file zqrt14.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          TRANS
      INTEGER            LDA, LDX, LWORK, M, N, NRHS
*     ..
*     .. Array Arguments ..
      COMPLEX*16         A( LDA, * ), WORK( LWORK ), X( LDX, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d0, one = 1.0d0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            TPSD
      INTEGER            I, INFO, J, LDWORK
      DOUBLE PRECISION   ANRM, ERR, XNRM
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   RWORK( 1 )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      DOUBLE PRECISION   DLAMCH, ZLANGE
      EXTERNAL           lsame, dlamch, zlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zgelq2, zgeqr2, zlacpy, zlascl
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dconjg, max, min
*     ..
*     .. Executable Statements ..
*
      zqrt14 = zero
      IF( lsame( trans, 'N' ) ) THEN
         ldwork = m + nrhs
         tpsd = .false.
         IF( lwork.LT.( m+nrhs )*( n+2 ) ) THEN
            CALL xerbla( 'ZQRT14', 10 )
            RETURN
         ELSE IF( n.LE.0 .OR. nrhs.LE.0 ) THEN
            RETURN
         END IF
      ELSE IF( lsame( trans, 'C' ) ) THEN
         ldwork = m
         tpsd = .true.
         IF( lwork.LT.( n+nrhs )*( m+2 ) ) THEN
            CALL xerbla( 'ZQRT14', 10 )
            RETURN
         ELSE IF( m.LE.0 .OR. nrhs.LE.0 ) THEN
            RETURN
         END IF
      ELSE
         CALL xerbla( 'ZQRT14', 1 )
         RETURN
      END IF
*
*     Copy and scale A
*
      CALL zlacpy( 'All', m, n, a, lda, work, ldwork )
      anrm = zlange( 'M', m, n, work, ldwork, rwork )
      IF( anrm.NE.zero )
     $   CALL zlascl( 'G', 0, 0, anrm, one, m, n, work, ldwork, info )
*
*     Copy X or X' into the right place and scale it
*
      IF( tpsd ) THEN
*
*        Copy X into columns n+1:n+nrhs of work
*
         CALL zlacpy( 'All', m, nrhs, x, ldx, work( n*ldwork+1 ),
     $                ldwork )
         xnrm = zlange( 'M', m, nrhs, work( n*ldwork+1 ), ldwork,
     $          rwork )
         IF( xnrm.NE.zero )
     $      CALL zlascl( 'G', 0, 0, xnrm, one, m, nrhs,
     $                   work( n*ldwork+1 ), ldwork, info )
*
*        Compute QR factorization of X
*
         CALL zgeqr2( m, n+nrhs, work, ldwork,
     $                work( ldwork*( n+nrhs )+1 ),
     $                work( ldwork*( n+nrhs )+min( m, n+nrhs )+1 ),
     $                info )
*
*        Compute largest entry in upper triangle of
*        work(n+1:m,n+1:n+nrhs)
*
         err = zero
         DO 20 j = n + 1, n + nrhs
            DO 10 i = n + 1, min( m, j )
               err = max( err, abs( work( i+( j-1 )*m ) ) )
   10       CONTINUE
   20    CONTINUE
*
      ELSE
*
*        Copy X' into rows m+1:m+nrhs of work
*
         DO 40 i = 1, n
            DO 30 j = 1, nrhs
               work( m+j+( i-1 )*ldwork ) = dconjg( x( i, j ) )
   30       CONTINUE
   40    CONTINUE
*
         xnrm = zlange( 'M', nrhs, n, work( m+1 ), ldwork, rwork )
         IF( xnrm.NE.zero )
     $      CALL zlascl( 'G', 0, 0, xnrm, one, nrhs, n, work( m+1 ),
     $                   ldwork, info )
*
*        Compute LQ factorization of work
*
         CALL zgelq2( ldwork, n, work, ldwork, work( ldwork*n+1 ),
     $                work( ldwork*( n+1 )+1 ), info )
*
*        Compute largest entry in lower triangle in
*        work(m+1:m+nrhs,m+1:n)
*
         err = zero
         DO 60 j = m + 1, n
            DO 50 i = j, ldwork
               err = max( err, abs( work( i+( j-1 )*ldwork ) ) )
   50       CONTINUE
   60    CONTINUE
*
      END IF
*
      zqrt14 = err / ( dble( max( m, n, nrhs ) )*dlamch( 'Epsilon' ) )
*
      RETURN
*
*     End of ZQRT14
*

Here is the call graph for this function:

Here is the caller graph for this function: