LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ sgbsvxx()

subroutine sgbsvxx ( character fact,
character trans,
integer n,
integer kl,
integer ku,
integer nrhs,
real, dimension( ldab, * ) ab,
integer ldab,
real, dimension( ldafb, * ) afb,
integer ldafb,
integer, dimension( * ) ipiv,
character equed,
real, dimension( * ) r,
real, dimension( * ) c,
real, dimension( ldb, * ) b,
integer ldb,
real, dimension( ldx , * ) x,
integer ldx,
real rcond,
real rpvgrw,
real, dimension( * ) berr,
integer n_err_bnds,
real, dimension( nrhs, * ) err_bnds_norm,
real, dimension( nrhs, * ) err_bnds_comp,
integer nparams,
real, dimension( * ) params,
real, dimension( * ) work,
integer, dimension( * ) iwork,
integer info )

SGBSVXX computes the solution to system of linear equations A * X = B for GB matrices

Download SGBSVXX + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!>    SGBSVXX uses the LU factorization to compute the solution to a
!>    real system of linear equations  A * X = B,  where A is an
!>    N-by-N matrix and X and B are N-by-NRHS matrices.
!>
!>    If requested, both normwise and maximum componentwise error bounds
!>    are returned. SGBSVXX will return a solution with a tiny
!>    guaranteed error (O(eps) where eps is the working machine
!>    precision) unless the matrix is very ill-conditioned, in which
!>    case a warning is returned. Relevant condition numbers also are
!>    calculated and returned.
!>
!>    SGBSVXX accepts user-provided factorizations and equilibration
!>    factors; see the definitions of the FACT and EQUED options.
!>    Solving with refinement and using a factorization from a previous
!>    SGBSVXX call will also produce a solution with either O(eps)
!>    errors or warnings, but we cannot make that claim for general
!>    user-provided factorizations and equilibration factors if they
!>    differ from what SGBSVXX would itself produce.
!>
Description:
!>
!>    The following steps are performed:
!>
!>    1. If FACT = 'E', real scaling factors are computed to equilibrate
!>    the system:
!>
!>      TRANS = 'N':  diag(R)*A*diag(C)     *inv(diag(C))*X = diag(R)*B
!>      TRANS = 'T': (diag(R)*A*diag(C))**T *inv(diag(R))*X = diag(C)*B
!>      TRANS = 'C': (diag(R)*A*diag(C))**H *inv(diag(R))*X = diag(C)*B
!>
!>    Whether or not the system will be equilibrated depends on the
!>    scaling of the matrix A, but if equilibration is used, A is
!>    overwritten by diag(R)*A*diag(C) and B by diag(R)*B (if TRANS='N')
!>    or diag(C)*B (if TRANS = 'T' or 'C').
!>
!>    2. If FACT = 'N' or 'E', the LU decomposition is used to factor
!>    the matrix A (after equilibration if FACT = 'E') as
!>
!>      A = P * L * U,
!>
!>    where P is a permutation matrix, L is a unit lower triangular
!>    matrix, and U is upper triangular.
!>
!>    3. If some U(i,i)=0, so that U is exactly singular, then the
!>    routine returns with INFO = i. Otherwise, the factored form of A
!>    is used to estimate the condition number of the matrix A (see
!>    argument RCOND). If the reciprocal of the condition number is less
!>    than machine precision, the routine still goes on to solve for X
!>    and compute error bounds as described below.
!>
!>    4. The system of equations is solved for X using the factored form
!>    of A.
!>
!>    5. By default (unless PARAMS(LA_LINRX_ITREF_I) is set to zero),
!>    the routine will use iterative refinement to try to get a small
!>    error and error bounds.  Refinement calculates the residual to at
!>    least twice the working precision.
!>
!>    6. If equilibration was used, the matrix X is premultiplied by
!>    diag(C) (if TRANS = 'N') or diag(R) (if TRANS = 'T' or 'C') so
!>    that it solves the original system before equilibration.
!> 
!>     Some optional parameters are bundled in the PARAMS array.  These
!>     settings determine how refinement is performed, but often the
!>     defaults are acceptable.  If the defaults are acceptable, users
!>     can pass NPARAMS = 0 which prevents the source code from accessing
!>     the PARAMS argument.
!>
Parameters
[in]FACT
!>          FACT is CHARACTER*1
!>     Specifies whether or not the factored form of the matrix A is
!>     supplied on entry, and if not, whether the matrix A should be
!>     equilibrated before it is factored.
!>       = 'F':  On entry, AF and IPIV contain the factored form of A.
!>               If EQUED is not 'N', the matrix A has been
!>               equilibrated with scaling factors given by R and C.
!>               A, AF, and IPIV are not modified.
!>       = 'N':  The matrix A will be copied to AF and factored.
!>       = 'E':  The matrix A will be equilibrated if necessary, then
!>               copied to AF and factored.
!>
[in]TRANS
!>          TRANS is CHARACTER*1
!>     Specifies the form of the system of equations:
!>       = 'N':  A * X = B     (No transpose)
!>       = 'T':  A**T * X = B  (Transpose)
!>       = 'C':  A**H * X = B  (Conjugate Transpose = Transpose)
!>
[in]N
!>          N is INTEGER
!>     The number of linear equations, i.e., the order of the
!>     matrix A.  N >= 0.
!>
[in]KL
!>          KL is INTEGER
!>     The number of subdiagonals within the band of A.  KL >= 0.
!>
[in]KU
!>          KU is INTEGER
!>     The number of superdiagonals within the band of A.  KU >= 0.
!>
[in]NRHS
!>          NRHS is INTEGER
!>     The number of right hand sides, i.e., the number of columns
!>     of the matrices B and X.  NRHS >= 0.
!>
[in,out]AB
!>          AB is REAL array, dimension (LDAB,N)
!>     On entry, the matrix A in band storage, in rows 1 to KL+KU+1.
!>     The j-th column of A is stored in the j-th column of the
!>     array AB as follows:
!>     AB(KU+1+i-j,j) = A(i,j) for max(1,j-KU)<=i<=min(N,j+kl)
!>
!>     If FACT = 'F' and EQUED is not 'N', then AB must have been
!>     equilibrated by the scaling factors in R and/or C.  AB is not
!>     modified if FACT = 'F' or 'N', or if FACT = 'E' and
!>     EQUED = 'N' on exit.
!>
!>     On exit, if EQUED .ne. 'N', A is scaled as follows:
!>     EQUED = 'R':  A := diag(R) * A
!>     EQUED = 'C':  A := A * diag(C)
!>     EQUED = 'B':  A := diag(R) * A * diag(C).
!>
[in]LDAB
!>          LDAB is INTEGER
!>     The leading dimension of the array AB.  LDAB >= KL+KU+1.
!>
[in,out]AFB
!>          AFB is REAL array, dimension (LDAFB,N)
!>     If FACT = 'F', then AFB is an input argument and on entry
!>     contains details of the LU factorization of the band matrix
!>     A, as computed by SGBTRF.  U is stored as an upper triangular
!>     band matrix with KL+KU superdiagonals in rows 1 to KL+KU+1,
!>     and the multipliers used during the factorization are stored
!>     in rows KL+KU+2 to 2*KL+KU+1.  If EQUED .ne. 'N', then AFB is
!>     the factored form of the equilibrated matrix A.
!>
!>     If FACT = 'N', then AF is an output argument and on exit
!>     returns the factors L and U from the factorization A = P*L*U
!>     of the original matrix A.
!>
!>     If FACT = 'E', then AF is an output argument and on exit
!>     returns the factors L and U from the factorization A = P*L*U
!>     of the equilibrated matrix A (see the description of A for
!>     the form of the equilibrated matrix).
!>
[in]LDAFB
!>          LDAFB is INTEGER
!>     The leading dimension of the array AFB.  LDAFB >= 2*KL+KU+1.
!>
[in,out]IPIV
!>          IPIV is INTEGER array, dimension (N)
!>     If FACT = 'F', then IPIV is an input argument and on entry
!>     contains the pivot indices from the factorization A = P*L*U
!>     as computed by SGETRF; row i of the matrix was interchanged
!>     with row IPIV(i).
!>
!>     If FACT = 'N', then IPIV is an output argument and on exit
!>     contains the pivot indices from the factorization A = P*L*U
!>     of the original matrix A.
!>
!>     If FACT = 'E', then IPIV is an output argument and on exit
!>     contains the pivot indices from the factorization A = P*L*U
!>     of the equilibrated matrix A.
!>
[in,out]EQUED
!>          EQUED is CHARACTER*1
!>     Specifies the form of equilibration that was done.
!>       = 'N':  No equilibration (always true if FACT = 'N').
!>       = 'R':  Row equilibration, i.e., A has been premultiplied by
!>               diag(R).
!>       = 'C':  Column equilibration, i.e., A has been postmultiplied
!>               by diag(C).
!>       = 'B':  Both row and column equilibration, i.e., A has been
!>               replaced by diag(R) * A * diag(C).
!>     EQUED is an input argument if FACT = 'F'; otherwise, it is an
!>     output argument.
!>
[in,out]R
!>          R is REAL array, dimension (N)
!>     The row scale factors for A.  If EQUED = 'R' or 'B', A is
!>     multiplied on the left by diag(R); if EQUED = 'N' or 'C', R
!>     is not accessed.  R is an input argument if FACT = 'F';
!>     otherwise, R is an output argument.  If FACT = 'F' and
!>     EQUED = 'R' or 'B', each element of R must be positive.
!>     If R is output, each element of R is a power of the radix.
!>     If R is input, each element of R should be a power of the radix
!>     to ensure a reliable solution and error estimates. Scaling by
!>     powers of the radix does not cause rounding errors unless the
!>     result underflows or overflows. Rounding errors during scaling
!>     lead to refining with a matrix that is not equivalent to the
!>     input matrix, producing error estimates that may not be
!>     reliable.
!>
[in,out]C
!>          C is REAL array, dimension (N)
!>     The column scale factors for A.  If EQUED = 'C' or 'B', A is
!>     multiplied on the right by diag(C); if EQUED = 'N' or 'R', C
!>     is not accessed.  C is an input argument if FACT = 'F';
!>     otherwise, C is an output argument.  If FACT = 'F' and
!>     EQUED = 'C' or 'B', each element of C must be positive.
!>     If C is output, each element of C is a power of the radix.
!>     If C is input, each element of C should be a power of the radix
!>     to ensure a reliable solution and error estimates. Scaling by
!>     powers of the radix does not cause rounding errors unless the
!>     result underflows or overflows. Rounding errors during scaling
!>     lead to refining with a matrix that is not equivalent to the
!>     input matrix, producing error estimates that may not be
!>     reliable.
!>
[in,out]B
!>          B is REAL array, dimension (LDB,NRHS)
!>     On entry, the N-by-NRHS right hand side matrix B.
!>     On exit,
!>     if EQUED = 'N', B is not modified;
!>     if TRANS = 'N' and EQUED = 'R' or 'B', B is overwritten by
!>        diag(R)*B;
!>     if TRANS = 'T' or 'C' and EQUED = 'C' or 'B', B is
!>        overwritten by diag(C)*B.
!>
[in]LDB
!>          LDB is INTEGER
!>     The leading dimension of the array B.  LDB >= max(1,N).
!>
[out]X
!>          X is REAL array, dimension (LDX,NRHS)
!>     If INFO = 0, the N-by-NRHS solution matrix X to the original
!>     system of equations.  Note that A and B are modified on exit
!>     if EQUED .ne. 'N', and the solution to the equilibrated system is
!>     inv(diag(C))*X if TRANS = 'N' and EQUED = 'C' or 'B', or
!>     inv(diag(R))*X if TRANS = 'T' or 'C' and EQUED = 'R' or 'B'.
!>
[in]LDX
!>          LDX is INTEGER
!>     The leading dimension of the array X.  LDX >= max(1,N).
!>
[out]RCOND
!>          RCOND is REAL
!>     Reciprocal scaled condition number.  This is an estimate of the
!>     reciprocal Skeel condition number of the matrix A after
!>     equilibration (if done).  If this is less than the machine
!>     precision (in particular, if it is zero), the matrix is singular
!>     to working precision.  Note that the error may still be small even
!>     if this number is very small and the matrix appears ill-
!>     conditioned.
!>
[out]RPVGRW
!>          RPVGRW is REAL
!>     Reciprocal pivot growth.  On exit, this contains the reciprocal
!>     pivot growth factor norm(A)/norm(U). The 
!>     norm is used.  If this is much less than 1, then the stability of
!>     the LU factorization of the (equilibrated) matrix A could be poor.
!>     This also means that the solution X, estimated condition numbers,
!>     and error bounds could be unreliable. If factorization fails with
!>     0<INFO<=N, then this contains the reciprocal pivot growth factor
!>     for the leading INFO columns of A.  In SGESVX, this quantity is
!>     returned in WORK(1).
!>
[out]BERR
!>          BERR is REAL array, dimension (NRHS)
!>     Componentwise relative backward error.  This is the
!>     componentwise relative backward error of each solution vector X(j)
!>     (i.e., the smallest relative change in any element of A or B that
!>     makes X(j) an exact solution).
!>
[in]N_ERR_BNDS
!>          N_ERR_BNDS is INTEGER
!>     Number of error bounds to return for each right hand side
!>     and each type (normwise or componentwise).  See ERR_BNDS_NORM and
!>     ERR_BNDS_COMP below.
!>
[out]ERR_BNDS_NORM
!>          ERR_BNDS_NORM is REAL array, dimension (NRHS, N_ERR_BNDS)
!>     For each right-hand side, this array contains information about
!>     various error bounds and condition numbers corresponding to the
!>     normwise relative error, which is defined as follows:
!>
!>     Normwise relative error in the ith solution vector:
!>             max_j (abs(XTRUE(j,i) - X(j,i)))
!>            ------------------------------
!>                  max_j abs(X(j,i))
!>
!>     The array is indexed by the type of error information as described
!>     below. There currently are up to three pieces of information
!>     returned.
!>
!>     The first index in ERR_BNDS_NORM(i,:) corresponds to the ith
!>     right-hand side.
!>
!>     The second index in ERR_BNDS_NORM(:,err) contains the following
!>     three fields:
!>     err = 1  boolean. Trust the answer if the
!>              reciprocal condition number is less than the threshold
!>              sqrt(n) * slamch('Epsilon').
!>
!>     err = 2  error bound: The estimated forward error,
!>              almost certainly within a factor of 10 of the true error
!>              so long as the next entry is greater than the threshold
!>              sqrt(n) * slamch('Epsilon'). This error bound should only
!>              be trusted if the previous boolean is true.
!>
!>     err = 3  Reciprocal condition number: Estimated normwise
!>              reciprocal condition number.  Compared with the threshold
!>              sqrt(n) * slamch('Epsilon') to determine if the error
!>              estimate is . These reciprocal condition
!>              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
!>              appropriately scaled matrix Z.
!>              Let Z = S*A, where S scales each row by a power of the
!>              radix so all absolute row sums of Z are approximately 1.
!>
!>     See Lapack Working Note 165 for further details and extra
!>     cautions.
!>
[out]ERR_BNDS_COMP
!>          ERR_BNDS_COMP is REAL array, dimension (NRHS, N_ERR_BNDS)
!>     For each right-hand side, this array contains information about
!>     various error bounds and condition numbers corresponding to the
!>     componentwise relative error, which is defined as follows:
!>
!>     Componentwise relative error in the ith solution vector:
!>                    abs(XTRUE(j,i) - X(j,i))
!>             max_j ----------------------
!>                         abs(X(j,i))
!>
!>     The array is indexed by the right-hand side i (on which the
!>     componentwise relative error depends), and the type of error
!>     information as described below. There currently are up to three
!>     pieces of information returned for each right-hand side. If
!>     componentwise accuracy is not requested (PARAMS(3) = 0.0), then
!>     ERR_BNDS_COMP is not accessed.  If N_ERR_BNDS < 3, then at most
!>     the first (:,N_ERR_BNDS) entries are returned.
!>
!>     The first index in ERR_BNDS_COMP(i,:) corresponds to the ith
!>     right-hand side.
!>
!>     The second index in ERR_BNDS_COMP(:,err) contains the following
!>     three fields:
!>     err = 1  boolean. Trust the answer if the
!>              reciprocal condition number is less than the threshold
!>              sqrt(n) * slamch('Epsilon').
!>
!>     err = 2  error bound: The estimated forward error,
!>              almost certainly within a factor of 10 of the true error
!>              so long as the next entry is greater than the threshold
!>              sqrt(n) * slamch('Epsilon'). This error bound should only
!>              be trusted if the previous boolean is true.
!>
!>     err = 3  Reciprocal condition number: Estimated componentwise
!>              reciprocal condition number.  Compared with the threshold
!>              sqrt(n) * slamch('Epsilon') to determine if the error
!>              estimate is . These reciprocal condition
!>              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
!>              appropriately scaled matrix Z.
!>              Let Z = S*(A*diag(x)), where x is the solution for the
!>              current right-hand side and S scales each row of
!>              A*diag(x) by a power of the radix so all absolute row
!>              sums of Z are approximately 1.
!>
!>     See Lapack Working Note 165 for further details and extra
!>     cautions.
!>
[in]NPARAMS
!>          NPARAMS is INTEGER
!>     Specifies the number of parameters set in PARAMS.  If <= 0, the
!>     PARAMS array is never referenced and default values are used.
!>
[in,out]PARAMS
!>          PARAMS is REAL array, dimension NPARAMS
!>     Specifies algorithm parameters.  If an entry is < 0.0, then
!>     that entry will be filled with default value used for that
!>     parameter.  Only positions up to NPARAMS are accessed; defaults
!>     are used for higher-numbered parameters.
!>
!>       PARAMS(LA_LINRX_ITREF_I = 1) : Whether to perform iterative
!>            refinement or not.
!>         Default: 1.0
!>            = 0.0:  No refinement is performed, and no error bounds are
!>                    computed.
!>            = 1.0:  Use the double-precision refinement algorithm,
!>                    possibly with doubled-single computations if the
!>                    compilation environment does not support DOUBLE
!>                    PRECISION.
!>              (other values are reserved for future use)
!>
!>       PARAMS(LA_LINRX_ITHRESH_I = 2) : Maximum number of residual
!>            computations allowed for refinement.
!>         Default: 10
!>         Aggressive: Set to 100 to permit convergence using approximate
!>                     factorizations or factorizations other than LU. If
!>                     the factorization uses a technique other than
!>                     Gaussian elimination, the guarantees in
!>                     err_bnds_norm and err_bnds_comp may no longer be
!>                     trustworthy.
!>
!>       PARAMS(LA_LINRX_CWISE_I = 3) : Flag determining if the code
!>            will attempt to find a solution with small componentwise
!>            relative error in the double-precision algorithm.  Positive
!>            is true, 0.0 is false.
!>         Default: 1.0 (attempt componentwise convergence)
!>
[out]WORK
!>          WORK is REAL array, dimension (4*N)
!>
[out]IWORK
!>          IWORK is INTEGER array, dimension (N)
!>
[out]INFO
!>          INFO is INTEGER
!>       = 0:  Successful exit. The solution to every right-hand side is
!>         guaranteed.
!>       < 0:  If INFO = -i, the i-th argument had an illegal value
!>       > 0 and <= N:  U(INFO,INFO) is exactly zero.  The factorization
!>         has been completed, but the factor U is exactly singular, so
!>         the solution and error bounds could not be computed. RCOND = 0
!>         is returned.
!>       = N+J: The solution corresponding to the Jth right-hand side is
!>         not guaranteed. The solutions corresponding to other right-
!>         hand sides K with K > J may not be guaranteed as well, but
!>         only the first such right-hand side is reported. If a small
!>         componentwise error is not requested (PARAMS(3) = 0.0) then
!>         the Jth right-hand side is the first with a normwise error
!>         bound that is not guaranteed (the smallest J such
!>         that ERR_BNDS_NORM(J,1) = 0.0). By default (PARAMS(3) = 1.0)
!>         the Jth right-hand side is the first with either a normwise or
!>         componentwise error bound that is not guaranteed (the smallest
!>         J such that either ERR_BNDS_NORM(J,1) = 0.0 or
!>         ERR_BNDS_COMP(J,1) = 0.0). See the definition of
!>         ERR_BNDS_NORM(:,1) and ERR_BNDS_COMP(:,1). To get information
!>         about all of the right-hand sides check ERR_BNDS_NORM or
!>         ERR_BNDS_COMP.
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 556 of file sgbsvxx.f.

562*
563* -- LAPACK driver routine --
564* -- LAPACK is a software package provided by Univ. of Tennessee, --
565* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
566*
567* .. Scalar Arguments ..
568 CHARACTER EQUED, FACT, TRANS
569 INTEGER INFO, LDAB, LDAFB, LDB, LDX, N, NRHS, NPARAMS,
570 $ N_ERR_BNDS
571 REAL RCOND, RPVGRW
572* ..
573* .. Array Arguments ..
574 INTEGER IPIV( * ), IWORK( * )
575 REAL AB( LDAB, * ), AFB( LDAFB, * ), B( LDB, * ),
576 $ X( LDX , * ),WORK( * )
577 REAL R( * ), C( * ), PARAMS( * ), BERR( * ),
578 $ ERR_BNDS_NORM( NRHS, * ),
579 $ ERR_BNDS_COMP( NRHS, * )
580* ..
581*
582* ==================================================================
583*
584* .. Parameters ..
585 REAL ZERO, ONE
586 parameter( zero = 0.0e+0, one = 1.0e+0 )
587 INTEGER FINAL_NRM_ERR_I, FINAL_CMP_ERR_I, BERR_I
588 INTEGER RCOND_I, NRM_RCOND_I, NRM_ERR_I, CMP_RCOND_I
589 INTEGER CMP_ERR_I, PIV_GROWTH_I
590 parameter( final_nrm_err_i = 1, final_cmp_err_i = 2,
591 $ berr_i = 3 )
592 parameter( rcond_i = 4, nrm_rcond_i = 5, nrm_err_i = 6 )
593 parameter( cmp_rcond_i = 7, cmp_err_i = 8,
594 $ piv_growth_i = 9 )
595* ..
596* .. Local Scalars ..
597 LOGICAL COLEQU, EQUIL, NOFACT, NOTRAN, ROWEQU
598 INTEGER INFEQU, I, J, KL, KU
599 REAL AMAX, BIGNUM, COLCND, RCMAX, RCMIN,
600 $ ROWCND, SMLNUM
601* ..
602* .. External Functions ..
603 EXTERNAL lsame, slamch, sla_gbrpvgrw
604 LOGICAL LSAME
605 REAL SLAMCH, SLA_GBRPVGRW
606* ..
607* .. External Subroutines ..
608 EXTERNAL sgbequb, sgbtrf, sgbtrs, slacpy,
609 $ slaqgb,
610 $ xerbla, slascl2, sgbrfsx
611* ..
612* .. Intrinsic Functions ..
613 INTRINSIC max, min
614* ..
615* .. Executable Statements ..
616*
617 info = 0
618 nofact = lsame( fact, 'N' )
619 equil = lsame( fact, 'E' )
620 notran = lsame( trans, 'N' )
621 smlnum = slamch( 'Safe minimum' )
622 bignum = one / smlnum
623 IF( nofact .OR. equil ) THEN
624 equed = 'N'
625 rowequ = .false.
626 colequ = .false.
627 ELSE
628 rowequ = lsame( equed, 'R' ) .OR. lsame( equed, 'B' )
629 colequ = lsame( equed, 'C' ) .OR. lsame( equed, 'B' )
630 END IF
631*
632* Default is failure. If an input parameter is wrong or
633* factorization fails, make everything look horrible. Only the
634* pivot growth is set here, the rest is initialized in SGBRFSX.
635*
636 rpvgrw = zero
637*
638* Test the input parameters. PARAMS is not tested until SGBRFSX.
639*
640 IF( .NOT.nofact .AND. .NOT.equil .AND. .NOT.
641 $ lsame( fact, 'F' ) ) THEN
642 info = -1
643 ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) .AND. .NOT.
644 $ lsame( trans, 'C' ) ) THEN
645 info = -2
646 ELSE IF( n.LT.0 ) THEN
647 info = -3
648 ELSE IF( kl.LT.0 ) THEN
649 info = -4
650 ELSE IF( ku.LT.0 ) THEN
651 info = -5
652 ELSE IF( nrhs.LT.0 ) THEN
653 info = -6
654 ELSE IF( ldab.LT.kl+ku+1 ) THEN
655 info = -8
656 ELSE IF( ldafb.LT.2*kl+ku+1 ) THEN
657 info = -10
658 ELSE IF( lsame( fact, 'F' ) .AND. .NOT.
659 $ ( rowequ .OR. colequ .OR. lsame( equed, 'N' ) ) ) THEN
660 info = -12
661 ELSE
662 IF( rowequ ) THEN
663 rcmin = bignum
664 rcmax = zero
665 DO 10 j = 1, n
666 rcmin = min( rcmin, r( j ) )
667 rcmax = max( rcmax, r( j ) )
668 10 CONTINUE
669 IF( rcmin.LE.zero ) THEN
670 info = -13
671 ELSE IF( n.GT.0 ) THEN
672 rowcnd = max( rcmin, smlnum ) / min( rcmax, bignum )
673 ELSE
674 rowcnd = one
675 END IF
676 END IF
677 IF( colequ .AND. info.EQ.0 ) THEN
678 rcmin = bignum
679 rcmax = zero
680 DO 20 j = 1, n
681 rcmin = min( rcmin, c( j ) )
682 rcmax = max( rcmax, c( j ) )
683 20 CONTINUE
684 IF( rcmin.LE.zero ) THEN
685 info = -14
686 ELSE IF( n.GT.0 ) THEN
687 colcnd = max( rcmin, smlnum ) / min( rcmax, bignum )
688 ELSE
689 colcnd = one
690 END IF
691 END IF
692 IF( info.EQ.0 ) THEN
693 IF( ldb.LT.max( 1, n ) ) THEN
694 info = -15
695 ELSE IF( ldx.LT.max( 1, n ) ) THEN
696 info = -16
697 END IF
698 END IF
699 END IF
700*
701 IF( info.NE.0 ) THEN
702 CALL xerbla( 'SGBSVXX', -info )
703 RETURN
704 END IF
705*
706 IF( equil ) THEN
707*
708* Compute row and column scalings to equilibrate the matrix A.
709*
710 CALL sgbequb( n, n, kl, ku, ab, ldab, r, c, rowcnd, colcnd,
711 $ amax, infequ )
712 IF( infequ.EQ.0 ) THEN
713*
714* Equilibrate the matrix.
715*
716 CALL slaqgb( n, n, kl, ku, ab, ldab, r, c, rowcnd,
717 $ colcnd,
718 $ amax, equed )
719 rowequ = lsame( equed, 'R' ) .OR. lsame( equed, 'B' )
720 colequ = lsame( equed, 'C' ) .OR. lsame( equed, 'B' )
721 END IF
722*
723* If the scaling factors are not applied, set them to 1.0.
724*
725 IF ( .NOT.rowequ ) THEN
726 DO j = 1, n
727 r( j ) = 1.0
728 END DO
729 END IF
730 IF ( .NOT.colequ ) THEN
731 DO j = 1, n
732 c( j ) = 1.0
733 END DO
734 END IF
735 END IF
736*
737* Scale the right hand side.
738*
739 IF( notran ) THEN
740 IF( rowequ ) CALL slascl2(n, nrhs, r, b, ldb)
741 ELSE
742 IF( colequ ) CALL slascl2(n, nrhs, c, b, ldb)
743 END IF
744*
745 IF( nofact .OR. equil ) THEN
746*
747* Compute the LU factorization of A.
748*
749 DO 40, j = 1, n
750 DO 30, i = kl+1, 2*kl+ku+1
751 afb( i, j ) = ab( i-kl, j )
752 30 CONTINUE
753 40 CONTINUE
754 CALL sgbtrf( n, n, kl, ku, afb, ldafb, ipiv, info )
755*
756* Return if INFO is non-zero.
757*
758 IF( info.GT.0 ) THEN
759*
760* Pivot in column INFO is exactly 0
761* Compute the reciprocal pivot growth factor of the
762* leading rank-deficient INFO columns of A.
763*
764 rpvgrw = sla_gbrpvgrw( n, kl, ku, info, ab, ldab, afb,
765 $ ldafb )
766 RETURN
767 END IF
768 END IF
769*
770* Compute the reciprocal pivot growth factor RPVGRW.
771*
772 rpvgrw = sla_gbrpvgrw( n, kl, ku, n, ab, ldab, afb, ldafb )
773*
774* Compute the solution matrix X.
775*
776 CALL slacpy( 'Full', n, nrhs, b, ldb, x, ldx )
777 CALL sgbtrs( trans, n, kl, ku, nrhs, afb, ldafb, ipiv, x, ldx,
778 $ info )
779*
780* Use iterative refinement to improve the computed solution and
781* compute error bounds and backward error estimates for it.
782*
783 CALL sgbrfsx( trans, equed, n, kl, ku, nrhs, ab, ldab, afb,
784 $ ldafb,
785 $ ipiv, r, c, b, ldb, x, ldx, rcond, berr,
786 $ n_err_bnds, err_bnds_norm, err_bnds_comp, nparams, params,
787 $ work, iwork, info )
788*
789* Scale solutions.
790*
791 IF ( colequ .AND. notran ) THEN
792 CALL slascl2 ( n, nrhs, c, x, ldx )
793 ELSE IF ( rowequ .AND. .NOT.notran ) THEN
794 CALL slascl2 ( n, nrhs, r, x, ldx )
795 END IF
796*
797 RETURN
798*
799* End of SGBSVXX
800*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
sgbequb
subroutine sgbequb(m, n, kl, ku, ab, ldab, r, c, rowcnd, colcnd, amax, info)
SGBEQUB
Definition sgbequb.f:159
sgbrfsx
subroutine sgbrfsx(trans, equed, n, kl, ku, nrhs, ab, ldab, afb, ldafb, ipiv, r, c, b, ldb, x, ldx, rcond, berr, n_err_bnds, err_bnds_norm, err_bnds_comp, nparams, params, work, iwork, info)
SGBRFSX
Definition sgbrfsx.f:439
sgbtrf
subroutine sgbtrf(m, n, kl, ku, ab, ldab, ipiv, info)
SGBTRF
Definition sgbtrf.f:142
sgbtrs
subroutine sgbtrs(trans, n, kl, ku, nrhs, ab, ldab, ipiv, b, ldb, info)
SGBTRS
Definition sgbtrs.f:137
sla_gbrpvgrw
real function sla_gbrpvgrw(n, kl, ku, ncols, ab, ldab, afb, ldafb)
SLA_GBRPVGRW computes the reciprocal pivot growth factor norm(A)/norm(U) for a general banded matrix.
Definition sla_gbrpvgrw.f:115
slacpy
subroutine slacpy(uplo, m, n, a, lda, b, ldb)
SLACPY copies all or part of one two-dimensional array to another.
Definition slacpy.f:101
slamch
real function slamch(cmach)
SLAMCH
Definition slamch.f:68
slaqgb
subroutine slaqgb(m, n, kl, ku, ab, ldab, r, c, rowcnd, colcnd, amax, equed)
SLAQGB scales a general band matrix, using row and column scaling factors computed by sgbequ.
Definition slaqgb.f:158
slascl2
subroutine slascl2(m, n, d, x, ldx)
SLASCL2 performs diagonal scaling on a matrix.
Definition slascl2.f:88
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
Here is the call graph for this function:
Here is the caller graph for this function: