LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
ssbgvd.f
Go to the documentation of this file.
1*> \brief \b SSBGVD
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> Download SSBGVD + dependencies
9*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/ssbgvd.f">
10*> [TGZ]</a>
11*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/ssbgvd.f">
12*> [ZIP]</a>
13*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/ssbgvd.f">
14*> [TXT]</a>
15*
16* Definition:
17* ===========
18*
19* SUBROUTINE SSBGVD( JOBZ, UPLO, N, KA, KB, AB, LDAB, BB, LDBB, W,
20* Z, LDZ, WORK, LWORK, IWORK, LIWORK, INFO )
21*
22* .. Scalar Arguments ..
23* CHARACTER JOBZ, UPLO
24* INTEGER INFO, KA, KB, LDAB, LDBB, LDZ, LIWORK, LWORK, N
25* ..
26* .. Array Arguments ..
27* INTEGER IWORK( * )
28* REAL AB( LDAB, * ), BB( LDBB, * ), W( * ),
29* $ WORK( * ), Z( LDZ, * )
30* ..
31*
32*
33*> \par Purpose:
34* =============
35*>
36*> \verbatim
37*>
38*> SSBGVD computes all the eigenvalues, and optionally, the eigenvectors
39*> of a real generalized symmetric-definite banded eigenproblem, of the
40*> form A*x=(lambda)*B*x. Here A and B are assumed to be symmetric and
41*> banded, and B is also positive definite. If eigenvectors are
42*> desired, it uses a divide and conquer algorithm.
43*>
44*> \endverbatim
45*
46* Arguments:
47* ==========
48*
49*> \param[in] JOBZ
50*> \verbatim
51*> JOBZ is CHARACTER*1
52*> = 'N': Compute eigenvalues only;
53*> = 'V': Compute eigenvalues and eigenvectors.
54*> \endverbatim
55*>
56*> \param[in] UPLO
57*> \verbatim
58*> UPLO is CHARACTER*1
59*> = 'U': Upper triangles of A and B are stored;
60*> = 'L': Lower triangles of A and B are stored.
61*> \endverbatim
62*>
63*> \param[in] N
64*> \verbatim
65*> N is INTEGER
66*> The order of the matrices A and B. N >= 0.
67*> \endverbatim
68*>
69*> \param[in] KA
70*> \verbatim
71*> KA is INTEGER
72*> The number of superdiagonals of the matrix A if UPLO = 'U',
73*> or the number of subdiagonals if UPLO = 'L'. KA >= 0.
74*> \endverbatim
75*>
76*> \param[in] KB
77*> \verbatim
78*> KB is INTEGER
79*> The number of superdiagonals of the matrix B if UPLO = 'U',
80*> or the number of subdiagonals if UPLO = 'L'. KB >= 0.
81*> \endverbatim
82*>
83*> \param[in,out] AB
84*> \verbatim
85*> AB is REAL array, dimension (LDAB, N)
86*> On entry, the upper or lower triangle of the symmetric band
87*> matrix A, stored in the first ka+1 rows of the array. The
88*> j-th column of A is stored in the j-th column of the array AB
89*> as follows:
90*> if UPLO = 'U', AB(ka+1+i-j,j) = A(i,j) for max(1,j-ka)<=i<=j;
91*> if UPLO = 'L', AB(1+i-j,j) = A(i,j) for j<=i<=min(n,j+ka).
92*>
93*> On exit, the contents of AB are destroyed.
94*> \endverbatim
95*>
96*> \param[in] LDAB
97*> \verbatim
98*> LDAB is INTEGER
99*> The leading dimension of the array AB. LDAB >= KA+1.
100*> \endverbatim
101*>
102*> \param[in,out] BB
103*> \verbatim
104*> BB is REAL array, dimension (LDBB, N)
105*> On entry, the upper or lower triangle of the symmetric band
106*> matrix B, stored in the first kb+1 rows of the array. The
107*> j-th column of B is stored in the j-th column of the array BB
108*> as follows:
109*> if UPLO = 'U', BB(ka+1+i-j,j) = B(i,j) for max(1,j-kb)<=i<=j;
110*> if UPLO = 'L', BB(1+i-j,j) = B(i,j) for j<=i<=min(n,j+kb).
111*>
112*> On exit, the factor S from the split Cholesky factorization
113*> B = S**T*S, as returned by SPBSTF.
114*> \endverbatim
115*>
116*> \param[in] LDBB
117*> \verbatim
118*> LDBB is INTEGER
119*> The leading dimension of the array BB. LDBB >= KB+1.
120*> \endverbatim
121*>
122*> \param[out] W
123*> \verbatim
124*> W is REAL array, dimension (N)
125*> If INFO = 0, the eigenvalues in ascending order.
126*> \endverbatim
127*>
128*> \param[out] Z
129*> \verbatim
130*> Z is REAL array, dimension (LDZ, N)
131*> If JOBZ = 'V', then if INFO = 0, Z contains the matrix Z of
132*> eigenvectors, with the i-th column of Z holding the
133*> eigenvector associated with W(i). The eigenvectors are
134*> normalized so Z**T*B*Z = I.
135*> If JOBZ = 'N', then Z is not referenced.
136*> \endverbatim
137*>
138*> \param[in] LDZ
139*> \verbatim
140*> LDZ is INTEGER
141*> The leading dimension of the array Z. LDZ >= 1, and if
142*> JOBZ = 'V', LDZ >= max(1,N).
143*> \endverbatim
144*>
145*> \param[out] WORK
146*> \verbatim
147*> WORK is REAL array, dimension (MAX(1,LWORK))
148*> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
149*> \endverbatim
150*>
151*> \param[in] LWORK
152*> \verbatim
153*> LWORK is INTEGER
154*> The dimension of the array WORK.
155*> If N <= 1, LWORK >= 1.
156*> If JOBZ = 'N' and N > 1, LWORK >= 3*N.
157*> If JOBZ = 'V' and N > 1, LWORK >= 1 + 5*N + 2*N**2.
158*>
159*> If LWORK = -1, then a workspace query is assumed; the routine
160*> only calculates the optimal sizes of the WORK and IWORK
161*> arrays, returns these values as the first entries of the WORK
162*> and IWORK arrays, and no error message related to LWORK or
163*> LIWORK is issued by XERBLA.
164*> \endverbatim
165*>
166*> \param[out] IWORK
167*> \verbatim
168*> IWORK is INTEGER array, dimension (MAX(1,LIWORK))
169*> On exit, if LIWORK > 0, IWORK(1) returns the optimal LIWORK.
170*> \endverbatim
171*>
172*> \param[in] LIWORK
173*> \verbatim
174*> LIWORK is INTEGER
175*> The dimension of the array IWORK.
176*> If JOBZ = 'N' or N <= 1, LIWORK >= 1.
177*> If JOBZ = 'V' and N > 1, LIWORK >= 3 + 5*N.
178*>
179*> If LIWORK = -1, then a workspace query is assumed; the
180*> routine only calculates the optimal sizes of the WORK and
181*> IWORK arrays, returns these values as the first entries of
182*> the WORK and IWORK arrays, and no error message related to
183*> LWORK or LIWORK is issued by XERBLA.
184*> \endverbatim
185*>
186*> \param[out] INFO
187*> \verbatim
188*> INFO is INTEGER
189*> = 0: successful exit
190*> < 0: if INFO = -i, the i-th argument had an illegal value
191*> > 0: if INFO = i, and i is:
192*> <= N: the algorithm failed to converge:
193*> i off-diagonal elements of an intermediate
194*> tridiagonal form did not converge to zero;
195*> > N: if INFO = N + i, for 1 <= i <= N, then SPBSTF
196*> returned INFO = i: B is not positive definite.
197*> The factorization of B could not be completed and
198*> no eigenvalues or eigenvectors were computed.
199*> \endverbatim
200*
201* Authors:
202* ========
203*
204*> \author Univ. of Tennessee
205*> \author Univ. of California Berkeley
206*> \author Univ. of Colorado Denver
207*> \author NAG Ltd.
208*
209*> \ingroup hbgvd
210*
211*> \par Contributors:
212* ==================
213*>
214*> Mark Fahey, Department of Mathematics, Univ. of Kentucky, USA
215*
216* =====================================================================
217 SUBROUTINE ssbgvd( JOBZ, UPLO, N, KA, KB, AB, LDAB, BB, LDBB,
218 $ W,
219 $ Z, LDZ, WORK, LWORK, IWORK, LIWORK, INFO )
220*
221* -- LAPACK driver routine --
222* -- LAPACK is a software package provided by Univ. of Tennessee, --
223* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
224*
225* .. Scalar Arguments ..
226 CHARACTER JOBZ, UPLO
227 INTEGER INFO, KA, KB, LDAB, LDBB, LDZ, LIWORK, LWORK, N
228* ..
229* .. Array Arguments ..
230 INTEGER IWORK( * )
231 REAL AB( LDAB, * ), BB( LDBB, * ), W( * ),
232 $ work( * ), z( ldz, * )
233* ..
234*
235* =====================================================================
236*
237* .. Parameters ..
238 REAL ONE, ZERO
239 PARAMETER ( ONE = 1.0e+0, zero = 0.0e+0 )
240* ..
241* .. Local Scalars ..
242 LOGICAL LQUERY, UPPER, WANTZ
243 CHARACTER VECT
244 INTEGER IINFO, INDE, INDWK2, INDWRK, LIWMIN, LLWRK2,
245 $ lwmin
246* ..
247* .. External Functions ..
248 LOGICAL LSAME
249 REAL SROUNDUP_LWORK
250 EXTERNAL lsame, sroundup_lwork
251* ..
252* .. External Subroutines ..
253 EXTERNAL sgemm, slacpy, spbstf, ssbgst, ssbtrd,
254 $ sstedc,
255 $ ssterf, xerbla
256* ..
257* .. Executable Statements ..
258*
259* Test the input parameters.
260*
261 wantz = lsame( jobz, 'V' )
262 upper = lsame( uplo, 'U' )
263 lquery = ( lwork.EQ.-1 .OR. liwork.EQ.-1 )
264*
265 info = 0
266 IF( n.LE.1 ) THEN
267 liwmin = 1
268 lwmin = 1
269 ELSE IF( wantz ) THEN
270 liwmin = 3 + 5*n
271 lwmin = 1 + 5*n + 2*n**2
272 ELSE
273 liwmin = 1
274 lwmin = 2*n
275 END IF
276*
277 IF( .NOT.( wantz .OR. lsame( jobz, 'N' ) ) ) THEN
278 info = -1
279 ELSE IF( .NOT.( upper .OR. lsame( uplo, 'L' ) ) ) THEN
280 info = -2
281 ELSE IF( n.LT.0 ) THEN
282 info = -3
283 ELSE IF( ka.LT.0 ) THEN
284 info = -4
285 ELSE IF( kb.LT.0 .OR. kb.GT.ka ) THEN
286 info = -5
287 ELSE IF( ldab.LT.ka+1 ) THEN
288 info = -7
289 ELSE IF( ldbb.LT.kb+1 ) THEN
290 info = -9
291 ELSE IF( ldz.LT.1 .OR. ( wantz .AND. ldz.LT.n ) ) THEN
292 info = -12
293 END IF
294*
295 IF( info.EQ.0 ) THEN
296 work( 1 ) = sroundup_lwork(lwmin)
297 iwork( 1 ) = liwmin
298*
299 IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
300 info = -14
301 ELSE IF( liwork.LT.liwmin .AND. .NOT.lquery ) THEN
302 info = -16
303 END IF
304 END IF
305*
306 IF( info.NE.0 ) THEN
307 CALL xerbla( 'SSBGVD', -info )
308 RETURN
309 ELSE IF( lquery ) THEN
310 RETURN
311 END IF
312*
313* Quick return if possible
314*
315 IF( n.EQ.0 )
316 $ RETURN
317*
318* Form a split Cholesky factorization of B.
319*
320 CALL spbstf( uplo, n, kb, bb, ldbb, info )
321 IF( info.NE.0 ) THEN
322 info = n + info
323 RETURN
324 END IF
325*
326* Transform problem to standard eigenvalue problem.
327*
328 inde = 1
329 indwrk = inde + n
330 indwk2 = indwrk + n*n
331 llwrk2 = lwork - indwk2 + 1
332 CALL ssbgst( jobz, uplo, n, ka, kb, ab, ldab, bb, ldbb, z, ldz,
333 $ work, iinfo )
334*
335* Reduce to tridiagonal form.
336*
337 IF( wantz ) THEN
338 vect = 'U'
339 ELSE
340 vect = 'N'
341 END IF
342 CALL ssbtrd( vect, uplo, n, ka, ab, ldab, w, work( inde ), z,
343 $ ldz,
344 $ work( indwrk ), iinfo )
345*
346* For eigenvalues only, call SSTERF. For eigenvectors, call SSTEDC.
347*
348 IF( .NOT.wantz ) THEN
349 CALL ssterf( n, w, work( inde ), info )
350 ELSE
351 CALL sstedc( 'I', n, w, work( inde ), work( indwrk ), n,
352 $ work( indwk2 ), llwrk2, iwork, liwork, info )
353 CALL sgemm( 'N', 'N', n, n, n, one, z, ldz, work( indwrk ),
354 $ n,
355 $ zero, work( indwk2 ), n )
356 CALL slacpy( 'A', n, n, work( indwk2 ), n, z, ldz )
357 END IF
358*
359 work( 1 ) = sroundup_lwork(lwmin)
360 iwork( 1 ) = liwmin
361*
362 RETURN
363*
364* End of SSBGVD
365*
366 END
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
sgemm
subroutine sgemm(transa, transb, m, n, k, alpha, a, lda, b, ldb, beta, c, ldc)
SGEMM
Definition sgemm.f:188
ssbgst
subroutine ssbgst(vect, uplo, n, ka, kb, ab, ldab, bb, ldbb, x, ldx, work, info)
SSBGST
Definition ssbgst.f:158
ssbgvd
subroutine ssbgvd(jobz, uplo, n, ka, kb, ab, ldab, bb, ldbb, w, z, ldz, work, lwork, iwork, liwork, info)
SSBGVD
Definition ssbgvd.f:220
ssbtrd
subroutine ssbtrd(vect, uplo, n, kd, ab, ldab, d, e, q, ldq, work, info)
SSBTRD
Definition ssbtrd.f:161
slacpy
subroutine slacpy(uplo, m, n, a, lda, b, ldb)
SLACPY copies all or part of one two-dimensional array to another.
Definition slacpy.f:101
spbstf
subroutine spbstf(uplo, n, kd, ab, ldab, info)
SPBSTF
Definition spbstf.f:150
sstedc
subroutine sstedc(compz, n, d, e, z, ldz, work, lwork, iwork, liwork, info)
SSTEDC
Definition sstedc.f:180
ssterf
subroutine ssterf(n, d, e, info)
SSTERF
Definition ssterf.f:84