stgsna()

subroutine stgsna	(	character	job,
		character	howmny,
		logical, dimension( * )	select,
		integer	n,
		real, dimension( lda, * )	a,
		integer	lda,
		real, dimension( ldb, * )	b,
		integer	ldb,
		real, dimension( ldvl, * )	vl,
		integer	ldvl,
		real, dimension( ldvr, * )	vr,
		integer	ldvr,
		real, dimension( * )	s,
		real, dimension( * )	dif,
		integer	mm,
		integer	m,
		real, dimension( * )	work,
		integer	lwork,
		integer, dimension( * )	iwork,
		integer	info )

STGSNA

Download STGSNA + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> STGSNA estimates reciprocal condition numbers for specified
!> eigenvalues and/or eigenvectors of a matrix pair (A, B) in
!> generalized real Schur canonical form (or of any matrix pair
!> (Q*A*Z**T, Q*B*Z**T) with orthogonal matrices Q and Z, where
!> Z**T denotes the transpose of Z.
!>
!> (A, B) must be in generalized real Schur form (as returned by SGGES),
!> i.e. A is block upper triangular with 1-by-1 and 2-by-2 diagonal
!> blocks. B is upper triangular.
!>
!> 

Parameters

[in]	JOB	!> JOB is CHARACTER*1 !> Specifies whether condition numbers are required for !> eigenvalues (S) or eigenvectors (DIF): !> = 'E': for eigenvalues only (S); !> = 'V': for eigenvectors only (DIF); !> = 'B': for both eigenvalues and eigenvectors (S and DIF). !>
[in]	HOWMNY	!> HOWMNY is CHARACTER*1 !> = 'A': compute condition numbers for all eigenpairs; !> = 'S': compute condition numbers for selected eigenpairs !> specified by the array SELECT. !>
[in]	SELECT	!> SELECT is LOGICAL array, dimension (N) !> If HOWMNY = 'S', SELECT specifies the eigenpairs for which !> condition numbers are required. To select condition numbers !> for the eigenpair corresponding to a real eigenvalue w(j), !> SELECT(j) must be set to .TRUE.. To select condition numbers !> corresponding to a complex conjugate pair of eigenvalues w(j) !> and w(j+1), either SELECT(j) or SELECT(j+1) or both, must be !> set to .TRUE.. !> If HOWMNY = 'A', SELECT is not referenced. !>
[in]	N	!> N is INTEGER !> The order of the square matrix pair (A, B). N >= 0. !>
[in]	A	!> A is REAL array, dimension (LDA,N) !> The upper quasi-triangular matrix A in the pair (A,B). !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[in]	B	!> B is REAL array, dimension (LDB,N) !> The upper triangular matrix B in the pair (A,B). !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,N). !>
[in]	VL	!> VL is REAL array, dimension (LDVL,M) !> If JOB = 'E' or 'B', VL must contain left eigenvectors of !> (A, B), corresponding to the eigenpairs specified by HOWMNY !> and SELECT. The eigenvectors must be stored in consecutive !> columns of VL, as returned by STGEVC. !> If JOB = 'V', VL is not referenced. !>
[in]	LDVL	!> LDVL is INTEGER !> The leading dimension of the array VL. LDVL >= 1. !> If JOB = 'E' or 'B', LDVL >= N. !>
[in]	VR	!> VR is REAL array, dimension (LDVR,M) !> If JOB = 'E' or 'B', VR must contain right eigenvectors of !> (A, B), corresponding to the eigenpairs specified by HOWMNY !> and SELECT. The eigenvectors must be stored in consecutive !> columns ov VR, as returned by STGEVC. !> If JOB = 'V', VR is not referenced. !>
[in]	LDVR	!> LDVR is INTEGER !> The leading dimension of the array VR. LDVR >= 1. !> If JOB = 'E' or 'B', LDVR >= N. !>
[out]	S	!> S is REAL array, dimension (MM) !> If JOB = 'E' or 'B', the reciprocal condition numbers of the !> selected eigenvalues, stored in consecutive elements of the !> array. For a complex conjugate pair of eigenvalues two !> consecutive elements of S are set to the same value. Thus !> S(j), DIF(j), and the j-th columns of VL and VR all !> correspond to the same eigenpair (but not in general the !> j-th eigenpair, unless all eigenpairs are selected). !> If JOB = 'V', S is not referenced. !>
[out]	DIF	!> DIF is REAL array, dimension (MM) !> If JOB = 'V' or 'B', the estimated reciprocal condition !> numbers of the selected eigenvectors, stored in consecutive !> elements of the array. For a complex eigenvector two !> consecutive elements of DIF are set to the same value. If !> the eigenvalues cannot be reordered to compute DIF(j), DIF(j) !> is set to 0; this can only occur when the true value would be !> very small anyway. !> If JOB = 'E', DIF is not referenced. !>
[in]	MM	!> MM is INTEGER !> The number of elements in the arrays S and DIF. MM >= M. !>
[out]	M	!> M is INTEGER !> The number of elements of the arrays S and DIF used to store !> the specified condition numbers; for each selected real !> eigenvalue one element is used, and for each selected complex !> conjugate pair of eigenvalues, two elements are used. !> If HOWMNY = 'A', M is set to N. !>
[out]	WORK	!> WORK is REAL array, dimension (MAX(1,LWORK)) !> On exit, if INFO = 0, WORK(1) returns the optimal LWORK. !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. LWORK >= max(1,N). !> If JOB = 'V' or 'B' LWORK >= 2*N*(N+2)+16. !> !> If LWORK = -1, then a workspace query is assumed; the routine !> only calculates the optimal size of the WORK array, returns !> this value as the first entry of the WORK array, and no error !> message related to LWORK is issued by XERBLA. !>
[out]	IWORK	!> IWORK is INTEGER array, dimension (N + 6) !> If JOB = 'E', IWORK is not referenced. !>
[out]	INFO	!> INFO is INTEGER !> =0: Successful exit !> <0: If INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>  The reciprocal of the condition number of a generalized eigenvalue
!>  w = (a, b) is defined as
!>
!>       S(w) = (|u**TAv|**2 + |u**TBv|**2)**(1/2) / (norm(u)*norm(v))
!>
!>  where u and v are the left and right eigenvectors of (A, B)
!>  corresponding to w; |z| denotes the absolute value of the complex
!>  number, and norm(u) denotes the 2-norm of the vector u.
!>  The pair (a, b) corresponds to an eigenvalue w = a/b (= u**TAv/u**TBv)
!>  of the matrix pair (A, B). If both a and b equal zero, then (A B) is
!>  singular and S(I) = -1 is returned.
!>
!>  An approximate error bound on the chordal distance between the i-th
!>  computed generalized eigenvalue w and the corresponding exact
!>  eigenvalue lambda is
!>
!>       chord(w, lambda) <= EPS * norm(A, B) / S(I)
!>
!>  where EPS is the machine precision.
!>
!>  The reciprocal of the condition number DIF(i) of right eigenvector u
!>  and left eigenvector v corresponding to the generalized eigenvalue w
!>  is defined as follows:
!>
!>  a) If the i-th eigenvalue w = (a,b) is real
!>
!>     Suppose U and V are orthogonal transformations such that
!>
!>              U**T*(A, B)*V  = (S, T) = ( a   *  ) ( b  *  )  1
!>                                        ( 0  S22 ),( 0 T22 )  n-1
!>                                          1  n-1     1 n-1
!>
!>     Then the reciprocal condition number DIF(i) is
!>
!>                Difl((a, b), (S22, T22)) = sigma-min( Zl ),
!>
!>     where sigma-min(Zl) denotes the smallest singular value of the
!>     2(n-1)-by-2(n-1) matrix
!>
!>         Zl = [ kron(a, In-1)  -kron(1, S22) ]
!>              [ kron(b, In-1)  -kron(1, T22) ] .
!>
!>     Here In-1 is the identity matrix of size n-1. kron(X, Y) is the
!>     Kronecker product between the matrices X and Y.
!>
!>     Note that if the default method for computing DIF(i) is wanted
!>     (see SLATDF), then the parameter DIFDRI (see below) should be
!>     changed from 3 to 4 (routine SLATDF(IJOB = 2 will be used)).
!>     See STGSYL for more details.
!>
!>  b) If the i-th and (i+1)-th eigenvalues are complex conjugate pair,
!>
!>     Suppose U and V are orthogonal transformations such that
!>
!>              U**T*(A, B)*V = (S, T) = ( S11  *   ) ( T11  *  )  2
!>                                       ( 0    S22 ),( 0    T22) n-2
!>                                         2    n-2     2    n-2
!>
!>     and (S11, T11) corresponds to the complex conjugate eigenvalue
!>     pair (w, conjg(w)). There exist unitary matrices U1 and V1 such
!>     that
!>
!>       U1**T*S11*V1 = ( s11 s12 ) and U1**T*T11*V1 = ( t11 t12 )
!>                      (  0  s22 )                    (  0  t22 )
!>
!>     where the generalized eigenvalues w = s11/t11 and
!>     conjg(w) = s22/t22.
!>
!>     Then the reciprocal condition number DIF(i) is bounded by
!>
!>         min( d1, max( 1, |real(s11)/real(s22)| )*d2 )
!>
!>     where, d1 = Difl((s11, t11), (s22, t22)) = sigma-min(Z1), where
!>     Z1 is the complex 2-by-2 matrix
!>
!>              Z1 =  [ s11  -s22 ]
!>                    [ t11  -t22 ],
!>
!>     This is done by computing (using real arithmetic) the
!>     roots of the characteristical polynomial det(Z1**T * Z1 - lambda I),
!>     where Z1**T denotes the transpose of Z1 and det(X) denotes
!>     the determinant of X.
!>
!>     and d2 is an upper bound on Difl((S11, T11), (S22, T22)), i.e. an
!>     upper bound on sigma-min(Z2), where Z2 is (2n-2)-by-(2n-2)
!>
!>              Z2 = [ kron(S11**T, In-2)  -kron(I2, S22) ]
!>                   [ kron(T11**T, In-2)  -kron(I2, T22) ]
!>
!>     Note that if the default method for computing DIF is wanted (see
!>     SLATDF), then the parameter DIFDRI (see below) should be changed
!>     from 3 to 4 (routine SLATDF(IJOB = 2 will be used)). See STGSYL
!>     for more details.
!>
!>  For each eigenvalue/vector specified by SELECT, DIF stores a
!>  Frobenius norm-based estimate of Difl.
!>
!>  An approximate error bound for the i-th computed eigenvector VL(i) or
!>  VR(i) is given by
!>
!>             EPS * norm(A, B) / DIF(i).
!>
!>  See ref. [2-3] for more details and further references.
!> 

