dqpt01()

double precision function dqpt01	(	integer	m,
		integer	n,
		integer	k,
		double precision, dimension( lda, * )	a,
		double precision, dimension( lda, * )	af,
		integer	lda,
		double precision, dimension( * )	tau,
		integer, dimension( * )	jpvt,
		double precision, dimension( lwork )	work,
		integer	lwork )

DQPT01

Purpose:

!>
!> DQPT01 tests the QR-factorization with pivoting of a matrix A.  The
!> array AF contains the (possibly partial) QR-factorization of A, where
!> the upper triangle of AF(1:K,1:K) is a partial triangular factor,
!> the entries below the diagonal in the first K columns are the
!> Householder vectors, and the rest of AF contains a partially updated
!> matrix.
!>
!> This function returns ||A*P - Q*R|| / ( ||norm(A)||*eps*max(M,N) ),
!> where || . || is matrix one norm.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrices A and AF. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrices A and AF. !>
[in]	K	!> K is INTEGER !> The number of columns of AF that have been reduced !> to upper triangular form. !>
[in]	A	!> A is DOUBLE PRECISION array, dimension (LDA, N) !> The original matrix A. !>
[in]	AF	!> AF is DOUBLE PRECISION array, dimension (LDA,N) !> The (possibly partial) output of DGEQPF. The upper triangle !> of AF(1:k,1:k) is a partial triangular factor, the entries !> below the diagonal in the first k columns are the Householder !> vectors, and the rest of AF contains a partially updated !> matrix. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the arrays A and AF. !>
[in]	TAU	!> TAU is DOUBLE PRECISION array, dimension (K) !> Details of the Householder transformations as returned by !> DGEQPF. !>
[in]	JPVT	!> JPVT is INTEGER array, dimension (N) !> Pivot information as returned by DGEQPF. !>
[out]	WORK	!> WORK is DOUBLE PRECISION array, dimension (LWORK) !>
[in]	LWORK	!> LWORK is INTEGER !> The length of the array WORK. LWORK >= M*N+N. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 119 of file dqpt01.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            K, LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      INTEGER            JPVT( * )
      DOUBLE PRECISION   A( LDA, * ), AF( LDA, * ), TAU( * ),
     $                   WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d0, one = 1.0d0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, INFO, J
      DOUBLE PRECISION   NORMA
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   RWORK( 1 )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, DLANGE
      EXTERNAL           dlamch, dlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           daxpy, dcopy, dormqr, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max, min
*     ..
*     .. Executable Statements ..
*
      dqpt01 = zero
*
*     Test if there is enough workspace
*
      IF( lwork.LT.m*n+n ) THEN
         CALL xerbla( 'DQPT01', 10 )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.LE.0 .OR. n.LE.0 )
     $   RETURN
*
      norma = dlange( 'One-norm', m, n, a, lda, rwork )
*
      DO j = 1, k
*
*        Copy the upper triangular part of the factor R stored
*        in AF(1:K,1:K) into the work array WORK.
*
         DO i = 1, min( j, m )
            work( ( j-1 )*m+i ) = af( i, j )
         END DO
*
*        Zero out the elements below the diagonal in the work array.
*
         DO i = j + 1, m
            work( ( j-1 )*m+i ) = zero
         END DO
      END DO
*
*     Copy columns (K+1,N) from AF into the work array WORK.
*     AF(1:K,K+1:N) contains the rectangular block of the upper trapezoidal
*     factor R, AF(K+1:M,K+1:N) contains the partially updated residual
*     matrix of R.
*
      DO j = k + 1, n
         CALL dcopy( m, af( 1, j ), 1, work( ( j-1 )*m+1 ), 1 )
      END DO
*
      CALL dormqr( 'Left', 'No transpose', m, n, k, af, lda, tau, work,
     $             m, work( m*n+1 ), lwork-m*n, info )
*
      DO j = 1, n
*
*        Compare J-th column of QR and JPVT(J)-th column of A.
*
         CALL daxpy( m, -one, a( 1, jpvt( j ) ), 1, work( ( j-1 )*m+1 ),
     $               1 )
      END DO
*
      dqpt01 = dlange( 'One-norm', m, n, work, m, rwork ) /
     $         ( dble( max( m, n ) )*dlamch( 'Epsilon' ) )
      IF( norma.NE.zero )
     $   dqpt01 = dqpt01 / norma
*
      RETURN
*
*     End of DQPT01
*

Here is the call graph for this function:

Here is the caller graph for this function: