dbdt02()

subroutine dbdt02	(	integer	m,
		integer	n,
		double precision, dimension( ldb, * )	b,
		integer	ldb,
		double precision, dimension( ldc, * )	c,
		integer	ldc,
		double precision, dimension( ldu, * )	u,
		integer	ldu,
		double precision, dimension( * )	work,
		double precision	resid )

DBDT02

Purpose:

!>
!> DBDT02 tests the change of basis C = U**H * B by computing the
!> residual
!>
!>    RESID = norm(B - U * C) / ( max(m,n) * norm(B) * EPS ),
!>
!> where B and C are M by N matrices, U is an M by M orthogonal matrix,
!> and EPS is the machine precision.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrices B and C and the order of !> the matrix Q. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrices B and C. !>
[in]	B	!> B is DOUBLE PRECISION array, dimension (LDB,N) !> The m by n matrix B. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,M). !>
[in]	C	!> C is DOUBLE PRECISION array, dimension (LDC,N) !> The m by n matrix C, assumed to contain U**H * B. !>
[in]	LDC	!> LDC is INTEGER !> The leading dimension of the array C. LDC >= max(1,M). !>
[in]	U	!> U is DOUBLE PRECISION array, dimension (LDU,M) !> The m by m orthogonal matrix U. !>
[in]	LDU	!> LDU is INTEGER !> The leading dimension of the array U. LDU >= max(1,M). !>
[out]	WORK	!> WORK is DOUBLE PRECISION array, dimension (M) !>
[out]	RESID	!> RESID is DOUBLE PRECISION !> RESID = norm(B - U * C) / ( max(m,n) * norm(B) * EPS ), !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 111 of file dbdt02.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDB, LDC, LDU, M, N
      DOUBLE PRECISION   RESID
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   B( LDB, * ), C( LDC, * ), U( LDU, * ),
     $                   WORK( * )
*     ..
*
* ======================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            J
      DOUBLE PRECISION   BNORM, EPS, REALMN
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DASUM, DLAMCH, DLANGE
      EXTERNAL           dasum, dlamch, dlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           dcopy, dgemv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max, min
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      resid = zero
      IF( m.LE.0 .OR. n.LE.0 )
     $   RETURN
      realmn = dble( max( m, n ) )
      eps = dlamch( 'Precision' )
*
*     Compute norm(B - U * C)
*
      DO 10 j = 1, n
         CALL dcopy( m, b( 1, j ), 1, work, 1 )
         CALL dgemv( 'No transpose', m, m, -one, u, ldu, c( 1, j ), 1,
     $               one, work, 1 )
         resid = max( resid, dasum( m, work, 1 ) )
   10 CONTINUE
*
*     Compute norm of B.
*
      bnorm = dlange( '1', m, n, b, ldb, work )
*
      IF( bnorm.LE.zero ) THEN
         IF( resid.NE.zero )
     $      resid = one / eps
      ELSE
         IF( bnorm.GE.resid ) THEN
            resid = ( resid / bnorm ) / ( realmn*eps )
         ELSE
            IF( bnorm.LT.one ) THEN
               resid = ( min( resid, realmn*bnorm ) / bnorm ) /
     $                 ( realmn*eps )
            ELSE
               resid = min( resid / bnorm, realmn ) / ( realmn*eps )
            END IF
         END IF
      END IF
      RETURN
*
*     End of DBDT02
*

Here is the call graph for this function:

Here is the caller graph for this function: