zlangb()

double precision function zlangb	(	character	norm,
		integer	n,
		integer	kl,
		integer	ku,
		complex*16, dimension( ldab, * )	ab,
		integer	ldab,
		double precision, dimension( * )	work )

ZLANGB returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of general band matrix.

Download ZLANGB + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> ZLANGB  returns the value of the one norm,  or the Frobenius norm, or
!> the  infinity norm,  or the element of  largest absolute value  of an
!> n by n band matrix  A,  with kl sub-diagonals and ku super-diagonals.
!> 

Returns

ZLANGB

!>
!>    ZLANGB = ( max(abs(A(i,j))), NORM = 'M' or 'm'
!>             (
!>             ( norm1(A),         NORM = '1', 'O' or 'o'
!>             (
!>             ( normI(A),         NORM = 'I' or 'i'
!>             (
!>             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'
!>
!> where  norm1  denotes the  one norm of a matrix (maximum column sum),
!> normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
!> normF  denotes the  Frobenius norm of a matrix (square root of sum of
!> squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
!> 

Parameters

[in]	NORM	!> NORM is CHARACTER*1 !> Specifies the value to be returned in ZLANGB as described !> above. !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. When N = 0, ZLANGB is !> set to zero. !>
[in]	KL	!> KL is INTEGER !> The number of sub-diagonals of the matrix A. KL >= 0. !>
[in]	KU	!> KU is INTEGER !> The number of super-diagonals of the matrix A. KU >= 0. !>
[in]	AB	!> AB is COMPLEX*16 array, dimension (LDAB,N) !> The band matrix A, stored in rows 1 to KL+KU+1. The j-th !> column of A is stored in the j-th column of the array AB as !> follows: !> AB(ku+1+i-j,j) = A(i,j) for max(1,j-ku)<=i<=min(n,j+kl). !>
[in]	LDAB	!> LDAB is INTEGER !> The leading dimension of the array AB. LDAB >= KL+KU+1. !>
[out]	WORK	!> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)), !> where LWORK >= N when NORM = 'I'; otherwise, WORK is not !> referenced. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 121 of file zlangb.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          NORM
      INTEGER            KL, KU, LDAB, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   WORK( * )
      COMPLEX*16         AB( LDAB, * )
*     ..
*
* =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J, K, L
      DOUBLE PRECISION   SCALE, SUM, VALUE, TEMP
*     ..
*     .. External Functions ..
      LOGICAL            LSAME, DISNAN
      EXTERNAL           lsame, disnan
*     ..
*     .. External Subroutines ..
      EXTERNAL           zlassq
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min, sqrt
*     ..
*     .. Executable Statements ..
*
      IF( n.EQ.0 ) THEN
         VALUE = zero
      ELSE IF( lsame( norm, 'M' ) ) THEN
*
*        Find max(abs(A(i,j))).
*
         VALUE = zero
         DO 20 j = 1, n
            DO 10 i = max( ku+2-j, 1 ), min( n+ku+1-j, kl+ku+1 )
               temp = abs( ab( i, j ) )
               IF( VALUE.LT.temp .OR. disnan( temp ) ) VALUE = temp
   10       CONTINUE
   20    CONTINUE
      ELSE IF( ( lsame( norm, 'O' ) ) .OR. ( norm.EQ.'1' ) ) THEN
*
*        Find norm1(A).
*
         VALUE = zero
         DO 40 j = 1, n
            sum = zero
            DO 30 i = max( ku+2-j, 1 ), min( n+ku+1-j, kl+ku+1 )
               sum = sum + abs( ab( i, j ) )
   30       CONTINUE
            IF( VALUE.LT.sum .OR. disnan( sum ) ) VALUE = sum
   40    CONTINUE
      ELSE IF( lsame( norm, 'I' ) ) THEN
*
*        Find normI(A).
*
         DO 50 i = 1, n
            work( i ) = zero
   50    CONTINUE
         DO 70 j = 1, n
            k = ku + 1 - j
            DO 60 i = max( 1, j-ku ), min( n, j+kl )
               work( i ) = work( i ) + abs( ab( k+i, j ) )
   60       CONTINUE
   70    CONTINUE
         VALUE = zero
         DO 80 i = 1, n
            temp = work( i )
            IF( VALUE.LT.temp .OR. disnan( temp ) ) VALUE = temp
   80    CONTINUE
      ELSE IF( ( lsame( norm, 'F' ) ) .OR.
     $         ( lsame( norm, 'E' ) ) ) THEN
*
*        Find normF(A).
*
         scale = zero
         sum = one
         DO 90 j = 1, n
            l = max( 1, j-ku )
            k = ku + 1 - j + l
            CALL zlassq( min( n, j+kl )-l+1, ab( k, j ), 1, scale,
     $                   sum )
   90    CONTINUE
         VALUE = scale*sqrt( sum )
      END IF
*
      zlangb = VALUE
      RETURN
*
*     End of ZLANGB
*

Here is the call graph for this function:

Here is the caller graph for this function: