subroutine zlaset	(	character	UPLO,
		integer	M,
		integer	N,
		complex*16	ALPHA,
		complex*16	BETA,
		complex*16, dimension( lda, * )	A,
		integer	LDA
	)

ZLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values.

Download ZLASET + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 ZLASET initializes a 2-D array A to BETA on the diagonal and
 ALPHA on the offdiagonals.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies the part of the matrix A to be set. = 'U': Upper triangular part is set. The lower triangle is unchanged. = 'L': Lower triangular part is set. The upper triangle is unchanged. Otherwise: All of the matrix A is set.
[in]	M	M is INTEGER On entry, M specifies the number of rows of A.
[in]	N	N is INTEGER On entry, N specifies the number of columns of A.
[in]	ALPHA	ALPHA is COMPLEX*16 All the offdiagonal array elements are set to ALPHA.
[in]	BETA	BETA is COMPLEX*16 All the diagonal array elements are set to BETA.
[out]	A	A is COMPLEX*16 array, dimension (LDA,N) On entry, the m by n matrix A. On exit, A(i,j) = ALPHA, 1 <= i <= m, 1 <= j <= n, i.ne.j; A(i,i) = BETA , 1 <= i <= min(m,n)
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,M).

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2015

Definition at line 108 of file zlaset.f.

*
*  -- LAPACK auxiliary routine (version 3.6.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2015
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            lda, m, n
      COMPLEX*16         alpha, beta
*     ..
*     .. Array Arguments ..
      COMPLEX*16         a( lda, * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            i, j
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      EXTERNAL           lsame
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          min
*     ..
*     .. Executable Statements ..
*
      IF( lsame( uplo, 'U' ) ) THEN
*
*        Set the diagonal to BETA and the strictly upper triangular
*        part of the array to ALPHA.
*
         DO 20 j = 2, n
            DO 10 i = 1, min( j-1, m )
               a( i, j ) = alpha
   10       CONTINUE
   20    CONTINUE
         DO 30 i = 1, min( n, m )
            a( i, i ) = beta
   30    CONTINUE
*
      ELSE IF( lsame( uplo, 'L' ) ) THEN
*
*        Set the diagonal to BETA and the strictly lower triangular
*        part of the array to ALPHA.
*
         DO 50 j = 1, min( m, n )
            DO 40 i = j + 1, m
               a( i, j ) = alpha
   40       CONTINUE
   50    CONTINUE
         DO 60 i = 1, min( n, m )
            a( i, i ) = beta
   60    CONTINUE
*
      ELSE
*
*        Set the array to BETA on the diagonal and ALPHA on the
*        offdiagonal.
*
         DO 80 j = 1, n
            DO 70 i = 1, m
               a( i, j ) = alpha
   70       CONTINUE
   80    CONTINUE
         DO 90 i = 1, min( m, n )
            a( i, i ) = beta
   90    CONTINUE
      END IF
*
      RETURN
*
*     End of ZLASET
*