slamswlq.f

Go to the documentation of this file.

*> \brief \b SLAMSWLQ
*
*  Definition:
*  ===========
*
*      SUBROUTINE SLAMSWLQ( SIDE, TRANS, M, N, K, MB, NB, A, LDA, T,
*     $                LDT, C, LDC, WORK, LWORK, INFO )
*
*
*     .. Scalar Arguments ..
*      CHARACTER         SIDE, TRANS
*      INTEGER           INFO, LDA, M, N, K, MB, NB, LDT, LWORK, LDC
*     ..
*     .. Array Arguments ..
*      DOUBLE        A( LDA, * ), WORK( * ), C(LDC, * ),
*     $                  T( LDT, * )
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*>    SLAMSWLQ overwrites the general real M-by-N matrix C with
*>
*>
*>                    SIDE = 'L'     SIDE = 'R'
*>    TRANS = 'N':      Q * C          C * Q
*>    TRANS = 'T':      Q**T * C       C * Q**T
*>    where Q is a real orthogonal matrix defined as the product of blocked
*>    elementary reflectors computed by short wide LQ
*>    factorization (SLASWLQ)
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] SIDE
*> \verbatim
*>          SIDE is CHARACTER*1
*>          = 'L': apply Q or Q**T from the Left;
*>          = 'R': apply Q or Q**T from the Right.
*> \endverbatim
*>
*> \param[in] TRANS
*> \verbatim
*>          TRANS is CHARACTER*1
*>          = 'N':  No transpose, apply Q;
*>          = 'T':  Transpose, apply Q**T.
*> \endverbatim
*>
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix C.  M >=0.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrix C. N >= 0.
*> \endverbatim
*>
*> \param[in] K
*> \verbatim
*>          K is INTEGER
*>          The number of elementary reflectors whose product defines
*>          the matrix Q.
*>          M >= K >= 0;
*>
*> \endverbatim
*> \param[in] MB
*> \verbatim
*>          MB is INTEGER
*>          The row block size to be used in the blocked LQ.
*>          M >= MB >= 1
*> \endverbatim
*>
*> \param[in] NB
*> \verbatim
*>          NB is INTEGER
*>          The column block size to be used in the blocked LQ.
*>          NB > M.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is REAL array, dimension
*>                               (LDA,M) if SIDE = 'L',
*>                               (LDA,N) if SIDE = 'R'
*>          The i-th row must contain the vector which defines the blocked
*>          elementary reflector H(i), for i = 1,2,...,k, as returned by
*>          SLASWLQ in the first k rows of its array argument A.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A. LDA >= max(1,K).
*> \endverbatim
*>
*> \param[in] T
*> \verbatim
*>          T is REAL array, dimension
*>          ( M * Number of blocks(CEIL(N-K/NB-K)),
*>          The blocked upper triangular block reflectors stored in compact form
*>          as a sequence of upper triangular blocks.  See below
*>          for further details.
*> \endverbatim
*>
*> \param[in] LDT
*> \verbatim
*>          LDT is INTEGER
*>          The leading dimension of the array T.  LDT >= MB.
*> \endverbatim
*>
*> \param[in,out] C
*> \verbatim
*>          C is REAL array, dimension (LDC,N)
*>          On entry, the M-by-N matrix C.
*>          On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q.
*> \endverbatim
*>
*> \param[in] LDC
*> \verbatim
*>          LDC is INTEGER
*>          The leading dimension of the array C. LDC >= max(1,M).
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          (workspace) REAL array, dimension (MAX(1,LWORK))
*>          On exit, if INFO = 0, WORK(1) returns the minimal LWORK.
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The dimension of the array WORK.
*>
*>          If MIN(M,N,K) = 0, LWORK >= 1.
*>          If SIDE = 'L', LWORK >= max(1,NB*MB).
*>          If SIDE = 'R', LWORK >= max(1,M*MB).
*>          If LWORK = -1, then a workspace query is assumed; the routine
*>          only calculates the minimal size of the WORK array, returns
*>          this value as the first entry of the WORK array, and no error
*>          message related to LWORK is issued by XERBLA.
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit
*>          < 0:  if INFO = -i, the i-th argument had an illegal value
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \par Further Details:
*  =====================
*>
*> \verbatim
*> Short-Wide LQ (SWLQ) performs LQ by a sequence of orthogonal transformations,
*> representing Q as a product of other orthogonal matrices
*>   Q = Q(1) * Q(2) * . . . * Q(k)
*> where each Q(i) zeros out upper diagonal entries of a block of NB rows of A:
*>   Q(1) zeros out the upper diagonal entries of rows 1:NB of A
*>   Q(2) zeros out the bottom MB-N rows of rows [1:M,NB+1:2*NB-M] of A
*>   Q(3) zeros out the bottom MB-N rows of rows [1:M,2*NB-M+1:3*NB-2*M] of A
*>   . . .
*>
*> Q(1) is computed by GELQT, which represents Q(1) by Householder vectors
*> stored under the diagonal of rows 1:MB of A, and by upper triangular
*> block reflectors, stored in array T(1:LDT,1:N).
*> For more information see Further Details in GELQT.
*>
*> Q(i) for i>1 is computed by TPLQT, which represents Q(i) by Householder vectors
*> stored in columns [(i-1)*(NB-M)+M+1:i*(NB-M)+M] of A, and by upper triangular
*> block reflectors, stored in array T(1:LDT,(i-1)*M+1:i*M).
*> The last Q(k) may use fewer rows.
*> For more information see Further Details in TPLQT.
*>
*> For more details of the overall algorithm, see the description of
*> Sequential TSQR in Section 2.2 of [1].
*>
*> [1] “Communication-Optimal Parallel and Sequential QR and LU Factorizations,”
*>     J. Demmel, L. Grigori, M. Hoemmen, J. Langou,
*>     SIAM J. Sci. Comput, vol. 34, no. 1, 2012
*> \endverbatim
*>
*> \ingroup lamswlq
*>
*  =====================================================================
      SUBROUTINE slamswlq( SIDE, TRANS, M, N, K, MB, NB, A, LDA, T,
     $                     LDT, C, LDC, WORK, LWORK, INFO )
*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          SIDE, TRANS
      INTEGER            INFO, LDA, M, N, K, MB, NB, LDT, LWORK, LDC
*     ..
*     .. Array Arguments ..
      REAL               A( LDA, * ), WORK( * ), C( LDC, * ),
     $                   t( ldt, * )
*     ..
*
* =====================================================================
*
*     ..
*     .. Local Scalars ..
      LOGICAL            LEFT, RIGHT, TRAN, NOTRAN, LQUERY
      INTEGER            I, II, KK, LW, CTR, MINMNK, LWMIN
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
      REAL               SROUNDUP_LWORK
      EXTERNAL           sroundup_lwork
*     ..
*     .. External Subroutines ..
      EXTERNAL           stpmlqt, sgemlqt, xerbla
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      lquery  = ( lwork.EQ.-1 )
      notran  = lsame( trans, 'N' )
      tran    = lsame( trans, 'T' )
      left    = lsame( side, 'L' )
      right   = lsame( side, 'R' )
      IF( left ) THEN
        lw = n * mb
      ELSE
        lw = m * mb
      END IF
*
      minmnk = min( m, n, k )
      IF( minmnk.EQ.0 ) THEN
        lwmin = 1
      ELSE
        lwmin = max( 1, lw )
      END IF
*
      info = 0
      IF( .NOT.left .AND. .NOT.right ) THEN
        info = -1
      ELSE IF( .NOT.tran .AND. .NOT.notran ) THEN
        info = -2
      ELSE IF( k.LT.0 ) THEN
        info = -5
      ELSE IF( m.LT.k ) THEN
        info = -3
      ELSE IF( n.LT.0 ) THEN
        info = -4
      ELSE IF( k.LT.mb .OR. mb.LT.1 ) THEN
        info = -6
      ELSE IF( lda.LT.max( 1, k ) ) THEN
        info = -9
      ELSE IF( ldt.LT.max( 1, mb ) ) THEN
        info = -11
      ELSE IF( ldc.LT.max( 1, m ) ) THEN
        info = -13
      ELSE IF( lwork.LT.lwmin .AND. (.NOT.lquery) ) THEN
        info = -15
      END IF
*
      IF( info.EQ.0 ) THEN
        work( 1 ) = sroundup_lwork( lwmin )
      END IF
      IF( info.NE.0 ) THEN
        CALL xerbla( 'SLAMSWLQ', -info )
        RETURN
      ELSE IF( lquery ) THEN
        RETURN
      END IF
*
*     Quick return if possible
*
      IF( minmnk.EQ.0 ) THEN
        RETURN
      END IF
*
      IF((nb.LE.k).OR.(nb.GE.max(m,n,k))) THEN
        CALL sgemlqt( side, trans, m, n, k, mb, a, lda,
     $        t, ldt, c, ldc, work, info)
        RETURN
      END IF
*
      IF(left.AND.tran) THEN
*
*         Multiply Q to the last block of C
*
          kk = mod((m-k),(nb-k))
          ctr = (m-k)/(nb-k)
*
          IF (kk.GT.0) THEN
            ii=m-kk+1
            CALL stpmlqt('L','T',kk , n, k, 0, mb, a(1,ii), lda,
     $        t(1,ctr*k+1), ldt, c(1,1), ldc,
     $        c(ii,1), ldc, work, info )
          ELSE
            ii=m+1
          END IF
*
          DO i=ii-(nb-k),nb+1,-(nb-k)
*
*         Multiply Q to the current block of C (1:M,I:I+NB)
*
            ctr = ctr - 1
            CALL stpmlqt('L','T',nb-k , n, k, 0,mb, a(1,i), lda,
     $          t(1,ctr*k+1),ldt, c(1,1), ldc,
     $          c(i,1), ldc, work, info )
          END DO
*
*         Multiply Q to the first block of C (1:M,1:NB)
*
          CALL sgemlqt('L','T',nb , n, k, mb, a(1,1), lda, t
     $              ,ldt ,c(1,1), ldc, work, info )
*
      ELSE IF (left.AND.notran) THEN
*
*         Multiply Q to the first block of C
*
         kk = mod((m-k),(nb-k))
         ii=m-kk+1
         ctr = 1
         CALL sgemlqt('L','N',nb , n, k, mb, a(1,1), lda, t
     $              ,ldt ,c(1,1), ldc, work, info )
*
         DO i=nb+1,ii-nb+k,(nb-k)
*
*         Multiply Q to the current block of C (I:I+NB,1:N)
*
          CALL stpmlqt('L','N',nb-k , n, k, 0,mb, a(1,i), lda,
     $         t(1,ctr * k+1), ldt, c(1,1), ldc,
     $         c(i,1), ldc, work, info )
          ctr = ctr + 1
*
         END DO
         IF(ii.LE.m) THEN
*
*         Multiply Q to the last block of C
*
          CALL stpmlqt('L','N',kk , n, k, 0, mb, a(1,ii), lda,
     $        t(1,ctr*k+1), ldt, c(1,1), ldc,
     $        c(ii,1), ldc, work, info )
*
         END IF
*
      ELSE IF(right.AND.notran) THEN
*
*         Multiply Q to the last block of C
*
          kk = mod((n-k),(nb-k))
          ctr = (n-k)/(nb-k)
          IF (kk.GT.0) THEN
            ii=n-kk+1
            CALL stpmlqt('R','N',m , kk, k, 0, mb, a(1, ii), lda,
     $        t(1,ctr*k+1), ldt, c(1,1), ldc,
     $        c(1,ii), ldc, work, info )
          ELSE
            ii=n+1
          END IF
*
          DO i=ii-(nb-k),nb+1,-(nb-k)
*
*         Multiply Q to the current block of C (1:M,I:I+MB)
*
             ctr = ctr - 1
             CALL stpmlqt('R','N', m, nb-k, k, 0, mb, a(1, i), lda,
     $            t(1,ctr*k+1), ldt, c(1,1), ldc,
     $            c(1,i), ldc, work, info )
 
          END DO
*
*         Multiply Q to the first block of C (1:M,1:MB)
*
          CALL sgemlqt('R','N',m , nb, k, mb, a(1,1), lda, t
     $            ,ldt ,c(1,1), ldc, work, info )
*
      ELSE IF (right.AND.tran) THEN
*
*       Multiply Q to the first block of C
*
         kk = mod((n-k),(nb-k))
         ii=n-kk+1
         ctr = 1
         CALL sgemlqt('R','T',m , nb, k, mb, a(1,1), lda, t
     $            ,ldt ,c(1,1), ldc, work, info )
*
         DO i=nb+1,ii-nb+k,(nb-k)
*
*         Multiply Q to the current block of C (1:M,I:I+MB)
*
          CALL stpmlqt('R','T',m , nb-k, k, 0,mb, a(1,i), lda,
     $       t(1, ctr*k+1), ldt, c(1,1), ldc,
     $       c(1,i), ldc, work, info )
          ctr = ctr + 1
*
         END DO
         IF(ii.LE.n) THEN
*
*       Multiply Q to the last block of C
*
          CALL stpmlqt('R','T',m , kk, k, 0,mb, a(1,ii), lda,
     $      t(1,ctr*k+1),ldt, c(1,1), ldc,
     $      c(1,ii), ldc, work, info )
*
         END IF
*
      END IF
*
      work( 1 ) = sroundup_lwork( lwmin )
      RETURN
*
*     End of SLAMSWLQ
*
      SUBROUTINE slamswlq( SIDE, TRANS, M, N, K, MB, NB, A, LDA, T, …
      END