LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
zgges3.f
Go to the documentation of this file.
1 *> \brief <b> ZGGES3 computes the eigenvalues, the Schur form, and, optionally, the matrix of Schur vectors for GE matrices (blocked algorithm)</b>
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download ZGGES3 + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zgges3.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zgges3.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zgges3.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE ZGGES3( JOBVSL, JOBVSR, SORT, SELCTG, N, A, LDA, B,
22 * $ LDB, SDIM, ALPHA, BETA, VSL, LDVSL, VSR, LDVSR,
23 * $ WORK, LWORK, RWORK, BWORK, INFO )
24 *
25 * .. Scalar Arguments ..
26 * CHARACTER JOBVSL, JOBVSR, SORT
27 * INTEGER INFO, LDA, LDB, LDVSL, LDVSR, LWORK, N, SDIM
28 * ..
29 * .. Array Arguments ..
30 * LOGICAL BWORK( * )
31 * DOUBLE PRECISION RWORK( * )
32 * COMPLEX*16 A( LDA, * ), ALPHA( * ), B( LDB, * ),
33 * $ BETA( * ), VSL( LDVSL, * ), VSR( LDVSR, * ),
34 * $ WORK( * )
35 * ..
36 * .. Function Arguments ..
37 * LOGICAL SELCTG
38 * EXTERNAL SELCTG
39 * ..
40 *
41 *
42 *> \par Purpose:
43 * =============
44 *>
45 *> \verbatim
46 *>
47 *> ZGGES3 computes for a pair of N-by-N complex nonsymmetric matrices
48 *> (A,B), the generalized eigenvalues, the generalized complex Schur
49 *> form (S, T), and optionally left and/or right Schur vectors (VSL
50 *> and VSR). This gives the generalized Schur factorization
51 *>
52 *> (A,B) = ( (VSL)*S*(VSR)**H, (VSL)*T*(VSR)**H )
53 *>
54 *> where (VSR)**H is the conjugate-transpose of VSR.
55 *>
56 *> Optionally, it also orders the eigenvalues so that a selected cluster
57 *> of eigenvalues appears in the leading diagonal blocks of the upper
58 *> triangular matrix S and the upper triangular matrix T. The leading
59 *> columns of VSL and VSR then form an unitary basis for the
60 *> corresponding left and right eigenspaces (deflating subspaces).
61 *>
62 *> (If only the generalized eigenvalues are needed, use the driver
63 *> ZGGEV instead, which is faster.)
64 *>
65 *> A generalized eigenvalue for a pair of matrices (A,B) is a scalar w
66 *> or a ratio alpha/beta = w, such that A - w*B is singular. It is
67 *> usually represented as the pair (alpha,beta), as there is a
68 *> reasonable interpretation for beta=0, and even for both being zero.
69 *>
70 *> A pair of matrices (S,T) is in generalized complex Schur form if S
71 *> and T are upper triangular and, in addition, the diagonal elements
72 *> of T are non-negative real numbers.
73 *> \endverbatim
74 *
75 * Arguments:
76 * ==========
77 *
78 *> \param[in] JOBVSL
79 *> \verbatim
80 *> JOBVSL is CHARACTER*1
81 *> = 'N': do not compute the left Schur vectors;
82 *> = 'V': compute the left Schur vectors.
83 *> \endverbatim
84 *>
85 *> \param[in] JOBVSR
86 *> \verbatim
87 *> JOBVSR is CHARACTER*1
88 *> = 'N': do not compute the right Schur vectors;
89 *> = 'V': compute the right Schur vectors.
90 *> \endverbatim
91 *>
92 *> \param[in] SORT
93 *> \verbatim
94 *> SORT is CHARACTER*1
95 *> Specifies whether or not to order the eigenvalues on the
96 *> diagonal of the generalized Schur form.
97 *> = 'N': Eigenvalues are not ordered;
98 *> = 'S': Eigenvalues are ordered (see SELCTG).
99 *> \endverbatim
100 *>
101 *> \param[in] SELCTG
102 *> \verbatim
103 *> SELCTG is a LOGICAL FUNCTION of two COMPLEX*16 arguments
104 *> SELCTG must be declared EXTERNAL in the calling subroutine.
105 *> If SORT = 'N', SELCTG is not referenced.
106 *> If SORT = 'S', SELCTG is used to select eigenvalues to sort
107 *> to the top left of the Schur form.
108 *> An eigenvalue ALPHA(j)/BETA(j) is selected if
109 *> SELCTG(ALPHA(j),BETA(j)) is true.
110 *>
111 *> Note that a selected complex eigenvalue may no longer satisfy
112 *> SELCTG(ALPHA(j),BETA(j)) = .TRUE. after ordering, since
113 *> ordering may change the value of complex eigenvalues
114 *> (especially if the eigenvalue is ill-conditioned), in this
115 *> case INFO is set to N+2 (See INFO below).
116 *> \endverbatim
117 *>
118 *> \param[in] N
119 *> \verbatim
120 *> N is INTEGER
121 *> The order of the matrices A, B, VSL, and VSR. N >= 0.
122 *> \endverbatim
123 *>
124 *> \param[in,out] A
125 *> \verbatim
126 *> A is COMPLEX*16 array, dimension (LDA, N)
127 *> On entry, the first of the pair of matrices.
128 *> On exit, A has been overwritten by its generalized Schur
129 *> form S.
130 *> \endverbatim
131 *>
132 *> \param[in] LDA
133 *> \verbatim
134 *> LDA is INTEGER
135 *> The leading dimension of A. LDA >= max(1,N).
136 *> \endverbatim
137 *>
138 *> \param[in,out] B
139 *> \verbatim
140 *> B is COMPLEX*16 array, dimension (LDB, N)
141 *> On entry, the second of the pair of matrices.
142 *> On exit, B has been overwritten by its generalized Schur
143 *> form T.
144 *> \endverbatim
145 *>
146 *> \param[in] LDB
147 *> \verbatim
148 *> LDB is INTEGER
149 *> The leading dimension of B. LDB >= max(1,N).
150 *> \endverbatim
151 *>
152 *> \param[out] SDIM
153 *> \verbatim
154 *> SDIM is INTEGER
155 *> If SORT = 'N', SDIM = 0.
156 *> If SORT = 'S', SDIM = number of eigenvalues (after sorting)
157 *> for which SELCTG is true.
158 *> \endverbatim
159 *>
160 *> \param[out] ALPHA
161 *> \verbatim
162 *> ALPHA is COMPLEX*16 array, dimension (N)
163 *> \endverbatim
164 *>
165 *> \param[out] BETA
166 *> \verbatim
167 *> BETA is COMPLEX*16 array, dimension (N)
168 *> On exit, ALPHA(j)/BETA(j), j=1,...,N, will be the
169 *> generalized eigenvalues. ALPHA(j), j=1,...,N and BETA(j),
170 *> j=1,...,N are the diagonals of the complex Schur form (A,B)
171 *> output by ZGGES3. The BETA(j) will be non-negative real.
172 *>
173 *> Note: the quotients ALPHA(j)/BETA(j) may easily over- or
174 *> underflow, and BETA(j) may even be zero. Thus, the user
175 *> should avoid naively computing the ratio alpha/beta.
176 *> However, ALPHA will be always less than and usually
177 *> comparable with norm(A) in magnitude, and BETA always less
178 *> than and usually comparable with norm(B).
179 *> \endverbatim
180 *>
181 *> \param[out] VSL
182 *> \verbatim
183 *> VSL is COMPLEX*16 array, dimension (LDVSL,N)
184 *> If JOBVSL = 'V', VSL will contain the left Schur vectors.
185 *> Not referenced if JOBVSL = 'N'.
186 *> \endverbatim
187 *>
188 *> \param[in] LDVSL
189 *> \verbatim
190 *> LDVSL is INTEGER
191 *> The leading dimension of the matrix VSL. LDVSL >= 1, and
192 *> if JOBVSL = 'V', LDVSL >= N.
193 *> \endverbatim
194 *>
195 *> \param[out] VSR
196 *> \verbatim
197 *> VSR is COMPLEX*16 array, dimension (LDVSR,N)
198 *> If JOBVSR = 'V', VSR will contain the right Schur vectors.
199 *> Not referenced if JOBVSR = 'N'.
200 *> \endverbatim
201 *>
202 *> \param[in] LDVSR
203 *> \verbatim
204 *> LDVSR is INTEGER
205 *> The leading dimension of the matrix VSR. LDVSR >= 1, and
206 *> if JOBVSR = 'V', LDVSR >= N.
207 *> \endverbatim
208 *>
209 *> \param[out] WORK
210 *> \verbatim
211 *> WORK is COMPLEX*16 array, dimension (MAX(1,LWORK))
212 *> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
213 *> \endverbatim
214 *>
215 *> \param[in] LWORK
216 *> \verbatim
217 *> LWORK is INTEGER
218 *> The dimension of the array WORK.
219 *>
220 *> If LWORK = -1, then a workspace query is assumed; the routine
221 *> only calculates the optimal size of the WORK array, returns
222 *> this value as the first entry of the WORK array, and no error
223 *> message related to LWORK is issued by XERBLA.
224 *> \endverbatim
225 *>
226 *> \param[out] RWORK
227 *> \verbatim
228 *> RWORK is DOUBLE PRECISION array, dimension (8*N)
229 *> \endverbatim
230 *>
231 *> \param[out] BWORK
232 *> \verbatim
233 *> BWORK is LOGICAL array, dimension (N)
234 *> Not referenced if SORT = 'N'.
235 *> \endverbatim
236 *>
237 *> \param[out] INFO
238 *> \verbatim
239 *> INFO is INTEGER
240 *> = 0: successful exit
241 *> < 0: if INFO = -i, the i-th argument had an illegal value.
242 *> =1,...,N:
243 *> The QZ iteration failed. (A,B) are not in Schur
244 *> form, but ALPHA(j) and BETA(j) should be correct for
245 *> j=INFO+1,...,N.
246 *> > N: =N+1: other than QZ iteration failed in ZHGEQZ
247 *> =N+2: after reordering, roundoff changed values of
248 *> some complex eigenvalues so that leading
249 *> eigenvalues in the Generalized Schur form no
250 *> longer satisfy SELCTG=.TRUE. This could also
251 *> be caused due to scaling.
252 *> =N+3: reordering failed in ZTGSEN.
253 *> \endverbatim
254 *
255 * Authors:
256 * ========
257 *
258 *> \author Univ. of Tennessee
259 *> \author Univ. of California Berkeley
260 *> \author Univ. of Colorado Denver
261 *> \author NAG Ltd.
262 *
263 *> \date January 2015
264 *
265 *> \ingroup complex16GEeigen
266 *
267 * =====================================================================
268  SUBROUTINE zgges3( JOBVSL, JOBVSR, SORT, SELCTG, N, A, LDA, B,
269  $ ldb, sdim, alpha, beta, vsl, ldvsl, vsr, ldvsr,
270  $ work, lwork, rwork, bwork, info )
271 *
272 * -- LAPACK driver routine (version 3.6.1) --
273 * -- LAPACK is a software package provided by Univ. of Tennessee, --
274 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
275 * January 2015
276 *
277 * .. Scalar Arguments ..
278  CHARACTER JOBVSL, JOBVSR, SORT
279  INTEGER INFO, LDA, LDB, LDVSL, LDVSR, LWORK, N, SDIM
280 * ..
281 * .. Array Arguments ..
282  LOGICAL BWORK( * )
283  DOUBLE PRECISION RWORK( * )
284  COMPLEX*16 A( lda, * ), ALPHA( * ), B( ldb, * ),
285  $ beta( * ), vsl( ldvsl, * ), vsr( ldvsr, * ),
286  $ work( * )
287 * ..
288 * .. Function Arguments ..
289  LOGICAL SELCTG
290  EXTERNAL selctg
291 * ..
292 *
293 * =====================================================================
294 *
295 * .. Parameters ..
296  DOUBLE PRECISION ZERO, ONE
297  parameter ( zero = 0.0d0, one = 1.0d0 )
298  COMPLEX*16 CZERO, CONE
299  parameter ( czero = ( 0.0d0, 0.0d0 ),
300  $ cone = ( 1.0d0, 0.0d0 ) )
301 * ..
302 * .. Local Scalars ..
303  LOGICAL CURSL, ILASCL, ILBSCL, ILVSL, ILVSR, LASTSL,
304  $ lquery, wantst
305  INTEGER I, ICOLS, IERR, IHI, IJOBVL, IJOBVR, ILEFT,
306  $ ilo, iright, irows, irwrk, itau, iwrk, lwkopt
307  DOUBLE PRECISION ANRM, ANRMTO, BIGNUM, BNRM, BNRMTO, EPS, PVSL,
308  $ pvsr, smlnum
309 * ..
310 * .. Local Arrays ..
311  INTEGER IDUM( 1 )
312  DOUBLE PRECISION DIF( 2 )
313 * ..
314 * .. External Subroutines ..
315  EXTERNAL dlabad, xerbla, zgeqrf, zggbak, zggbal, zgghd3,
317  $ zunmqr
318 * ..
319 * .. External Functions ..
320  LOGICAL LSAME
321  DOUBLE PRECISION DLAMCH, ZLANGE
322  EXTERNAL lsame, dlamch, zlange
323 * ..
324 * .. Intrinsic Functions ..
325  INTRINSIC max, sqrt
326 * ..
327 * .. Executable Statements ..
328 *
329 * Decode the input arguments
330 *
331  IF( lsame( jobvsl, 'N' ) ) THEN
332  ijobvl = 1
333  ilvsl = .false.
334  ELSE IF( lsame( jobvsl, 'V' ) ) THEN
335  ijobvl = 2
336  ilvsl = .true.
337  ELSE
338  ijobvl = -1
339  ilvsl = .false.
340  END IF
341 *
342  IF( lsame( jobvsr, 'N' ) ) THEN
343  ijobvr = 1
344  ilvsr = .false.
345  ELSE IF( lsame( jobvsr, 'V' ) ) THEN
346  ijobvr = 2
347  ilvsr = .true.
348  ELSE
349  ijobvr = -1
350  ilvsr = .false.
351  END IF
352 *
353  wantst = lsame( sort, 'S' )
354 *
355 * Test the input arguments
356 *
357  info = 0
358  lquery = ( lwork.EQ.-1 )
359  IF( ijobvl.LE.0 ) THEN
360  info = -1
361  ELSE IF( ijobvr.LE.0 ) THEN
362  info = -2
363  ELSE IF( ( .NOT.wantst ) .AND. ( .NOT.lsame( sort, 'N' ) ) ) THEN
364  info = -3
365  ELSE IF( n.LT.0 ) THEN
366  info = -5
367  ELSE IF( lda.LT.max( 1, n ) ) THEN
368  info = -7
369  ELSE IF( ldb.LT.max( 1, n ) ) THEN
370  info = -9
371  ELSE IF( ldvsl.LT.1 .OR. ( ilvsl .AND. ldvsl.LT.n ) ) THEN
372  info = -14
373  ELSE IF( ldvsr.LT.1 .OR. ( ilvsr .AND. ldvsr.LT.n ) ) THEN
374  info = -16
375  ELSE IF( lwork.LT.max( 1, 2*n ) .AND. .NOT.lquery ) THEN
376  info = -18
377  END IF
378 *
379 * Compute workspace
380 *
381  IF( info.EQ.0 ) THEN
382  CALL zgeqrf( n, n, b, ldb, work, work, -1, ierr )
383  lwkopt = max( 1, n + int( work( 1 ) ) )
384  CALL zunmqr( 'L', 'C', n, n, n, b, ldb, work, a, lda, work,
385  $ -1, ierr )
386  lwkopt = max( lwkopt, n + int( work( 1 ) ) )
387  IF( ilvsl ) THEN
388  CALL zungqr( n, n, n, vsl, ldvsl, work, work, -1, ierr )
389  lwkopt = max( lwkopt, n + int( work( 1 ) ) )
390  END IF
391  CALL zgghd3( jobvsl, jobvsr, n, 1, n, a, lda, b, ldb, vsl,
392  $ ldvsl, vsr, ldvsr, work, -1, ierr )
393  lwkopt = max( lwkopt, n + int( work( 1 ) ) )
394  CALL zhgeqz( 'S', jobvsl, jobvsr, n, 1, n, a, lda, b, ldb,
395  $ alpha, beta, vsl, ldvsl, vsr, ldvsr, work, -1,
396  $ rwork, ierr )
397  lwkopt = max( lwkopt, int( work( 1 ) ) )
398  IF( wantst ) THEN
399  CALL ztgsen( 0, ilvsl, ilvsr, bwork, n, a, lda, b, ldb,
400  $ alpha, beta, vsl, ldvsl, vsr, ldvsr, sdim,
401  $ pvsl, pvsr, dif, work, -1, idum, 1, ierr )
402  lwkopt = max( lwkopt, int( work( 1 ) ) )
403  END IF
404  work( 1 ) = dcmplx( lwkopt )
405  END IF
406 *
407  IF( info.NE.0 ) THEN
408  CALL xerbla( 'ZGGES3 ', -info )
409  RETURN
410  ELSE IF( lquery ) THEN
411  RETURN
412  END IF
413 *
414 * Quick return if possible
415 *
416  IF( n.EQ.0 ) THEN
417  sdim = 0
418  RETURN
419  END IF
420 *
421 * Get machine constants
422 *
423  eps = dlamch( 'P' )
424  smlnum = dlamch( 'S' )
425  bignum = one / smlnum
426  CALL dlabad( smlnum, bignum )
427  smlnum = sqrt( smlnum ) / eps
428  bignum = one / smlnum
429 *
430 * Scale A if max element outside range [SMLNUM,BIGNUM]
431 *
432  anrm = zlange( 'M', n, n, a, lda, rwork )
433  ilascl = .false.
434  IF( anrm.GT.zero .AND. anrm.LT.smlnum ) THEN
435  anrmto = smlnum
436  ilascl = .true.
437  ELSE IF( anrm.GT.bignum ) THEN
438  anrmto = bignum
439  ilascl = .true.
440  END IF
441 *
442  IF( ilascl )
443  $ CALL zlascl( 'G', 0, 0, anrm, anrmto, n, n, a, lda, ierr )
444 *
445 * Scale B if max element outside range [SMLNUM,BIGNUM]
446 *
447  bnrm = zlange( 'M', n, n, b, ldb, rwork )
448  ilbscl = .false.
449  IF( bnrm.GT.zero .AND. bnrm.LT.smlnum ) THEN
450  bnrmto = smlnum
451  ilbscl = .true.
452  ELSE IF( bnrm.GT.bignum ) THEN
453  bnrmto = bignum
454  ilbscl = .true.
455  END IF
456 *
457  IF( ilbscl )
458  $ CALL zlascl( 'G', 0, 0, bnrm, bnrmto, n, n, b, ldb, ierr )
459 *
460 * Permute the matrix to make it more nearly triangular
461 *
462  ileft = 1
463  iright = n + 1
464  irwrk = iright + n
465  CALL zggbal( 'P', n, a, lda, b, ldb, ilo, ihi, rwork( ileft ),
466  $ rwork( iright ), rwork( irwrk ), ierr )
467 *
468 * Reduce B to triangular form (QR decomposition of B)
469 *
470  irows = ihi + 1 - ilo
471  icols = n + 1 - ilo
472  itau = 1
473  iwrk = itau + irows
474  CALL zgeqrf( irows, icols, b( ilo, ilo ), ldb, work( itau ),
475  $ work( iwrk ), lwork+1-iwrk, ierr )
476 *
477 * Apply the orthogonal transformation to matrix A
478 *
479  CALL zunmqr( 'L', 'C', irows, icols, irows, b( ilo, ilo ), ldb,
480  $ work( itau ), a( ilo, ilo ), lda, work( iwrk ),
481  $ lwork+1-iwrk, ierr )
482 *
483 * Initialize VSL
484 *
485  IF( ilvsl ) THEN
486  CALL zlaset( 'Full', n, n, czero, cone, vsl, ldvsl )
487  IF( irows.GT.1 ) THEN
488  CALL zlacpy( 'L', irows-1, irows-1, b( ilo+1, ilo ), ldb,
489  $ vsl( ilo+1, ilo ), ldvsl )
490  END IF
491  CALL zungqr( irows, irows, irows, vsl( ilo, ilo ), ldvsl,
492  $ work( itau ), work( iwrk ), lwork+1-iwrk, ierr )
493  END IF
494 *
495 * Initialize VSR
496 *
497  IF( ilvsr )
498  $ CALL zlaset( 'Full', n, n, czero, cone, vsr, ldvsr )
499 *
500 * Reduce to generalized Hessenberg form
501 *
502  CALL zgghd3( jobvsl, jobvsr, n, ilo, ihi, a, lda, b, ldb, vsl,
503  $ ldvsl, vsr, ldvsr, work( iwrk ), lwork+1-iwrk, ierr )
504 *
505  sdim = 0
506 *
507 * Perform QZ algorithm, computing Schur vectors if desired
508 *
509  iwrk = itau
510  CALL zhgeqz( 'S', jobvsl, jobvsr, n, ilo, ihi, a, lda, b, ldb,
511  $ alpha, beta, vsl, ldvsl, vsr, ldvsr, work( iwrk ),
512  $ lwork+1-iwrk, rwork( irwrk ), ierr )
513  IF( ierr.NE.0 ) THEN
514  IF( ierr.GT.0 .AND. ierr.LE.n ) THEN
515  info = ierr
516  ELSE IF( ierr.GT.n .AND. ierr.LE.2*n ) THEN
517  info = ierr - n
518  ELSE
519  info = n + 1
520  END IF
521  GO TO 30
522  END IF
523 *
524 * Sort eigenvalues ALPHA/BETA if desired
525 *
526  IF( wantst ) THEN
527 *
528 * Undo scaling on eigenvalues before selecting
529 *
530  IF( ilascl )
531  $ CALL zlascl( 'G', 0, 0, anrm, anrmto, n, 1, alpha, n, ierr )
532  IF( ilbscl )
533  $ CALL zlascl( 'G', 0, 0, bnrm, bnrmto, n, 1, beta, n, ierr )
534 *
535 * Select eigenvalues
536 *
537  DO 10 i = 1, n
538  bwork( i ) = selctg( alpha( i ), beta( i ) )
539  10 CONTINUE
540 *
541  CALL ztgsen( 0, ilvsl, ilvsr, bwork, n, a, lda, b, ldb, alpha,
542  $ beta, vsl, ldvsl, vsr, ldvsr, sdim, pvsl, pvsr,
543  $ dif, work( iwrk ), lwork-iwrk+1, idum, 1, ierr )
544  IF( ierr.EQ.1 )
545  $ info = n + 3
546 *
547  END IF
548 *
549 * Apply back-permutation to VSL and VSR
550 *
551  IF( ilvsl )
552  $ CALL zggbak( 'P', 'L', n, ilo, ihi, rwork( ileft ),
553  $ rwork( iright ), n, vsl, ldvsl, ierr )
554  IF( ilvsr )
555  $ CALL zggbak( 'P', 'R', n, ilo, ihi, rwork( ileft ),
556  $ rwork( iright ), n, vsr, ldvsr, ierr )
557 *
558 * Undo scaling
559 *
560  IF( ilascl ) THEN
561  CALL zlascl( 'U', 0, 0, anrmto, anrm, n, n, a, lda, ierr )
562  CALL zlascl( 'G', 0, 0, anrmto, anrm, n, 1, alpha, n, ierr )
563  END IF
564 *
565  IF( ilbscl ) THEN
566  CALL zlascl( 'U', 0, 0, bnrmto, bnrm, n, n, b, ldb, ierr )
567  CALL zlascl( 'G', 0, 0, bnrmto, bnrm, n, 1, beta, n, ierr )
568  END IF
569 *
570  IF( wantst ) THEN
571 *
572 * Check if reordering is correct
573 *
574  lastsl = .true.
575  sdim = 0
576  DO 20 i = 1, n
577  cursl = selctg( alpha( i ), beta( i ) )
578  IF( cursl )
579  $ sdim = sdim + 1
580  IF( cursl .AND. .NOT.lastsl )
581  $ info = n + 2
582  lastsl = cursl
583  20 CONTINUE
584 *
585  END IF
586 *
587  30 CONTINUE
588 *
589  work( 1 ) = dcmplx( lwkopt )
590 *
591  RETURN
592 *
593 * End of ZGGES3
594 *
595  END
subroutine zlacpy(UPLO, M, N, A, LDA, B, LDB)
ZLACPY copies all or part of one two-dimensional array to another.
Definition: zlacpy.f:105
subroutine zgges3(JOBVSL, JOBVSR, SORT, SELCTG, N, A, LDA, B, LDB, SDIM, ALPHA, BETA, VSL, LDVSL, VSR, LDVSR, WORK, LWORK, RWORK, BWORK, INFO)
ZGGES3 computes the eigenvalues, the Schur form, and, optionally, the matrix of Schur vectors for GE...
Definition: zgges3.f:271
subroutine ztgsen(IJOB, WANTQ, WANTZ, SELECT, N, A, LDA, B, LDB, ALPHA, BETA, Q, LDQ, Z, LDZ, M, PL, PR, DIF, WORK, LWORK, IWORK, LIWORK, INFO)
ZTGSEN
Definition: ztgsen.f:435
subroutine zgeqrf(M, N, A, LDA, TAU, WORK, LWORK, INFO)
ZGEQRF VARIANT: left-looking Level 3 BLAS of the algorithm.
Definition: zgeqrf.f:151
subroutine zggbak(JOB, SIDE, N, ILO, IHI, LSCALE, RSCALE, M, V, LDV, INFO)
ZGGBAK
Definition: zggbak.f:150
subroutine zlaset(UPLO, M, N, ALPHA, BETA, A, LDA)
ZLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values...
Definition: zlaset.f:108
subroutine zggbal(JOB, N, A, LDA, B, LDB, ILO, IHI, LSCALE, RSCALE, WORK, INFO)
ZGGBAL
Definition: zggbal.f:179
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine dlabad(SMALL, LARGE)
DLABAD
Definition: dlabad.f:76
subroutine zunmqr(SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK, LWORK, INFO)
ZUNMQR
Definition: zunmqr.f:169
subroutine zgghd3(COMPQ, COMPZ, N, ILO, IHI, A, LDA, B, LDB, Q, LDQ, Z, LDZ, WORK, LWORK, INFO)
ZGGHD3
Definition: zgghd3.f:229
subroutine zungqr(M, N, K, A, LDA, TAU, WORK, LWORK, INFO)
ZUNGQR
Definition: zungqr.f:130
subroutine zhgeqz(JOB, COMPQ, COMPZ, N, ILO, IHI, H, LDH, T, LDT, ALPHA, BETA, Q, LDQ, Z, LDZ, WORK, LWORK, RWORK, INFO)
ZHGEQZ
Definition: zhgeqz.f:286
subroutine zlascl(TYPE, KL, KU, CFROM, CTO, M, N, A, LDA, INFO)
ZLASCL multiplies a general rectangular matrix by a real scalar defined as cto/cfrom.
Definition: zlascl.f:145