LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
subroutine zunm2r ( character  SIDE,
character  TRANS,
integer  M,
integer  N,
integer  K,
complex*16, dimension( lda, * )  A,
integer  LDA,
complex*16, dimension( * )  TAU,
complex*16, dimension( ldc, * )  C,
integer  LDC,
complex*16, dimension( * )  WORK,
integer  INFO 
)

ZUNM2R multiplies a general matrix by the unitary matrix from a QR factorization determined by cgeqrf (unblocked algorithm).

Download ZUNM2R + dependencies [TGZ] [ZIP] [TXT]

Purpose: 
 ZUNM2R overwrites the general complex m-by-n matrix C with

       Q * C  if SIDE = 'L' and TRANS = 'N', or

       Q**H* C  if SIDE = 'L' and TRANS = 'C', or

       C * Q  if SIDE = 'R' and TRANS = 'N', or

       C * Q**H if SIDE = 'R' and TRANS = 'C',

 where Q is a complex unitary matrix defined as the product of k
 elementary reflectors

       Q = H(1) H(2) . . . H(k)

 as returned by ZGEQRF. Q is of order m if SIDE = 'L' and of order n
 if SIDE = 'R'.
Parameters
[in]SIDE
          SIDE is CHARACTER*1
          = 'L': apply Q or Q**H from the Left
          = 'R': apply Q or Q**H from the Right
[in]TRANS
          TRANS is CHARACTER*1
          = 'N': apply Q  (No transpose)
          = 'C': apply Q**H (Conjugate transpose)
[in]M
          M is INTEGER
          The number of rows of the matrix C. M >= 0.
[in]N
          N is INTEGER
          The number of columns of the matrix C. N >= 0.
[in]K
          K is INTEGER
          The number of elementary reflectors whose product defines
          the matrix Q.
          If SIDE = 'L', M >= K >= 0;
          if SIDE = 'R', N >= K >= 0.
[in]A
          A is COMPLEX*16 array, dimension (LDA,K)
          The i-th column must contain the vector which defines the
          elementary reflector H(i), for i = 1,2,...,k, as returned by
          ZGEQRF in the first k columns of its array argument A.
          A is modified by the routine but restored on exit.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.
          If SIDE = 'L', LDA >= max(1,M);
          if SIDE = 'R', LDA >= max(1,N).
[in]TAU
          TAU is COMPLEX*16 array, dimension (K)
          TAU(i) must contain the scalar factor of the elementary
          reflector H(i), as returned by ZGEQRF.
[in,out]C
          C is COMPLEX*16 array, dimension (LDC,N)
          On entry, the m-by-n matrix C.
          On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
[in]LDC
          LDC is INTEGER
          The leading dimension of the array C. LDC >= max(1,M).
[out]WORK
          WORK is COMPLEX*16 array, dimension
                                   (N) if SIDE = 'L',
                                   (M) if SIDE = 'R'
[out]INFO
          INFO is INTEGER
          = 0: successful exit
          < 0: if INFO = -i, the i-th argument had an illegal value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
September 2012

Definition at line 161 of file zunm2r.f.

161 *
162 * -- LAPACK computational routine (version 3.4.2) --
163 * -- LAPACK is a software package provided by Univ. of Tennessee, --
164 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
165 * September 2012
166 *
167 * .. Scalar Arguments ..
168  CHARACTER side, trans
169  INTEGER info, k, lda, ldc, m, n
170 * ..
171 * .. Array Arguments ..
172  COMPLEX*16 a( lda, * ), c( ldc, * ), tau( * ), work( * )
173 * ..
174 *
175 * =====================================================================
176 *
177 * .. Parameters ..
178  COMPLEX*16 one
179  parameter ( one = ( 1.0d+0, 0.0d+0 ) )
180 * ..
181 * .. Local Scalars ..
182  LOGICAL left, notran
183  INTEGER i, i1, i2, i3, ic, jc, mi, ni, nq
184  COMPLEX*16 aii, taui
185 * ..
186 * .. External Functions ..
187  LOGICAL lsame
188  EXTERNAL lsame
189 * ..
190 * .. External Subroutines ..
191  EXTERNAL xerbla, zlarf
192 * ..
193 * .. Intrinsic Functions ..
194  INTRINSIC dconjg, max
195 * ..
196 * .. Executable Statements ..
197 *
198 * Test the input arguments
199 *
200  info = 0
201  left = lsame( side, 'L' )
202  notran = lsame( trans, 'N' )
203 *
204 * NQ is the order of Q
205 *
206  IF( left ) THEN
207  nq = m
208  ELSE
209  nq = n
210  END IF
211  IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
212  info = -1
213  ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'C' ) ) THEN
214  info = -2
215  ELSE IF( m.LT.0 ) THEN
216  info = -3
217  ELSE IF( n.LT.0 ) THEN
218  info = -4
219  ELSE IF( k.LT.0 .OR. k.GT.nq ) THEN
220  info = -5
221  ELSE IF( lda.LT.max( 1, nq ) ) THEN
222  info = -7
223  ELSE IF( ldc.LT.max( 1, m ) ) THEN
224  info = -10
225  END IF
226  IF( info.NE.0 ) THEN
227  CALL xerbla( 'ZUNM2R', -info )
228  RETURN
229  END IF
230 *
231 * Quick return if possible
232 *
233  IF( m.EQ.0 .OR. n.EQ.0 .OR. k.EQ.0 )
234  $ RETURN
235 *
236  IF( ( left .AND. .NOT.notran .OR. .NOT.left .AND. notran ) ) THEN
237  i1 = 1
238  i2 = k
239  i3 = 1
240  ELSE
241  i1 = k
242  i2 = 1
243  i3 = -1
244  END IF
245 *
246  IF( left ) THEN
247  ni = n
248  jc = 1
249  ELSE
250  mi = m
251  ic = 1
252  END IF
253 *
254  DO 10 i = i1, i2, i3
255  IF( left ) THEN
256 *
257 * H(i) or H(i)**H is applied to C(i:m,1:n)
258 *
259  mi = m - i + 1
260  ic = i
261  ELSE
262 *
263 * H(i) or H(i)**H is applied to C(1:m,i:n)
264 *
265  ni = n - i + 1
266  jc = i
267  END IF
268 *
269 * Apply H(i) or H(i)**H
270 *
271  IF( notran ) THEN
272  taui = tau( i )
273  ELSE
274  taui = dconjg( tau( i ) )
275  END IF
276  aii = a( i, i )
277  a( i, i ) = one
278  CALL zlarf( side, mi, ni, a( i, i ), 1, taui, c( ic, jc ), ldc,
279  $ work )
280  a( i, i ) = aii
281  10 CONTINUE
282  RETURN
283 *
284 * End of ZUNM2R
285 *
xerbla
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
zlarf
subroutine zlarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
ZLARF applies an elementary reflector to a general rectangular matrix.
Definition: zlarf.f:130
lsame
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55

Here is the call graph for this function:

Here is the caller graph for this function: