zggrqf()

subroutine zggrqf	(	integer	m,
		integer	p,
		integer	n,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		complex*16, dimension( * )	taua,
		complex*16, dimension( ldb, * )	b,
		integer	ldb,
		complex*16, dimension( * )	taub,
		complex*16, dimension( * )	work,
		integer	lwork,
		integer	info )

ZGGRQF

Download ZGGRQF + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> ZGGRQF computes a generalized RQ factorization of an M-by-N matrix A
!> and a P-by-N matrix B:
!>
!>             A = R*Q,        B = Z*T*Q,
!>
!> where Q is an N-by-N unitary matrix, Z is a P-by-P unitary
!> matrix, and R and T assume one of the forms:
!>
!> if M <= N,  R = ( 0  R12 ) M,   or if M > N,  R = ( R11 ) M-N,
!>                  N-M  M                           ( R21 ) N
!>                                                      N
!>
!> where R12 or R21 is upper triangular, and
!>
!> if P >= N,  T = ( T11 ) N  ,   or if P < N,  T = ( T11  T12 ) P,
!>                 (  0  ) P-N                         P   N-P
!>                    N
!>
!> where T11 is upper triangular.
!>
!> In particular, if B is square and nonsingular, the GRQ factorization
!> of A and B implicitly gives the RQ factorization of A*inv(B):
!>
!>              A*inv(B) = (R*inv(T))*Z**H
!>
!> where inv(B) denotes the inverse of the matrix B, and Z**H denotes the
!> conjugate transpose of the matrix Z.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrix A. M >= 0. !>
[in]	P	!> P is INTEGER !> The number of rows of the matrix B. P >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrices A and B. N >= 0. !>
[in,out]	A	!> A is COMPLEX*16 array, dimension (LDA,N) !> On entry, the M-by-N matrix A. !> On exit, if M <= N, the upper triangle of the subarray !> A(1:M,N-M+1:N) contains the M-by-M upper triangular matrix R; !> if M > N, the elements on and above the (M-N)-th subdiagonal !> contain the M-by-N upper trapezoidal matrix R; the remaining !> elements, with the array TAUA, represent the unitary !> matrix Q as a product of elementary reflectors (see Further !> Details). !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,M). !>
[out]	TAUA	!> TAUA is COMPLEX*16 array, dimension (min(M,N)) !> The scalar factors of the elementary reflectors which !> represent the unitary matrix Q (see Further Details). !>
[in,out]	B	!> B is COMPLEX*16 array, dimension (LDB,N) !> On entry, the P-by-N matrix B. !> On exit, the elements on and above the diagonal of the array !> contain the min(P,N)-by-N upper trapezoidal matrix T (T is !> upper triangular if P >= N); the elements below the diagonal, !> with the array TAUB, represent the unitary matrix Z as a !> product of elementary reflectors (see Further Details). !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,P). !>
[out]	TAUB	!> TAUB is COMPLEX*16 array, dimension (min(P,N)) !> The scalar factors of the elementary reflectors which !> represent the unitary matrix Z (see Further Details). !>
[out]	WORK	!> WORK is COMPLEX*16 array, dimension (MAX(1,LWORK)) !> On exit, if INFO = 0, WORK(1) returns the optimal LWORK. !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. LWORK >= max(1,N,M,P). !> For optimum performance LWORK >= max(N,M,P)*max(NB1,NB2,NB3), !> where NB1 is the optimal blocksize for the RQ factorization !> of an M-by-N matrix, NB2 is the optimal blocksize for the !> QR factorization of a P-by-N matrix, and NB3 is the optimal !> blocksize for a call of ZUNMRQ. !> !> If LWORK = -1, then a workspace query is assumed; the routine !> only calculates the optimal size of the WORK array, returns !> this value as the first entry of the WORK array, and no error !> message related to LWORK is issued by XERBLA. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO=-i, the i-th argument had an illegal value. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>  The matrix Q is represented as a product of elementary reflectors
!>
!>     Q = H(1) H(2) . . . H(k), where k = min(m,n).
!>
!>  Each H(i) has the form
!>
!>     H(i) = I - taua * v * v**H
!>
!>  where taua is a complex scalar, and v is a complex vector with
!>  v(n-k+i+1:n) = 0 and v(n-k+i) = 1; v(1:n-k+i-1) is stored on exit in
!>  A(m-k+i,1:n-k+i-1), and taua in TAUA(i).
!>  To form Q explicitly, use LAPACK subroutine ZUNGRQ.
!>  To use Q to update another matrix, use LAPACK subroutine ZUNMRQ.
!>
!>  The matrix Z is represented as a product of elementary reflectors
!>
!>     Z = H(1) H(2) . . . H(k), where k = min(p,n).
!>
!>  Each H(i) has the form
!>
!>     H(i) = I - taub * v * v**H
!>
!>  where taub is a complex scalar, and v is a complex vector with
!>  v(1:i-1) = 0 and v(i) = 1; v(i+1:p) is stored on exit in B(i+1:p,i),
!>  and taub in TAUB(i).
!>  To form Z explicitly, use LAPACK subroutine ZUNGQR.
!>  To use Z to update another matrix, use LAPACK subroutine ZUNMQR.
!> 

Definition at line 210 of file zggrqf.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, LDB, LWORK, M, N, P
*     ..
*     .. Array Arguments ..
      COMPLEX*16         A( LDA, * ), B( LDB, * ), TAUA( * ), TAUB( * ),
     $                   WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      LOGICAL            LQUERY
      INTEGER            LOPT, LWKOPT, NB, NB1, NB2, NB3
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zgeqrf, zgerqf, zunmrq
*     ..
*     .. External Functions ..
      INTEGER            ILAENV
      EXTERNAL           ilaenv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          int, max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters
*
      info = 0
      nb1 = ilaenv( 1, 'ZGERQF', ' ', m, n, -1, -1 )
      nb2 = ilaenv( 1, 'ZGEQRF', ' ', p, n, -1, -1 )
      nb3 = ilaenv( 1, 'ZUNMRQ', ' ', m, n, p, -1 )
      nb = max( nb1, nb2, nb3 )
      lwkopt = max( 1, max( n, m, p )*nb )
      work( 1 ) = lwkopt
      lquery = ( lwork.EQ.-1 )
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( p.LT.0 ) THEN
         info = -2
      ELSE IF( n.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -5
      ELSE IF( ldb.LT.max( 1, p ) ) THEN
         info = -8
      ELSE IF( lwork.LT.max( 1, m, p, n ) .AND. .NOT.lquery ) THEN
         info = -11
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZGGRQF', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     RQ factorization of M-by-N matrix A: A = R*Q
*
      CALL zgerqf( m, n, a, lda, taua, work, lwork, info )
      lopt = int( work( 1 ) )
*
*     Update B := B*Q**H
*
      CALL zunmrq( 'Right', 'Conjugate Transpose', p, n, min( m, n ),
     $             a( max( 1, m-n+1 ), 1 ), lda, taua, b, ldb, work,
     $             lwork, info )
      lopt = max( lopt, int( work( 1 ) ) )
*
*     QR factorization of P-by-N matrix B: B = Z*T
*
      CALL zgeqrf( p, n, b, ldb, taub, work, lwork, info )
      work( 1 ) = max( lopt, int( work( 1 ) ) )
*
      RETURN
*
*     End of ZGGRQF
*

Here is the call graph for this function:

Here is the caller graph for this function: