zgerqf()

subroutine zgerqf	(	integer	m,
		integer	n,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		complex*16, dimension( * )	tau,
		complex*16, dimension( * )	work,
		integer	lwork,
		integer	info )

ZGERQF

Download ZGERQF + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> ZGERQF computes an RQ factorization of a complex M-by-N matrix A:
!> A = R * Q.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrix A. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix A. N >= 0. !>
[in,out]	A	!> A is COMPLEX*16 array, dimension (LDA,N) !> On entry, the M-by-N matrix A. !> On exit, !> if m <= n, the upper triangle of the subarray !> A(1:m,n-m+1:n) contains the M-by-M upper triangular matrix R; !> if m >= n, the elements on and above the (m-n)-th subdiagonal !> contain the M-by-N upper trapezoidal matrix R; !> the remaining elements, with the array TAU, represent the !> unitary matrix Q as a product of min(m,n) elementary !> reflectors (see Further Details). !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,M). !>
[out]	TAU	!> TAU is COMPLEX*16 array, dimension (min(M,N)) !> The scalar factors of the elementary reflectors (see Further !> Details). !>
[out]	WORK	!> WORK is COMPLEX*16 array, dimension (MAX(1,LWORK)) !> On exit, if INFO = 0, WORK(1) returns the optimal LWORK. !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. !> LWORK >= 1, if MIN(M,N) = 0, and LWORK >= M, otherwise. !> For optimum performance LWORK >= M*NB, where NB is !> the optimal blocksize. !> !> If LWORK = -1, then a workspace query is assumed; the routine !> only calculates the optimal size of the WORK array, returns !> this value as the first entry of the WORK array, and no error !> message related to LWORK is issued by XERBLA. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>  The matrix Q is represented as a product of elementary reflectors
!>
!>     Q = H(1)**H H(2)**H . . . H(k)**H, where k = min(m,n).
!>
!>  Each H(i) has the form
!>
!>     H(i) = I - tau * v * v**H
!>
!>  where tau is a complex scalar, and v is a complex vector with
!>  v(n-k+i+1:n) = 0 and v(n-k+i) = 1; conjg(v(1:n-k+i-1)) is stored on
!>  exit in A(m-k+i,1:n-k+i-1), and tau in TAU(i).
!> 

Definition at line 136 of file zgerqf.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      COMPLEX*16         A( LDA, * ), TAU( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      LOGICAL            LQUERY
      INTEGER            I, IB, IINFO, IWS, K, KI, KK, LDWORK, LWKOPT,
     $                   MU, NB, NBMIN, NU, NX
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zgerq2, zlarfb, zlarft
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. External Functions ..
      INTEGER            ILAENV
      EXTERNAL           ilaenv
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      lquery = ( lwork.EQ.-1 )
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -4
      END IF
*
      IF( info.EQ.0 ) THEN
         k = min( m, n )
         IF( k.EQ.0 ) THEN
            lwkopt = 1
         ELSE
            nb = ilaenv( 1, 'ZGERQF', ' ', m, n, -1, -1 )
            lwkopt = m*nb
         END IF
         work( 1 ) = lwkopt
*
         IF ( .NOT.lquery ) THEN
            IF( lwork.LE.0 .OR. ( n.GT.0 .AND. lwork.LT.max( 1, m ) ) )
     $         info = -7
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZGERQF', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( k.EQ.0 ) THEN
         RETURN
      END IF
*
      nbmin = 2
      nx = 1
      iws = m
      IF( nb.GT.1 .AND. nb.LT.k ) THEN
*
*        Determine when to cross over from blocked to unblocked code.
*
         nx = max( 0, ilaenv( 3, 'ZGERQF', ' ', m, n, -1, -1 ) )
         IF( nx.LT.k ) THEN
*
*           Determine if workspace is large enough for blocked code.
*
            ldwork = m
            iws = ldwork*nb
            IF( lwork.LT.iws ) THEN
*
*              Not enough workspace to use optimal NB:  reduce NB and
*              determine the minimum value of NB.
*
               nb = lwork / ldwork
               nbmin = max( 2, ilaenv( 2, 'ZGERQF', ' ', m, n, -1,
     $                 -1 ) )
            END IF
         END IF
      END IF
*
      IF( nb.GE.nbmin .AND. nb.LT.k .AND. nx.LT.k ) THEN
*
*        Use blocked code initially.
*        The last kk rows are handled by the block method.
*
         ki = ( ( k-nx-1 ) / nb )*nb
         kk = min( k, ki+nb )
*
         DO 10 i = k - kk + ki + 1, k - kk + 1, -nb
            ib = min( k-i+1, nb )
*
*           Compute the RQ factorization of the current block
*           A(m-k+i:m-k+i+ib-1,1:n-k+i+ib-1)
*
            CALL zgerq2( ib, n-k+i+ib-1, a( m-k+i, 1 ), lda,
     $                   tau( i ),
     $                   work, iinfo )
            IF( m-k+i.GT.1 ) THEN
*
*              Form the triangular factor of the block reflector
*              H = H(i+ib-1) . . . H(i+1) H(i)
*
               CALL zlarft( 'Backward', 'Rowwise', n-k+i+ib-1, ib,
     $                      a( m-k+i, 1 ), lda, tau( i ), work, ldwork )
*
*              Apply H to A(1:m-k+i-1,1:n-k+i+ib-1) from the right
*
               CALL zlarfb( 'Right', 'No transpose', 'Backward',
     $                      'Rowwise', m-k+i-1, n-k+i+ib-1, ib,
     $                      a( m-k+i, 1 ), lda, work, ldwork, a, lda,
     $                      work( ib+1 ), ldwork )
            END IF
   10    CONTINUE
         mu = m - k + i + nb - 1
         nu = n - k + i + nb - 1
      ELSE
         mu = m
         nu = n
      END IF
*
*     Use unblocked code to factor the last or only block
*
      IF( mu.GT.0 .AND. nu.GT.0 )
     $   CALL zgerq2( mu, nu, a, lda, tau, work, iinfo )
*
      work( 1 ) = iws
      RETURN
*
*     End of ZGERQF
*

Here is the call graph for this function:

Here is the caller graph for this function: