LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ zgbsvx()

subroutine zgbsvx ( character fact,
character trans,
integer n,
integer kl,
integer ku,
integer nrhs,
complex*16, dimension( ldab, * ) ab,
integer ldab,
complex*16, dimension( ldafb, * ) afb,
integer ldafb,
integer, dimension( * ) ipiv,
character equed,
double precision, dimension( * ) r,
double precision, dimension( * ) c,
complex*16, dimension( ldb, * ) b,
integer ldb,
complex*16, dimension( ldx, * ) x,
integer ldx,
double precision rcond,
double precision, dimension( * ) ferr,
double precision, dimension( * ) berr,
complex*16, dimension( * ) work,
double precision, dimension( * ) rwork,
integer info )

ZGBSVX computes the solution to system of linear equations A * X = B for GB matrices

Download ZGBSVX + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!> ZGBSVX uses the LU factorization to compute the solution to a complex
!> system of linear equations A * X = B, A**T * X = B, or A**H * X = B,
!> where A is a band matrix of order N with KL subdiagonals and KU
!> superdiagonals, and X and B are N-by-NRHS matrices.
!>
!> Error bounds on the solution and a condition estimate are also
!> provided.
!>
Description:
!>
!> The following steps are performed by this subroutine:
!>
!> 1. If FACT = 'E', real scaling factors are computed to equilibrate
!>    the system:
!>       TRANS = 'N':  diag(R)*A*diag(C)     *inv(diag(C))*X = diag(R)*B
!>       TRANS = 'T': (diag(R)*A*diag(C))**T *inv(diag(R))*X = diag(C)*B
!>       TRANS = 'C': (diag(R)*A*diag(C))**H *inv(diag(R))*X = diag(C)*B
!>    Whether or not the system will be equilibrated depends on the
!>    scaling of the matrix A, but if equilibration is used, A is
!>    overwritten by diag(R)*A*diag(C) and B by diag(R)*B (if TRANS='N')
!>    or diag(C)*B (if TRANS = 'T' or 'C').
!>
!> 2. If FACT = 'N' or 'E', the LU decomposition is used to factor the
!>    matrix A (after equilibration if FACT = 'E') as
!>       A = L * U,
!>    where L is a product of permutation and unit lower triangular
!>    matrices with KL subdiagonals, and U is upper triangular with
!>    KL+KU superdiagonals.
!>
!> 3. If some U(i,i)=0, so that U is exactly singular, then the routine
!>    returns with INFO = i. Otherwise, the factored form of A is used
!>    to estimate the condition number of the matrix A.  If the
!>    reciprocal of the condition number is less than machine precision,
!>    INFO = N+1 is returned as a warning, but the routine still goes on
!>    to solve for X and compute error bounds as described below.
!>
!> 4. The system of equations is solved for X using the factored form
!>    of A.
!>
!> 5. Iterative refinement is applied to improve the computed solution
!>    matrix and calculate error bounds and backward error estimates
!>    for it.
!>
!> 6. If equilibration was used, the matrix X is premultiplied by
!>    diag(C) (if TRANS = 'N') or diag(R) (if TRANS = 'T' or 'C') so
!>    that it solves the original system before equilibration.
!>
Parameters
[in]FACT
!>          FACT is CHARACTER*1
!>          Specifies whether or not the factored form of the matrix A is
!>          supplied on entry, and if not, whether the matrix A should be
!>          equilibrated before it is factored.
!>          = 'F':  On entry, AFB and IPIV contain the factored form of
!>                  A.  If EQUED is not 'N', the matrix A has been
!>                  equilibrated with scaling factors given by R and C.
!>                  AB, AFB, and IPIV are not modified.
!>          = 'N':  The matrix A will be copied to AFB and factored.
!>          = 'E':  The matrix A will be equilibrated if necessary, then
!>                  copied to AFB and factored.
!>
[in]TRANS
!>          TRANS is CHARACTER*1
!>          Specifies the form of the system of equations.
!>          = 'N':  A * X = B     (No transpose)
!>          = 'T':  A**T * X = B  (Transpose)
!>          = 'C':  A**H * X = B  (Conjugate transpose)
!>
[in]N
!>          N is INTEGER
!>          The number of linear equations, i.e., the order of the
!>          matrix A.  N >= 0.
!>
[in]KL
!>          KL is INTEGER
!>          The number of subdiagonals within the band of A.  KL >= 0.
!>
[in]KU
!>          KU is INTEGER
!>          The number of superdiagonals within the band of A.  KU >= 0.
!>
[in]NRHS
!>          NRHS is INTEGER
!>          The number of right hand sides, i.e., the number of columns
!>          of the matrices B and X.  NRHS >= 0.
!>
[in,out]AB
!>          AB is COMPLEX*16 array, dimension (LDAB,N)
!>          On entry, the matrix A in band storage, in rows 1 to KL+KU+1.
!>          The j-th column of A is stored in the j-th column of the
!>          array AB as follows:
!>          AB(KU+1+i-j,j) = A(i,j) for max(1,j-KU)<=i<=min(N,j+kl)
!>
!>          If FACT = 'F' and EQUED is not 'N', then A must have been
!>          equilibrated by the scaling factors in R and/or C.  AB is not
!>          modified if FACT = 'F' or 'N', or if FACT = 'E' and
!>          EQUED = 'N' on exit.
!>
!>          On exit, if EQUED .ne. 'N', A is scaled as follows:
!>          EQUED = 'R':  A := diag(R) * A
!>          EQUED = 'C':  A := A * diag(C)
!>          EQUED = 'B':  A := diag(R) * A * diag(C).
!>
[in]LDAB
!>          LDAB is INTEGER
!>          The leading dimension of the array AB.  LDAB >= KL+KU+1.
!>
[in,out]AFB
!>          AFB is COMPLEX*16 array, dimension (LDAFB,N)
!>          If FACT = 'F', then AFB is an input argument and on entry
!>          contains details of the LU factorization of the band matrix
!>          A, as computed by ZGBTRF.  U is stored as an upper triangular
!>          band matrix with KL+KU superdiagonals in rows 1 to KL+KU+1,
!>          and the multipliers used during the factorization are stored
!>          in rows KL+KU+2 to 2*KL+KU+1.  If EQUED .ne. 'N', then AFB is
!>          the factored form of the equilibrated matrix A.
!>
!>          If FACT = 'N', then AFB is an output argument and on exit
!>          returns details of the LU factorization of A.
!>
!>          If FACT = 'E', then AFB is an output argument and on exit
!>          returns details of the LU factorization of the equilibrated
!>          matrix A (see the description of AB for the form of the
!>          equilibrated matrix).
!>
[in]LDAFB
!>          LDAFB is INTEGER
!>          The leading dimension of the array AFB.  LDAFB >= 2*KL+KU+1.
!>
[in,out]IPIV
!>          IPIV is INTEGER array, dimension (N)
!>          If FACT = 'F', then IPIV is an input argument and on entry
!>          contains the pivot indices from the factorization A = L*U
!>          as computed by ZGBTRF; row i of the matrix was interchanged
!>          with row IPIV(i).
!>
!>          If FACT = 'N', then IPIV is an output argument and on exit
!>          contains the pivot indices from the factorization A = L*U
!>          of the original matrix A.
!>
!>          If FACT = 'E', then IPIV is an output argument and on exit
!>          contains the pivot indices from the factorization A = L*U
!>          of the equilibrated matrix A.
!>
[in,out]EQUED
!>          EQUED is CHARACTER*1
!>          Specifies the form of equilibration that was done.
!>          = 'N':  No equilibration (always true if FACT = 'N').
!>          = 'R':  Row equilibration, i.e., A has been premultiplied by
!>                  diag(R).
!>          = 'C':  Column equilibration, i.e., A has been postmultiplied
!>                  by diag(C).
!>          = 'B':  Both row and column equilibration, i.e., A has been
!>                  replaced by diag(R) * A * diag(C).
!>          EQUED is an input argument if FACT = 'F'; otherwise, it is an
!>          output argument.
!>
[in,out]R
!>          R is DOUBLE PRECISION array, dimension (N)
!>          The row scale factors for A.  If EQUED = 'R' or 'B', A is
!>          multiplied on the left by diag(R); if EQUED = 'N' or 'C', R
!>          is not accessed.  R is an input argument if FACT = 'F';
!>          otherwise, R is an output argument.  If FACT = 'F' and
!>          EQUED = 'R' or 'B', each element of R must be positive.
!>
[in,out]C
!>          C is DOUBLE PRECISION array, dimension (N)
!>          The column scale factors for A.  If EQUED = 'C' or 'B', A is
!>          multiplied on the right by diag(C); if EQUED = 'N' or 'R', C
!>          is not accessed.  C is an input argument if FACT = 'F';
!>          otherwise, C is an output argument.  If FACT = 'F' and
!>          EQUED = 'C' or 'B', each element of C must be positive.
!>
[in,out]B
!>          B is COMPLEX*16 array, dimension (LDB,NRHS)
!>          On entry, the right hand side matrix B.
!>          On exit,
!>          if EQUED = 'N', B is not modified;
!>          if TRANS = 'N' and EQUED = 'R' or 'B', B is overwritten by
!>          diag(R)*B;
!>          if TRANS = 'T' or 'C' and EQUED = 'C' or 'B', B is
!>          overwritten by diag(C)*B.
!>
[in]LDB
!>          LDB is INTEGER
!>          The leading dimension of the array B.  LDB >= max(1,N).
!>
[out]X
!>          X is COMPLEX*16 array, dimension (LDX,NRHS)
!>          If INFO = 0 or INFO = N+1, the N-by-NRHS solution matrix X
!>          to the original system of equations.  Note that A and B are
!>          modified on exit if EQUED .ne. 'N', and the solution to the
!>          equilibrated system is inv(diag(C))*X if TRANS = 'N' and
!>          EQUED = 'C' or 'B', or inv(diag(R))*X if TRANS = 'T' or 'C'
!>          and EQUED = 'R' or 'B'.
!>
[in]LDX
!>          LDX is INTEGER
!>          The leading dimension of the array X.  LDX >= max(1,N).
!>
[out]RCOND
!>          RCOND is DOUBLE PRECISION
!>          The estimate of the reciprocal condition number of the matrix
!>          A after equilibration (if done).  If RCOND is less than the
!>          machine precision (in particular, if RCOND = 0), the matrix
!>          is singular to working precision.  This condition is
!>          indicated by a return code of INFO > 0.
!>
[out]FERR
!>          FERR is DOUBLE PRECISION array, dimension (NRHS)
!>          The estimated forward error bound for each solution vector
!>          X(j) (the j-th column of the solution matrix X).
!>          If XTRUE is the true solution corresponding to X(j), FERR(j)
!>          is an estimated upper bound for the magnitude of the largest
!>          element in (X(j) - XTRUE) divided by the magnitude of the
!>          largest element in X(j).  The estimate is as reliable as
!>          the estimate for RCOND, and is almost always a slight
!>          overestimate of the true error.
!>
[out]BERR
!>          BERR is DOUBLE PRECISION array, dimension (NRHS)
!>          The componentwise relative backward error of each solution
!>          vector X(j) (i.e., the smallest relative change in
!>          any element of A or B that makes X(j) an exact solution).
!>
[out]WORK
!>          WORK is COMPLEX*16 array, dimension (2*N)
!>
[out]RWORK
!>          RWORK is DOUBLE PRECISION array, dimension (MAX(1,N))
!>          On exit, RWORK(1) contains the reciprocal pivot growth
!>          factor norm(A)/norm(U). The  norm is
!>          used. If RWORK(1) is much less than 1, then the stability
!>          of the LU factorization of the (equilibrated) matrix A
!>          could be poor. This also means that the solution X, condition
!>          estimator RCOND, and forward error bound FERR could be
!>          unreliable. If factorization fails with 0<INFO<=N, then
!>          RWORK(1) contains the reciprocal pivot growth factor for the
!>          leading INFO columns of A.
!>
[out]INFO
!>          INFO is INTEGER
!>          = 0:  successful exit
!>          < 0:  if INFO = -i, the i-th argument had an illegal value
!>          > 0:  if INFO = i, and i is
!>                <= N:  U(i,i) is exactly zero.  The factorization
!>                       has been completed, but the factor U is exactly
!>                       singular, so the solution and error bounds
!>                       could not be computed. RCOND = 0 is returned.
!>                = N+1: U is nonsingular, but RCOND is less than machine
!>                       precision, meaning that the matrix is singular
!>                       to working precision.  Nevertheless, the
!>                       solution and error bounds are computed because
!>                       there are a number of situations where the
!>                       computed solution can be more accurate than the
!>                       value of RCOND would suggest.
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 365 of file zgbsvx.f.

368*
369* -- LAPACK driver routine --
370* -- LAPACK is a software package provided by Univ. of Tennessee, --
371* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
372*
373* .. Scalar Arguments ..
374 CHARACTER EQUED, FACT, TRANS
375 INTEGER INFO, KL, KU, LDAB, LDAFB, LDB, LDX, N, NRHS
376 DOUBLE PRECISION RCOND
377* ..
378* .. Array Arguments ..
379 INTEGER IPIV( * )
380 DOUBLE PRECISION BERR( * ), C( * ), FERR( * ), R( * ),
381 $ RWORK( * )
382 COMPLEX*16 AB( LDAB, * ), AFB( LDAFB, * ), B( LDB, * ),
383 $ WORK( * ), X( LDX, * )
384* ..
385*
386* =====================================================================
387* Moved setting of INFO = N+1 so INFO does not subsequently get
388* overwritten. Sven, 17 Mar 05.
389* =====================================================================
390*
391* .. Parameters ..
392 DOUBLE PRECISION ZERO, ONE
393 parameter( zero = 0.0d+0, one = 1.0d+0 )
394* ..
395* .. Local Scalars ..
396 LOGICAL COLEQU, EQUIL, NOFACT, NOTRAN, ROWEQU
397 CHARACTER NORM
398 INTEGER I, INFEQU, J, J1, J2
399 DOUBLE PRECISION AMAX, ANORM, BIGNUM, COLCND, RCMAX, RCMIN,
400 $ ROWCND, RPVGRW, SMLNUM
401* ..
402* .. External Functions ..
403 LOGICAL LSAME
404 DOUBLE PRECISION DLAMCH, ZLANGB, ZLANTB
405 EXTERNAL lsame, dlamch, zlangb, zlantb
406* ..
407* .. External Subroutines ..
408 EXTERNAL xerbla, zcopy, zgbcon, zgbequ, zgbrfs,
409 $ zgbtrf,
410 $ zgbtrs, zlacpy, zlaqgb
411* ..
412* .. Intrinsic Functions ..
413 INTRINSIC abs, max, min
414* ..
415* .. Executable Statements ..
416*
417 info = 0
418 nofact = lsame( fact, 'N' )
419 equil = lsame( fact, 'E' )
420 notran = lsame( trans, 'N' )
421 IF( nofact .OR. equil ) THEN
422 equed = 'N'
423 rowequ = .false.
424 colequ = .false.
425 ELSE
426 rowequ = lsame( equed, 'R' ) .OR. lsame( equed, 'B' )
427 colequ = lsame( equed, 'C' ) .OR. lsame( equed, 'B' )
428 smlnum = dlamch( 'Safe minimum' )
429 bignum = one / smlnum
430 END IF
431*
432* Test the input parameters.
433*
434 IF( .NOT.nofact .AND.
435 $ .NOT.equil .AND.
436 $ .NOT.lsame( fact, 'F' ) )
437 $ THEN
438 info = -1
439 ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) .AND. .NOT.
440 $ lsame( trans, 'C' ) ) THEN
441 info = -2
442 ELSE IF( n.LT.0 ) THEN
443 info = -3
444 ELSE IF( kl.LT.0 ) THEN
445 info = -4
446 ELSE IF( ku.LT.0 ) THEN
447 info = -5
448 ELSE IF( nrhs.LT.0 ) THEN
449 info = -6
450 ELSE IF( ldab.LT.kl+ku+1 ) THEN
451 info = -8
452 ELSE IF( ldafb.LT.2*kl+ku+1 ) THEN
453 info = -10
454 ELSE IF( lsame( fact, 'F' ) .AND. .NOT.
455 $ ( rowequ .OR. colequ .OR. lsame( equed, 'N' ) ) ) THEN
456 info = -12
457 ELSE
458 IF( rowequ ) THEN
459 rcmin = bignum
460 rcmax = zero
461 DO 10 j = 1, n
462 rcmin = min( rcmin, r( j ) )
463 rcmax = max( rcmax, r( j ) )
464 10 CONTINUE
465 IF( rcmin.LE.zero ) THEN
466 info = -13
467 ELSE IF( n.GT.0 ) THEN
468 rowcnd = max( rcmin, smlnum ) / min( rcmax, bignum )
469 ELSE
470 rowcnd = one
471 END IF
472 END IF
473 IF( colequ .AND. info.EQ.0 ) THEN
474 rcmin = bignum
475 rcmax = zero
476 DO 20 j = 1, n
477 rcmin = min( rcmin, c( j ) )
478 rcmax = max( rcmax, c( j ) )
479 20 CONTINUE
480 IF( rcmin.LE.zero ) THEN
481 info = -14
482 ELSE IF( n.GT.0 ) THEN
483 colcnd = max( rcmin, smlnum ) / min( rcmax, bignum )
484 ELSE
485 colcnd = one
486 END IF
487 END IF
488 IF( info.EQ.0 ) THEN
489 IF( ldb.LT.max( 1, n ) ) THEN
490 info = -16
491 ELSE IF( ldx.LT.max( 1, n ) ) THEN
492 info = -18
493 END IF
494 END IF
495 END IF
496*
497 IF( info.NE.0 ) THEN
498 CALL xerbla( 'ZGBSVX', -info )
499 RETURN
500 END IF
501*
502 IF( equil ) THEN
503*
504* Compute row and column scalings to equilibrate the matrix A.
505*
506 CALL zgbequ( n, n, kl, ku, ab, ldab, r, c, rowcnd, colcnd,
507 $ amax, infequ )
508 IF( infequ.EQ.0 ) THEN
509*
510* Equilibrate the matrix.
511*
512 CALL zlaqgb( n, n, kl, ku, ab, ldab, r, c, rowcnd,
513 $ colcnd,
514 $ amax, equed )
515 rowequ = lsame( equed, 'R' ) .OR. lsame( equed, 'B' )
516 colequ = lsame( equed, 'C' ) .OR. lsame( equed, 'B' )
517 END IF
518 END IF
519*
520* Scale the right hand side.
521*
522 IF( notran ) THEN
523 IF( rowequ ) THEN
524 DO 40 j = 1, nrhs
525 DO 30 i = 1, n
526 b( i, j ) = r( i )*b( i, j )
527 30 CONTINUE
528 40 CONTINUE
529 END IF
530 ELSE IF( colequ ) THEN
531 DO 60 j = 1, nrhs
532 DO 50 i = 1, n
533 b( i, j ) = c( i )*b( i, j )
534 50 CONTINUE
535 60 CONTINUE
536 END IF
537*
538 IF( nofact .OR. equil ) THEN
539*
540* Compute the LU factorization of the band matrix A.
541*
542 DO 70 j = 1, n
543 j1 = max( j-ku, 1 )
544 j2 = min( j+kl, n )
545 CALL zcopy( j2-j1+1, ab( ku+1-j+j1, j ), 1,
546 $ afb( kl+ku+1-j+j1, j ), 1 )
547 70 CONTINUE
548*
549 CALL zgbtrf( n, n, kl, ku, afb, ldafb, ipiv, info )
550*
551* Return if INFO is non-zero.
552*
553 IF( info.GT.0 ) THEN
554*
555* Compute the reciprocal pivot growth factor of the
556* leading rank-deficient INFO columns of A.
557*
558 anorm = zero
559 DO 90 j = 1, info
560 DO 80 i = max( ku+2-j, 1 ), min( n+ku+1-j, kl+ku+1 )
561 anorm = max( anorm, abs( ab( i, j ) ) )
562 80 CONTINUE
563 90 CONTINUE
564 rpvgrw = zlantb( 'M', 'U', 'N', info, min( info-1,
565 $ kl+ku ),
566 $ afb( max( 1, kl+ku+2-info ), 1 ), ldafb,
567 $ rwork )
568 IF( rpvgrw.EQ.zero ) THEN
569 rpvgrw = one
570 ELSE
571 rpvgrw = anorm / rpvgrw
572 END IF
573 rwork( 1 ) = rpvgrw
574 rcond = zero
575 RETURN
576 END IF
577 END IF
578*
579* Compute the norm of the matrix A and the
580* reciprocal pivot growth factor RPVGRW.
581*
582 IF( notran ) THEN
583 norm = '1'
584 ELSE
585 norm = 'I'
586 END IF
587 anorm = zlangb( norm, n, kl, ku, ab, ldab, rwork )
588 rpvgrw = zlantb( 'M', 'U', 'N', n, kl+ku, afb, ldafb, rwork )
589 IF( rpvgrw.EQ.zero ) THEN
590 rpvgrw = one
591 ELSE
592 rpvgrw = zlangb( 'M', n, kl, ku, ab, ldab, rwork ) / rpvgrw
593 END IF
594*
595* Compute the reciprocal of the condition number of A.
596*
597 CALL zgbcon( norm, n, kl, ku, afb, ldafb, ipiv, anorm, rcond,
598 $ work, rwork, info )
599*
600* Compute the solution matrix X.
601*
602 CALL zlacpy( 'Full', n, nrhs, b, ldb, x, ldx )
603 CALL zgbtrs( trans, n, kl, ku, nrhs, afb, ldafb, ipiv, x, ldx,
604 $ info )
605*
606* Use iterative refinement to improve the computed solution and
607* compute error bounds and backward error estimates for it.
608*
609 CALL zgbrfs( trans, n, kl, ku, nrhs, ab, ldab, afb, ldafb,
610 $ ipiv,
611 $ b, ldb, x, ldx, ferr, berr, work, rwork, info )
612*
613* Transform the solution matrix X to a solution of the original
614* system.
615*
616 IF( notran ) THEN
617 IF( colequ ) THEN
618 DO 110 j = 1, nrhs
619 DO 100 i = 1, n
620 x( i, j ) = c( i )*x( i, j )
621 100 CONTINUE
622 110 CONTINUE
623 DO 120 j = 1, nrhs
624 ferr( j ) = ferr( j ) / colcnd
625 120 CONTINUE
626 END IF
627 ELSE IF( rowequ ) THEN
628 DO 140 j = 1, nrhs
629 DO 130 i = 1, n
630 x( i, j ) = r( i )*x( i, j )
631 130 CONTINUE
632 140 CONTINUE
633 DO 150 j = 1, nrhs
634 ferr( j ) = ferr( j ) / rowcnd
635 150 CONTINUE
636 END IF
637*
638* Set INFO = N+1 if the matrix is singular to working precision.
639*
640 IF( rcond.LT.dlamch( 'Epsilon' ) )
641 $ info = n + 1
642*
643 rwork( 1 ) = rpvgrw
644 RETURN
645*
646* End of ZGBSVX
647*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
zcopy
subroutine zcopy(n, zx, incx, zy, incy)
ZCOPY
Definition zcopy.f:81
zgbcon
subroutine zgbcon(norm, n, kl, ku, ab, ldab, ipiv, anorm, rcond, work, rwork, info)
ZGBCON
Definition zgbcon.f:146
zgbequ
subroutine zgbequ(m, n, kl, ku, ab, ldab, r, c, rowcnd, colcnd, amax, info)
ZGBEQU
Definition zgbequ.f:153
zgbrfs
subroutine zgbrfs(trans, n, kl, ku, nrhs, ab, ldab, afb, ldafb, ipiv, b, ldb, x, ldx, ferr, berr, work, rwork, info)
ZGBRFS
Definition zgbrfs.f:205
zgbtrf
subroutine zgbtrf(m, n, kl, ku, ab, ldab, ipiv, info)
ZGBTRF
Definition zgbtrf.f:142
zgbtrs
subroutine zgbtrs(trans, n, kl, ku, nrhs, ab, ldab, ipiv, b, ldb, info)
ZGBTRS
Definition zgbtrs.f:137
zlacpy
subroutine zlacpy(uplo, m, n, a, lda, b, ldb)
ZLACPY copies all or part of one two-dimensional array to another.
Definition zlacpy.f:101
dlamch
double precision function dlamch(cmach)
DLAMCH
Definition dlamch.f:69
zlangb
double precision function zlangb(norm, n, kl, ku, ab, ldab, work)
ZLANGB returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition zlangb.f:123
zlantb
double precision function zlantb(norm, uplo, diag, n, k, ab, ldab, work)
ZLANTB returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition zlantb.f:139
zlaqgb
subroutine zlaqgb(m, n, kl, ku, ab, ldab, r, c, rowcnd, colcnd, amax, equed)
ZLAQGB scales a general band matrix, using row and column scaling factors computed by sgbequ.
Definition zlaqgb.f:159
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
Here is the call graph for this function:
Here is the caller graph for this function: