cgeev.f

Go to the documentation of this file.

*> \brief <b> CGEEV computes the eigenvalues and, optionally, the left and/or right eigenvectors for GE matrices</b>
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download CGEEV + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cgeev.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cgeev.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cgeev.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       SUBROUTINE CGEEV( JOBVL, JOBVR, N, A, LDA, W, VL, LDVL, VR, LDVR,
*                         WORK, LWORK, RWORK, INFO )
*
*       .. Scalar Arguments ..
*       CHARACTER          JOBVL, JOBVR
*       INTEGER            INFO, LDA, LDVL, LDVR, LWORK, N
*       ..
*       .. Array Arguments ..
*       REAL   RWORK( * )
*       COMPLEX         A( LDA, * ), VL( LDVL, * ), VR( LDVR, * ),
*      $                   W( * ), WORK( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CGEEV computes for an N-by-N complex nonsymmetric matrix A, the
*> eigenvalues and, optionally, the left and/or right eigenvectors.
*>
*> The right eigenvector v(j) of A satisfies
*>                  A * v(j) = lambda(j) * v(j)
*> where lambda(j) is its eigenvalue.
*> The left eigenvector u(j) of A satisfies
*>               u(j)**H * A = lambda(j) * u(j)**H
*> where u(j)**H denotes the conjugate transpose of u(j).
*>
*> The computed eigenvectors are normalized to have Euclidean norm
*> equal to 1 and largest component real.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] JOBVL
*> \verbatim
*>          JOBVL is CHARACTER*1
*>          = 'N': left eigenvectors of A are not computed;
*>          = 'V': left eigenvectors of are computed.
*> \endverbatim
*>
*> \param[in] JOBVR
*> \verbatim
*>          JOBVR is CHARACTER*1
*>          = 'N': right eigenvectors of A are not computed;
*>          = 'V': right eigenvectors of A are computed.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the matrix A. N >= 0.
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*>          A is COMPLEX array, dimension (LDA,N)
*>          On entry, the N-by-N matrix A.
*>          On exit, A has been overwritten.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(1,N).
*> \endverbatim
*>
*> \param[out] W
*> \verbatim
*>          W is COMPLEX array, dimension (N)
*>          W contains the computed eigenvalues.
*> \endverbatim
*>
*> \param[out] VL
*> \verbatim
*>          VL is COMPLEX array, dimension (LDVL,N)
*>          If JOBVL = 'V', the left eigenvectors u(j) are stored one
*>          after another in the columns of VL, in the same order
*>          as their eigenvalues.
*>          If JOBVL = 'N', VL is not referenced.
*>          u(j) = VL(:,j), the j-th column of VL.
*> \endverbatim
*>
*> \param[in] LDVL
*> \verbatim
*>          LDVL is INTEGER
*>          The leading dimension of the array VL.  LDVL >= 1; if
*>          JOBVL = 'V', LDVL >= N.
*> \endverbatim
*>
*> \param[out] VR
*> \verbatim
*>          VR is COMPLEX array, dimension (LDVR,N)
*>          If JOBVR = 'V', the right eigenvectors v(j) are stored one
*>          after another in the columns of VR, in the same order
*>          as their eigenvalues.
*>          If JOBVR = 'N', VR is not referenced.
*>          v(j) = VR(:,j), the j-th column of VR.
*> \endverbatim
*>
*> \param[in] LDVR
*> \verbatim
*>          LDVR is INTEGER
*>          The leading dimension of the array VR.  LDVR >= 1; if
*>          JOBVR = 'V', LDVR >= N.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX array, dimension (MAX(1,LWORK))
*>          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The dimension of the array WORK.  LWORK >= max(1,2*N).
*>          For good performance, LWORK must generally be larger.
*>
*>          If LWORK = -1, then a workspace query is assumed; the routine
*>          only calculates the optimal size of the WORK array, returns
*>          this value as the first entry of the WORK array, and no error
*>          message related to LWORK is issued by XERBLA.
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is REAL array, dimension (2*N)
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit
*>          < 0:  if INFO = -i, the i-th argument had an illegal value.
*>          > 0:  if INFO = i, the QR algorithm failed to compute all the
*>                eigenvalues, and no eigenvectors have been computed;
*>                elements i+1:N of W contain eigenvalues which have
*>                converged.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*
*  @generated from zgeev.f, fortran z -> c, Tue Apr 19 01:47:44 2016
*
*> \ingroup complexGEeigen
*
*  =====================================================================
      SUBROUTINE cgeev( JOBVL, JOBVR, N, A, LDA, W, VL, LDVL, VR, LDVR,
     $                  WORK, LWORK, RWORK, INFO )
      implicit none
*
*  -- LAPACK driver routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          JOBVL, JOBVR
      INTEGER            INFO, LDA, LDVL, LDVR, LWORK, N
*     ..
*     .. Array Arguments ..
      REAL   RWORK( * )
      COMPLEX         A( LDA, * ), VL( LDVL, * ), VR( LDVR, * ),
     $                   w( * ), work( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL   ZERO, ONE
      parameter( zero = 0.0e0, one = 1.0e0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY, SCALEA, WANTVL, WANTVR
      CHARACTER          SIDE
      INTEGER            HSWORK, I, IBAL, IERR, IHI, ILO, IRWORK, ITAU,
     $                   iwrk, k, lwork_trevc, maxwrk, minwrk, nout
      REAL   ANRM, BIGNUM, CSCALE, EPS, SCL, SMLNUM
      COMPLEX         TMP
*     ..
*     .. Local Arrays ..
      LOGICAL            SELECT( 1 )
      REAL   DUM( 1 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           slabad, xerbla, csscal, cgebak, cgebal, cgehrd,
     $                   chseqr, clacpy, clascl, cscal, ctrevc3, cunghr
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ISAMAX, ILAENV
      REAL   SLAMCH, SCNRM2, CLANGE
      EXTERNAL           lsame, isamax, ilaenv, slamch, scnrm2, clange
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          real, cmplx, conjg, aimag, max, sqrt
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      lquery = ( lwork.EQ.-1 )
      wantvl = lsame( jobvl, 'V' )
      wantvr = lsame( jobvr, 'V' )
      IF( ( .NOT.wantvl ) .AND. ( .NOT.lsame( jobvl, 'N' ) ) ) THEN
         info = -1
      ELSE IF( ( .NOT.wantvr ) .AND. ( .NOT.lsame( jobvr, 'N' ) ) ) THEN
         info = -2
      ELSE IF( n.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -5
      ELSE IF( ldvl.LT.1 .OR. ( wantvl .AND. ldvl.LT.n ) ) THEN
         info = -8
      ELSE IF( ldvr.LT.1 .OR. ( wantvr .AND. ldvr.LT.n ) ) THEN
         info = -10
      END IF
*
*     Compute workspace
*      (Note: Comments in the code beginning "Workspace:" describe the
*       minimal amount of workspace needed at that point in the code,
*       as well as the preferred amount for good performance.
*       CWorkspace refers to complex workspace, and RWorkspace to real
*       workspace. NB refers to the optimal block size for the
*       immediately following subroutine, as returned by ILAENV.
*       HSWORK refers to the workspace preferred by CHSEQR, as
*       calculated below. HSWORK is computed assuming ILO=1 and IHI=N,
*       the worst case.)
*
      IF( info.EQ.0 ) THEN
         IF( n.EQ.0 ) THEN
            minwrk = 1
            maxwrk = 1
         ELSE
            maxwrk = n + n*ilaenv( 1, 'CGEHRD', ' ', n, 1, n, 0 )
            minwrk = 2*n
            IF( wantvl ) THEN
               maxwrk = max( maxwrk, n + ( n - 1 )*ilaenv( 1, 'CUNGHR',
     $                       ' ', n, 1, n, -1 ) )
               CALL ctrevc3( 'L', 'B', SELECT, n, a, lda,
     $                       vl, ldvl, vr, ldvr,
     $                       n, nout, work, -1, rwork, -1, ierr )
               lwork_trevc = int( work(1) )
               maxwrk = max( maxwrk, n + lwork_trevc )
               CALL chseqr( 'S', 'V', n, 1, n, a, lda, w, vl, ldvl,
     $                      work, -1, info )
            ELSE IF( wantvr ) THEN
               maxwrk = max( maxwrk, n + ( n - 1 )*ilaenv( 1, 'CUNGHR',
     $                       ' ', n, 1, n, -1 ) )
               CALL ctrevc3( 'R', 'B', SELECT, n, a, lda,
     $                       vl, ldvl, vr, ldvr,
     $                       n, nout, work, -1, rwork, -1, ierr )
               lwork_trevc = int( work(1) )
               maxwrk = max( maxwrk, n + lwork_trevc )
               CALL chseqr( 'S', 'V', n, 1, n, a, lda, w, vr, ldvr,
     $                      work, -1, info )
            ELSE
               CALL chseqr( 'E', 'N', n, 1, n, a, lda, w, vr, ldvr,
     $                      work, -1, info )
            END IF
            hswork = int( work(1) )
            maxwrk = max( maxwrk, hswork, minwrk )
         END IF
         work( 1 ) = maxwrk
*
         IF( lwork.LT.minwrk .AND. .NOT.lquery ) THEN
            info = -12
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CGEEV ', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Get machine constants
*
      eps = slamch( 'P' )
      smlnum = slamch( 'S' )
      bignum = one / smlnum
      CALL slabad( smlnum, bignum )
      smlnum = sqrt( smlnum ) / eps
      bignum = one / smlnum
*
*     Scale A if max element outside range [SMLNUM,BIGNUM]
*
      anrm = clange( 'M', n, n, a, lda, dum )
      scalea = .false.
      IF( anrm.GT.zero .AND. anrm.LT.smlnum ) THEN
         scalea = .true.
         cscale = smlnum
      ELSE IF( anrm.GT.bignum ) THEN
         scalea = .true.
         cscale = bignum
      END IF
      IF( scalea )
     $   CALL clascl( 'G', 0, 0, anrm, cscale, n, n, a, lda, ierr )
*
*     Balance the matrix
*     (CWorkspace: none)
*     (RWorkspace: need N)
*
      ibal = 1
      CALL cgebal( 'B', n, a, lda, ilo, ihi, rwork( ibal ), ierr )
*
*     Reduce to upper Hessenberg form
*     (CWorkspace: need 2*N, prefer N+N*NB)
*     (RWorkspace: none)
*
      itau = 1
      iwrk = itau + n
      CALL cgehrd( n, ilo, ihi, a, lda, work( itau ), work( iwrk ),
     $             lwork-iwrk+1, ierr )
*
      IF( wantvl ) THEN
*
*        Want left eigenvectors
*        Copy Householder vectors to VL
*
         side = 'L'
         CALL clacpy( 'L', n, n, a, lda, vl, ldvl )
*
*        Generate unitary matrix in VL
*        (CWorkspace: need 2*N-1, prefer N+(N-1)*NB)
*        (RWorkspace: none)
*
         CALL cunghr( n, ilo, ihi, vl, ldvl, work( itau ), work( iwrk ),
     $                lwork-iwrk+1, ierr )
*
*        Perform QR iteration, accumulating Schur vectors in VL
*        (CWorkspace: need 1, prefer HSWORK (see comments) )
*        (RWorkspace: none)
*
         iwrk = itau
         CALL chseqr( 'S', 'V', n, ilo, ihi, a, lda, w, vl, ldvl,
     $                work( iwrk ), lwork-iwrk+1, info )
*
         IF( wantvr ) THEN
*
*           Want left and right eigenvectors
*           Copy Schur vectors to VR
*
            side = 'B'
            CALL clacpy( 'F', n, n, vl, ldvl, vr, ldvr )
         END IF
*
      ELSE IF( wantvr ) THEN
*
*        Want right eigenvectors
*        Copy Householder vectors to VR
*
         side = 'R'
         CALL clacpy( 'L', n, n, a, lda, vr, ldvr )
*
*        Generate unitary matrix in VR
*        (CWorkspace: need 2*N-1, prefer N+(N-1)*NB)
*        (RWorkspace: none)
*
         CALL cunghr( n, ilo, ihi, vr, ldvr, work( itau ), work( iwrk ),
     $                lwork-iwrk+1, ierr )
*
*        Perform QR iteration, accumulating Schur vectors in VR
*        (CWorkspace: need 1, prefer HSWORK (see comments) )
*        (RWorkspace: none)
*
         iwrk = itau
         CALL chseqr( 'S', 'V', n, ilo, ihi, a, lda, w, vr, ldvr,
     $                work( iwrk ), lwork-iwrk+1, info )
*
      ELSE
*
*        Compute eigenvalues only
*        (CWorkspace: need 1, prefer HSWORK (see comments) )
*        (RWorkspace: none)
*
         iwrk = itau
         CALL chseqr( 'E', 'N', n, ilo, ihi, a, lda, w, vr, ldvr,
     $                work( iwrk ), lwork-iwrk+1, info )
      END IF
*
*     If INFO .NE. 0 from CHSEQR, then quit
*
      IF( info.NE.0 )
     $   GO TO 50
*
      IF( wantvl .OR. wantvr ) THEN
*
*        Compute left and/or right eigenvectors
*        (CWorkspace: need 2*N, prefer N + 2*N*NB)
*        (RWorkspace: need 2*N)
*
         irwork = ibal + n
         CALL ctrevc3( side, 'B', SELECT, n, a, lda, vl, ldvl, vr, ldvr,
     $                 n, nout, work( iwrk ), lwork-iwrk+1,
     $                 rwork( irwork ), n, ierr )
      END IF
*
      IF( wantvl ) THEN
*
*        Undo balancing of left eigenvectors
*        (CWorkspace: none)
*        (RWorkspace: need N)
*
         CALL cgebak( 'B', 'L', n, ilo, ihi, rwork( ibal ), n, vl, ldvl,
     $                ierr )
*
*        Normalize left eigenvectors and make largest component real
*
         DO 20 i = 1, n
            scl = one / scnrm2( n, vl( 1, i ), 1 )
            CALL csscal( n, scl, vl( 1, i ), 1 )
            DO 10 k = 1, n
               rwork( irwork+k-1 ) = real( vl( k, i ) )**2 +
     $                               aimag( vl( k, i ) )**2
   10       CONTINUE
            k = isamax( n, rwork( irwork ), 1 )
            tmp = conjg( vl( k, i ) ) / sqrt( rwork( irwork+k-1 ) )
            CALL cscal( n, tmp, vl( 1, i ), 1 )
            vl( k, i ) = cmplx( real( vl( k, i ) ), zero )
   20    CONTINUE
      END IF
*
      IF( wantvr ) THEN
*
*        Undo balancing of right eigenvectors
*        (CWorkspace: none)
*        (RWorkspace: need N)
*
         CALL cgebak( 'B', 'R', n, ilo, ihi, rwork( ibal ), n, vr, ldvr,
     $                ierr )
*
*        Normalize right eigenvectors and make largest component real
*
         DO 40 i = 1, n
            scl = one / scnrm2( n, vr( 1, i ), 1 )
            CALL csscal( n, scl, vr( 1, i ), 1 )
            DO 30 k = 1, n
               rwork( irwork+k-1 ) = real( vr( k, i ) )**2 +
     $                               aimag( vr( k, i ) )**2
   30       CONTINUE
            k = isamax( n, rwork( irwork ), 1 )
            tmp = conjg( vr( k, i ) ) / sqrt( rwork( irwork+k-1 ) )
            CALL cscal( n, tmp, vr( 1, i ), 1 )
            vr( k, i ) = cmplx( real( vr( k, i ) ), zero )
   40    CONTINUE
      END IF
*
*     Undo scaling if necessary
*
   50 CONTINUE
      IF( scalea ) THEN
         CALL clascl( 'G', 0, 0, cscale, anrm, n-info, 1, w( info+1 ),
     $                max( n-info, 1 ), ierr )
         IF( info.GT.0 ) THEN
            CALL clascl( 'G', 0, 0, cscale, anrm, ilo-1, 1, w, n, ierr )
         END IF
      END IF
*
      work( 1 ) = maxwrk
      RETURN
*
*     End of CGEEV
*
      END