sla_gbrpvgrw()

real function sla_gbrpvgrw	(	integer	n,
		integer	kl,
		integer	ku,
		integer	ncols,
		real, dimension( ldab, * )	ab,
		integer	ldab,
		real, dimension( ldafb, * )	afb,
		integer	ldafb
	)

SLA_GBRPVGRW computes the reciprocal pivot growth factor norm(A)/norm(U) for a general banded matrix.

Download SLA_GBRPVGRW + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 SLA_GBRPVGRW computes the reciprocal pivot growth factor
 norm(A)/norm(U). The "max absolute element" norm is used. If this is
 much less than 1, the stability of the LU factorization of the
 (equilibrated) matrix A could be poor. This also means that the
 solution X, estimated condition numbers, and error bounds could be
 unreliable.

Parameters

[in]	N	N is INTEGER The number of linear equations, i.e., the order of the matrix A. N >= 0.
[in]	KL	KL is INTEGER The number of subdiagonals within the band of A. KL >= 0.
[in]	KU	KU is INTEGER The number of superdiagonals within the band of A. KU >= 0.
[in]	NCOLS	NCOLS is INTEGER The number of columns of the matrix A. NCOLS >= 0.
[in]	AB	AB is REAL array, dimension (LDAB,N) On entry, the matrix A in band storage, in rows 1 to KL+KU+1. The j-th column of A is stored in the j-th column of the array AB as follows: AB(KU+1+i-j,j) = A(i,j) for max(1,j-KU)<=i<=min(N,j+kl)
[in]	LDAB	LDAB is INTEGER The leading dimension of the array AB. LDAB >= KL+KU+1.
[in]	AFB	AFB is REAL array, dimension (LDAFB,N) Details of the LU factorization of the band matrix A, as computed by SGBTRF. U is stored as an upper triangular band matrix with KL+KU superdiagonals in rows 1 to KL+KU+1, and the multipliers used during the factorization are stored in rows KL+KU+2 to 2*KL+KU+1.
[in]	LDAFB	LDAFB is INTEGER The leading dimension of the array AFB. LDAFB >= 2*KL+KU+1.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 115 of file sla_gbrpvgrw.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            N, KL, KU, NCOLS, LDAB, LDAFB
*     ..
*     .. Array Arguments ..
      REAL               AB( LDAB, * ), AFB( LDAFB, * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            I, J, KD
      REAL               AMAX, UMAX, RPVGRW
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min
*     ..
*     .. Executable Statements ..
*
      rpvgrw = 1.0
 
      kd = ku + 1
      DO j = 1, ncols
         amax = 0.0
         umax = 0.0
         DO i = max( j-ku, 1 ), min( j+kl, n )
            amax = max( abs( ab( kd+i-j, j)), amax )
         END DO
         DO i = max( j-ku, 1 ), j
            umax = max( abs( afb( kd+i-j, j ) ), umax )
         END DO
         IF ( umax /= 0.0 ) THEN
            rpvgrw = min( amax / umax, rpvgrw )
         END IF
      END DO
      sla_gbrpvgrw = rpvgrw
*
*     End of SLA_GBRPVGRW
*

Here is the call graph for this function:

Here is the caller graph for this function: