dglmts()

subroutine dglmts	(	integer	n,
		integer	m,
		integer	p,
		double precision, dimension( lda, * )	a,
		double precision, dimension( lda, * )	af,
		integer	lda,
		double precision, dimension( ldb, * )	b,
		double precision, dimension( ldb, * )	bf,
		integer	ldb,
		double precision, dimension( * )	d,
		double precision, dimension( * )	df,
		double precision, dimension( * )	x,
		double precision, dimension( * )	u,
		double precision, dimension( lwork )	work,
		integer	lwork,
		double precision, dimension( * )	rwork,
		double precision	result
	)

DGLMTS

Purpose:

 DGLMTS tests DGGGLM - a subroutine for solving the generalized
 linear model problem.

Parameters

[in]	N	N is INTEGER The number of rows of the matrices A and B. N >= 0.
[in]	M	M is INTEGER The number of columns of the matrix A. M >= 0.
[in]	P	P is INTEGER The number of columns of the matrix B. P >= 0.
[in]	A	A is DOUBLE PRECISION array, dimension (LDA,M) The N-by-M matrix A.
[out]	AF	AF is DOUBLE PRECISION array, dimension (LDA,M)
[in]	LDA	LDA is INTEGER The leading dimension of the arrays A, AF. LDA >= max(M,N).
[in]	B	B is DOUBLE PRECISION array, dimension (LDB,P) The N-by-P matrix A.
[out]	BF	BF is DOUBLE PRECISION array, dimension (LDB,P)
[in]	LDB	LDB is INTEGER The leading dimension of the arrays B, BF. LDB >= max(P,N).
[in]	D	D is DOUBLE PRECISION array, dimension( N ) On input, the left hand side of the GLM.
[out]	DF	DF is DOUBLE PRECISION array, dimension( N )
[out]	X	X is DOUBLE PRECISION array, dimension( M ) solution vector X in the GLM problem.
[out]	U	U is DOUBLE PRECISION array, dimension( P ) solution vector U in the GLM problem.
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The dimension of the array WORK.
[out]	RWORK	RWORK is DOUBLE PRECISION array, dimension (M)
[out]	RESULT	RESULT is DOUBLE PRECISION The test ratio: norm( d - A*x - B*u ) RESULT = ----------------------------------------- (norm(A)+norm(B))*(norm(x)+norm(u))*EPS

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 144 of file dglmts.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LDB, LWORK, M, N, P
      DOUBLE PRECISION   RESULT
*     ..
*     .. Array Arguments ..
*
*  ====================================================================
*
      DOUBLE PRECISION   A( LDA, * ), AF( LDA, * ), B( LDB, * ),
     $                   BF( LDB, * ), D( * ), DF( * ), RWORK( * ),
     $                   U( * ), WORK( LWORK ), X( * )
*     ..
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            INFO
      DOUBLE PRECISION   ANORM, BNORM, DNORM, EPS, UNFL, XNORM, YNORM
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DASUM, DLAMCH, DLANGE
      EXTERNAL           dasum, dlamch, dlange
*     ..
*     .. External Subroutines ..
*
      EXTERNAL           dcopy, dgemv, dggglm, dlacpy
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
      eps = dlamch( 'Epsilon' )
      unfl = dlamch( 'Safe minimum' )
      anorm = max( dlange( '1', n, m, a, lda, rwork ), unfl )
      bnorm = max( dlange( '1', n, p, b, ldb, rwork ), unfl )
*
*     Copy the matrices A and B to the arrays AF and BF,
*     and the vector D the array DF.
*
      CALL dlacpy( 'Full', n, m, a, lda, af, lda )
      CALL dlacpy( 'Full', n, p, b, ldb, bf, ldb )
      CALL dcopy( n, d, 1, df, 1 )
*
*     Solve GLM problem
*
      CALL dggglm( n, m, p, af, lda, bf, ldb, df, x, u, work, lwork,
     $             info )
*
*     Test the residual for the solution of LSE
*
*                       norm( d - A*x - B*u )
*       RESULT = -----------------------------------------
*                (norm(A)+norm(B))*(norm(x)+norm(u))*EPS
*
      CALL dcopy( n, d, 1, df, 1 )
      CALL dgemv( 'No transpose', n, m, -one, a, lda, x, 1, one, df, 1 )
*
      CALL dgemv( 'No transpose', n, p, -one, b, ldb, u, 1, one, df, 1 )
*
      dnorm = dasum( n, df, 1 )
      xnorm = dasum( m, x, 1 ) + dasum( p, u, 1 )
      ynorm = anorm + bnorm
*
      IF( xnorm.LE.zero ) THEN
         result = zero
      ELSE
         result = ( ( dnorm / ynorm ) / xnorm ) / eps
      END IF
*
      RETURN
*
*     End of DGLMTS
*

Here is the call graph for this function:

Here is the caller graph for this function: