cdrvev.f

Go to the documentation of this file.

*> \brief \b CDRVEV
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE CDRVEV( NSIZES, NN, NTYPES, DOTYPE, ISEED, THRESH,
*                          NOUNIT, A, LDA, H, W, W1, VL, LDVL, VR, LDVR,
*                          LRE, LDLRE, RESULT, WORK, NWORK, RWORK, IWORK,
*                          INFO )
*
*       .. Scalar Arguments ..
*       INTEGER            INFO, LDA, LDLRE, LDVL, LDVR, NOUNIT, NSIZES,
*      $                   NTYPES, NWORK
*       REAL               THRESH
*       ..
*       .. Array Arguments ..
*       LOGICAL            DOTYPE( * )
*       INTEGER            ISEED( 4 ), IWORK( * ), NN( * )
*       REAL               RESULT( 7 ), RWORK( * )
*       COMPLEX            A( LDA, * ), H( LDA, * ), LRE( LDLRE, * ),
*      $                   VL( LDVL, * ), VR( LDVR, * ), W( * ), W1( * ),
*      $                   WORK( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*>    CDRVEV  checks the nonsymmetric eigenvalue problem driver CGEEV.
*>
*>    When CDRVEV is called, a number of matrix "sizes" ("n's") and a
*>    number of matrix "types" are specified.  For each size ("n")
*>    and each type of matrix, one matrix will be generated and used
*>    to test the nonsymmetric eigenroutines.  For each matrix, 7
*>    tests will be performed:
*>
*>    (1)     | A * VR - VR * W | / ( n |A| ulp )
*>
*>      Here VR is the matrix of unit right eigenvectors.
*>      W is a diagonal matrix with diagonal entries W(j).
*>
*>    (2)     | A**H * VL - VL * W**H | / ( n |A| ulp )
*>
*>      Here VL is the matrix of unit left eigenvectors, A**H is the
*>      conjugate-transpose of A, and W is as above.
*>
*>    (3)     | |VR(i)| - 1 | / ulp and whether largest component real
*>
*>      VR(i) denotes the i-th column of VR.
*>
*>    (4)     | |VL(i)| - 1 | / ulp and whether largest component real
*>
*>      VL(i) denotes the i-th column of VL.
*>
*>    (5)     W(full) = W(partial)
*>
*>      W(full) denotes the eigenvalues computed when both VR and VL
*>      are also computed, and W(partial) denotes the eigenvalues
*>      computed when only W, only W and VR, or only W and VL are
*>      computed.
*>
*>    (6)     VR(full) = VR(partial)
*>
*>      VR(full) denotes the right eigenvectors computed when both VR
*>      and VL are computed, and VR(partial) denotes the result
*>      when only VR is computed.
*>
*>     (7)     VL(full) = VL(partial)
*>
*>      VL(full) denotes the left eigenvectors computed when both VR
*>      and VL are also computed, and VL(partial) denotes the result
*>      when only VL is computed.
*>
*>    The "sizes" are specified by an array NN(1:NSIZES); the value of
*>    each element NN(j) specifies one size.
*>    The "types" are specified by a logical array DOTYPE( 1:NTYPES );
*>    if DOTYPE(j) is .TRUE., then matrix type "j" will be generated.
*>    Currently, the list of possible types is:
*>
*>    (1)  The zero matrix.
*>    (2)  The identity matrix.
*>    (3)  A (transposed) Jordan block, with 1's on the diagonal.
*>
*>    (4)  A diagonal matrix with evenly spaced entries
*>         1, ..., ULP  and random complex angles.
*>         (ULP = (first number larger than 1) - 1 )
*>    (5)  A diagonal matrix with geometrically spaced entries
*>         1, ..., ULP  and random complex angles.
*>    (6)  A diagonal matrix with "clustered" entries 1, ULP, ..., ULP
*>         and random complex angles.
*>
*>    (7)  Same as (4), but multiplied by a constant near
*>         the overflow threshold
*>    (8)  Same as (4), but multiplied by a constant near
*>         the underflow threshold
*>
*>    (9)  A matrix of the form  U' T U, where U is unitary and
*>         T has evenly spaced entries 1, ..., ULP with random complex
*>         angles on the diagonal and random O(1) entries in the upper
*>         triangle.
*>
*>    (10) A matrix of the form  U' T U, where U is unitary and
*>         T has geometrically spaced entries 1, ..., ULP with random
*>         complex angles on the diagonal and random O(1) entries in
*>         the upper triangle.
*>
*>    (11) A matrix of the form  U' T U, where U is unitary and
*>         T has "clustered" entries 1, ULP,..., ULP with random
*>         complex angles on the diagonal and random O(1) entries in
*>         the upper triangle.
*>
*>    (12) A matrix of the form  U' T U, where U is unitary and
*>         T has complex eigenvalues randomly chosen from
*>         ULP < |z| < 1   and random O(1) entries in the upper
*>         triangle.
*>
*>    (13) A matrix of the form  X' T X, where X has condition
*>         SQRT( ULP ) and T has evenly spaced entries 1, ..., ULP
*>         with random complex angles on the diagonal and random O(1)
*>         entries in the upper triangle.
*>
*>    (14) A matrix of the form  X' T X, where X has condition
*>         SQRT( ULP ) and T has geometrically spaced entries
*>         1, ..., ULP with random complex angles on the diagonal
*>         and random O(1) entries in the upper triangle.
*>
*>    (15) A matrix of the form  X' T X, where X has condition
*>         SQRT( ULP ) and T has "clustered" entries 1, ULP,..., ULP
*>         with random complex angles on the diagonal and random O(1)
*>         entries in the upper triangle.
*>
*>    (16) A matrix of the form  X' T X, where X has condition
*>         SQRT( ULP ) and T has complex eigenvalues randomly chosen
*>         from ULP < |z| < 1 and random O(1) entries in the upper
*>         triangle.
*>
*>    (17) Same as (16), but multiplied by a constant
*>         near the overflow threshold
*>    (18) Same as (16), but multiplied by a constant
*>         near the underflow threshold
*>
*>    (19) Nonsymmetric matrix with random entries chosen from |z| < 1
*>         If N is at least 4, all entries in first two rows and last
*>         row, and first column and last two columns are zero.
*>    (20) Same as (19), but multiplied by a constant
*>         near the overflow threshold
*>    (21) Same as (19), but multiplied by a constant
*>         near the underflow threshold
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] NSIZES
*> \verbatim
*>          NSIZES is INTEGER
*>          The number of sizes of matrices to use.  If it is zero,
*>          CDRVEV does nothing.  It must be at least zero.
*> \endverbatim
*>
*> \param[in] NN
*> \verbatim
*>          NN is INTEGER array, dimension (NSIZES)
*>          An array containing the sizes to be used for the matrices.
*>          Zero values will be skipped.  The values must be at least
*>          zero.
*> \endverbatim
*>
*> \param[in] NTYPES
*> \verbatim
*>          NTYPES is INTEGER
*>          The number of elements in DOTYPE.   If it is zero, CDRVEV
*>          does nothing.  It must be at least zero.  If it is MAXTYP+1
*>          and NSIZES is 1, then an additional type, MAXTYP+1 is
*>          defined, which is to use whatever matrix is in A.  This
*>          is only useful if DOTYPE(1:MAXTYP) is .FALSE. and
*>          DOTYPE(MAXTYP+1) is .TRUE. .
*> \endverbatim
*>
*> \param[in] DOTYPE
*> \verbatim
*>          DOTYPE is LOGICAL array, dimension (NTYPES)
*>          If DOTYPE(j) is .TRUE., then for each size in NN a
*>          matrix of that size and of type j will be generated.
*>          If NTYPES is smaller than the maximum number of types
*>          defined (PARAMETER MAXTYP), then types NTYPES+1 through
*>          MAXTYP will not be generated.  If NTYPES is larger
*>          than MAXTYP, DOTYPE(MAXTYP+1) through DOTYPE(NTYPES)
*>          will be ignored.
*> \endverbatim
*>
*> \param[in,out] ISEED
*> \verbatim
*>          ISEED is INTEGER array, dimension (4)
*>          On entry ISEED specifies the seed of the random number
*>          generator. The array elements should be between 0 and 4095;
*>          if not they will be reduced mod 4096.  Also, ISEED(4) must
*>          be odd.  The random number generator uses a linear
*>          congruential sequence limited to small integers, and so
*>          should produce machine independent random numbers. The
*>          values of ISEED are changed on exit, and can be used in the
*>          next call to CDRVEV to continue the same random number
*>          sequence.
*> \endverbatim
*>
*> \param[in] THRESH
*> \verbatim
*>          THRESH is REAL
*>          A test will count as "failed" if the "error", computed as
*>          described above, exceeds THRESH.  Note that the error
*>          is scaled to be O(1), so THRESH should be a reasonably
*>          small multiple of 1, e.g., 10 or 100.  In particular,
*>          it should not depend on the precision (single vs. double)
*>          or the size of the matrix.  It must be at least zero.
*> \endverbatim
*>
*> \param[in] NOUNIT
*> \verbatim
*>          NOUNIT is INTEGER
*>          The FORTRAN unit number for printing out error messages
*>          (e.g., if a routine returns INFO not equal to 0.)
*> \endverbatim
*>
*> \param[out] A
*> \verbatim
*>          A is COMPLEX array, dimension (LDA, max(NN))
*>          Used to hold the matrix whose eigenvalues are to be
*>          computed.  On exit, A contains the last matrix actually used.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of A, and H. LDA must be at
*>          least 1 and at least max(NN).
*> \endverbatim
*>
*> \param[out] H
*> \verbatim
*>          H is COMPLEX array, dimension (LDA, max(NN))
*>          Another copy of the test matrix A, modified by CGEEV.
*> \endverbatim
*>
*> \param[out] W
*> \verbatim
*>          W is COMPLEX array, dimension (max(NN))
*>          The eigenvalues of A. On exit, W are the eigenvalues of
*>          the matrix in A.
*> \endverbatim
*>
*> \param[out] W1
*> \verbatim
*>          W1 is COMPLEX array, dimension (max(NN))
*>          Like W, this array contains the eigenvalues of A,
*>          but those computed when CGEEV only computes a partial
*>          eigendecomposition, i.e. not the eigenvalues and left
*>          and right eigenvectors.
*> \endverbatim
*>
*> \param[out] VL
*> \verbatim
*>          VL is COMPLEX array, dimension (LDVL, max(NN))
*>          VL holds the computed left eigenvectors.
*> \endverbatim
*>
*> \param[in] LDVL
*> \verbatim
*>          LDVL is INTEGER
*>          Leading dimension of VL. Must be at least max(1,max(NN)).
*> \endverbatim
*>
*> \param[out] VR
*> \verbatim
*>          VR is COMPLEX array, dimension (LDVR, max(NN))
*>          VR holds the computed right eigenvectors.
*> \endverbatim
*>
*> \param[in] LDVR
*> \verbatim
*>          LDVR is INTEGER
*>          Leading dimension of VR. Must be at least max(1,max(NN)).
*> \endverbatim
*>
*> \param[out] LRE
*> \verbatim
*>          LRE is COMPLEX array, dimension (LDLRE, max(NN))
*>          LRE holds the computed right or left eigenvectors.
*> \endverbatim
*>
*> \param[in] LDLRE
*> \verbatim
*>          LDLRE is INTEGER
*>          Leading dimension of LRE. Must be at least max(1,max(NN)).
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is REAL array, dimension (7)
*>          The values computed by the seven tests described above.
*>          The values are currently limited to 1/ulp, to avoid
*>          overflow.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX array, dimension (NWORK)
*> \endverbatim
*>
*> \param[in] NWORK
*> \verbatim
*>          NWORK is INTEGER
*>          The number of entries in WORK.  This must be at least
*>          5*NN(j)+2*NN(j)**2 for all j.
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is REAL array, dimension (2*max(NN))
*> \endverbatim
*>
*> \param[out] IWORK
*> \verbatim
*>          IWORK is INTEGER array, dimension (max(NN))
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          If 0, then everything ran OK.
*>           -1: NSIZES < 0
*>           -2: Some NN(j) < 0
*>           -3: NTYPES < 0
*>           -6: THRESH < 0
*>           -9: LDA < 1 or LDA < NMAX, where NMAX is max( NN(j) ).
*>          -14: LDVL < 1 or LDVL < NMAX, where NMAX is max( NN(j) ).
*>          -16: LDVR < 1 or LDVR < NMAX, where NMAX is max( NN(j) ).
*>          -18: LDLRE < 1 or LDLRE < NMAX, where NMAX is max( NN(j) ).
*>          -21: NWORK too small.
*>          If  CLATMR, CLATMS, CLATME or CGEEV returns an error code,
*>              the absolute value of it is returned.
*>
*>-----------------------------------------------------------------------
*>
*>     Some Local Variables and Parameters:
*>     ---- ----- --------- --- ----------
*>
*>     ZERO, ONE       Real 0 and 1.
*>     MAXTYP          The number of types defined.
*>     NMAX            Largest value in NN.
*>     NERRS           The number of tests which have exceeded THRESH
*>     COND, CONDS,
*>     IMODE           Values to be passed to the matrix generators.
*>     ANORM           Norm of A; passed to matrix generators.
*>
*>     OVFL, UNFL      Overflow and underflow thresholds.
*>     ULP, ULPINV     Finest relative precision and its inverse.
*>     RTULP, RTULPI   Square roots of the previous 4 values.
*>
*>             The following four arrays decode JTYPE:
*>     KTYPE(j)        The general type (1-10) for type "j".
*>     KMODE(j)        The MODE value to be passed to the matrix
*>                     generator for type "j".
*>     KMAGN(j)        The order of magnitude ( O(1),
*>                     O(overflow^(1/2) ), O(underflow^(1/2) )
*>     KCONDS(j)       Selectw whether CONDS is to be 1 or
*>                     1/sqrt(ulp).  (0 means irrelevant.)
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup complex_eig
*
*  =====================================================================
      SUBROUTINE cdrvev( NSIZES, NN, NTYPES, DOTYPE, ISEED, THRESH,
     $                   NOUNIT, A, LDA, H, W, W1, VL, LDVL, VR, LDVR,
     $                   LRE, LDLRE, RESULT, WORK, NWORK, RWORK, IWORK,
     $                   INFO )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, LDLRE, LDVL, LDVR, NOUNIT, NSIZES,
     $                   NTYPES, NWORK
      REAL               THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            ISEED( 4 ), IWORK( * ), NN( * )
      REAL               RESULT( 7 ), RWORK( * )
      COMPLEX            A( LDA, * ), H( LDA, * ), LRE( LDLRE, * ),
     $                   vl( ldvl, * ), vr( ldvr, * ), w( * ), w1( * ),
     $                   work( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX            CZERO
      PARAMETER          ( CZERO = ( 0.0e+0, 0.0e+0 ) )
      COMPLEX            CONE
      parameter( cone = ( 1.0e+0, 0.0e+0 ) )
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      REAL               TWO
      parameter( two = 2.0e+0 )
      INTEGER            MAXTYP
      parameter( maxtyp = 21 )
*     ..
*     .. Local Scalars ..
      LOGICAL            BADNN
      CHARACTER*3        PATH
      INTEGER            IINFO, IMODE, ITYPE, IWK, J, JCOL, JJ, JSIZE,
     $                   jtype, mtypes, n, nerrs, nfail, nmax,
     $                   nnwork, ntest, ntestf, ntestt
      REAL               ANORM, COND, CONDS, OVFL, RTULP, RTULPI, TNRM,
     $                   ULP, ULPINV, UNFL, VMX, VRMX, VTST
*     ..
*     .. Local Arrays ..
      INTEGER            IDUMMA( 1 ), IOLDSD( 4 ), KCONDS( MAXTYP ),
     $                   KMAGN( MAXTYP ), KMODE( MAXTYP ),
     $                   KTYPE( MAXTYP )
      REAL               RES( 2 )
      COMPLEX            DUM( 1 )
*     ..
*     .. External Functions ..
      REAL               SCNRM2, SLAMCH
      EXTERNAL           SCNRM2, SLAMCH
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgeev, cget22, clacpy, clatme, clatmr, clatms,
     $                   claset, slabad, slasum, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, aimag, cmplx, max, min, real, sqrt
*     ..
*     .. Data statements ..
      DATA               ktype / 1, 2, 3, 5*4, 4*6, 6*6, 3*9 /
      DATA               kmagn / 3*1, 1, 1, 1, 2, 3, 4*1, 1, 1, 1, 1, 2,
     $                   3, 1, 2, 3 /
      DATA               kmode / 3*0, 4, 3, 1, 4, 4, 4, 3, 1, 5, 4, 3,
     $                   1, 5, 5, 5, 4, 3, 1 /
      DATA               kconds / 3*0, 5*0, 4*1, 6*2, 3*0 /
*     ..
*     .. Executable Statements ..
*
      path( 1: 1 ) = 'Complex precision'
      path( 2: 3 ) = 'EV'
*
*     Check for errors
*
      ntestt = 0
      ntestf = 0
      info = 0
*
*     Important constants
*
      badnn = .false.
      nmax = 0
      DO 10 j = 1, nsizes
         nmax = max( nmax, nn( j ) )
         IF( nn( j ).LT.0 )
     $      badnn = .true.
   10 CONTINUE
*
*     Check for errors
*
      IF( nsizes.LT.0 ) THEN
         info = -1
      ELSE IF( badnn ) THEN
         info = -2
      ELSE IF( ntypes.LT.0 ) THEN
         info = -3
      ELSE IF( thresh.LT.zero ) THEN
         info = -6
      ELSE IF( nounit.LE.0 ) THEN
         info = -7
      ELSE IF( lda.LT.1 .OR. lda.LT.nmax ) THEN
         info = -9
      ELSE IF( ldvl.LT.1 .OR. ldvl.LT.nmax ) THEN
         info = -14
      ELSE IF( ldvr.LT.1 .OR. ldvr.LT.nmax ) THEN
         info = -16
      ELSE IF( ldlre.LT.1 .OR. ldlre.LT.nmax ) THEN
         info = -28
      ELSE IF( 5*nmax+2*nmax**2.GT.nwork ) THEN
         info = -21
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CDRVEV', -info )
         RETURN
      END IF
*
*     Quick return if nothing to do
*
      IF( nsizes.EQ.0 .OR. ntypes.EQ.0 )
     $   RETURN
*
*     More Important constants
*
      unfl = slamch( 'Safe minimum' )
      ovfl = one / unfl
      CALL slabad( unfl, ovfl )
      ulp = slamch( 'Precision' )
      ulpinv = one / ulp
      rtulp = sqrt( ulp )
      rtulpi = one / rtulp
*
*     Loop over sizes, types
*
      nerrs = 0
*
      DO 270 jsize = 1, nsizes
         n = nn( jsize )
         IF( nsizes.NE.1 ) THEN
            mtypes = min( maxtyp, ntypes )
         ELSE
            mtypes = min( maxtyp+1, ntypes )
         END IF
*
         DO 260 jtype = 1, mtypes
            IF( .NOT.dotype( jtype ) )
     $         GO TO 260
*
*           Save ISEED in case of an error.
*
            DO 20 j = 1, 4
               ioldsd( j ) = iseed( j )
   20       CONTINUE
*
*           Compute "A"
*
*           Control parameters:
*
*           KMAGN  KCONDS  KMODE        KTYPE
*       =1  O(1)   1       clustered 1  zero
*       =2  large  large   clustered 2  identity
*       =3  small          exponential  Jordan
*       =4                 arithmetic   diagonal, (w/ eigenvalues)
*       =5                 random log   symmetric, w/ eigenvalues
*       =6                 random       general, w/ eigenvalues
*       =7                              random diagonal
*       =8                              random symmetric
*       =9                              random general
*       =10                             random triangular
*
            IF( mtypes.GT.maxtyp )
     $         GO TO 90
*
            itype = ktype( jtype )
            imode = kmode( jtype )
*
*           Compute norm
*
            GO TO ( 30, 40, 50 )kmagn( jtype )
*
   30       CONTINUE
            anorm = one
            GO TO 60
*
   40       CONTINUE
            anorm = ovfl*ulp
            GO TO 60
*
   50       CONTINUE
            anorm = unfl*ulpinv
            GO TO 60
*
   60       CONTINUE
*
            CALL claset( 'Full', lda, n, czero, czero, a, lda )
            iinfo = 0
            cond = ulpinv
*
*           Special Matrices -- Identity & Jordan block
*
*              Zero
*
            IF( itype.EQ.1 ) THEN
               iinfo = 0
*
            ELSE IF( itype.EQ.2 ) THEN
*
*              Identity
*
               DO 70 jcol = 1, n
                  a( jcol, jcol ) = cmplx( anorm )
   70          CONTINUE
*
            ELSE IF( itype.EQ.3 ) THEN
*
*              Jordan Block
*
               DO 80 jcol = 1, n
                  a( jcol, jcol ) = cmplx( anorm )
                  IF( jcol.GT.1 )
     $               a( jcol, jcol-1 ) = cone
   80          CONTINUE
*
            ELSE IF( itype.EQ.4 ) THEN
*
*              Diagonal Matrix, [Eigen]values Specified
*
               CALL clatms( n, n, 'S', iseed, 'H', rwork, imode, cond,
     $                      anorm, 0, 0, 'N', a, lda, work( n+1 ),
     $                      iinfo )
*
            ELSE IF( itype.EQ.5 ) THEN
*
*              Hermitian, eigenvalues specified
*
               CALL clatms( n, n, 'S', iseed, 'H', rwork, imode, cond,
     $                      anorm, n, n, 'N', a, lda, work( n+1 ),
     $                      iinfo )
*
            ELSE IF( itype.EQ.6 ) THEN
*
*              General, eigenvalues specified
*
               IF( kconds( jtype ).EQ.1 ) THEN
                  conds = one
               ELSE IF( kconds( jtype ).EQ.2 ) THEN
                  conds = rtulpi
               ELSE
                  conds = zero
               END IF
*
               CALL clatme( n, 'D', iseed, work, imode, cond, cone,
     $                      'T', 'T', 'T', rwork, 4, conds, n, n,
     $                      anorm, a, lda, work( 2*n+1 ), iinfo )
*
            ELSE IF( itype.EQ.7 ) THEN
*
*              Diagonal, random eigenvalues
*
               CALL clatmr( n, n, 'D', iseed, 'N', work, 6, one, cone,
     $                      'T', 'N', work( n+1 ), 1, one,
     $                      work( 2*n+1 ), 1, one, 'N', idumma, 0, 0,
     $                      zero, anorm, 'NO', a, lda, iwork, iinfo )
*
            ELSE IF( itype.EQ.8 ) THEN
*
*              Symmetric, random eigenvalues
*
               CALL clatmr( n, n, 'D', iseed, 'H', work, 6, one, cone,
     $                      'T', 'N', work( n+1 ), 1, one,
     $                      work( 2*n+1 ), 1, one, 'N', idumma, n, n,
     $                      zero, anorm, 'NO', a, lda, iwork, iinfo )
*
            ELSE IF( itype.EQ.9 ) THEN
*
*              General, random eigenvalues
*
               CALL clatmr( n, n, 'D', iseed, 'N', work, 6, one, cone,
     $                      'T', 'N', work( n+1 ), 1, one,
     $                      work( 2*n+1 ), 1, one, 'N', idumma, n, n,
     $                      zero, anorm, 'NO', a, lda, iwork, iinfo )
               IF( n.GE.4 ) THEN
                  CALL claset( 'Full', 2, n, czero, czero, a, lda )
                  CALL claset( 'Full', n-3, 1, czero, czero, a( 3, 1 ),
     $                         lda )
                  CALL claset( 'Full', n-3, 2, czero, czero,
     $                         a( 3, n-1 ), lda )
                  CALL claset( 'Full', 1, n, czero, czero, a( n, 1 ),
     $                         lda )
               END IF
*
            ELSE IF( itype.EQ.10 ) THEN
*
*              Triangular, random eigenvalues
*
               CALL clatmr( n, n, 'D', iseed, 'N', work, 6, one, cone,
     $                      'T', 'N', work( n+1 ), 1, one,
     $                      work( 2*n+1 ), 1, one, 'N', idumma, n, 0,
     $                      zero, anorm, 'NO', a, lda, iwork, iinfo )
*
            ELSE
*
               iinfo = 1
            END IF
*
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9993 )'Generator', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               RETURN
            END IF
*
   90       CONTINUE
*
*           Test for minimal and generous workspace
*
            DO 250 iwk = 1, 2
               IF( iwk.EQ.1 ) THEN
                  nnwork = 2*n
               ELSE
                  nnwork = 5*n + 2*n**2
               END IF
               nnwork = max( nnwork, 1 )
*
*              Initialize RESULT
*
               DO 100 j = 1, 7
                  result( j ) = -one
  100          CONTINUE
*
*              Compute eigenvalues and eigenvectors, and test them
*
               CALL clacpy( 'F', n, n, a, lda, h, lda )
               CALL cgeev( 'V', 'V', n, h, lda, w, vl, ldvl, vr, ldvr,
     $                     work, nnwork, rwork, iinfo )
               IF( iinfo.NE.0 ) THEN
                  result( 1 ) = ulpinv
                  WRITE( nounit, fmt = 9993 )'CGEEV1', iinfo, n, jtype,
     $               ioldsd
                  info = abs( iinfo )
                  GO TO 220
               END IF
*
*              Do Test (1)
*
               CALL cget22( 'N', 'N', 'N', n, a, lda, vr, ldvr, w, work,
     $                      rwork, res )
               result( 1 ) = res( 1 )
*
*              Do Test (2)
*
               CALL cget22( 'C', 'N', 'C', n, a, lda, vl, ldvl, w, work,
     $                      rwork, res )
               result( 2 ) = res( 1 )
*
*              Do Test (3)
*
               DO 120 j = 1, n
                  tnrm = scnrm2( n, vr( 1, j ), 1 )
                  result( 3 ) = max( result( 3 ),
     $                          min( ulpinv, abs( tnrm-one ) / ulp ) )
                  vmx = zero
                  vrmx = zero
                  DO 110 jj = 1, n
                     vtst = abs( vr( jj, j ) )
                     IF( vtst.GT.vmx )
     $                  vmx = vtst
                     IF( aimag( vr( jj, j ) ).EQ.zero .AND.
     $                   abs( real( vr( jj, j ) ) ).GT.vrmx )
     $                   vrmx = abs( real( vr( jj, j ) ) )
  110             CONTINUE
                  IF( vrmx / vmx.LT.one-two*ulp )
     $               result( 3 ) = ulpinv
  120          CONTINUE
*
*              Do Test (4)
*
               DO 140 j = 1, n
                  tnrm = scnrm2( n, vl( 1, j ), 1 )
                  result( 4 ) = max( result( 4 ),
     $                          min( ulpinv, abs( tnrm-one ) / ulp ) )
                  vmx = zero
                  vrmx = zero
                  DO 130 jj = 1, n
                     vtst = abs( vl( jj, j ) )
                     IF( vtst.GT.vmx )
     $                  vmx = vtst
                     IF( aimag( vl( jj, j ) ).EQ.zero .AND.
     $                   abs( real( vl( jj, j ) ) ).GT.vrmx )
     $                   vrmx = abs( real( vl( jj, j ) ) )
  130             CONTINUE
                  IF( vrmx / vmx.LT.one-two*ulp )
     $               result( 4 ) = ulpinv
  140          CONTINUE
*
*              Compute eigenvalues only, and test them
*
               CALL clacpy( 'F', n, n, a, lda, h, lda )
               CALL cgeev( 'N', 'N', n, h, lda, w1, dum, 1, dum, 1,
     $                     work, nnwork, rwork, iinfo )
               IF( iinfo.NE.0 ) THEN
                  result( 1 ) = ulpinv
                  WRITE( nounit, fmt = 9993 )'CGEEV2', iinfo, n, jtype,
     $               ioldsd
                  info = abs( iinfo )
                  GO TO 220
               END IF
*
*              Do Test (5)
*
               DO 150 j = 1, n
                  IF( w( j ).NE.w1( j ) )
     $               result( 5 ) = ulpinv
  150          CONTINUE
*
*              Compute eigenvalues and right eigenvectors, and test them
*
               CALL clacpy( 'F', n, n, a, lda, h, lda )
               CALL cgeev( 'N', 'V', n, h, lda, w1, dum, 1, lre, ldlre,
     $                     work, nnwork, rwork, iinfo )
               IF( iinfo.NE.0 ) THEN
                  result( 1 ) = ulpinv
                  WRITE( nounit, fmt = 9993 )'CGEEV3', iinfo, n, jtype,
     $               ioldsd
                  info = abs( iinfo )
                  GO TO 220
               END IF
*
*              Do Test (5) again
*
               DO 160 j = 1, n
                  IF( w( j ).NE.w1( j ) )
     $               result( 5 ) = ulpinv
  160          CONTINUE
*
*              Do Test (6)
*
               DO 180 j = 1, n
                  DO 170 jj = 1, n
                     IF( vr( j, jj ).NE.lre( j, jj ) )
     $                  result( 6 ) = ulpinv
  170             CONTINUE
  180          CONTINUE
*
*              Compute eigenvalues and left eigenvectors, and test them
*
               CALL clacpy( 'F', n, n, a, lda, h, lda )
               CALL cgeev( 'V', 'N', n, h, lda, w1, lre, ldlre, dum, 1,
     $                     work, nnwork, rwork, iinfo )
               IF( iinfo.NE.0 ) THEN
                  result( 1 ) = ulpinv
                  WRITE( nounit, fmt = 9993 )'CGEEV4', iinfo, n, jtype,
     $               ioldsd
                  info = abs( iinfo )
                  GO TO 220
               END IF
*
*              Do Test (5) again
*
               DO 190 j = 1, n
                  IF( w( j ).NE.w1( j ) )
     $               result( 5 ) = ulpinv
  190          CONTINUE
*
*              Do Test (7)
*
               DO 210 j = 1, n
                  DO 200 jj = 1, n
                     IF( vl( j, jj ).NE.lre( j, jj ) )
     $                  result( 7 ) = ulpinv
  200             CONTINUE
  210          CONTINUE
*
*              End of Loop -- Check for RESULT(j) > THRESH
*
  220          CONTINUE
*
               ntest = 0
               nfail = 0
               DO 230 j = 1, 7
                  IF( result( j ).GE.zero )
     $               ntest = ntest + 1
                  IF( result( j ).GE.thresh )
     $               nfail = nfail + 1
  230          CONTINUE
*
               IF( nfail.GT.0 )
     $            ntestf = ntestf + 1
               IF( ntestf.EQ.1 ) THEN
                  WRITE( nounit, fmt = 9999 )path
                  WRITE( nounit, fmt = 9998 )
                  WRITE( nounit, fmt = 9997 )
                  WRITE( nounit, fmt = 9996 )
                  WRITE( nounit, fmt = 9995 )thresh
                  ntestf = 2
               END IF
*
               DO 240 j = 1, 7
                  IF( result( j ).GE.thresh ) THEN
                     WRITE( nounit, fmt = 9994 )n, iwk, ioldsd, jtype,
     $                  j, result( j )
                  END IF
  240          CONTINUE
*
               nerrs = nerrs + nfail
               ntestt = ntestt + ntest
*
  250       CONTINUE
  260    CONTINUE
  270 CONTINUE
*
*     Summary
*
      CALL slasum( path, nounit, nerrs, ntestt )
*
 9999 FORMAT( / 1x, a3, ' -- Complex Eigenvalue-Eigenvector ',
     $      'Decomposition Driver', /
     $      ' Matrix types (see CDRVEV for details): ' )
*
 9998 FORMAT( / ' Special Matrices:', / '  1=Zero matrix.             ',
     $      '           ', '  5=Diagonal: geometr. spaced entries.',
     $      / '  2=Identity matrix.                    ', '  6=Diagona',
     $      'l: clustered entries.', / '  3=Transposed Jordan block.  ',
     $      '          ', '  7=Diagonal: large, evenly spaced.', / '  ',
     $      '4=Diagonal: evenly spaced entries.    ', '  8=Diagonal: s',
     $      'mall, evenly spaced.' )
 9997 FORMAT( ' Dense, Non-Symmetric Matrices:', / '  9=Well-cond., ev',
     $      'enly spaced eigenvals.', ' 14=Ill-cond., geomet. spaced e',
     $      'igenals.', / ' 10=Well-cond., geom. spaced eigenvals. ',
     $      ' 15=Ill-conditioned, clustered e.vals.', / ' 11=Well-cond',
     $      'itioned, clustered e.vals. ', ' 16=Ill-cond., random comp',
     $      'lex ', a6, / ' 12=Well-cond., random complex ', a6, '   ',
     $      ' 17=Ill-cond., large rand. complx ', a4, / ' 13=Ill-condi',
     $      'tioned, evenly spaced.     ', ' 18=Ill-cond., small rand.',
     $      ' complx ', a4 )
 9996 FORMAT( ' 19=Matrix with random O(1) entries.    ', ' 21=Matrix ',
     $      'with small random entries.', / ' 20=Matrix with large ran',
     $      'dom entries.   ', / )
 9995 FORMAT( ' Tests performed with test threshold =', f8.2,
     $      / / ' 1 = | A VR - VR W | / ( n |A| ulp ) ',
     $      / ' 2 = | conj-trans(A) VL - VL conj-trans(W) | /',
     $      ' ( n |A| ulp ) ', / ' 3 = | |VR(i)| - 1 | / ulp ',
     $      / ' 4 = | |VL(i)| - 1 | / ulp ',
     $      / ' 5 = 0 if W same no matter if VR or VL computed,',
     $      ' 1/ulp otherwise', /
     $      ' 6 = 0 if VR same no matter if VL computed,',
     $      '  1/ulp otherwise', /
     $      ' 7 = 0 if VL same no matter if VR computed,',
     $      '  1/ulp otherwise', / )
 9994 FORMAT( ' N=', i5, ', IWK=', i2, ', seed=', 4( i4, ',' ),
     $      ' type ', i2, ', test(', i2, ')=', g10.3 )
 9993 FORMAT( ' CDRVEV: ', a, ' returned INFO=', i6, '.', / 9x, 'N=',
     $      i6, ', JTYPE=', i6, ', ISEED=(', 3( i5, ',' ), i5, ')' )
*
      RETURN
*
*     End of CDRVEV
*
      END