LAPACK 3.12.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches
sgemlq.f
Go to the documentation of this file.
1*> \brief \b SGEMLQ
2*
3* Definition:
4* ===========
5*
6* SUBROUTINE SGEMLQ( SIDE, TRANS, M, N, K, A, LDA, T,
7* \$ TSIZE, C, LDC, WORK, LWORK, INFO )
8*
9*
10* .. Scalar Arguments ..
11* CHARACTER SIDE, TRANS
12* INTEGER INFO, LDA, M, N, K, LDT, TSIZE, LWORK, LDC
13* ..
14* .. Array Arguments ..
15* REAL A( LDA, * ), T( * ), C(LDC, * ), WORK( * )
16* ..
17*
18*> \par Purpose:
19* =============
20*>
21*> \verbatim
22*>
23*> SGEMLQ overwrites the general real M-by-N matrix C with
24*>
25*> SIDE = 'L' SIDE = 'R'
26*> TRANS = 'N': Q * C C * Q
27*> TRANS = 'T': Q**T * C C * Q**T
28*> where Q is a real orthogonal matrix defined as the product
29*> of blocked elementary reflectors computed by short wide LQ
30*> factorization (SGELQ)
31*>
32*> \endverbatim
33*
34* Arguments:
35* ==========
36*
37*> \param[in] SIDE
38*> \verbatim
39*> SIDE is CHARACTER*1
40*> = 'L': apply Q or Q**T from the Left;
41*> = 'R': apply Q or Q**T from the Right.
42*> \endverbatim
43*>
44*> \param[in] TRANS
45*> \verbatim
46*> TRANS is CHARACTER*1
47*> = 'N': No transpose, apply Q;
48*> = 'T': Transpose, apply Q**T.
49*> \endverbatim
50*>
51*> \param[in] M
52*> \verbatim
53*> M is INTEGER
54*> The number of rows of the matrix A. M >=0.
55*> \endverbatim
56*>
57*> \param[in] N
58*> \verbatim
59*> N is INTEGER
60*> The number of columns of the matrix C. N >= 0.
61*> \endverbatim
62*>
63*> \param[in] K
64*> \verbatim
65*> K is INTEGER
66*> The number of elementary reflectors whose product defines
67*> the matrix Q.
68*> If SIDE = 'L', M >= K >= 0;
69*> if SIDE = 'R', N >= K >= 0.
70*> \endverbatim
71*>
72*> \param[in] A
73*> \verbatim
74*> A is REAL array, dimension
75*> (LDA,M) if SIDE = 'L',
76*> (LDA,N) if SIDE = 'R'
77*> Part of the data structure to represent Q as returned by DGELQ.
78*> \endverbatim
79*>
80*> \param[in] LDA
81*> \verbatim
82*> LDA is INTEGER
83*> The leading dimension of the array A. LDA >= max(1,K).
84*> \endverbatim
85*>
86*> \param[in] T
87*> \verbatim
88*> T is REAL array, dimension (MAX(5,TSIZE)).
89*> Part of the data structure to represent Q as returned by SGELQ.
90*> \endverbatim
91*>
92*> \param[in] TSIZE
93*> \verbatim
94*> TSIZE is INTEGER
95*> The dimension of the array T. TSIZE >= 5.
96*> \endverbatim
97*>
98*> \param[in,out] C
99*> \verbatim
100*> C is REAL array, dimension (LDC,N)
101*> On entry, the M-by-N matrix C.
102*> On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q.
103*> \endverbatim
104*>
105*> \param[in] LDC
106*> \verbatim
107*> LDC is INTEGER
108*> The leading dimension of the array C. LDC >= max(1,M).
109*> \endverbatim
110*>
111*> \param[out] WORK
112*> \verbatim
113*> (workspace) REAL array, dimension (MAX(1,LWORK))
114*> \endverbatim
115*>
116*> \param[in] LWORK
117*> \verbatim
118*> LWORK is INTEGER
119*> The dimension of the array WORK.
120*> If LWORK = -1, then a workspace query is assumed. The routine
121*> only calculates the size of the WORK array, returns this
122*> value as WORK(1), and no error message related to WORK
123*> is issued by XERBLA.
124*> \endverbatim
125*>
126*> \param[out] INFO
127*> \verbatim
128*> INFO is INTEGER
129*> = 0: successful exit
130*> < 0: if INFO = -i, the i-th argument had an illegal value
131*> \endverbatim
132*
133* Authors:
134* ========
135*
136*> \author Univ. of Tennessee
137*> \author Univ. of California Berkeley
138*> \author Univ. of Colorado Denver
139*> \author NAG Ltd.
140*
141*> \par Further Details
142* ====================
143*>
144*> \verbatim
145*>
146*> These details are particular for this LAPACK implementation. Users should not
147*> take them for granted. These details may change in the future, and are not likely
148*> true for another LAPACK implementation. These details are relevant if one wants
149*> to try to understand the code. They are not part of the interface.
150*>
151*> In this version,
152*>
153*> T(2): row block size (MB)
154*> T(3): column block size (NB)
155*> T(6:TSIZE): data structure needed for Q, computed by
156*> SLASWLQ or SGELQT
157*>
158*> Depending on the matrix dimensions M and N, and row and column
159*> block sizes MB and NB returned by ILAENV, SGELQ will use either
160*> SLASWLQ (if the matrix is wide-and-short) or SGELQT to compute
161*> the LQ factorization.
162*> This version of SGEMLQ will use either SLAMSWLQ or SGEMLQT to
163*> multiply matrix Q by another matrix.
164*> Further Details in SLAMSWLQ or SGEMLQT.
165*> \endverbatim
166*>
167*> \ingroup gemlq
168*>
169* =====================================================================
170 SUBROUTINE sgemlq( SIDE, TRANS, M, N, K, A, LDA, T, TSIZE,
171 \$ C, LDC, WORK, LWORK, INFO )
172*
173* -- LAPACK computational routine --
174* -- LAPACK is a software package provided by Univ. of Tennessee, --
175* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
176*
177* .. Scalar Arguments ..
178 CHARACTER SIDE, TRANS
179 INTEGER INFO, LDA, M, N, K, TSIZE, LWORK, LDC
180* ..
181* .. Array Arguments ..
182 REAL A( LDA, * ), T( * ), C( LDC, * ), WORK( * )
183* ..
184*
185* =====================================================================
186*
187* ..
188* .. Local Scalars ..
189 LOGICAL LEFT, RIGHT, TRAN, NOTRAN, LQUERY
190 INTEGER MB, NB, LW, NBLCKS, MN
191* ..
192* .. External Functions ..
193 LOGICAL LSAME
194 EXTERNAL lsame
195* ..
196* .. External Functions ..
197 REAL SROUNDUP_LWORK
198 EXTERNAL sroundup_lwork
199* ..
200* .. External Subroutines ..
201 EXTERNAL slamswlq, sgemlqt, xerbla
202* ..
203* .. Intrinsic Functions ..
204 INTRINSIC int, max, min, mod
205* ..
206* .. Executable Statements ..
207*
208* Test the input arguments
209*
210 lquery = lwork.EQ.-1
211 notran = lsame( trans, 'N' )
212 tran = lsame( trans, 'T' )
213 left = lsame( side, 'L' )
214 right = lsame( side, 'R' )
215*
216 mb = int( t( 2 ) )
217 nb = int( t( 3 ) )
218 IF( left ) THEN
219 lw = n * mb
220 mn = m
221 ELSE
222 lw = m * mb
223 mn = n
224 END IF
225*
226 IF( ( nb.GT.k ) .AND. ( mn.GT.k ) ) THEN
227 IF( mod( mn - k, nb - k ) .EQ. 0 ) THEN
228 nblcks = ( mn - k ) / ( nb - k )
229 ELSE
230 nblcks = ( mn - k ) / ( nb - k ) + 1
231 END IF
232 ELSE
233 nblcks = 1
234 END IF
235*
236 info = 0
237 IF( .NOT.left .AND. .NOT.right ) THEN
238 info = -1
239 ELSE IF( .NOT.tran .AND. .NOT.notran ) THEN
240 info = -2
241 ELSE IF( m.LT.0 ) THEN
242 info = -3
243 ELSE IF( n.LT.0 ) THEN
244 info = -4
245 ELSE IF( k.LT.0 .OR. k.GT.mn ) THEN
246 info = -5
247 ELSE IF( lda.LT.max( 1, k ) ) THEN
248 info = -7
249 ELSE IF( tsize.LT.5 ) THEN
250 info = -9
251 ELSE IF( ldc.LT.max( 1, m ) ) THEN
252 info = -11
253 ELSE IF( ( lwork.LT.max( 1, lw ) ) .AND. ( .NOT.lquery ) ) THEN
254 info = -13
255 END IF
256*
257 IF( info.EQ.0 ) THEN
258 work( 1 ) = sroundup_lwork( lw )
259 END IF
260*
261 IF( info.NE.0 ) THEN
262 CALL xerbla( 'SGEMLQ', -info )
263 RETURN
264 ELSE IF( lquery ) THEN
265 RETURN
266 END IF
267*
268* Quick return if possible
269*
270 IF( min( m, n, k ).EQ.0 ) THEN
271 RETURN
272 END IF
273*
274 IF( ( left .AND. m.LE.k ) .OR. ( right .AND. n.LE.k )
275 \$ .OR. ( nb.LE.k ) .OR. ( nb.GE.max( m, n, k ) ) ) THEN
276 CALL sgemlqt( side, trans, m, n, k, mb, a, lda,
277 \$ t( 6 ), mb, c, ldc, work, info )
278 ELSE
279 CALL slamswlq( side, trans, m, n, k, mb, nb, a, lda, t( 6 ),
280 \$ mb, c, ldc, work, lwork, info )
281 END IF
282*
283 work( 1 ) = sroundup_lwork( lw )
284*
285 RETURN
286*
287* End of SGEMLQ
288*
289 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine sgemlq(side, trans, m, n, k, a, lda, t, tsize, c, ldc, work, lwork, info)
SGEMLQ
Definition sgemlq.f:172
subroutine sgemlqt(side, trans, m, n, k, mb, v, ldv, t, ldt, c, ldc, work, info)
SGEMLQT
Definition sgemlqt.f:153
subroutine slamswlq(side, trans, m, n, k, mb, nb, a, lda, t, ldt, c, ldc, work, lwork, info)
SLAMSWLQ
Definition slamswlq.f:197