sstedc.f

Go to the documentation of this file.

*> \brief \b SSTEDC
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download SSTEDC + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sstedc.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sstedc.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sstedc.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       SUBROUTINE SSTEDC( COMPZ, N, D, E, Z, LDZ, WORK, LWORK, IWORK,
*                          LIWORK, INFO )
*
*       .. Scalar Arguments ..
*       CHARACTER          COMPZ
*       INTEGER            INFO, LDZ, LIWORK, LWORK, N
*       ..
*       .. Array Arguments ..
*       INTEGER            IWORK( * )
*       REAL               D( * ), E( * ), WORK( * ), Z( LDZ, * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SSTEDC computes all eigenvalues and, optionally, eigenvectors of a
*> symmetric tridiagonal matrix using the divide and conquer method.
*> The eigenvectors of a full or band real symmetric matrix can also be
*> found if SSYTRD or SSPTRD or SSBTRD has been used to reduce this
*> matrix to tridiagonal form.
*>
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] COMPZ
*> \verbatim
*>          COMPZ is CHARACTER*1
*>          = 'N':  Compute eigenvalues only.
*>          = 'I':  Compute eigenvectors of tridiagonal matrix also.
*>          = 'V':  Compute eigenvectors of original dense symmetric
*>                  matrix also.  On entry, Z contains the orthogonal
*>                  matrix used to reduce the original matrix to
*>                  tridiagonal form.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The dimension of the symmetric tridiagonal matrix.  N >= 0.
*> \endverbatim
*>
*> \param[in,out] D
*> \verbatim
*>          D is REAL array, dimension (N)
*>          On entry, the diagonal elements of the tridiagonal matrix.
*>          On exit, if INFO = 0, the eigenvalues in ascending order.
*> \endverbatim
*>
*> \param[in,out] E
*> \verbatim
*>          E is REAL array, dimension (N-1)
*>          On entry, the subdiagonal elements of the tridiagonal matrix.
*>          On exit, E has been destroyed.
*> \endverbatim
*>
*> \param[in,out] Z
*> \verbatim
*>          Z is REAL array, dimension (LDZ,N)
*>          On entry, if COMPZ = 'V', then Z contains the orthogonal
*>          matrix used in the reduction to tridiagonal form.
*>          On exit, if INFO = 0, then if COMPZ = 'V', Z contains the
*>          orthonormal eigenvectors of the original symmetric matrix,
*>          and if COMPZ = 'I', Z contains the orthonormal eigenvectors
*>          of the symmetric tridiagonal matrix.
*>          If  COMPZ = 'N', then Z is not referenced.
*> \endverbatim
*>
*> \param[in] LDZ
*> \verbatim
*>          LDZ is INTEGER
*>          The leading dimension of the array Z.  LDZ >= 1.
*>          If eigenvectors are desired, then LDZ >= max(1,N).
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension (MAX(1,LWORK))
*>          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The dimension of the array WORK.
*>          If COMPZ = 'N' or N <= 1 then LWORK must be at least 1.
*>          If COMPZ = 'V' and N > 1 then LWORK must be at least
*>                         ( 1 + 3*N + 2*N*lg N + 4*N**2 ),
*>                         where lg( N ) = smallest integer k such
*>                         that 2**k >= N.
*>          If COMPZ = 'I' and N > 1 then LWORK must be at least
*>                         ( 1 + 4*N + N**2 ).
*>          Note that for COMPZ = 'I' or 'V', then if N is less than or
*>          equal to the minimum divide size, usually 25, then LWORK need
*>          only be max(1,2*(N-1)).
*>
*>          If LWORK = -1, then a workspace query is assumed; the routine
*>          only calculates the optimal size of the WORK array, returns
*>          this value as the first entry of the WORK array, and no error
*>          message related to LWORK is issued by XERBLA.
*> \endverbatim
*>
*> \param[out] IWORK
*> \verbatim
*>          IWORK is INTEGER array, dimension (MAX(1,LIWORK))
*>          On exit, if INFO = 0, IWORK(1) returns the optimal LIWORK.
*> \endverbatim
*>
*> \param[in] LIWORK
*> \verbatim
*>          LIWORK is INTEGER
*>          The dimension of the array IWORK.
*>          If COMPZ = 'N' or N <= 1 then LIWORK must be at least 1.
*>          If COMPZ = 'V' and N > 1 then LIWORK must be at least
*>                         ( 6 + 6*N + 5*N*lg N ).
*>          If COMPZ = 'I' and N > 1 then LIWORK must be at least
*>                         ( 3 + 5*N ).
*>          Note that for COMPZ = 'I' or 'V', then if N is less than or
*>          equal to the minimum divide size, usually 25, then LIWORK
*>          need only be 1.
*>
*>          If LIWORK = -1, then a workspace query is assumed; the
*>          routine only calculates the optimal size of the IWORK array,
*>          returns this value as the first entry of the IWORK array, and
*>          no error message related to LIWORK is issued by XERBLA.
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit.
*>          < 0:  if INFO = -i, the i-th argument had an illegal value.
*>          > 0:  The algorithm failed to compute an eigenvalue while
*>                working on the submatrix lying in rows and columns
*>                INFO/(N+1) through mod(INFO,N+1).
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup stedc
*
*> \par Contributors:
*  ==================
*>
*> Jeff Rutter, Computer Science Division, University of California
*> at Berkeley, USA \n
*>  Modified by Francoise Tisseur, University of Tennessee
*>
*  =====================================================================
      SUBROUTINE sstedc( COMPZ, N, D, E, Z, LDZ, WORK, LWORK, IWORK,
     $                   LIWORK, INFO )
*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          COMPZ
      INTEGER            INFO, LDZ, LIWORK, LWORK, N
*     ..
*     .. Array Arguments ..
      INTEGER            IWORK( * )
      REAL               D( * ), E( * ), WORK( * ), Z( LDZ, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE, TWO
      parameter( zero = 0.0e0, one = 1.0e0, two = 2.0e0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY
      INTEGER            FINISH, I, ICOMPZ, II, J, K, LGN, LIWMIN,
     $                   lwmin, m, smlsiz, start, storez, strtrw
      REAL               EPS, ORGNRM, P, TINY
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ILAENV
      REAL               SLAMCH, SLANST, SROUNDUP_LWORK
      EXTERNAL           ilaenv, lsame, slamch, slanst, sroundup_lwork
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemm, slacpy, slaed0, slascl, slaset, slasrt,
     $                   ssteqr, ssterf, sswap, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, int, log, max, mod, real, sqrt
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      lquery = ( lwork.EQ.-1 .OR. liwork.EQ.-1 )
*
      IF( lsame( compz, 'N' ) ) THEN
         icompz = 0
      ELSE IF( lsame( compz, 'V' ) ) THEN
         icompz = 1
      ELSE IF( lsame( compz, 'I' ) ) THEN
         icompz = 2
      ELSE
         icompz = -1
      END IF
      IF( icompz.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( ( ldz.LT.1 ) .OR.
     $         ( icompz.GT.0 .AND. ldz.LT.max( 1, n ) ) ) THEN
         info = -6
      END IF
*
      IF( info.EQ.0 ) THEN
*
*        Compute the workspace requirements
*
         smlsiz = ilaenv( 9, 'SSTEDC', ' ', 0, 0, 0, 0 )
         IF( n.LE.1 .OR. icompz.EQ.0 ) THEN
            liwmin = 1
            lwmin = 1
         ELSE IF( n.LE.smlsiz ) THEN
            liwmin = 1
            lwmin = 2*( n - 1 )
         ELSE
            lgn = int( log( real( n ) )/log( two ) )
            IF( 2**lgn.LT.n )
     $         lgn = lgn + 1
            IF( 2**lgn.LT.n )
     $         lgn = lgn + 1
            IF( icompz.EQ.1 ) THEN
               lwmin = 1 + 3*n + 2*n*lgn + 4*n**2
               liwmin = 6 + 6*n + 5*n*lgn
            ELSE IF( icompz.EQ.2 ) THEN
               lwmin = 1 + 4*n + n**2
               liwmin = 3 + 5*n
            END IF
         END IF
         work( 1 ) = sroundup_lwork(lwmin)
         iwork( 1 ) = liwmin
*
         IF( lwork.LT.lwmin .AND. .NOT. lquery ) THEN
            info = -8
         ELSE IF( liwork.LT.liwmin .AND. .NOT. lquery ) THEN
            info = -10
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SSTEDC', -info )
         RETURN
      ELSE IF (lquery) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
      IF( n.EQ.1 ) THEN
         IF( icompz.NE.0 )
     $      z( 1, 1 ) = one
         RETURN
      END IF
*
*     If the following conditional clause is removed, then the routine
*     will use the Divide and Conquer routine to compute only the
*     eigenvalues, which requires (3N + 3N**2) real workspace and
*     (2 + 5N + 2N lg(N)) integer workspace.
*     Since on many architectures SSTERF is much faster than any other
*     algorithm for finding eigenvalues only, it is used here
*     as the default. If the conditional clause is removed, then
*     information on the size of workspace needs to be changed.
*
*     If COMPZ = 'N', use SSTERF to compute the eigenvalues.
*
      IF( icompz.EQ.0 ) THEN
         CALL ssterf( n, d, e, info )
         GO TO 50
      END IF
*
*     If N is smaller than the minimum divide size (SMLSIZ+1), then
*     solve the problem with another solver.
*
      IF( n.LE.smlsiz ) THEN
*
         CALL ssteqr( compz, n, d, e, z, ldz, work, info )
*
      ELSE
*
*        If COMPZ = 'V', the Z matrix must be stored elsewhere for later
*        use.
*
         IF( icompz.EQ.1 ) THEN
            storez = 1 + n*n
         ELSE
            storez = 1
         END IF
*
         IF( icompz.EQ.2 ) THEN
            CALL slaset( 'Full', n, n, zero, one, z, ldz )
         END IF
*
*        Scale.
*
         orgnrm = slanst( 'M', n, d, e )
         IF( orgnrm.EQ.zero )
     $      GO TO 50
*
         eps = slamch( 'Epsilon' )
*
         start = 1
*
*        while ( START <= N )
*
   10    CONTINUE
         IF( start.LE.n ) THEN
*
*           Let FINISH be the position of the next subdiagonal entry
*           such that E( FINISH ) <= TINY or FINISH = N if no such
*           subdiagonal exists.  The matrix identified by the elements
*           between START and FINISH constitutes an independent
*           sub-problem.
*
            finish = start
   20       CONTINUE
            IF( finish.LT.n ) THEN
               tiny = eps*sqrt( abs( d( finish ) ) )*
     $                    sqrt( abs( d( finish+1 ) ) )
               IF( abs( e( finish ) ).GT.tiny ) THEN
                  finish = finish + 1
                  GO TO 20
               END IF
            END IF
*
*           (Sub) Problem determined.  Compute its size and solve it.
*
            m = finish - start + 1
            IF( m.EQ.1 ) THEN
               start = finish + 1
               GO TO 10
            END IF
            IF( m.GT.smlsiz ) THEN
*
*              Scale.
*
               orgnrm = slanst( 'M', m, d( start ), e( start ) )
               CALL slascl( 'G', 0, 0, orgnrm, one, m, 1, d( start ), m,
     $                      info )
               CALL slascl( 'G', 0, 0, orgnrm, one, m-1, 1, e( start ),
     $                      m-1, info )
*
               IF( icompz.EQ.1 ) THEN
                  strtrw = 1
               ELSE
                  strtrw = start
               END IF
               CALL slaed0( icompz, n, m, d( start ), e( start ),
     $                      z( strtrw, start ), ldz, work( 1 ), n,
     $                      work( storez ), iwork, info )
               IF( info.NE.0 ) THEN
                  info = ( info / ( m+1 )+start-1 )*( n+1 ) +
     $                   mod( info, ( m+1 ) ) + start - 1
                  GO TO 50
               END IF
*
*              Scale back.
*
               CALL slascl( 'G', 0, 0, one, orgnrm, m, 1, d( start ), m,
     $                      info )
*
            ELSE
               IF( icompz.EQ.1 ) THEN
*
*                 Since QR won't update a Z matrix which is larger than
*                 the length of D, we must solve the sub-problem in a
*                 workspace and then multiply back into Z.
*
                  CALL ssteqr( 'I', m, d( start ), e( start ), work, m,
     $                         work( m*m+1 ), info )
                  CALL slacpy( 'A', n, m, z( 1, start ), ldz,
     $                         work( storez ), n )
                  CALL sgemm( 'N', 'N', n, m, m, one,
     $                        work( storez ), n, work, m, zero,
     $                        z( 1, start ), ldz )
               ELSE IF( icompz.EQ.2 ) THEN
                  CALL ssteqr( 'I', m, d( start ), e( start ),
     $                         z( start, start ), ldz, work, info )
               ELSE
                  CALL ssterf( m, d( start ), e( start ), info )
               END IF
               IF( info.NE.0 ) THEN
                  info = start*( n+1 ) + finish
                  GO TO 50
               END IF
            END IF
*
            start = finish + 1
            GO TO 10
         END IF
*
*        endwhile
*
         IF( icompz.EQ.0 ) THEN
*
*          Use Quick Sort
*
           CALL slasrt( 'I', n, d, info )
*
         ELSE
*
*          Use Selection Sort to minimize swaps of eigenvectors
*
           DO 40 ii = 2, n
              i = ii - 1
              k = i
              p = d( i )
              DO 30 j = ii, n
                 IF( d( j ).LT.p ) THEN
                    k = j
                    p = d( j )
                 END IF
   30         CONTINUE
              IF( k.NE.i ) THEN
                 d( k ) = d( i )
                 d( i ) = p
                 CALL sswap( n, z( 1, i ), 1, z( 1, k ), 1 )
              END IF
   40      CONTINUE
         END IF
      END IF
*
   50 CONTINUE
      work( 1 ) = sroundup_lwork(lwmin)
      iwork( 1 ) = liwmin
*
      RETURN
*
*     End of SSTEDC
*
      END