Contributors:

Bo Kagstrom and Peter Poromaa, Department of Computing Science, Umea University, S-901 87 Umea, Sweden.

References:

!>
!>  [1] B. Kagstrom; A Direct Method for Reordering Eigenvalues in the
!>      Generalized Real Schur Form of a Regular Matrix Pair (A, B), in
!>      M.S. Moonen et al (eds), Linear Algebra for Large Scale and
!>      Real-Time Applications, Kluwer Academic Publ. 1993, pp 195-218.
!>
!>  [2] B. Kagstrom and P. Poromaa; Computing Eigenspaces with Specified
!>      Eigenvalues of a Regular Matrix Pair (A, B) and Condition
!>      Estimation: Theory, Algorithms and Software,
!>      Report UMINF - 94.04, Department of Computing Science, Umea
!>      University, S-901 87 Umea, Sweden, 1994. Also as LAPACK Working
!>      Note 87. To appear in Numerical Algorithms, 1996.
!>
!>  [3] B. Kagstrom and P. Poromaa, LAPACK-Style Algorithms and Software
!>      for Solving the Generalized Sylvester Equation and Estimating the
!>      Separation between Regular Matrix Pairs, Report UMINF - 93.23,
!>      Department of Computing Science, Umea University, S-901 87 Umea,
!>      Sweden, December 1993, Revised April 1994, Also as LAPACK Working
!>      Note 75.  To appear in ACM Trans. on Math. Software, Vol 22,
!>      No 1, 1996.
!> 

Definition at line 376 of file stgsna.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          HOWMNY, JOB
      INTEGER            INFO, LDA, LDB, LDVL, LDVR, LWORK, M, MM, N
*     ..
*     .. Array Arguments ..
      LOGICAL            SELECT( * )
      INTEGER            IWORK( * )
      REAL               A( LDA, * ), B( LDB, * ), DIF( * ), S( * ),
     $                   VL( LDVL, * ), VR( LDVR, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            DIFDRI
      parameter( difdri = 3 )
      REAL               ZERO, ONE, TWO, FOUR
      parameter( zero = 0.0e+0, one = 1.0e+0, two = 2.0e+0,
     $                   four = 4.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY, PAIR, SOMCON, WANTBH, WANTDF, WANTS
      INTEGER            I, IERR, IFST, ILST, IZ, K, KS, LWMIN, N1, N2
      REAL               ALPHAI, ALPHAR, ALPRQT, BETA, C1, C2, COND,
     $                   EPS, LNRM, RNRM, ROOT1, ROOT2, SCALE, SMLNUM,
     $                   TMPII, TMPIR, TMPRI, TMPRR, UHAV, UHAVI, UHBV,
     $                   UHBVI
*     ..
*     .. Local Arrays ..
      REAL               DUMMY( 1 ), DUMMY1( 1 )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               SDOT, SLAMCH, SLAPY2,
     $                   SNRM2, SROUNDUP_LWORK
      EXTERNAL           lsame, sdot, slamch,
     $                   slapy2, snrm2,
     $                   sroundup_lwork
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemv, slacpy, slag2,
     $                   stgexc, stgsyl, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, sqrt
*     ..
*     .. Executable Statements ..
*
*     Decode and test the input parameters
*
      wantbh = lsame( job, 'B' )
      wants = lsame( job, 'E' ) .OR. wantbh
      wantdf = lsame( job, 'V' ) .OR. wantbh
*
      somcon = lsame( howmny, 'S' )
*
      info = 0
      lquery = ( lwork.EQ.-1 )
*
      IF( .NOT.wants .AND. .NOT.wantdf ) THEN
         info = -1
      ELSE IF( .NOT.lsame( howmny, 'A' ) .AND. .NOT.somcon ) THEN
         info = -2
      ELSE IF( n.LT.0 ) THEN
         info = -4
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -6
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -8
      ELSE IF( wants .AND. ldvl.LT.n ) THEN
         info = -10
      ELSE IF( wants .AND. ldvr.LT.n ) THEN
         info = -12
      ELSE
*
*        Set M to the number of eigenpairs for which condition numbers
*        are required, and test MM.
*
         IF( somcon ) THEN
            m = 0
            pair = .false.
            DO 10 k = 1, n
               IF( pair ) THEN
                  pair = .false.
               ELSE
                  IF( k.LT.n ) THEN
                     IF( a( k+1, k ).EQ.zero ) THEN
                        IF( SELECT( k ) )
     $                     m = m + 1
                     ELSE
                        pair = .true.
                        IF( SELECT( k ) .OR. SELECT( k+1 ) )
     $                     m = m + 2
                     END IF
                  ELSE
                     IF( SELECT( n ) )
     $                  m = m + 1
                  END IF
               END IF
   10       CONTINUE
         ELSE
            m = n
         END IF
*
         IF( n.EQ.0 ) THEN
            lwmin = 1
         ELSE IF( lsame( job, 'V' ) .OR. lsame( job, 'B' ) ) THEN
            lwmin = 2*n*( n + 2 ) + 16
         ELSE
            lwmin = n
         END IF
         work( 1 ) = sroundup_lwork(lwmin)
*
         IF( mm.LT.m ) THEN
            info = -15
         ELSE IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
            info = -18
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'STGSNA', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Get machine constants
*
      eps = slamch( 'P' )
      smlnum = slamch( 'S' ) / eps
      ks = 0
      pair = .false.
*
      DO 20 k = 1, n
*
*        Determine whether A(k,k) begins a 1-by-1 or 2-by-2 block.
*
         IF( pair ) THEN
            pair = .false.
            GO TO 20
         ELSE
            IF( k.LT.n )
     $         pair = a( k+1, k ).NE.zero
         END IF
*
*        Determine whether condition numbers are required for the k-th
*        eigenpair.
*
         IF( somcon ) THEN
            IF( pair ) THEN
               IF( .NOT.SELECT( k ) .AND. .NOT.SELECT( k+1 ) )
     $            GO TO 20
            ELSE
               IF( .NOT.SELECT( k ) )
     $            GO TO 20
            END IF
         END IF
*
         ks = ks + 1
*
         IF( wants ) THEN
*
*           Compute the reciprocal condition number of the k-th
*           eigenvalue.
*
            IF( pair ) THEN
*
*              Complex eigenvalue pair.
*
               rnrm = slapy2( snrm2( n, vr( 1, ks ), 1 ),
     $                snrm2( n, vr( 1, ks+1 ), 1 ) )
               lnrm = slapy2( snrm2( n, vl( 1, ks ), 1 ),
     $                snrm2( n, vl( 1, ks+1 ), 1 ) )
               CALL sgemv( 'N', n, n, one, a, lda, vr( 1, ks ), 1,
     $                     zero,
     $                     work, 1 )
               tmprr = sdot( n, work, 1, vl( 1, ks ), 1 )
               tmpri = sdot( n, work, 1, vl( 1, ks+1 ), 1 )
               CALL sgemv( 'N', n, n, one, a, lda, vr( 1, ks+1 ), 1,
     $                     zero, work, 1 )
               tmpii = sdot( n, work, 1, vl( 1, ks+1 ), 1 )
               tmpir = sdot( n, work, 1, vl( 1, ks ), 1 )
               uhav = tmprr + tmpii
               uhavi = tmpir - tmpri
               CALL sgemv( 'N', n, n, one, b, ldb, vr( 1, ks ), 1,
     $                     zero,
     $                     work, 1 )
               tmprr = sdot( n, work, 1, vl( 1, ks ), 1 )
               tmpri = sdot( n, work, 1, vl( 1, ks+1 ), 1 )
               CALL sgemv( 'N', n, n, one, b, ldb, vr( 1, ks+1 ), 1,
     $                     zero, work, 1 )
               tmpii = sdot( n, work, 1, vl( 1, ks+1 ), 1 )
               tmpir = sdot( n, work, 1, vl( 1, ks ), 1 )
               uhbv = tmprr + tmpii
               uhbvi = tmpir - tmpri
               uhav = slapy2( uhav, uhavi )
               uhbv = slapy2( uhbv, uhbvi )
               cond = slapy2( uhav, uhbv )
               s( ks ) = cond / ( rnrm*lnrm )
               s( ks+1 ) = s( ks )
*
            ELSE
*
*              Real eigenvalue.
*
               rnrm = snrm2( n, vr( 1, ks ), 1 )
               lnrm = snrm2( n, vl( 1, ks ), 1 )
               CALL sgemv( 'N', n, n, one, a, lda, vr( 1, ks ), 1,
     $                     zero,
     $                     work, 1 )
               uhav = sdot( n, work, 1, vl( 1, ks ), 1 )
               CALL sgemv( 'N', n, n, one, b, ldb, vr( 1, ks ), 1,
     $                     zero,
     $                     work, 1 )
               uhbv = sdot( n, work, 1, vl( 1, ks ), 1 )
               cond = slapy2( uhav, uhbv )
               IF( cond.EQ.zero ) THEN
                  s( ks ) = -one
               ELSE
                  s( ks ) = cond / ( rnrm*lnrm )
               END IF
            END IF
         END IF
*
         IF( wantdf ) THEN
            IF( n.EQ.1 ) THEN
               dif( ks ) = slapy2( a( 1, 1 ), b( 1, 1 ) )
               GO TO 20
            END IF
*
*           Estimate the reciprocal condition number of the k-th
*           eigenvectors.
            IF( pair ) THEN
*
*              Copy the  2-by 2 pencil beginning at (A(k,k), B(k, k)).
*              Compute the eigenvalue(s) at position K.
*
               work( 1 ) = a( k, k )
               work( 2 ) = a( k+1, k )
               work( 3 ) = a( k, k+1 )
               work( 4 ) = a( k+1, k+1 )
               work( 5 ) = b( k, k )
               work( 6 ) = b( k+1, k )
               work( 7 ) = b( k, k+1 )
               work( 8 ) = b( k+1, k+1 )
               CALL slag2( work, 2, work( 5 ), 2, smlnum*eps, beta,
     $                     dummy1( 1 ), alphar, dummy( 1 ), alphai )
               alprqt = one
               c1 = two*( alphar*alphar+alphai*alphai+beta*beta )
               c2 = four*beta*beta*alphai*alphai
               root1 = c1 + sqrt( c1*c1-4.0*c2 )
               root1 = root1 / two
               root2 = c2 / root1
               cond = min( sqrt( root1 ), sqrt( root2 ) )
            END IF
*
*           Copy the matrix (A, B) to the array WORK and swap the
*           diagonal block beginning at A(k,k) to the (1,1) position.
*
            CALL slacpy( 'Full', n, n, a, lda, work, n )
            CALL slacpy( 'Full', n, n, b, ldb, work( n*n+1 ), n )
            ifst = k
            ilst = 1
*
            CALL stgexc( .false., .false., n, work, n, work( n*n+1 ),
     $                   n,
     $                   dummy, 1, dummy1, 1, ifst, ilst,
     $                   work( n*n*2+1 ), lwork-2*n*n, ierr )
*
            IF( ierr.GT.0 ) THEN
*
*              Ill-conditioned problem - swap rejected.
*
               dif( ks ) = zero
            ELSE
*
*              Reordering successful, solve generalized Sylvester
*              equation for R and L,
*                         A22 * R - L * A11 = A12
*                         B22 * R - L * B11 = B12,
*              and compute estimate of Difl((A11,B11), (A22, B22)).
*
               n1 = 1
               IF( work( 2 ).NE.zero )
     $            n1 = 2
               n2 = n - n1
               IF( n2.EQ.0 ) THEN
                  dif( ks ) = cond
               ELSE
                  i = n*n + 1
                  iz = 2*n*n + 1
                  CALL stgsyl( 'N', difdri, n2, n1,
     $                         work( n*n1+n1+1 ),
     $                         n, work, n, work( n1+1 ), n,
     $                         work( n*n1+n1+i ), n, work( i ), n,
     $                         work( n1+i ), n, scale, dif( ks ),
     $                         work( iz+1 ), lwork-2*n*n, iwork, ierr )
*
                  IF( pair )
     $               dif( ks ) = min( max( one, alprqt )*dif( ks ),
     $                           cond )
               END IF
            END IF
            IF( pair )
     $         dif( ks+1 ) = dif( ks )
         END IF
         IF( pair )
     $      ks = ks + 1
*
   20 CONTINUE
      work( 1 ) = sroundup_lwork(lwmin)
      RETURN
*
*     End of STGSNA
*

Here is the call graph for this function:

Here is the caller graph for this function: