dlaqz0.f

Go to the documentation of this file.

*> \brief \b DLAQZ0
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download DLAQZ0 + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dlaqz0.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dlaqz0.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dlaqz0.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*     RECURSIVE SUBROUTINE DLAQZ0( WANTS, WANTQ, WANTZ, N, ILO, IHI, A,
*    $                             LDA, B, LDB, ALPHAR, ALPHAI, BETA,
*    $                             Q, LDQ, Z, LDZ, WORK, LWORK, REC,
*    $                             INFO )
*     IMPLICIT NONE
*
*     Arguments
*     CHARACTER, INTENT( IN ) :: WANTS, WANTQ, WANTZ
*     INTEGER, INTENT( IN ) :: N, ILO, IHI, LDA, LDB, LDQ, LDZ, LWORK,
*    $         REC
*
*     INTEGER, INTENT( OUT ) :: INFO
*
*     DOUBLE PRECISION, INTENT( INOUT ) :: A( LDA, * ), B( LDB, * ),
*    $                  Q( LDQ, * ), Z( LDZ, * ), ALPHAR( * ),
*    $                  ALPHAI( * ), BETA( * ), WORK( * )
*      ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DLAQZ0 computes the eigenvalues of a real matrix pair (H,T),
*> where H is an upper Hessenberg matrix and T is upper triangular,
*> using the double-shift QZ method.
*> Matrix pairs of this type are produced by the reduction to
*> generalized upper Hessenberg form of a real matrix pair (A,B):
*>
*>    A = Q1*H*Z1**T,  B = Q1*T*Z1**T,
*>
*> as computed by DGGHRD.
*>
*> If JOB='S', then the Hessenberg-triangular pair (H,T) is
*> also reduced to generalized Schur form,
*>
*>    H = Q*S*Z**T,  T = Q*P*Z**T,
*>
*> where Q and Z are orthogonal matrices, P is an upper triangular
*> matrix, and S is a quasi-triangular matrix with 1-by-1 and 2-by-2
*> diagonal blocks.
*>
*> The 1-by-1 blocks correspond to real eigenvalues of the matrix pair
*> (H,T) and the 2-by-2 blocks correspond to complex conjugate pairs of
*> eigenvalues.
*>
*> Additionally, the 2-by-2 upper triangular diagonal blocks of P
*> corresponding to 2-by-2 blocks of S are reduced to positive diagonal
*> form, i.e., if S(j+1,j) is non-zero, then P(j+1,j) = P(j,j+1) = 0,
*> P(j,j) > 0, and P(j+1,j+1) > 0.
*>
*> Optionally, the orthogonal matrix Q from the generalized Schur
*> factorization may be postmultiplied into an input matrix Q1, and the
*> orthogonal matrix Z may be postmultiplied into an input matrix Z1.
*> If Q1 and Z1 are the orthogonal matrices from DGGHRD that reduced
*> the matrix pair (A,B) to generalized upper Hessenberg form, then the
*> output matrices Q1*Q and Z1*Z are the orthogonal factors from the
*> generalized Schur factorization of (A,B):
*>
*>    A = (Q1*Q)*S*(Z1*Z)**T,  B = (Q1*Q)*P*(Z1*Z)**T.
*>
*> To avoid overflow, eigenvalues of the matrix pair (H,T) (equivalently,
*> of (A,B)) are computed as a pair of values (alpha,beta), where alpha is
*> complex and beta real.
*> If beta is nonzero, lambda = alpha / beta is an eigenvalue of the
*> generalized nonsymmetric eigenvalue problem (GNEP)
*>    A*x = lambda*B*x
*> and if alpha is nonzero, mu = beta / alpha is an eigenvalue of the
*> alternate form of the GNEP
*>    mu*A*y = B*y.
*> Real eigenvalues can be read directly from the generalized Schur
*> form:
*>   alpha = S(i,i), beta = P(i,i).
*>
*> Ref: C.B. Moler & G.W. Stewart, "An Algorithm for Generalized Matrix
*>      Eigenvalue Problems", SIAM J. Numer. Anal., 10(1973),
*>      pp. 241--256.
*>
*> Ref: B. Kagstrom, D. Kressner, "Multishift Variants of the QZ
*>      Algorithm with Aggressive Early Deflation", SIAM J. Numer.
*>      Anal., 29(2006), pp. 199--227.
*>
*> Ref: T. Steel, D. Camps, K. Meerbergen, R. Vandebril "A multishift,
*>      multipole rational QZ method with agressive early deflation"
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] WANTS
*> \verbatim
*>          WANTS is CHARACTER*1
*>          = 'E': Compute eigenvalues only;
*>          = 'S': Compute eigenvalues and the Schur form.
*> \endverbatim
*>
*> \param[in] WANTQ
*> \verbatim
*>          WANTQ is CHARACTER*1
*>          = 'N': Left Schur vectors (Q) are not computed;
*>          = 'I': Q is initialized to the unit matrix and the matrix Q
*>                 of left Schur vectors of (A,B) is returned;
*>          = 'V': Q must contain an orthogonal matrix Q1 on entry and
*>                 the product Q1*Q is returned.
*> \endverbatim
*>
*> \param[in] WANTZ
*> \verbatim
*>          WANTZ is CHARACTER*1
*>          = 'N': Right Schur vectors (Z) are not computed;
*>          = 'I': Z is initialized to the unit matrix and the matrix Z
*>                 of right Schur vectors of (A,B) is returned;
*>          = 'V': Z must contain an orthogonal matrix Z1 on entry and
*>                 the product Z1*Z is returned.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the matrices A, B, Q, and Z.  N >= 0.
*> \endverbatim
*>
*> \param[in] ILO
*> \verbatim
*>          ILO is INTEGER
*> \endverbatim
*>
*> \param[in] IHI
*> \verbatim
*>          IHI is INTEGER
*>          ILO and IHI mark the rows and columns of A which are in
*>          Hessenberg form.  It is assumed that A is already upper
*>          triangular in rows and columns 1:ILO-1 and IHI+1:N.
*>          If N > 0, 1 <= ILO <= IHI <= N; if N = 0, ILO=1 and IHI=0.
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*>          A is DOUBLE PRECISION array, dimension (LDA, N)
*>          On entry, the N-by-N upper Hessenberg matrix A.
*>          On exit, if JOB = 'S', A contains the upper quasi-triangular
*>          matrix S from the generalized Schur factorization.
*>          If JOB = 'E', the diagonal blocks of A match those of S, but
*>          the rest of A is unspecified.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max( 1, N ).
*> \endverbatim
*>
*> \param[in,out] B
*> \verbatim
*>          B is DOUBLE PRECISION array, dimension (LDB, N)
*>          On entry, the N-by-N upper triangular matrix B.
*>          On exit, if JOB = 'S', B contains the upper triangular
*>          matrix P from the generalized Schur factorization;
*>          2-by-2 diagonal blocks of P corresponding to 2-by-2 blocks of S
*>          are reduced to positive diagonal form, i.e., if A(j+1,j) is
*>          non-zero, then B(j+1,j) = B(j,j+1) = 0, B(j,j) > 0, and
*>          B(j+1,j+1) > 0.
*>          If JOB = 'E', the diagonal blocks of B match those of P, but
*>          the rest of B is unspecified.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of the array B.  LDB >= max( 1, N ).
*> \endverbatim
*>
*> \param[out] ALPHAR
*> \verbatim
*>          ALPHAR is DOUBLE PRECISION array, dimension (N)
*>          The real parts of each scalar alpha defining an eigenvalue
*>          of GNEP.
*> \endverbatim
*>
*> \param[out] ALPHAI
*> \verbatim
*>          ALPHAI is DOUBLE PRECISION array, dimension (N)
*>          The imaginary parts of each scalar alpha defining an
*>          eigenvalue of GNEP.
*>          If ALPHAI(j) is zero, then the j-th eigenvalue is real; if
*>          positive, then the j-th and (j+1)-st eigenvalues are a
*>          complex conjugate pair, with ALPHAI(j+1) = -ALPHAI(j).
*> \endverbatim
*>
*> \param[out] BETA
*> \verbatim
*>          BETA is DOUBLE PRECISION array, dimension (N)
*>          The scalars beta that define the eigenvalues of GNEP.
*>          Together, the quantities alpha = (ALPHAR(j),ALPHAI(j)) and
*>          beta = BETA(j) represent the j-th eigenvalue of the matrix
*>          pair (A,B), in one of the forms lambda = alpha/beta or
*>          mu = beta/alpha.  Since either lambda or mu may overflow,
*>          they should not, in general, be computed.
*> \endverbatim
*>
*> \param[in,out] Q
*> \verbatim
*>          Q is DOUBLE PRECISION array, dimension (LDQ, N)
*>          On entry, if COMPQ = 'V', the orthogonal matrix Q1 used in
*>          the reduction of (A,B) to generalized Hessenberg form.
*>          On exit, if COMPQ = 'I', the orthogonal matrix of left Schur
*>          vectors of (A,B), and if COMPQ = 'V', the orthogonal matrix
*>          of left Schur vectors of (A,B).
*>          Not referenced if COMPQ = 'N'.
*> \endverbatim
*>
*> \param[in] LDQ
*> \verbatim
*>          LDQ is INTEGER
*>          The leading dimension of the array Q.  LDQ >= 1.
*>          If COMPQ='V' or 'I', then LDQ >= N.
*> \endverbatim
*>
*> \param[in,out] Z
*> \verbatim
*>          Z is DOUBLE PRECISION array, dimension (LDZ, N)
*>          On entry, if COMPZ = 'V', the orthogonal matrix Z1 used in
*>          the reduction of (A,B) to generalized Hessenberg form.
*>          On exit, if COMPZ = 'I', the orthogonal matrix of
*>          right Schur vectors of (H,T), and if COMPZ = 'V', the
*>          orthogonal matrix of right Schur vectors of (A,B).
*>          Not referenced if COMPZ = 'N'.
*> \endverbatim
*>
*> \param[in] LDZ
*> \verbatim
*>          LDZ is INTEGER
*>          The leading dimension of the array Z.  LDZ >= 1.
*>          If COMPZ='V' or 'I', then LDZ >= N.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK))
*>          On exit, if INFO >= 0, WORK(1) returns the optimal LWORK.
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The dimension of the array WORK.  LWORK >= max(1,N).
*>
*>          If LWORK = -1, then a workspace query is assumed; the routine
*>          only calculates the optimal size of the WORK array, returns
*>          this value as the first entry of the WORK array, and no error
*>          message related to LWORK is issued by XERBLA.
*> \endverbatim
*>
*> \param[in] REC
*> \verbatim
*>          REC is INTEGER
*>             REC indicates the current recursion level. Should be set
*>             to 0 on first call.
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0: successful exit
*>          < 0: if INFO = -i, the i-th argument had an illegal value
*>          = 1,...,N: the QZ iteration did not converge.  (A,B) is not
*>                     in Schur form, but ALPHAR(i), ALPHAI(i), and
*>                     BETA(i), i=INFO+1,...,N should be correct.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Thijs Steel, KU Leuven
*
*> \date May 2020
*
*> \ingroup doubleGEcomputational
*>
*  =====================================================================
      RECURSIVE SUBROUTINE dlaqz0( WANTS, WANTQ, WANTZ, N, ILO, IHI, A,
     $                             LDA, B, LDB, ALPHAR, ALPHAI, BETA,
     $                             Q, LDQ, Z, LDZ, WORK, LWORK, REC,
     $                             INFO )
      IMPLICIT NONE
 
*     Arguments
      CHARACTER, INTENT( IN ) :: wants, wantq, wantz
      INTEGER, INTENT( IN ) :: n, ilo, ihi, lda, ldb, ldq, ldz, lwork,
     $         rec
 
      INTEGER, INTENT( OUT ) :: info
 
      DOUBLE PRECISION, INTENT( INOUT ) :: a( lda, * ), b( ldb, * ),
     $                  q( ldq, * ), z( ldz, * ), alphar( * ),
     $                  alphai( * ), beta( * ), work( * )
 
*     Parameters
      DOUBLE PRECISION :: zero, one, half
      PARAMETER( zero = 0.0d0, one = 1.0d0, half = 0.5d0 )
 
*     Local scalars
      DOUBLE PRECISION :: smlnum, ulp, eshift, safmin, safmax, c1, s1,
     $                    temp, swap, bnorm, btol
      INTEGER :: istart, istop, iiter, maxit, istart2, k, ld, nshifts,
     $           nblock, nw, nmin, nibble, n_undeflated, n_deflated,
     $           ns, sweep_info, shiftpos, lworkreq, k2, istartm,
     $           istopm, iwants, iwantq, iwantz, norm_info, aed_info,
     $           nwr, nbr, nsr, itemp1, itemp2, rcost, i
      LOGICAL :: ilschur, ilq, ilz
      CHARACTER :: jbcmpz*3
 
*     External Functions
      EXTERNAL :: xerbla, dhgeqz, dlaset, dlaqz3, dlaqz4, dlabad,
     $            dlartg, drot
      DOUBLE PRECISION, EXTERNAL :: dlamch, dlanhs
      LOGICAL, EXTERNAL :: lsame
      INTEGER, EXTERNAL :: ilaenv
 
*
*     Decode wantS,wantQ,wantZ
*      
      IF( lsame( wants, 'E' ) ) THEN
         ilschur = .false.
         iwants = 1
      ELSE IF( lsame( wants, 'S' ) ) THEN
         ilschur = .true.
         iwants = 2
      ELSE
         iwants = 0
      END IF
 
      IF( lsame( wantq, 'N' ) ) THEN
         ilq = .false.
         iwantq = 1
      ELSE IF( lsame( wantq, 'V' ) ) THEN
         ilq = .true.
         iwantq = 2
      ELSE IF( lsame( wantq, 'I' ) ) THEN
         ilq = .true.
         iwantq = 3
      ELSE
         iwantq = 0
      END IF
 
      IF( lsame( wantz, 'N' ) ) THEN
         ilz = .false.
         iwantz = 1
      ELSE IF( lsame( wantz, 'V' ) ) THEN
         ilz = .true.
         iwantz = 2
      ELSE IF( lsame( wantz, 'I' ) ) THEN
         ilz = .true.
         iwantz = 3
      ELSE
         iwantz = 0
      END IF
*
*     Check Argument Values
*
      info = 0
      IF( iwants.EQ.0 ) THEN
         info = -1
      ELSE IF( iwantq.EQ.0 ) THEN
         info = -2
      ELSE IF( iwantz.EQ.0 ) THEN
         info = -3
      ELSE IF( n.LT.0 ) THEN
         info = -4
      ELSE IF( ilo.LT.1 ) THEN
         info = -5
      ELSE IF( ihi.GT.n .OR. ihi.LT.ilo-1 ) THEN
         info = -6
      ELSE IF( lda.LT.n ) THEN
         info = -8
      ELSE IF( ldb.LT.n ) THEN
         info = -10
      ELSE IF( ldq.LT.1 .OR. ( ilq .AND. ldq.LT.n ) ) THEN
         info = -15
      ELSE IF( ldz.LT.1 .OR. ( ilz .AND. ldz.LT.n ) ) THEN
         info = -17
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DLAQZ0', -info )
         RETURN
      END IF
   
*
*     Quick return if possible
*
      IF( n.LE.0 ) THEN
         work( 1 ) = dble( 1 )
         RETURN
      END IF
 
*
*     Get the parameters
*
      jbcmpz( 1:1 ) = wants
      jbcmpz( 2:2 ) = wantq
      jbcmpz( 3:3 ) = wantz
 
      nmin = ilaenv( 12, 'DLAQZ0', jbcmpz, n, ilo, ihi, lwork )
 
      nwr = ilaenv( 13, 'DLAQZ0', jbcmpz, n, ilo, ihi, lwork )
      nwr = max( 2, nwr )
      nwr = min( ihi-ilo+1, ( n-1 ) / 3, nwr )
 
      nibble = ilaenv( 14, 'DLAQZ0', jbcmpz, n, ilo, ihi, lwork )
      
      nsr = ilaenv( 15, 'DLAQZ0', jbcmpz, n, ilo, ihi, lwork )
      nsr = min( nsr, ( n+6 ) / 9, ihi-ilo )
      nsr = max( 2, nsr-mod( nsr, 2 ) )
 
      rcost = ilaenv( 17, 'DLAQZ0', jbcmpz, n, ilo, ihi, lwork )
      itemp1 = int( nsr/sqrt( 1+2*nsr/( dble( rcost )/100*n ) ) )
      itemp1 = ( ( itemp1-1 )/4 )*4+4
      nbr = nsr+itemp1
 
      IF( n .LT. nmin .OR. rec .GE. 2 ) THEN
         CALL dhgeqz( wants, wantq, wantz, n, ilo, ihi, a, lda, b, ldb,
     $                alphar, alphai, beta, q, ldq, z, ldz, work,
     $                lwork, info )
         RETURN
      END IF
 
*
*     Find out required workspace
*
 
*     Workspace query to dlaqz3
      nw = max( nwr, nmin )
      CALL dlaqz3( ilschur, ilq, ilz, n, ilo, ihi, nw, a, lda, b, ldb,
     $             q, ldq, z, ldz, n_undeflated, n_deflated, alphar,
     $             alphai, beta, work, nw, work, nw, work, -1, rec,
     $             aed_info )
      itemp1 = int( work( 1 ) )
*     Workspace query to dlaqz4
      CALL dlaqz4( ilschur, ilq, ilz, n, ilo, ihi, nsr, nbr, alphar,
     $             alphai, beta, a, lda, b, ldb, q, ldq, z, ldz, work,
     $             nbr, work, nbr, work, -1, sweep_info )
      itemp2 = int( work( 1 ) )
 
      lworkreq = max( itemp1+2*nw**2, itemp2+2*nbr**2 )
      IF ( lwork .EQ.-1 ) THEN
         work( 1 ) = dble( lworkreq )
         RETURN
      ELSE IF ( lwork .LT. lworkreq ) THEN
         info = -19
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DLAQZ0', info )
         RETURN
      END IF
*
*     Initialize Q and Z
*
      IF( iwantq.EQ.3 ) CALL dlaset( 'FULL', n, n, zero, one, q, ldq )
      IF( iwantz.EQ.3 ) CALL dlaset( 'FULL', n, n, zero, one, z, ldz )
 
*     Get machine constants
      safmin = dlamch( 'SAFE MINIMUM' )
      safmax = one/safmin
      CALL dlabad( safmin, safmax )
      ulp = dlamch( 'PRECISION' )
      smlnum = safmin*( dble( n )/ulp )
 
      bnorm = dlanhs( 'F', ihi-ilo+1, b( ilo, ilo ), ldb, work )
      btol = max( safmin, ulp*bnorm )
 
      istart = ilo
      istop = ihi
      maxit = 3*( ihi-ilo+1 )
      ld = 0
 
      DO iiter = 1, maxit
         IF( iiter .GE. maxit ) THEN
            info = istop+1
            GOTO 80
         END IF
         IF ( istart+1 .GE. istop ) THEN
            istop = istart
            EXIT
         END IF
 
*        Check deflations at the end
         IF ( abs( a( istop-1, istop-2 ) ) .LE. max( smlnum,
     $      ulp*( abs( a( istop-1, istop-1 ) )+abs( a( istop-2,
     $      istop-2 ) ) ) ) ) THEN
            a( istop-1, istop-2 ) = zero
            istop = istop-2
            ld = 0
            eshift = zero
         ELSE IF ( abs( a( istop, istop-1 ) ) .LE. max( smlnum,
     $      ulp*( abs( a( istop, istop ) )+abs( a( istop-1,
     $      istop-1 ) ) ) ) ) THEN
            a( istop, istop-1 ) = zero
            istop = istop-1
            ld = 0
            eshift = zero
         END IF
*        Check deflations at the start
         IF ( abs( a( istart+2, istart+1 ) ) .LE. max( smlnum,
     $      ulp*( abs( a( istart+1, istart+1 ) )+abs( a( istart+2,
     $      istart+2 ) ) ) ) ) THEN
            a( istart+2, istart+1 ) = zero
            istart = istart+2
            ld = 0
            eshift = zero
         ELSE IF ( abs( a( istart+1, istart ) ) .LE. max( smlnum,
     $      ulp*( abs( a( istart, istart ) )+abs( a( istart+1,
     $      istart+1 ) ) ) ) ) THEN
            a( istart+1, istart ) = zero
            istart = istart+1
            ld = 0
            eshift = zero
         END IF
 
         IF ( istart+1 .GE. istop ) THEN
            EXIT
         END IF
 
*        Check interior deflations
         istart2 = istart
         DO k = istop, istart+1, -1
            IF ( abs( a( k, k-1 ) ) .LE. max( smlnum, ulp*( abs( a( k,
     $         k ) )+abs( a( k-1, k-1 ) ) ) ) ) THEN
               a( k, k-1 ) = zero
               istart2 = k
               EXIT
            END IF
         END DO
 
*        Get range to apply rotations to
         IF ( ilschur ) THEN
            istartm = 1
            istopm = n
         ELSE
            istartm = istart2
            istopm = istop
         END IF
 
*        Check infinite eigenvalues, this is done without blocking so might
*        slow down the method when many infinite eigenvalues are present
         k = istop
         DO WHILE ( k.GE.istart2 )
 
            IF( abs( b( k, k ) ) .LT. btol ) THEN
*              A diagonal element of B is negligable, move it
*              to the top and deflate it
               
               DO k2 = k, istart2+1, -1
                  CALL dlartg( b( k2-1, k2 ), b( k2-1, k2-1 ), c1, s1,
     $                         temp )
                  b( k2-1, k2 ) = temp
                  b( k2-1, k2-1 ) = zero
 
                  CALL drot( k2-2-istartm+1, b( istartm, k2 ), 1,
     $                       b( istartm, k2-1 ), 1, c1, s1 )
                  CALL drot( min( k2+1, istop )-istartm+1, a( istartm,
     $                       k2 ), 1, a( istartm, k2-1 ), 1, c1, s1 )
                  IF ( ilz ) THEN
                     CALL drot( n, z( 1, k2 ), 1, z( 1, k2-1 ), 1, c1,
     $                          s1 )
                  END IF
 
                  IF( k2.LT.istop ) THEN
                     CALL dlartg( a( k2, k2-1 ), a( k2+1, k2-1 ), c1,
     $                            s1, temp )
                     a( k2, k2-1 ) = temp
                     a( k2+1, k2-1 ) = zero
 
                     CALL drot( istopm-k2+1, a( k2, k2 ), lda, a( k2+1,
     $                          k2 ), lda, c1, s1 )
                     CALL drot( istopm-k2+1, b( k2, k2 ), ldb, b( k2+1,
     $                          k2 ), ldb, c1, s1 )
                     IF( ilq ) THEN
                        CALL drot( n, q( 1, k2 ), 1, q( 1, k2+1 ), 1,
     $                             c1, s1 )
                     END IF
                  END IF
 
               END DO
 
               IF( istart2.LT.istop )THEN
                  CALL dlartg( a( istart2, istart2 ), a( istart2+1,
     $                         istart2 ), c1, s1, temp )
                  a( istart2, istart2 ) = temp
                  a( istart2+1, istart2 ) = zero
 
                  CALL drot( istopm-( istart2+1 )+1, a( istart2,
     $                       istart2+1 ), lda, a( istart2+1,
     $                       istart2+1 ), lda, c1, s1 )
                  CALL drot( istopm-( istart2+1 )+1, b( istart2,
     $                       istart2+1 ), ldb, b( istart2+1,
     $                       istart2+1 ), ldb, c1, s1 )
                  IF( ilq ) THEN
                     CALL drot( n, q( 1, istart2 ), 1, q( 1,
     $                          istart2+1 ), 1, c1, s1 )
                  END IF
               END IF
 
               istart2 = istart2+1
   
            END IF
            k = k-1
         END DO
 
*        istart2 now points to the top of the bottom right
*        unreduced Hessenberg block
         IF ( istart2 .GE. istop ) THEN
            istop = istart2-1
            ld = 0
            eshift = zero
            cycle
         END IF
 
         nw = nwr
         nshifts = nsr
         nblock = nbr
 
         IF ( istop-istart2+1 .LT. nmin ) THEN
*           Setting nw to the size of the subblock will make AED deflate
*           all the eigenvalues. This is slightly more efficient than just
*           using DHGEQZ because the off diagonal part gets updated via BLAS.
            IF ( istop-istart+1 .LT. nmin ) THEN
               nw = istop-istart+1
               istart2 = istart
            ELSE
               nw = istop-istart2+1
            END IF
         END IF
 
*
*        Time for AED
*
         CALL dlaqz3( ilschur, ilq, ilz, n, istart2, istop, nw, a, lda,
     $                b, ldb, q, ldq, z, ldz, n_undeflated, n_deflated,
     $                alphar, alphai, beta, work, nw, work( nw**2+1 ),
     $                nw, work( 2*nw**2+1 ), lwork-2*nw**2, rec,
     $                aed_info )
 
         IF ( n_deflated > 0 ) THEN
            istop = istop-n_deflated
            ld = 0
            eshift = zero
         END IF
 
         IF ( 100*n_deflated > nibble*( n_deflated+n_undeflated ) .OR.
     $      istop-istart2+1 .LT. nmin ) THEN
*           AED has uncovered many eigenvalues. Skip a QZ sweep and run
*           AED again.
            cycle
         END IF
 
         ld = ld+1
 
         ns = min( nshifts, istop-istart2 )
         ns = min( ns, n_undeflated )
         shiftpos = istop-n_deflated-n_undeflated+1
*
*        Shuffle shifts to put double shifts in front
*        This ensures that we don't split up a double shift
*
         DO i = shiftpos, shiftpos+n_undeflated-1, 2
            IF( alphai( i ).NE.-alphai( i+1 ) ) THEN
*
               swap = alphar( i )
               alphar( i ) = alphar( i+1 )
               alphar( i+1 ) = alphar( i+2 )
               alphar( i+2 ) = swap
 
               swap = alphai( i )
               alphai( i ) = alphai( i+1 )
               alphai( i+1 ) = alphai( i+2 )
               alphai( i+2 ) = swap
               
               swap = beta( i )
               beta( i ) = beta( i+1 )
               beta( i+1 ) = beta( i+2 )
               beta( i+2 ) = swap
            END IF
         END DO
 
         IF ( mod( ld, 6 ) .EQ. 0 ) THEN
* 
*           Exceptional shift.  Chosen for no particularly good reason.
*
            IF( ( dble( maxit )*safmin )*abs( a( istop,
     $         istop-1 ) ).LT.abs( a( istop-1, istop-1 ) ) ) THEN
               eshift = a( istop, istop-1 )/b( istop-1, istop-1 )
            ELSE
               eshift = eshift+one/( safmin*dble( maxit ) )
            END IF
            alphar( shiftpos ) = one
            alphar( shiftpos+1 ) = zero
            alphai( shiftpos ) = zero
            alphai( shiftpos+1 ) = zero
            beta( shiftpos ) = eshift
            beta( shiftpos+1 ) = eshift
            ns = 2
         END IF
 
*
*        Time for a QZ sweep
*
         CALL dlaqz4( ilschur, ilq, ilz, n, istart2, istop, ns, nblock,
     $                alphar( shiftpos ), alphai( shiftpos ),
     $                beta( shiftpos ), a, lda, b, ldb, q, ldq, z, ldz,
     $                work, nblock, work( nblock**2+1 ), nblock,
     $                work( 2*nblock**2+1 ), lwork-2*nblock**2,
     $                sweep_info )
 
      END DO
 
*
*     Call DHGEQZ to normalize the eigenvalue blocks and set the eigenvalues
*     If all the eigenvalues have been found, DHGEQZ will not do any iterations
*     and only normalize the blocks. In case of a rare convergence failure,
*     the single shift might perform better.
*
   80 CALL dhgeqz( wants, wantq, wantz, n, ilo, ihi, a, lda, b, ldb,
     $             alphar, alphai, beta, q, ldq, z, ldz, work, lwork,
     $             norm_info )
      
      info = norm_info
 
      END SUBROUTINE