slag2()

subroutine slag2	(	real, dimension( lda, * )	a,
		integer	lda,
		real, dimension( ldb, * )	b,
		integer	ldb,
		real	safmin,
		real	scale1,
		real	scale2,
		real	wr1,
		real	wr2,
		real	wi )

SLAG2 computes the eigenvalues of a 2-by-2 generalized eigenvalue problem, with scaling as necessary to avoid over-/underflow.

Download SLAG2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> SLAG2 computes the eigenvalues of a 2 x 2 generalized eigenvalue
!> problem  A - w B, with scaling as necessary to avoid over-/underflow.
!>
!> The scaling factor  results in a modified eigenvalue equation
!>
!>     s A - w B
!>
!> where  s  is a non-negative scaling factor chosen so that  w,  w B,
!> and  s A  do not overflow and, if possible, do not underflow, either.
!> 

Parameters

[in]	A	!> A is REAL array, dimension (LDA, 2) !> On entry, the 2 x 2 matrix A. It is assumed that its 1-norm !> is less than 1/SAFMIN. Entries less than !> sqrt(SAFMIN)*norm(A) are subject to being treated as zero. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= 2. !>
[in]	B	!> B is REAL array, dimension (LDB, 2) !> On entry, the 2 x 2 upper triangular matrix B. It is !> assumed that the one-norm of B is less than 1/SAFMIN. The !> diagonals should be at least sqrt(SAFMIN) times the largest !> element of B (in absolute value); if a diagonal is smaller !> than that, then +/- sqrt(SAFMIN) will be used instead of !> that diagonal. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= 2. !>
[in]	SAFMIN	!> SAFMIN is REAL !> The smallest positive number s.t. 1/SAFMIN does not !> overflow. (This should always be SLAMCH('S') -- it is an !> argument in order to avoid having to call SLAMCH frequently.) !>
[out]	SCALE1	!> SCALE1 is REAL !> A scaling factor used to avoid over-/underflow in the !> eigenvalue equation which defines the first eigenvalue. If !> the eigenvalues are complex, then the eigenvalues are !> ( WR1 +/- WI i ) / SCALE1 (which may lie outside the !> exponent range of the machine), SCALE1=SCALE2, and SCALE1 !> will always be positive. If the eigenvalues are real, then !> the first (real) eigenvalue is WR1 / SCALE1 , but this may !> overflow or underflow, and in fact, SCALE1 may be zero or !> less than the underflow threshold if the exact eigenvalue !> is sufficiently large. !>
[out]	SCALE2	!> SCALE2 is REAL !> A scaling factor used to avoid over-/underflow in the !> eigenvalue equation which defines the second eigenvalue. If !> the eigenvalues are complex, then SCALE2=SCALE1. If the !> eigenvalues are real, then the second (real) eigenvalue is !> WR2 / SCALE2 , but this may overflow or underflow, and in !> fact, SCALE2 may be zero or less than the underflow !> threshold if the exact eigenvalue is sufficiently large. !>
[out]	WR1	!> WR1 is REAL !> If the eigenvalue is real, then WR1 is SCALE1 times the !> eigenvalue closest to the (2,2) element of A B**(-1). If the !> eigenvalue is complex, then WR1=WR2 is SCALE1 times the real !> part of the eigenvalues. !>
[out]	WR2	!> WR2 is REAL !> If the eigenvalue is real, then WR2 is SCALE2 times the !> other eigenvalue. If the eigenvalue is complex, then !> WR1=WR2 is SCALE1 times the real part of the eigenvalues. !>
[out]	WI	!> WI is REAL !> If the eigenvalue is real, then WI is zero. If the !> eigenvalue is complex, then WI is SCALE1 times the imaginary !> part of the eigenvalues. WI will always be non-negative. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 152 of file slag2.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LDB
      REAL               SAFMIN, SCALE1, SCALE2, WI, WR1, WR2
*     ..
*     .. Array Arguments ..
      REAL               A( LDA, * ), B( LDB, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE, TWO
      parameter( zero = 0.0e+0, one = 1.0e+0, two = 2.0e+0 )
      REAL               HALF
      parameter( half = one / two )
      REAL               FUZZY1
      parameter( fuzzy1 = one+1.0e-5 )
*     ..
*     .. Local Scalars ..
      REAL               A11, A12, A21, A22, ABI22, ANORM, AS11, AS12,
     $                   AS22, ASCALE, B11, B12, B22, BINV11, BINV22,
     $                   BMIN, BNORM, BSCALE, BSIZE, C1, C2, C3, C4, C5,
     $                   DIFF, DISCR, PP, QQ, R, RTMAX, RTMIN, S1, S2,
     $                   SAFMAX, SHIFT, SS, SUM, WABS, WBIG, WDET,
     $                   WSCALE, WSIZE, WSMALL
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min, sign, sqrt
*     ..
*     .. Executable Statements ..
*
      rtmin = sqrt( safmin )
      rtmax = one / rtmin
      safmax = one / safmin
*
*     Scale A
*
      anorm = max( abs( a( 1, 1 ) )+abs( a( 2, 1 ) ),
     $        abs( a( 1, 2 ) )+abs( a( 2, 2 ) ), safmin )
      ascale = one / anorm
      a11 = ascale*a( 1, 1 )
      a21 = ascale*a( 2, 1 )
      a12 = ascale*a( 1, 2 )
      a22 = ascale*a( 2, 2 )
*
*     Perturb B if necessary to insure non-singularity
*
      b11 = b( 1, 1 )
      b12 = b( 1, 2 )
      b22 = b( 2, 2 )
      bmin = rtmin*max( abs( b11 ), abs( b12 ), abs( b22 ), rtmin )
      IF( abs( b11 ).LT.bmin )
     $   b11 = sign( bmin, b11 )
      IF( abs( b22 ).LT.bmin )
     $   b22 = sign( bmin, b22 )
*
*     Scale B
*
      bnorm = max( abs( b11 ), abs( b12 )+abs( b22 ), safmin )
      bsize = max( abs( b11 ), abs( b22 ) )
      bscale = one / bsize
      b11 = b11*bscale
      b12 = b12*bscale
      b22 = b22*bscale
*
*     Compute larger eigenvalue by method described by C. van Loan
*
*     ( AS is A shifted by -SHIFT*B )
*
      binv11 = one / b11
      binv22 = one / b22
      s1 = a11*binv11
      s2 = a22*binv22
      IF( abs( s1 ).LE.abs( s2 ) ) THEN
         as12 = a12 - s1*b12
         as22 = a22 - s1*b22
         ss = a21*( binv11*binv22 )
         abi22 = as22*binv22 - ss*b12
         pp = half*abi22
         shift = s1
      ELSE
         as12 = a12 - s2*b12
         as11 = a11 - s2*b11
         ss = a21*( binv11*binv22 )
         abi22 = -ss*b12
         pp = half*( as11*binv11+abi22 )
         shift = s2
      END IF
      qq = ss*as12
      IF( abs( pp*rtmin ).GE.one ) THEN
         discr = ( rtmin*pp )**2 + qq*safmin
         r = sqrt( abs( discr ) )*rtmax
      ELSE
         IF( pp**2+abs( qq ).LE.safmin ) THEN
            discr = ( rtmax*pp )**2 + qq*safmax
            r = sqrt( abs( discr ) )*rtmin
         ELSE
            discr = pp**2 + qq
            r = sqrt( abs( discr ) )
         END IF
      END IF
*
*     Note: the test of R in the following IF is to cover the case when
*           DISCR is small and negative and is flushed to zero during
*           the calculation of R.  On machines which have a consistent
*           flush-to-zero threshold and handle numbers above that
*           threshold correctly, it would not be necessary.
*
      IF( discr.GE.zero .OR. r.EQ.zero ) THEN
         sum = pp + sign( r, pp )
         diff = pp - sign( r, pp )
         wbig = shift + sum
*
*        Compute smaller eigenvalue
*
         wsmall = shift + diff
         IF( half*abs( wbig ).GT.max( abs( wsmall ), safmin ) ) THEN
            wdet = ( a11*a22-a12*a21 )*( binv11*binv22 )
            wsmall = wdet / wbig
         END IF
*
*        Choose (real) eigenvalue closest to 2,2 element of A*B**(-1)
*        for WR1.
*
         IF( pp.GT.abi22 ) THEN
            wr1 = min( wbig, wsmall )
            wr2 = max( wbig, wsmall )
         ELSE
            wr1 = max( wbig, wsmall )
            wr2 = min( wbig, wsmall )
         END IF
         wi = zero
      ELSE
*
*        Complex eigenvalues
*
         wr1 = shift + pp
         wr2 = wr1
         wi = r
      END IF
*
*     Further scaling to avoid underflow and overflow in computing
*     SCALE1 and overflow in computing w*B.
*
*     This scale factor (WSCALE) is bounded from above using C1 and C2,
*     and from below using C3 and C4.
*        C1 implements the condition  s A  must never overflow.
*        C2 implements the condition  w B  must never overflow.
*        C3, with C2,
*           implement the condition that s A - w B must never overflow.
*        C4 implements the condition  s    should not underflow.
*        C5 implements the condition  max(s,|w|) should be at least 2.
*
      c1 = bsize*( safmin*max( one, ascale ) )
      c2 = safmin*max( one, bnorm )
      c3 = bsize*safmin
      IF( ascale.LE.one .AND. bsize.LE.one ) THEN
         c4 = min( one, ( ascale / safmin )*bsize )
      ELSE
         c4 = one
      END IF
      IF( ascale.LE.one .OR. bsize.LE.one ) THEN
         c5 = min( one, ascale*bsize )
      ELSE
         c5 = one
      END IF
*
*     Scale first eigenvalue
*
      wabs = abs( wr1 ) + abs( wi )
      wsize = max( safmin, c1, fuzzy1*( wabs*c2+c3 ),
     $        min( c4, half*max( wabs, c5 ) ) )
      IF( wsize.NE.one ) THEN
         wscale = one / wsize
         IF( wsize.GT.one ) THEN
            scale1 = ( max( ascale, bsize )*wscale )*
     $               min( ascale, bsize )
         ELSE
            scale1 = ( min( ascale, bsize )*wscale )*
     $               max( ascale, bsize )
         END IF
         wr1 = wr1*wscale
         IF( wi.NE.zero ) THEN
            wi = wi*wscale
            wr2 = wr1
            scale2 = scale1
         END IF
      ELSE
         scale1 = ascale*bsize
         scale2 = scale1
      END IF
*
*     Scale second eigenvalue (if real)
*
      IF( wi.EQ.zero ) THEN
         wsize = max( safmin, c1, fuzzy1*( abs( wr2 )*c2+c3 ),
     $           min( c4, half*max( abs( wr2 ), c5 ) ) )
         IF( wsize.NE.one ) THEN
            wscale = one / wsize
            IF( wsize.GT.one ) THEN
               scale2 = ( max( ascale, bsize )*wscale )*
     $                  min( ascale, bsize )
            ELSE
               scale2 = ( min( ascale, bsize )*wscale )*
     $                  max( ascale, bsize )
            END IF
            wr2 = wr2*wscale
         ELSE
            scale2 = ascale*bsize
         END IF
      END IF
*
*     End of SLAG2
*
      RETURN

Here is the caller graph for this function: