sgbtrs()

subroutine sgbtrs	(	character	trans,
		integer	n,
		integer	kl,
		integer	ku,
		integer	nrhs,
		real, dimension( ldab, * )	ab,
		integer	ldab,
		integer, dimension( * )	ipiv,
		real, dimension( ldb, * )	b,
		integer	ldb,
		integer	info )

SGBTRS

Download SGBTRS + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> SGBTRS solves a system of linear equations
!>    A * X = B  or  A**T * X = B
!> with a general band matrix A using the LU factorization computed
!> by SGBTRF.
!> 

Parameters

[in]	TRANS	!> TRANS is CHARACTER*1 !> Specifies the form of the system of equations. !> = 'N': A * X = B (No transpose) !> = 'T': A**T* X = B (Transpose) !> = 'C': A**T* X = B (Conjugate transpose = Transpose) !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in]	KL	!> KL is INTEGER !> The number of subdiagonals within the band of A. KL >= 0. !>
[in]	KU	!> KU is INTEGER !> The number of superdiagonals within the band of A. KU >= 0. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of right hand sides, i.e., the number of columns !> of the matrix B. NRHS >= 0. !>
[in]	AB	!> AB is REAL array, dimension (LDAB,N) !> Details of the LU factorization of the band matrix A, as !> computed by SGBTRF. U is stored as an upper triangular band !> matrix with KL+KU superdiagonals in rows 1 to KL+KU+1, and !> the multipliers used during the factorization are stored in !> rows KL+KU+2 to 2*KL+KU+1. !>
[in]	LDAB	!> LDAB is INTEGER !> The leading dimension of the array AB. LDAB >= 2*KL+KU+1. !>
[in]	IPIV	!> IPIV is INTEGER array, dimension (N) !> The pivot indices; for 1 <= i <= N, row i of the matrix was !> interchanged with row IPIV(i). !>
[in,out]	B	!> B is REAL array, dimension (LDB,NRHS) !> On entry, the right hand side matrix B. !> On exit, the solution matrix X. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,N). !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 134 of file sgbtrs.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          TRANS
      INTEGER            INFO, KL, KU, LDAB, LDB, N, NRHS
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * )
      REAL               AB( LDAB, * ), B( LDB, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE
      parameter( one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LNOTI, NOTRAN
      INTEGER            I, J, KD, L, LM
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemv, sger, sswap, stbsv, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      notran = lsame( trans, 'N' )
      IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) .AND. .NOT.
     $    lsame( trans, 'C' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( kl.LT.0 ) THEN
         info = -3
      ELSE IF( ku.LT.0 ) THEN
         info = -4
      ELSE IF( nrhs.LT.0 ) THEN
         info = -5
      ELSE IF( ldab.LT.( 2*kl+ku+1 ) ) THEN
         info = -7
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -10
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SGBTRS', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 .OR. nrhs.EQ.0 )
     $   RETURN
*
      kd = ku + kl + 1
      lnoti = kl.GT.0
*
      IF( notran ) THEN
*
*        Solve  A*X = B.
*
*        Solve L*X = B, overwriting B with X.
*
*        L is represented as a product of permutations and unit lower
*        triangular matrices L = P(1) * L(1) * ... * P(n-1) * L(n-1),
*        where each transformation L(i) is a rank-one modification of
*        the identity matrix.
*
         IF( lnoti ) THEN
            DO 10 j = 1, n - 1
               lm = min( kl, n-j )
               l = ipiv( j )
               IF( l.NE.j )
     $            CALL sswap( nrhs, b( l, 1 ), ldb, b( j, 1 ), ldb )
               CALL sger( lm, nrhs, -one, ab( kd+1, j ), 1, b( j,
     $                    1 ),
     $                    ldb, b( j+1, 1 ), ldb )
   10       CONTINUE
         END IF
*
         DO 20 i = 1, nrhs
*
*           Solve U*X = B, overwriting B with X.
*
            CALL stbsv( 'Upper', 'No transpose', 'Non-unit', n,
     $                  kl+ku,
     $                  ab, ldab, b( 1, i ), 1 )
   20    CONTINUE
*
      ELSE
*
*        Solve A**T*X = B.
*
         DO 30 i = 1, nrhs
*
*           Solve U**T*X = B, overwriting B with X.
*
            CALL stbsv( 'Upper', 'Transpose', 'Non-unit', n, kl+ku,
     $                  ab,
     $                  ldab, b( 1, i ), 1 )
   30    CONTINUE
*
*        Solve L**T*X = B, overwriting B with X.
*
         IF( lnoti ) THEN
            DO 40 j = n - 1, 1, -1
               lm = min( kl, n-j )
               CALL sgemv( 'Transpose', lm, nrhs, -one, b( j+1, 1 ),
     $                     ldb, ab( kd+1, j ), 1, one, b( j, 1 ), ldb )
               l = ipiv( j )
               IF( l.NE.j )
     $            CALL sswap( nrhs, b( l, 1 ), ldb, b( j, 1 ), ldb )
   40       CONTINUE
         END IF
      END IF
      RETURN
*
*     End of SGBTRS
*

Here is the call graph for this function:

Here is the caller graph for this function: