zunmrq()

subroutine zunmrq	(	character	side,
		character	trans,
		integer	m,
		integer	n,
		integer	k,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		complex*16, dimension( * )	tau,
		complex*16, dimension( ldc, * )	c,
		integer	ldc,
		complex*16, dimension( * )	work,
		integer	lwork,
		integer	info )

ZUNMRQ

Download ZUNMRQ + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> ZUNMRQ overwrites the general complex M-by-N matrix C with
!>
!>                 SIDE = 'L'     SIDE = 'R'
!> TRANS = 'N':      Q * C          C * Q
!> TRANS = 'C':      Q**H * C       C * Q**H
!>
!> where Q is a complex unitary matrix defined as the product of k
!> elementary reflectors
!>
!>       Q = H(1)**H H(2)**H . . . H(k)**H
!>
!> as returned by ZGERQF. Q is of order M if SIDE = 'L' and of order N
!> if SIDE = 'R'.
!> 

Parameters

[in]	SIDE	!> SIDE is CHARACTER*1 !> = 'L': apply Q or Q**H from the Left; !> = 'R': apply Q or Q**H from the Right. !>
[in]	TRANS	!> TRANS is CHARACTER*1 !> = 'N': No transpose, apply Q; !> = 'C': Conjugate transpose, apply Q**H. !>
[in]	M	!> M is INTEGER !> The number of rows of the matrix C. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix C. N >= 0. !>
[in]	K	!> K is INTEGER !> The number of elementary reflectors whose product defines !> the matrix Q. !> If SIDE = 'L', M >= K >= 0; !> if SIDE = 'R', N >= K >= 0. !>
[in]	A	!> A is COMPLEX*16 array, dimension !> (LDA,M) if SIDE = 'L', !> (LDA,N) if SIDE = 'R' !> The i-th row must contain the vector which defines the !> elementary reflector H(i), for i = 1,2,...,k, as returned by !> ZGERQF in the last k rows of its array argument A. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,K). !>
[in]	TAU	!> TAU is COMPLEX*16 array, dimension (K) !> TAU(i) must contain the scalar factor of the elementary !> reflector H(i), as returned by ZGERQF. !>
[in,out]	C	!> C is COMPLEX*16 array, dimension (LDC,N) !> On entry, the M-by-N matrix C. !> On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q. !>
[in]	LDC	!> LDC is INTEGER !> The leading dimension of the array C. LDC >= max(1,M). !>
[out]	WORK	!> WORK is COMPLEX*16 array, dimension (MAX(1,LWORK)) !> On exit, if INFO = 0, WORK(1) returns the optimal LWORK. !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. !> If SIDE = 'L', LWORK >= max(1,N); !> if SIDE = 'R', LWORK >= max(1,M). !> For good performance, LWORK should generally be larger. !> !> If LWORK = -1, then a workspace query is assumed; the routine !> only calculates the optimal size of the WORK array, returns !> this value as the first entry of the WORK array, and no error !> message related to LWORK is issued by XERBLA. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 163 of file zunmrq.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          SIDE, TRANS
      INTEGER            INFO, K, LDA, LDC, LWORK, M, N
*     ..
*     .. Array Arguments ..
      COMPLEX*16         A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            NBMAX, LDT, TSIZE
      parameter( nbmax = 64, ldt = nbmax+1,
     $                     tsize = ldt*nbmax )
*     ..
*     .. Local Scalars ..
      LOGICAL            LEFT, LQUERY, NOTRAN
      CHARACTER          TRANST
      INTEGER            I, I1, I2, I3, IB, IINFO, IWT, LDWORK, LWKOPT,
     $                   MI, NB, NBMIN, NI, NQ, NW
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ILAENV
      EXTERNAL           lsame, ilaenv
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zlarfb, zlarft, zunmr2
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      left = lsame( side, 'L' )
      notran = lsame( trans, 'N' )
      lquery = ( lwork.EQ.-1 )
*
*     NQ is the order of Q and NW is the minimum dimension of WORK
*
      IF( left ) THEN
         nq = m
         nw = max( 1, n )
      ELSE
         nq = n
         nw = max( 1, m )
      END IF
      IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
         info = -1
      ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'C' ) ) THEN
         info = -2
      ELSE IF( m.LT.0 ) THEN
         info = -3
      ELSE IF( n.LT.0 ) THEN
         info = -4
      ELSE IF( k.LT.0 .OR. k.GT.nq ) THEN
         info = -5
      ELSE IF( lda.LT.max( 1, k ) ) THEN
         info = -7
      ELSE IF( ldc.LT.max( 1, m ) ) THEN
         info = -10
      ELSE IF( lwork.LT.nw .AND. .NOT.lquery ) THEN
         info = -12
      END IF
*
      IF( info.EQ.0 ) THEN
*
*        Compute the workspace requirements
*
         IF( m.EQ.0 .OR. n.EQ.0 ) THEN
            lwkopt = 1
         ELSE
            nb = min( nbmax, ilaenv( 1, 'ZUNMRQ', side // trans, m,
     $                n,
     $                               k, -1 ) )
            lwkopt = nw*nb + tsize
         END IF
         work( 1 ) = lwkopt
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZUNMRQ', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.EQ.0 .OR. n.EQ.0 ) THEN
         RETURN
      END IF
*
      nbmin = 2
      ldwork = nw
      IF( nb.GT.1 .AND. nb.LT.k ) THEN
         IF( lwork.LT.lwkopt ) THEN
            nb = (lwork-tsize) / ldwork
            nbmin = max( 2, ilaenv( 2, 'ZUNMRQ', side // trans, m, n,
     $                   k,
     $                              -1 ) )
         END IF
      END IF
*
      IF( nb.LT.nbmin .OR. nb.GE.k ) THEN
*
*        Use unblocked code
*
         CALL zunmr2( side, trans, m, n, k, a, lda, tau, c, ldc,
     $                work,
     $                iinfo )
      ELSE
*
*        Use blocked code
*
         iwt = 1 + nw*nb
         IF( ( left .AND. .NOT.notran ) .OR.
     $       ( .NOT.left .AND. notran ) ) THEN
            i1 = 1
            i2 = k
            i3 = nb
         ELSE
            i1 = ( ( k-1 ) / nb )*nb + 1
            i2 = 1
            i3 = -nb
         END IF
*
         IF( left ) THEN
            ni = n
         ELSE
            mi = m
         END IF
*
         IF( notran ) THEN
            transt = 'C'
         ELSE
            transt = 'N'
         END IF
*
         DO 10 i = i1, i2, i3
            ib = min( nb, k-i+1 )
*
*           Form the triangular factor of the block reflector
*           H = H(i+ib-1) . . . H(i+1) H(i)
*
            CALL zlarft( 'Backward', 'Rowwise', nq-k+i+ib-1, ib,
     $                   a( i, 1 ), lda, tau( i ), work( iwt ), ldt )
            IF( left ) THEN
*
*              H or H**H is applied to C(1:m-k+i+ib-1,1:n)
*
               mi = m - k + i + ib - 1
            ELSE
*
*              H or H**H is applied to C(1:m,1:n-k+i+ib-1)
*
               ni = n - k + i + ib - 1
            END IF
*
*           Apply H or H**H
*
            CALL zlarfb( side, transt, 'Backward', 'Rowwise', mi, ni,
     $                   ib, a( i, 1 ), lda, work( iwt ), ldt, c, ldc,
     $                   work, ldwork )
   10    CONTINUE
      END IF
      work( 1 ) = lwkopt
      RETURN
*
*     End of ZUNMRQ
*

Here is the call graph for this function:

Here is the caller graph for this function: