subroutine zggsvp	(	character	JOBU,
		character	JOBV,
		character	JOBQ,
		integer	M,
		integer	P,
		integer	N,
		complex*16, dimension( lda, * )	A,
		integer	LDA,
		complex*16, dimension( ldb, * )	B,
		integer	LDB,
		double precision	TOLA,
		double precision	TOLB,
		integer	K,
		integer	L,
		complex*16, dimension( ldu, * )	U,
		integer	LDU,
		complex*16, dimension( ldv, * )	V,
		integer	LDV,
		complex*16, dimension( ldq, * )	Q,
		integer	LDQ,
		integer, dimension( * )	IWORK,
		double precision, dimension( * )	RWORK,
		complex*16, dimension( * )	TAU,
		complex*16, dimension( * )	WORK,
		integer	INFO
	)

ZGGSVP

Download ZGGSVP + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 This routine is deprecated and has been replaced by routine ZGGSVP3.

 ZGGSVP computes unitary matrices U, V and Q such that

                    N-K-L  K    L
  U**H*A*Q =     K ( 0    A12  A13 )  if M-K-L >= 0;
                 L ( 0     0   A23 )
             M-K-L ( 0     0    0  )

                  N-K-L  K    L
         =     K ( 0    A12  A13 )  if M-K-L < 0;
             M-K ( 0     0   A23 )

                  N-K-L  K    L
  V**H*B*Q =   L ( 0     0   B13 )
             P-L ( 0     0    0  )

 where the K-by-K matrix A12 and L-by-L matrix B13 are nonsingular
 upper triangular; A23 is L-by-L upper triangular if M-K-L >= 0,
 otherwise A23 is (M-K)-by-L upper trapezoidal.  K+L = the effective
 numerical rank of the (M+P)-by-N matrix (A**H,B**H)**H. 

 This decomposition is the preprocessing step for computing the
 Generalized Singular Value Decomposition (GSVD), see subroutine
 ZGGSVD.

Parameters

[in]	JOBU	JOBU is CHARACTER*1 = 'U': Unitary matrix U is computed; = 'N': U is not computed.
[in]	JOBV	JOBV is CHARACTER*1 = 'V': Unitary matrix V is computed; = 'N': V is not computed.
[in]	JOBQ	JOBQ is CHARACTER*1 = 'Q': Unitary matrix Q is computed; = 'N': Q is not computed.
[in]	M	M is INTEGER The number of rows of the matrix A. M >= 0.
[in]	P	P is INTEGER The number of rows of the matrix B. P >= 0.
[in]	N	N is INTEGER The number of columns of the matrices A and B. N >= 0.
[in,out]	A	A is COMPLEX*16 array, dimension (LDA,N) On entry, the M-by-N matrix A. On exit, A contains the triangular (or trapezoidal) matrix described in the Purpose section.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,M).
[in,out]	B	B is COMPLEX*16 array, dimension (LDB,N) On entry, the P-by-N matrix B. On exit, B contains the triangular matrix described in the Purpose section.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. LDB >= max(1,P).
[in]	TOLA	TOLA is DOUBLE PRECISION
[in]	TOLB	TOLB is DOUBLE PRECISION TOLA and TOLB are the thresholds to determine the effective numerical rank of matrix B and a subblock of A. Generally, they are set to TOLA = MAX(M,N)*norm(A)*MAZHEPS, TOLB = MAX(P,N)*norm(B)*MAZHEPS. The size of TOLA and TOLB may affect the size of backward errors of the decomposition.
[out]	K	K is INTEGER
[out]	L	L is INTEGER On exit, K and L specify the dimension of the subblocks described in Purpose section. K + L = effective numerical rank of (A**H,B**H)**H.
[out]	U	U is COMPLEX*16 array, dimension (LDU,M) If JOBU = 'U', U contains the unitary matrix U. If JOBU = 'N', U is not referenced.
[in]	LDU	LDU is INTEGER The leading dimension of the array U. LDU >= max(1,M) if JOBU = 'U'; LDU >= 1 otherwise.
[out]	V	V is COMPLEX*16 array, dimension (LDV,P) If JOBV = 'V', V contains the unitary matrix V. If JOBV = 'N', V is not referenced.
[in]	LDV	LDV is INTEGER The leading dimension of the array V. LDV >= max(1,P) if JOBV = 'V'; LDV >= 1 otherwise.
[out]	Q	Q is COMPLEX*16 array, dimension (LDQ,N) If JOBQ = 'Q', Q contains the unitary matrix Q. If JOBQ = 'N', Q is not referenced.
[in]	LDQ	LDQ is INTEGER The leading dimension of the array Q. LDQ >= max(1,N) if JOBQ = 'Q'; LDQ >= 1 otherwise.
[out]	IWORK	IWORK is INTEGER array, dimension (N)
[out]	RWORK	RWORK is DOUBLE PRECISION array, dimension (2*N)
[out]	TAU	TAU is COMPLEX*16 array, dimension (N)
[out]	WORK	WORK is COMPLEX*16 array, dimension (max(3*N,M,P))
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Further Details:

  The subroutine uses LAPACK subroutine ZGEQPF for the QR factorization
  with column pivoting to detect the effective numerical rank of the
  a matrix. It may be replaced by a better rank determination strategy.

Definition at line 267 of file zggsvp.f.

*
*  -- LAPACK computational routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      CHARACTER          jobq, jobu, jobv
      INTEGER            info, k, l, lda, ldb, ldq, ldu, ldv, m, n, p
      DOUBLE PRECISION   tola, tolb
*     ..
*     .. Array Arguments ..
      INTEGER            iwork( * )
      DOUBLE PRECISION   rwork( * )
      COMPLEX*16         a( lda, * ), b( ldb, * ), q( ldq, * ),
     $                   tau( * ), u( ldu, * ), v( ldv, * ), work( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX*16         czero, cone
      parameter                ( czero = ( 0.0d+0, 0.0d+0 ),
     $                   cone = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            forwrd, wantq, wantu, wantv
      INTEGER            i, j
      COMPLEX*16         t
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zgeqpf, zgeqr2, zgerq2, zlacpy, zlapmt,
     $                   zlaset, zung2r, zunm2r, zunmr2
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dimag, max, min
*     ..
*     .. Statement Functions ..
      DOUBLE PRECISION   cabs1
*     ..
*     .. Statement Function definitions ..
      cabs1( t ) = abs( dble( t ) ) + abs( dimag( t ) )
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters
*
      wantu = lsame( jobu, 'U' )
      wantv = lsame( jobv, 'V' )
      wantq = lsame( jobq, 'Q' )
      forwrd = .true.
*
      info = 0
      IF( .NOT.( wantu .OR. lsame( jobu, 'N' ) ) ) THEN
         info = -1
      ELSE IF( .NOT.( wantv .OR. lsame( jobv, 'N' ) ) ) THEN
         info = -2
      ELSE IF( .NOT.( wantq .OR. lsame( jobq, 'N' ) ) ) THEN
         info = -3
      ELSE IF( m.LT.0 ) THEN
         info = -4
      ELSE IF( p.LT.0 ) THEN
         info = -5
      ELSE IF( n.LT.0 ) THEN
         info = -6
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -8
      ELSE IF( ldb.LT.max( 1, p ) ) THEN
         info = -10
      ELSE IF( ldu.LT.1 .OR. ( wantu .AND. ldu.LT.m ) ) THEN
         info = -16
      ELSE IF( ldv.LT.1 .OR. ( wantv .AND. ldv.LT.p ) ) THEN
         info = -18
      ELSE IF( ldq.LT.1 .OR. ( wantq .AND. ldq.LT.n ) ) THEN
         info = -20
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZGGSVP', -info )
         RETURN
      END IF
*
*     QR with column pivoting of B: B*P = V*( S11 S12 )
*                                           (  0   0  )
*
      DO 10 i = 1, n
         iwork( i ) = 0
   10 CONTINUE
      CALL zgeqpf( p, n, b, ldb, iwork, tau, work, rwork, info )
*
*     Update A := A*P
*
      CALL zlapmt( forwrd, m, n, a, lda, iwork )
*
*     Determine the effective rank of matrix B.
*
      l = 0
      DO 20 i = 1, min( p, n )
         IF( cabs1( b( i, i ) ).GT.tolb )
     $      l = l + 1
   20 CONTINUE
*
      IF( wantv ) THEN
*
*        Copy the details of V, and form V.
*
         CALL zlaset( 'Full', p, p, czero, czero, v, ldv )
         IF( p.GT.1 )
     $      CALL zlacpy( 'Lower', p-1, n, b( 2, 1 ), ldb, v( 2, 1 ),
     $                   ldv )
         CALL zung2r( p, p, min( p, n ), v, ldv, tau, work, info )
      END IF
*
*     Clean up B
*
      DO 40 j = 1, l - 1
         DO 30 i = j + 1, l
            b( i, j ) = czero
   30    CONTINUE
   40 CONTINUE
      IF( p.GT.l )
     $   CALL zlaset( 'Full', p-l, n, czero, czero, b( l+1, 1 ), ldb )
*
      IF( wantq ) THEN
*
*        Set Q = I and Update Q := Q*P
*
         CALL zlaset( 'Full', n, n, czero, cone, q, ldq )
         CALL zlapmt( forwrd, n, n, q, ldq, iwork )
      END IF
*
      IF( p.GE.l .AND. n.NE.l ) THEN
*
*        RQ factorization of ( S11 S12 ) = ( 0 S12 )*Z
*
         CALL zgerq2( l, n, b, ldb, tau, work, info )
*
*        Update A := A*Z**H
*
         CALL zunmr2( 'Right', 'Conjugate transpose', m, n, l, b, ldb,
     $                tau, a, lda, work, info )
         IF( wantq ) THEN
*
*           Update Q := Q*Z**H
*
            CALL zunmr2( 'Right', 'Conjugate transpose', n, n, l, b,
     $                   ldb, tau, q, ldq, work, info )
         END IF
*
*        Clean up B
*
         CALL zlaset( 'Full', l, n-l, czero, czero, b, ldb )
         DO 60 j = n - l + 1, n
            DO 50 i = j - n + l + 1, l
               b( i, j ) = czero
   50       CONTINUE
   60    CONTINUE
*
      END IF
*
*     Let              N-L     L
*                A = ( A11    A12 ) M,
*
*     then the following does the complete QR decomposition of A11:
*
*              A11 = U*(  0  T12 )*P1**H
*                      (  0   0  )
*
      DO 70 i = 1, n - l
         iwork( i ) = 0
   70 CONTINUE
      CALL zgeqpf( m, n-l, a, lda, iwork, tau, work, rwork, info )
*
*     Determine the effective rank of A11
*
      k = 0
      DO 80 i = 1, min( m, n-l )
         IF( cabs1( a( i, i ) ).GT.tola )
     $      k = k + 1
   80 CONTINUE
*
*     Update A12 := U**H*A12, where A12 = A( 1:M, N-L+1:N )
*
      CALL zunm2r( 'Left', 'Conjugate transpose', m, l, min( m, n-l ),
     $             a, lda, tau, a( 1, n-l+1 ), lda, work, info )
*
      IF( wantu ) THEN
*
*        Copy the details of U, and form U
*
         CALL zlaset( 'Full', m, m, czero, czero, u, ldu )
         IF( m.GT.1 )
     $      CALL zlacpy( 'Lower', m-1, n-l, a( 2, 1 ), lda, u( 2, 1 ),
     $                   ldu )
         CALL zung2r( m, m, min( m, n-l ), u, ldu, tau, work, info )
      END IF
*
      IF( wantq ) THEN
*
*        Update Q( 1:N, 1:N-L )  = Q( 1:N, 1:N-L )*P1
*
         CALL zlapmt( forwrd, n, n-l, q, ldq, iwork )
      END IF
*
*     Clean up A: set the strictly lower triangular part of
*     A(1:K, 1:K) = 0, and A( K+1:M, 1:N-L ) = 0.
*
      DO 100 j = 1, k - 1
         DO 90 i = j + 1, k
            a( i, j ) = czero
   90    CONTINUE
  100 CONTINUE
      IF( m.GT.k )
     $   CALL zlaset( 'Full', m-k, n-l, czero, czero, a( k+1, 1 ), lda )
*
      IF( n-l.GT.k ) THEN
*
*        RQ factorization of ( T11 T12 ) = ( 0 T12 )*Z1
*
         CALL zgerq2( k, n-l, a, lda, tau, work, info )
*
         IF( wantq ) THEN
*
*           Update Q( 1:N,1:N-L ) = Q( 1:N,1:N-L )*Z1**H
*
            CALL zunmr2( 'Right', 'Conjugate transpose', n, n-l, k, a,
     $                   lda, tau, q, ldq, work, info )
         END IF
*
*        Clean up A
*
         CALL zlaset( 'Full', k, n-l-k, czero, czero, a, lda )
         DO 120 j = n - l - k + 1, n - l
            DO 110 i = j - n + l + k + 1, k
               a( i, j ) = czero
  110       CONTINUE
  120    CONTINUE
*
      END IF
*
      IF( m.GT.k ) THEN
*
*        QR factorization of A( K+1:M,N-L+1:N )
*
         CALL zgeqr2( m-k, l, a( k+1, n-l+1 ), lda, tau, work, info )
*
         IF( wantu ) THEN
*
*           Update U(:,K+1:M) := U(:,K+1:M)*U1
*
            CALL zunm2r( 'Right', 'No transpose', m, m-k, min( m-k, l ),
     $                   a( k+1, n-l+1 ), lda, tau, u( 1, k+1 ), ldu,
     $                   work, info )
         END IF
*
*        Clean up
*
         DO 140 j = n - l + 1, n
            DO 130 i = j - n + k + l + 1, m
               a( i, j ) = czero
  130       CONTINUE
  140    CONTINUE
*
      END IF
*
      RETURN
*
*     End of ZGGSVP
*

Here is the call graph for this function:

Here is the caller graph for this function: