double precision function zqrt11	(	integer	M,
		integer	K,
		complex*16, dimension( lda, * )	A,
		integer	LDA,
		complex*16, dimension( * )	TAU,
		complex*16, dimension( lwork )	WORK,
		integer	LWORK
	)

ZQRT11

Purpose:

 ZQRT11 computes the test ratio

       || Q'*Q - I || / (eps * m)

 where the orthogonal matrix Q is represented as a product of
 elementary transformations.  Each transformation has the form

    H(k) = I - tau(k) v(k) v(k)'

 where tau(k) is stored in TAU(k) and v(k) is an m-vector of the form
 [ 0 ... 0 1 x(k) ]', where x(k) is a vector of length m-k stored
 in A(k+1:m,k).

Parameters

[in]	M	M is INTEGER The number of rows of the matrix A.
[in]	K	K is INTEGER The number of columns of A whose subdiagonal entries contain information about orthogonal transformations.
[in]	A	A is COMPLEX*16 array, dimension (LDA,K) The (possibly partial) output of a QR reduction routine.
[in]	LDA	LDA is INTEGER The leading dimension of the array A.
[in]	TAU	TAU is COMPLEX*16 array, dimension (K) The scaling factors tau for the elementary transformations as computed by the QR factorization routine.
[out]	WORK	WORK is COMPLEX*16 array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The length of the array WORK. LWORK >= M*M + M.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 100 of file zqrt11.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            k, lda, lwork, m
*     ..
*     .. Array Arguments ..
      COMPLEX*16         a( lda, * ), tau( * ), work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter                ( zero = 0.0d0, one = 1.0d0 )
*     ..
*     .. Local Scalars ..
      INTEGER            info, j
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch, zlange
      EXTERNAL           dlamch, zlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zlaset, zunm2r
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dcmplx
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   rdummy( 1 )
*     ..
*     .. Executable Statements ..
*
      zqrt11 = zero
*
*     Test for sufficient workspace
*
      IF( lwork.LT.m*m+m ) THEN
         CALL xerbla( 'ZQRT11', 7 )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.LE.0 )
     $   RETURN
*
      CALL zlaset( 'Full', m, m, dcmplx( zero ), dcmplx( one ), work,
     $             m )
*
*     Form Q
*
      CALL zunm2r( 'Left', 'No transpose', m, m, k, a, lda, tau, work,
     $             m, work( m*m+1 ), info )
*
*     Form Q'*Q
*
      CALL zunm2r( 'Left', 'Conjugate transpose', m, m, k, a, lda, tau,
     $             work, m, work( m*m+1 ), info )
*
      DO 10 j = 1, m
         work( ( j-1 )*m+j ) = work( ( j-1 )*m+j ) - one
   10 CONTINUE
*
      zqrt11 = zlange( 'One-norm', m, m, work, m, rdummy ) /
     $         ( dble( m )*dlamch( 'Epsilon' ) )
*
      RETURN
*
*     End of ZQRT11
*

Here is the call graph for this function: