LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ chseqr()

subroutine chseqr ( character job,
character compz,
integer n,
integer ilo,
integer ihi,
complex, dimension( ldh, * ) h,
integer ldh,
complex, dimension( * ) w,
complex, dimension( ldz, * ) z,
integer ldz,
complex, dimension( * ) work,
integer lwork,
integer info )

CHSEQR

Download CHSEQR + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!>    CHSEQR computes the eigenvalues of a Hessenberg matrix H
!>    and, optionally, the matrices T and Z from the Schur decomposition
!>    H = Z T Z**H, where T is an upper triangular matrix (the
!>    Schur form), and Z is the unitary matrix of Schur vectors.
!>
!>    Optionally Z may be postmultiplied into an input unitary
!>    matrix Q so that this routine can give the Schur factorization
!>    of a matrix A which has been reduced to the Hessenberg form H
!>    by the unitary matrix Q:  A = Q*H*Q**H = (QZ)*T*(QZ)**H.
!>
Parameters
[in]JOB
!>          JOB is CHARACTER*1
!>           = 'E':  compute eigenvalues only;
!>           = 'S':  compute eigenvalues and the Schur form T.
!>
[in]COMPZ
!>          COMPZ is CHARACTER*1
!>           = 'N':  no Schur vectors are computed;
!>           = 'I':  Z is initialized to the unit matrix and the matrix Z
!>                   of Schur vectors of H is returned;
!>           = 'V':  Z must contain an unitary matrix Q on entry, and
!>                   the product Q*Z is returned.
!>
[in]N
!>          N is INTEGER
!>           The order of the matrix H.  N >= 0.
!>
[in]ILO
!>          ILO is INTEGER
!>
[in]IHI
!>          IHI is INTEGER
!>
!>           It is assumed that H is already upper triangular in rows
!>           and columns 1:ILO-1 and IHI+1:N. ILO and IHI are normally
!>           set by a previous call to CGEBAL, and then passed to ZGEHRD
!>           when the matrix output by CGEBAL is reduced to Hessenberg
!>           form. Otherwise ILO and IHI should be set to 1 and N
!>           respectively.  If N > 0, then 1 <= ILO <= IHI <= N.
!>           If N = 0, then ILO = 1 and IHI = 0.
!>
[in,out]H
!>          H is COMPLEX array, dimension (LDH,N)
!>           On entry, the upper Hessenberg matrix H.
!>           On exit, if INFO = 0 and JOB = 'S', H contains the upper
!>           triangular matrix T from the Schur decomposition (the
!>           Schur form). If INFO = 0 and JOB = 'E', the contents of
!>           H are unspecified on exit.  (The output value of H when
!>           INFO > 0 is given under the description of INFO below.)
!>
!>           Unlike earlier versions of CHSEQR, this subroutine may
!>           explicitly H(i,j) = 0 for i > j and j = 1, 2, ... ILO-1
!>           or j = IHI+1, IHI+2, ... N.
!>
[in]LDH
!>          LDH is INTEGER
!>           The leading dimension of the array H. LDH >= max(1,N).
!>
[out]W
!>          W is COMPLEX array, dimension (N)
!>           The computed eigenvalues. If JOB = 'S', the eigenvalues are
!>           stored in the same order as on the diagonal of the Schur
!>           form returned in H, with W(i) = H(i,i).
!>
[in,out]Z
!>          Z is COMPLEX array, dimension (LDZ,N)
!>           If COMPZ = 'N', Z is not referenced.
!>           If COMPZ = 'I', on entry Z need not be set and on exit,
!>           if INFO = 0, Z contains the unitary matrix Z of the Schur
!>           vectors of H.  If COMPZ = 'V', on entry Z must contain an
!>           N-by-N matrix Q, which is assumed to be equal to the unit
!>           matrix except for the submatrix Z(ILO:IHI,ILO:IHI). On exit,
!>           if INFO = 0, Z contains Q*Z.
!>           Normally Q is the unitary matrix generated by CUNGHR
!>           after the call to CGEHRD which formed the Hessenberg matrix
!>           H. (The output value of Z when INFO > 0 is given under
!>           the description of INFO below.)
!>
[in]LDZ
!>          LDZ is INTEGER
!>           The leading dimension of the array Z.  if COMPZ = 'I' or
!>           COMPZ = 'V', then LDZ >= MAX(1,N).  Otherwise, LDZ >= 1.
!>
[out]WORK
!>          WORK is COMPLEX array, dimension (LWORK)
!>           On exit, if INFO = 0, WORK(1) returns an estimate of
!>           the optimal value for LWORK.
!>
[in]LWORK
!>          LWORK is INTEGER
!>           The dimension of the array WORK.  LWORK >= max(1,N)
!>           is sufficient and delivers very good and sometimes
!>           optimal performance.  However, LWORK as large as 11*N
!>           may be required for optimal performance.  A workspace
!>           query is recommended to determine the optimal workspace
!>           size.
!>
!>           If LWORK = -1, then CHSEQR does a workspace query.
!>           In this case, CHSEQR checks the input parameters and
!>           estimates the optimal workspace size for the given
!>           values of N, ILO and IHI.  The estimate is returned
!>           in WORK(1).  No error message related to LWORK is
!>           issued by XERBLA.  Neither H nor Z are accessed.
!>
[out]INFO
!>          INFO is INTEGER
!>             = 0:  successful exit
!>             < 0:  if INFO = -i, the i-th argument had an illegal
!>                    value
!>             > 0:  if INFO = i, CHSEQR failed to compute all of
!>                the eigenvalues.  Elements 1:ilo-1 and i+1:n of W
!>                contain those eigenvalues which have been
!>                successfully computed.  (Failures are rare.)
!>
!>                If INFO > 0 and JOB = 'E', then on exit, the
!>                remaining unconverged eigenvalues are the eigen-
!>                values of the upper Hessenberg matrix rows and
!>                columns ILO through INFO of the final, output
!>                value of H.
!>
!>                If INFO > 0 and JOB   = 'S', then on exit
!>
!>           (*)  (initial value of H)*U  = U*(final value of H)
!>
!>                where U is a unitary matrix.  The final
!>                value of  H is upper Hessenberg and triangular in
!>                rows and columns INFO+1 through IHI.
!>
!>                If INFO > 0 and COMPZ = 'V', then on exit
!>
!>                  (final value of Z)  =  (initial value of Z)*U
!>
!>                where U is the unitary matrix in (*) (regard-
!>                less of the value of JOB.)
!>
!>                If INFO > 0 and COMPZ = 'I', then on exit
!>                      (final value of Z)  = U
!>                where U is the unitary matrix in (*) (regard-
!>                less of the value of JOB.)
!>
!>                If INFO > 0 and COMPZ = 'N', then Z is not
!>                accessed.
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Contributors:
Karen Braman and Ralph Byers, Department of Mathematics, University of Kansas, USA
Further Details:
!>
!>             Default values supplied by
!>             ILAENV(ISPEC,'CHSEQR',JOB(:1)//COMPZ(:1),N,ILO,IHI,LWORK).
!>             It is suggested that these defaults be adjusted in order
!>             to attain best performance in each particular
!>             computational environment.
!>
!>            ISPEC=12: The CLAHQR vs CLAQR0 crossover point.
!>                      Default: 75. (Must be at least 11.)
!>
!>            ISPEC=13: Recommended deflation window size.
!>                      This depends on ILO, IHI and NS.  NS is the
!>                      number of simultaneous shifts returned
!>                      by ILAENV(ISPEC=15).  (See ISPEC=15 below.)
!>                      The default for (IHI-ILO+1) <= 500 is NS.
!>                      The default for (IHI-ILO+1) >  500 is 3*NS/2.
!>
!>            ISPEC=14: Nibble crossover point. (See IPARMQ for
!>                      details.)  Default: 14% of deflation window
!>                      size.
!>
!>            ISPEC=15: Number of simultaneous shifts in a multishift
!>                      QR iteration.
!>
!>                      If IHI-ILO+1 is ...
!>
!>                      greater than      ...but less    ... the
!>                      or equal to ...      than        default is
!>
!>                           1               30          NS =   2(+)
!>                          30               60          NS =   4(+)
!>                          60              150          NS =  10(+)
!>                         150              590          NS =  **
!>                         590             3000          NS =  64
!>                        3000             6000          NS = 128
!>                        6000             infinity      NS = 256
!>
!>                  (+)  By default some or all matrices of this order
!>                       are passed to the implicit double shift routine
!>                       CLAHQR and this parameter is ignored.  See
!>                       ISPEC=12 above and comments in IPARMQ for
!>                       details.
!>
!>                 (**)  The asterisks (**) indicate an ad-hoc
!>                       function of N increasing from 10 to 64.
!>
!>            ISPEC=16: Select structured matrix multiply.
!>                      If the number of simultaneous shifts (specified
!>                      by ISPEC=15) is less than 14, then the default
!>                      for ISPEC=16 is 0.  Otherwise the default for
!>                      ISPEC=16 is 2.
!>
References:
  K. Braman, R. Byers and R. Mathias, The Multi-Shift QR
  Algorithm Part I: Maintaining Well Focused Shifts, and Level 3
  Performance, SIAM Journal of Matrix Analysis, volume 23, pages
  929--947, 2002.

K. Braman, R. Byers and R. Mathias, The Multi-Shift QR Algorithm Part II: Aggressive Early Deflation, SIAM Journal of Matrix Analysis, volume 23, pages 948–973, 2002.

Definition at line 295 of file chseqr.f.

297*
298* -- LAPACK computational routine --
299* -- LAPACK is a software package provided by Univ. of Tennessee, --
300* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
301*
302* .. Scalar Arguments ..
303 INTEGER IHI, ILO, INFO, LDH, LDZ, LWORK, N
304 CHARACTER COMPZ, JOB
305* ..
306* .. Array Arguments ..
307 COMPLEX H( LDH, * ), W( * ), WORK( * ), Z( LDZ, * )
308* ..
309*
310* =====================================================================
311*
312* .. Parameters ..
313*
314* ==== Matrices of order NTINY or smaller must be processed by
315* . CLAHQR because of insufficient subdiagonal scratch space.
316* . (This is a hard limit.) ====
317 INTEGER NTINY
318 parameter( ntiny = 15 )
319*
320* ==== NL allocates some local workspace to help small matrices
321* . through a rare CLAHQR failure. NL > NTINY = 15 is
322* . required and NL <= NMIN = ILAENV(ISPEC=12,...) is recom-
323* . mended. (The default value of NMIN is 75.) Using NL = 49
324* . allows up to six simultaneous shifts and a 16-by-16
325* . deflation window. ====
326 INTEGER NL
327 parameter( nl = 49 )
328 COMPLEX ZERO, ONE
329 parameter( zero = ( 0.0e0, 0.0e0 ),
330 $ one = ( 1.0e0, 0.0e0 ) )
331 REAL RZERO
332 parameter( rzero = 0.0e0 )
333* ..
334* .. Local Arrays ..
335 COMPLEX HL( NL, NL ), WORKL( NL )
336* ..
337* .. Local Scalars ..
338 INTEGER KBOT, NMIN
339 LOGICAL INITZ, LQUERY, WANTT, WANTZ
340* ..
341* .. External Functions ..
342 INTEGER ILAENV
343 LOGICAL LSAME
344 REAL SROUNDUP_LWORK
345 EXTERNAL ilaenv, lsame, sroundup_lwork
346* ..
347* .. External Subroutines ..
348 EXTERNAL ccopy, clacpy, clahqr, claqr0, claset,
349 $ xerbla
350* ..
351* .. Intrinsic Functions ..
352 INTRINSIC cmplx, max, min, real
353* ..
354* .. Executable Statements ..
355*
356* ==== Decode and check the input parameters. ====
357*
358 wantt = lsame( job, 'S' )
359 initz = lsame( compz, 'I' )
360 wantz = initz .OR. lsame( compz, 'V' )
361 work( 1 ) = cmplx( real( max( 1, n ) ), rzero )
362 lquery = lwork.EQ.-1
363*
364 info = 0
365 IF( .NOT.lsame( job, 'E' ) .AND. .NOT.wantt ) THEN
366 info = -1
367 ELSE IF( .NOT.lsame( compz, 'N' ) .AND. .NOT.wantz ) THEN
368 info = -2
369 ELSE IF( n.LT.0 ) THEN
370 info = -3
371 ELSE IF( ilo.LT.1 .OR. ilo.GT.max( 1, n ) ) THEN
372 info = -4
373 ELSE IF( ihi.LT.min( ilo, n ) .OR. ihi.GT.n ) THEN
374 info = -5
375 ELSE IF( ldh.LT.max( 1, n ) ) THEN
376 info = -7
377 ELSE IF( ldz.LT.1 .OR. ( wantz .AND. ldz.LT.max( 1, n ) ) ) THEN
378 info = -10
379 ELSE IF( lwork.LT.max( 1, n ) .AND. .NOT.lquery ) THEN
380 info = -12
381 END IF
382*
383 IF( info.NE.0 ) THEN
384*
385* ==== Quick return in case of invalid argument. ====
386*
387 CALL xerbla( 'CHSEQR', -info )
388 RETURN
389*
390 ELSE IF( n.EQ.0 ) THEN
391*
392* ==== Quick return in case N = 0; nothing to do. ====
393*
394 RETURN
395*
396 ELSE IF( lquery ) THEN
397*
398* ==== Quick return in case of a workspace query ====
399*
400 CALL claqr0( wantt, wantz, n, ilo, ihi, h, ldh, w, ilo, ihi,
401 $ z,
402 $ ldz, work, lwork, info )
403* ==== Ensure reported workspace size is backward-compatible with
404* . previous LAPACK versions. ====
405 work( 1 ) = cmplx( max( real( work( 1 ) ), real( max( 1,
406 $ n ) ) ), rzero )
407 RETURN
408*
409 ELSE
410*
411* ==== copy eigenvalues isolated by CGEBAL ====
412*
413 IF( ilo.GT.1 )
414 $ CALL ccopy( ilo-1, h, ldh+1, w, 1 )
415 IF( ihi.LT.n )
416 $ CALL ccopy( n-ihi, h( ihi+1, ihi+1 ), ldh+1, w( ihi+1 ),
417 $ 1 )
418*
419* ==== Initialize Z, if requested ====
420*
421 IF( initz )
422 $ CALL claset( 'A', n, n, zero, one, z, ldz )
423*
424* ==== Quick return if possible ====
425*
426 IF( ilo.EQ.ihi ) THEN
427 w( ilo ) = h( ilo, ilo )
428 RETURN
429 END IF
430*
431* ==== CLAHQR/CLAQR0 crossover point ====
432*
433 nmin = ilaenv( 12, 'CHSEQR', job( : 1 ) // compz( : 1 ), n,
434 $ ilo, ihi, lwork )
435 nmin = max( ntiny, nmin )
436*
437* ==== CLAQR0 for big matrices; CLAHQR for small ones ====
438*
439 IF( n.GT.nmin ) THEN
440 CALL claqr0( wantt, wantz, n, ilo, ihi, h, ldh, w, ilo,
441 $ ihi,
442 $ z, ldz, work, lwork, info )
443 ELSE
444*
445* ==== Small matrix ====
446*
447 CALL clahqr( wantt, wantz, n, ilo, ihi, h, ldh, w, ilo,
448 $ ihi,
449 $ z, ldz, info )
450*
451 IF( info.GT.0 ) THEN
452*
453* ==== A rare CLAHQR failure! CLAQR0 sometimes succeeds
454* . when CLAHQR fails. ====
455*
456 kbot = info
457*
458 IF( n.GE.nl ) THEN
459*
460* ==== Larger matrices have enough subdiagonal scratch
461* . space to call CLAQR0 directly. ====
462*
463 CALL claqr0( wantt, wantz, n, ilo, kbot, h, ldh, w,
464 $ ilo, ihi, z, ldz, work, lwork, info )
465*
466 ELSE
467*
468* ==== Tiny matrices don't have enough subdiagonal
469* . scratch space to benefit from CLAQR0. Hence,
470* . tiny matrices must be copied into a larger
471* . array before calling CLAQR0. ====
472*
473 CALL clacpy( 'A', n, n, h, ldh, hl, nl )
474 hl( n+1, n ) = zero
475 CALL claset( 'A', nl, nl-n, zero, zero, hl( 1,
476 $ n+1 ),
477 $ nl )
478 CALL claqr0( wantt, wantz, nl, ilo, kbot, hl, nl,
479 $ w,
480 $ ilo, ihi, z, ldz, workl, nl, info )
481 IF( wantt .OR. info.NE.0 )
482 $ CALL clacpy( 'A', n, n, hl, nl, h, ldh )
483 END IF
484 END IF
485 END IF
486*
487* ==== Clear out the trash, if necessary. ====
488*
489 IF( ( wantt .OR. info.NE.0 ) .AND. n.GT.2 )
490 $ CALL claset( 'L', n-2, n-2, zero, zero, h( 3, 1 ), ldh )
491*
492* ==== Ensure reported workspace size is backward-compatible with
493* . previous LAPACK versions. ====
494*
495 work( 1 ) = cmplx( max( real( max( 1, n ) ),
496 $ real( work( 1 ) ) ), rzero )
497 END IF
498*
499* ==== End of CHSEQR ====
500*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
ccopy
subroutine ccopy(n, cx, incx, cy, incy)
CCOPY
Definition ccopy.f:81
ilaenv
integer function ilaenv(ispec, name, opts, n1, n2, n3, n4)
ILAENV
Definition ilaenv.f:160
clacpy
subroutine clacpy(uplo, m, n, a, lda, b, ldb)
CLACPY copies all or part of one two-dimensional array to another.
Definition clacpy.f:101
clahqr
subroutine clahqr(wantt, wantz, n, ilo, ihi, h, ldh, w, iloz, ihiz, z, ldz, info)
CLAHQR computes the eigenvalues and Schur factorization of an upper Hessenberg matrix,...
Definition clahqr.f:193
claqr0
subroutine claqr0(wantt, wantz, n, ilo, ihi, h, ldh, w, iloz, ihiz, z, ldz, work, lwork, info)
CLAQR0 computes the eigenvalues of a Hessenberg matrix, and optionally the matrices from the Schur de...
Definition claqr0.f:238
claset
subroutine claset(uplo, m, n, alpha, beta, a, lda)
CLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values.
Definition claset.f:104
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
sroundup_lwork
real function sroundup_lwork(lwork)
SROUNDUP_LWORK
Definition sroundup_lwork.f:59
Here is the call graph for this function:
Here is the caller graph for this function: