dstt21()

subroutine dstt21	(	integer	n,
		integer	kband,
		double precision, dimension( * )	ad,
		double precision, dimension( * )	ae,
		double precision, dimension( * )	sd,
		double precision, dimension( * )	se,
		double precision, dimension( ldu, * )	u,
		integer	ldu,
		double precision, dimension( * )	work,
		double precision, dimension( 2 )	result )

DSTT21

Purpose:

!>
!> DSTT21 checks a decomposition of the form
!>
!>    A = U S U'
!>
!> where ' means transpose, A is symmetric tridiagonal, U is orthogonal,
!> and S is diagonal (if KBAND=0) or symmetric tridiagonal (if KBAND=1).
!> Two tests are performed:
!>
!>    RESULT(1) = | A - U S U' | / ( |A| n ulp )
!>
!>    RESULT(2) = | I - UU' | / ( n ulp )
!> 

Parameters

[in]	N	!> N is INTEGER !> The size of the matrix. If it is zero, DSTT21 does nothing. !> It must be at least zero. !>
[in]	KBAND	!> KBAND is INTEGER !> The bandwidth of the matrix S. It may only be zero or one. !> If zero, then S is diagonal, and SE is not referenced. If !> one, then S is symmetric tri-diagonal. !>
[in]	AD	!> AD is DOUBLE PRECISION array, dimension (N) !> The diagonal of the original (unfactored) matrix A. A is !> assumed to be symmetric tridiagonal. !>
[in]	AE	!> AE is DOUBLE PRECISION array, dimension (N-1) !> The off-diagonal of the original (unfactored) matrix A. A !> is assumed to be symmetric tridiagonal. AE(1) is the (1,2) !> and (2,1) element, AE(2) is the (2,3) and (3,2) element, etc. !>
[in]	SD	!> SD is DOUBLE PRECISION array, dimension (N) !> The diagonal of the (symmetric tri-) diagonal matrix S. !>
[in]	SE	!> SE is DOUBLE PRECISION array, dimension (N-1) !> The off-diagonal of the (symmetric tri-) diagonal matrix S. !> Not referenced if KBSND=0. If KBAND=1, then AE(1) is the !> (1,2) and (2,1) element, SE(2) is the (2,3) and (3,2) !> element, etc. !>
[in]	U	!> U is DOUBLE PRECISION array, dimension (LDU, N) !> The orthogonal matrix in the decomposition. !>
[in]	LDU	!> LDU is INTEGER !> The leading dimension of U. LDU must be at least N. !>
[out]	WORK	!> WORK is DOUBLE PRECISION array, dimension (N*(N+1)) !>
[out]	RESULT	!> RESULT is DOUBLE PRECISION array, dimension (2) !> The values computed by the two tests described above. The !> values are currently limited to 1/ulp, to avoid overflow. !> RESULT(1) is always modified. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 125 of file dstt21.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            KBAND, LDU, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   AD( * ), AE( * ), RESULT( 2 ), SD( * ),
     $                   SE( * ), U( LDU, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d0, one = 1.0d0 )
*     ..
*     .. Local Scalars ..
      INTEGER            J
      DOUBLE PRECISION   ANORM, TEMP1, TEMP2, ULP, UNFL, WNORM
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, DLANGE, DLANSY
      EXTERNAL           dlamch, dlange, dlansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgemm, dlaset, dsyr, dsyr2
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, max, min
*     ..
*     .. Executable Statements ..
*
*     1)      Constants
*
      result( 1 ) = zero
      result( 2 ) = zero
      IF( n.LE.0 )
     $   RETURN
*
      unfl = dlamch( 'Safe minimum' )
      ulp = dlamch( 'Precision' )
*
*     Do Test 1
*
*     Copy A & Compute its 1-Norm:
*
      CALL dlaset( 'Full', n, n, zero, zero, work, n )
*
      anorm = zero
      temp1 = zero
*
      DO 10 j = 1, n - 1
         work( ( n+1 )*( j-1 )+1 ) = ad( j )
         work( ( n+1 )*( j-1 )+2 ) = ae( j )
         temp2 = abs( ae( j ) )
         anorm = max( anorm, abs( ad( j ) )+temp1+temp2 )
         temp1 = temp2
   10 CONTINUE
*
      work( n**2 ) = ad( n )
      anorm = max( anorm, abs( ad( n ) )+temp1, unfl )
*
*     Norm of A - USU'
*
      DO 20 j = 1, n
         CALL dsyr( 'L', n, -sd( j ), u( 1, j ), 1, work, n )
   20 CONTINUE
*
      IF( n.GT.1 .AND. kband.EQ.1 ) THEN
         DO 30 j = 1, n - 1
            CALL dsyr2( 'L', n, -se( j ), u( 1, j ), 1, u( 1, j+1 ), 1,
     $                  work, n )
   30    CONTINUE
      END IF
*
      wnorm = dlansy( '1', 'L', n, work, n, work( n**2+1 ) )
*
      IF( anorm.GT.wnorm ) THEN
         result( 1 ) = ( wnorm / anorm ) / ( n*ulp )
      ELSE
         IF( anorm.LT.one ) THEN
            result( 1 ) = ( min( wnorm, n*anorm ) / anorm ) / ( n*ulp )
         ELSE
            result( 1 ) = min( wnorm / anorm, dble( n ) ) / ( n*ulp )
         END IF
      END IF
*
*     Do Test 2
*
*     Compute  UU' - I
*
      CALL dgemm( 'N', 'C', n, n, n, one, u, ldu, u, ldu, zero, work,
     $            n )
*
      DO 40 j = 1, n
         work( ( n+1 )*( j-1 )+1 ) = work( ( n+1 )*( j-1 )+1 ) - one
   40 CONTINUE
*
      result( 2 ) = min( dble( n ), dlange( '1', n, n, work, n,
     $              work( n**2+1 ) ) ) / ( n*ulp )
*
      RETURN
*
*     End of DSTT21
*

Here is the call graph for this function:

Here is the caller graph for this function: