sdot()

real function sdot	(	integer	n,
		real, dimension(*)	sx,
		integer	incx,
		real, dimension(*)	sy,
		integer	incy
	)

SDOT

Purpose:

    SDOT forms the dot product of two vectors.
    uses unrolled loops for increments equal to one.

Parameters

[in]	N	N is INTEGER number of elements in input vector(s)
[in]	SX	SX is REAL array, dimension ( 1 + ( N - 1 )*abs( INCX ) )
[in]	INCX	INCX is INTEGER storage spacing between elements of SX
[in]	SY	SY is REAL array, dimension ( 1 + ( N - 1 )*abs( INCY ) )
[in]	INCY	INCY is INTEGER storage spacing between elements of SY

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

     jack dongarra, linpack, 3/11/78.
     modified 12/3/93, array(1) declarations changed to array(*)

Definition at line 81 of file sdot.f.

*
*  -- Reference BLAS level1 routine --
*  -- Reference BLAS is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER INCX,INCY,N
*     ..
*     .. Array Arguments ..
      REAL SX(*),SY(*)
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      REAL STEMP
      INTEGER I,IX,IY,M,MP1
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC mod
*     ..
      stemp = 0.0e0
      sdot = 0.0e0
      IF (n.LE.0) RETURN
      IF (incx.EQ.1 .AND. incy.EQ.1) THEN
*
*        code for both increments equal to 1
*
*
*        clean-up loop
*
         m = mod(n,5)
         IF (m.NE.0) THEN
            DO i = 1,m
               stemp = stemp + sx(i)*sy(i)
            END DO
            IF (n.LT.5) THEN
               sdot=stemp
            RETURN
            END IF
         END IF
         mp1 = m + 1
         DO i = mp1,n,5
          stemp = stemp + sx(i)*sy(i) + sx(i+1)*sy(i+1) +
     $            sx(i+2)*sy(i+2) + sx(i+3)*sy(i+3) + sx(i+4)*sy(i+4)
         END DO
      ELSE
*
*        code for unequal increments or equal increments
*          not equal to 1
*
         ix = 1
         iy = 1
         IF (incx.LT.0) ix = (-n+1)*incx + 1
         IF (incy.LT.0) iy = (-n+1)*incy + 1
         DO i = 1,n
            stemp = stemp + sx(ix)*sy(iy)
            ix = ix + incx
            iy = iy + incy
         END DO
      END IF
      sdot = stemp
      RETURN
*
*     End of SDOT
*

Here is the call graph for this function:

Here is the caller graph for this function: