pcdbmv1.f

Go to the documentation of this file.

      SUBROUTINE pcgbdcmv( LDBW, BWL, BWU, TRANS, N, A, JA, DESCA, NRHS,
     $                     B, IB, DESCB, X, WORK, LWORK, INFO )
*
*
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     November 15, 1997
*
*     .. Scalar Arguments ..
      CHARACTER          TRANS
      INTEGER            BWL, BWU, IB, INFO, JA, LDBW, LWORK, N, NRHS
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * ), DESCB( * )
      COMPLEX            A( * ), B( * ), WORK( * ), X( * )
*     ..
*
*
*  Purpose
*  =======
*
*
*  =====================================================================
*
*  Arguments
*  =========
*
*
*  TRANS   (global input) CHARACTER
*          = 'N':  Solve with A(1:N, JA:JA+N-1);
*          = 'C':  Solve with conjugate_transpose( A(1:N, JA:JA+N-1) );
*
*  N       (global input) INTEGER
*          The number of rows and columns to be operated on, i.e. the
*          order of the distributed submatrix A(1:N, JA:JA+N-1). N >= 0.
*
*  BWL     (global input) INTEGER
*          Number of subdiagonals. 0 <= BWL <= N-1
*
*  BWU     (global input) INTEGER
*          Number of superdiagonals. 0 <= BWU <= N-1
*
*  A       (local input/local output) COMPLEX pointer into
*          local memory to an array with first dimension
*          LLD_A >=(bwl+bwu+1) (stored in DESCA).
*          On entry, this array contains the local pieces of the
*          This local portion is stored in the packed banded format
*            used in LAPACK. Please see the Notes below and the
*            ScaLAPACK manual for more detail on the format of
*            distributed matrices.
*
*  JA      (global input) INTEGER
*          The index in the global array A that points to the start of
*          the matrix to be operated on (which may be either all of A
*          or a submatrix of A).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN.
*          if 1D type (DTYPE_A=501), DLEN >= 7;
*          if 2D type (DTYPE_A=1), DLEN >= 9 .
*          The array descriptor for the distributed matrix A.
*          Contains information of mapping of A to memory. Please
*          see NOTES below for full description and options.
*
*  AF      (local output) COMPLEX array, dimension LAF.
*          Auxiliary Fillin Space.
*          Fillin is created during the factorization routine
*          PCDBTRF and this is stored in AF. If a linear system
*          is to be solved using PCDBTRS after the factorization
*          routine, AF *must not be altered* after the factorization.
*
*  LAF     (local input) INTEGER
*          Size of user-input Auxiliary Fillin space AF. Must be >=
*          NB*(bwl+bwu)+6*max(bwl,bwu)*max(bwl,bwu)
*          If LAF is not large enough, an error code will be returned
*          and the minimum acceptable size will be returned in AF( 1 )
*
*  WORK    (local workspace/local output)
*          COMPLEX temporary workspace. This space may
*          be overwritten in between calls to routines. WORK must be
*          the size given in LWORK.
*          On exit, WORK( 1 ) contains the minimal LWORK.
*
*  LWORK   (local input or global input) INTEGER
*          Size of user-input workspace WORK.
*          If LWORK is too small, the minimal acceptable size will be
*          returned in WORK(1) and an error code is returned. LWORK>=
*
*  INFO    (global output) INTEGER
*          = 0:  successful exit
*          < 0:  If the i-th argument is an array and the j-entry had
*                an illegal value, then INFO = -(i*100+j), if the i-th
*                argument is a scalar and had an illegal value, then
*                INFO = -i.
*
*  =====================================================================
*
*
*  Restrictions
*  ============
*
*  The following are restrictions on the input parameters. Some of these
*    are temporary and will be removed in future releases, while others
*    may reflect fundamental technical limitations.
*
*    Non-cyclic restriction: VERY IMPORTANT!
*      P*NB>= mod(JA-1,NB)+N.
*      The mapping for matrices must be blocked, reflecting the nature
*      of the divide and conquer algorithm as a task-parallel algorithm.
*      This formula in words is: no processor may have more than one
*      chunk of the matrix.
*
*    Blocksize cannot be too small:
*      If the matrix spans more than one processor, the following
*      restriction on NB, the size of each block on each processor,
*      must hold:
*      NB >= 2*MAX(BWL,BWU)
*      The bulk of parallel computation is done on the matrix of size
*      O(NB) on each processor. If this is too small, divide and conquer
*      is a poor choice of algorithm.
*
*    Submatrix reference:
*      JA = IB
*      Alignment restriction that prevents unnecessary communication.
*
*
*  =====================================================================
*
*
*  Notes
*  =====
*
*  If the factorization routine and the solve routine are to be called
*    separately (to solve various sets of righthand sides using the same
*    coefficient matrix), the auxiliary space AF *must not be altered*
*    between calls to the factorization routine and the solve routine.
*
*  The best algorithm for solving banded and tridiagonal linear systems
*    depends on a variety of parameters, especially the bandwidth.
*    Currently, only algorithms designed for the case N/P >> bw are
*    implemented. These go by many names, including Divide and Conquer,
*    Partitioning, domain decomposition-type, etc.
*
*  Algorithm description: Divide and Conquer
*
*    The Divide and Conqer algorithm assumes the matrix is narrowly
*      banded compared with the number of equations. In this situation,
*      it is best to distribute the input matrix A one-dimensionally,
*      with columns atomic and rows divided amongst the processes.
*      The basic algorithm divides the banded matrix up into
*      P pieces with one stored on each processor,
*      and then proceeds in 2 phases for the factorization or 3 for the
*      solution of a linear system.
*      1) Local Phase:
*         The individual pieces are factored independently and in
*         parallel. These factors are applied to the matrix creating
*         fillin, which is stored in a non-inspectable way in auxiliary
*         space AF. Mathematically, this is equivalent to reordering
*         the matrix A as P A P^T and then factoring the principal
*         leading submatrix of size equal to the sum of the sizes of
*         the matrices factored on each processor. The factors of
*         these submatrices overwrite the corresponding parts of A
*         in memory.
*      2) Reduced System Phase:
*         A small (max(bwl,bwu)* (P-1)) system is formed representing
*         interaction of the larger blocks, and is stored (as are its
*         factors) in the space AF. A parallel Block Cyclic Reduction
*         algorithm is used. For a linear system, a parallel front solve
*         followed by an analagous backsolve, both using the structure
*         of the factored matrix, are performed.
*      3) Backsubsitution Phase:
*         For a linear system, a local backsubstitution is performed on
*         each processor in parallel.
*
*
*  Descriptors
*  ===========
*
*  Descriptors now have *types* and differ from ScaLAPACK 1.0.
*
*  Note: banded codes can use either the old two dimensional
*    or new one-dimensional descriptors, though the processor grid in
*    both cases *must be one-dimensional*. We describe both types below.
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*
*  One-dimensional descriptors:
*
*  One-dimensional descriptors are a new addition to ScaLAPACK since
*    version 1.0. They simplify and shorten the descriptor for 1D
*    arrays.
*
*  Since ScaLAPACK supports two-dimensional arrays as the fundamental
*    object, we allow 1D arrays to be distributed either over the
*    first dimension of the array (as if the grid were P-by-1) or the
*    2nd dimension (as if the grid were 1-by-P). This choice is
*    indicated by the descriptor type (501 or 502)
*    as described below.
*
*    IMPORTANT NOTE: the actual BLACS grid represented by the
*    CTXT entry in the descriptor may be *either*  P-by-1 or 1-by-P
*    irrespective of which one-dimensional descriptor type
*    (501 or 502) is input.
*    This routine will interpret the grid properly either way.
*    ScaLAPACK routines *do not support intercontext operations* so that
*    the grid passed to a single ScaLAPACK routine *must be the same*
*    for all array descriptors passed to that routine.
*
*    NOTE: In all cases where 1D descriptors are used, 2D descriptors
*    may also be used, since a one-dimensional array is a special case
*    of a two-dimensional array with one dimension of size unity.
*    The two-dimensional array used in this case *must* be of the
*    proper orientation:
*      If the appropriate one-dimensional descriptor is DTYPEA=501
*      (1 by P type), then the two dimensional descriptor must
*      have a CTXT value that refers to a 1 by P BLACS grid;
*      If the appropriate one-dimensional descriptor is DTYPEA=502
*      (P by 1 type), then the two dimensional descriptor must
*      have a CTXT value that refers to a P by 1 BLACS grid.
*
*
*  Summary of allowed descriptors, types, and BLACS grids:
*  DTYPE           501         502         1         1
*  BLACS grid      1xP or Px1  1xP or Px1  1xP       Px1
*  -----------------------------------------------------
*  A               OK          NO          OK        NO
*  B               NO          OK          NO        OK
*
*  Let A be a generic term for any 1D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN  EXPLANATION
*  --------------- ---------- ------------------------------------------
*  DTYPE_A(global) DESCA( 1 ) The descriptor type. For 1D grids,
*                                TYPE_A = 501: 1-by-P grid.
*                                TYPE_A = 502: P-by-1 grid.
*  CTXT_A (global) DESCA( 2 ) The BLACS context handle, indicating
*                                the BLACS process grid A is distribu-
*                                ted over. The context itself is glo-
*                                bal, but the handle (the integer
*                                value) may vary.
*  N_A    (global) DESCA( 3 ) The size of the array dimension being
*                                distributed.
*  NB_A   (global) DESCA( 4 ) The blocking factor used to distribute
*                                the distributed dimension of the array.
*  SRC_A  (global) DESCA( 5 ) The process row or column over which the
*                                first row or column of the array
*                                is distributed.
*  LLD_A  (local)  DESCA( 6 ) The leading dimension of the local array
*                                storing the local blocks of the distri-
*                                buted array A. Minimum value of LLD_A
*                                depends on TYPE_A.
*                                TYPE_A = 501: LLD_A >=
*                                   size of undistributed dimension, 1.
*                                TYPE_A = 502: LLD_A >=NB_A, 1.
*  Reserved        DESCA( 7 ) Reserved for future use.
*
*
*
*  =====================================================================
*
*  Code Developer: Andrew J. Cleary, University of Tennessee.
*    Current address: Lawrence Livermore National Labs.
*  This version released: August, 2001.
*
*  =====================================================================
*
*     ..
*     .. Parameters ..
      REAL               ONE, ZERO
      parameter( one = 1.0e+0 )
      parameter( zero = 0.0e+0 )
      COMPLEX            CONE, CZERO
      parameter( cone = ( 1.0e+0, 0.0e+0 ) )
      parameter( czero = ( 0.0e+0, 0.0e+0 ) )
      INTEGER            INT_ONE
      parameter( int_one = 1 )
      INTEGER            DESCMULT, BIGNUM
      parameter(descmult = 100, bignum = descmult * descmult)
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   lld_, mb_, m_, nb_, n_, rsrc_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
*     ..
*     .. Local Scalars ..
      INTEGER            CSRC, DL_N_M, DL_N_N, DL_P_M, DL_P_N, DU_N_M,
     $                   du_n_n, du_p_m, du_p_n, first_proc, i, ictxt,
     $                   ictxt_new, ictxt_save, idum2, idum3, j, ja_new,
     $                   llda, lldb, max_bw, mycol, myrow, my_num_cols,
     $                   nb, np, npcol, nprow, np_save, odd_size, ofst,
     $                   part_offset, part_size, store_m_b, store_n_a
      INTEGER NUMROC_SIZE
*     ..
*     .. Local Arrays ..
      INTEGER            PARAM_CHECK( 17, 3 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, pxerbla, reshape
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            NUMROC
      EXTERNAL           lsame, numroc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          ichar, min, mod
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters
*
      info = 0
*
      ictxt = desca( ctxt_ )
      csrc = desca( csrc_ )
      nb = desca( nb_ )
      llda = desca( lld_ )
      store_n_a = desca( n_ )
      lldb = descb( lld_ )
      store_m_b = descb( m_ )
*
*
*     Size of separator blocks is maximum of bandwidths
*
      max_bw = max(bwl,bwu)
*
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
      np = nprow * npcol
*
*
*
      IF( lsame( trans, 'N' ) ) THEN
         idum2 = ichar( 'N' )
      ELSE IF ( lsame( trans, 'C' ) ) THEN
         idum2 = ichar( 'C' )
      ELSE
         info = -1
      END IF
*
      IF( lwork .LT. -1) THEN
         info = -15
      ELSE IF ( lwork .EQ. -1 ) THEN
         idum3 = -1
      ELSE
         idum3 = 1
      ENDIF
*
      IF( n .LT. 0 ) THEN
         info = -2
      ENDIF
*
      IF( n+ja-1 .GT. store_n_a ) THEN
         info = -( 8*100 + 6 )
      ENDIF
*
      IF(( bwl .GT. n-1 ) .OR.
     $   ( bwl .LT. 0 ) ) THEN
         info = -3
      ENDIF
*
      IF(( bwu .GT. n-1 ) .OR.
     $   ( bwu .LT. 0 ) ) THEN
         info = -4
      ENDIF
*
      IF( llda .LT. (bwl+bwu+1) ) THEN
         info = -( 8*100 + 6 )
      ENDIF
*
      IF( nb .LE. 0 ) THEN
         info = -( 8*100 + 4 )
      ENDIF
*
*     Argument checking that is specific to Divide & Conquer routine
*
      IF( nprow .NE. 1 ) THEN
         info = -( 8*100+2 )
      ENDIF
*
      IF( n .GT. np*nb-mod( ja-1, nb )) THEN
         info = -( 2 )
         CALL pxerbla( ictxt,
     $      'PCDBDCMV, D&C alg.: only 1 block per proc',
     $      -info )
         RETURN
      ENDIF
*
      IF((ja+n-1.GT.nb) .AND. ( nb.LT.2*max(bwl,bwu) )) THEN
         info = -( 8*100+4 )
         CALL pxerbla( ictxt,
     $      'PCDBDCMV, D&C alg.: NB too small',
     $      -info )
         RETURN
      ENDIF
*
*
*     Pack params and positions into arrays for global consistency check
*
      param_check( 17, 1 ) = descb(5)
      param_check( 16, 1 ) = descb(4)
      param_check( 15, 1 ) = descb(3)
      param_check( 14, 1 ) = descb(2)
      param_check( 13, 1 ) = descb(1)
      param_check( 12, 1 ) = ib
      param_check( 11, 1 ) = desca(5)
      param_check( 10, 1 ) = desca(4)
      param_check(  9, 1 ) = desca(3)
      param_check(  8, 1 ) = desca(1)
      param_check(  7, 1 ) = ja
      param_check(  6, 1 ) = nrhs
      param_check(  5, 1 ) = bwu
      param_check(  4, 1 ) = bwl
      param_check(  3, 1 ) = n
      param_check(  2, 1 ) = idum3
      param_check(  1, 1 ) = idum2
*
      param_check( 17, 2 ) = 1105
      param_check( 16, 2 ) = 1104
      param_check( 15, 2 ) = 1103
      param_check( 14, 2 ) = 1102
      param_check( 13, 2 ) = 1101
      param_check( 12, 2 ) = 10
      param_check( 11, 2 ) = 805
      param_check( 10, 2 ) = 804
      param_check(  9, 2 ) = 803
      param_check(  8, 2 ) = 801
      param_check(  7, 2 ) = 7
      param_check(  6, 2 ) = 5
      param_check(  5, 2 ) = 4
      param_check(  4, 2 ) = 3
      param_check(  3, 2 ) = 2
      param_check(  2, 2 ) = 15
      param_check(  1, 2 ) = 1
*
*     Want to find errors with MIN( ), so if no error, set it to a big
*     number. If there already is an error, multiply by the the
*     descriptor multiplier.
*
      IF( info.GE.0 ) THEN
         info = bignum
      ELSE IF( info.LT.-descmult ) THEN
         info = -info
      ELSE
         info = -info * descmult
      END IF
*
*     Check consistency across processors
*
      CALL globchk( ictxt, 17, param_check, 17,
     $              param_check( 1, 3 ), info )
*
*     Prepare output: set info = 0 if no error, and divide by DESCMULT
*     if error is not in a descriptor entry.
*
      IF( info.EQ.bignum ) THEN
         info = 0
      ELSE IF( mod( info, descmult ) .EQ. 0 ) THEN
         info = -info / descmult
      ELSE
         info = -info
      END IF
*
      IF( info.LT.0 ) THEN
         CALL pxerbla( ictxt, 'PCDBDCMV', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*
*     Adjust addressing into matrix space to properly get into
*        the beginning part of the relevant data
*
      part_offset = nb*( (ja-1)/(npcol*nb) )
*
      IF ( (mycol-csrc) .LT. (ja-part_offset-1)/nb ) THEN
         part_offset = part_offset + nb
      ENDIF
*
      IF ( mycol .LT. csrc ) THEN
         part_offset = part_offset - nb
      ENDIF
*
*     Form a new BLACS grid (the "standard form" grid) with only procs
*        holding part of the matrix, of size 1xNP where NP is adjusted,
*        starting at csrc=0, with JA modified to reflect dropped procs.
*
*     First processor to hold part of the matrix:
*
      first_proc = mod( ( ja-1 )/nb+csrc, npcol )
*
*     Calculate new JA one while dropping off unused processors.
*
      ja_new = mod( ja-1, nb ) + 1
*
*     Save and compute new value of NP
*
      np_save = np
      np = ( ja_new+n-2 )/nb + 1
*
*     Call utility routine that forms "standard-form" grid
*
      CALL reshape( ictxt, int_one, ictxt_new, int_one,
     $              first_proc, int_one, np )
*
*     Use new context from standard grid as context.
*
      ictxt_save = ictxt
      ictxt = ictxt_new
*
*     Get information about new grid.
*
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Drop out processors that do not have part of the matrix.
*
      IF( myrow .LT. 0 ) THEN
         GOTO 1234
      ENDIF
*
*     ********************************
*     Values reused throughout routine
*
*     User-input value of partition size
*
      part_size = nb
*
*     Number of columns in each processor
*
      my_num_cols = numroc( n, part_size, mycol, 0, npcol )
*
*     Offset in columns to beginning of main partition in each proc
*
      IF ( mycol .EQ. 0 ) THEN
        part_offset = part_offset+mod( ja_new-1, part_size )
        my_num_cols = my_num_cols - mod(ja_new-1, part_size )
      ENDIF
*
*     Offset in elements
*
      ofst = part_offset*llda
*
*     Size of main (or odd) partition in each processor
*
      odd_size = my_num_cols
      IF ( mycol .LT. np-1 ) THEN
         odd_size = odd_size - max_bw
      ENDIF
*
*
*
*       Zero out solution to use to accumulate answer
*
        numroc_size =
     $    numroc( n, part_size, mycol, 0, npcol)
*
        DO 2279 j=1,nrhs
          DO 4502 i=1,numroc_size
            x( (j-1)*lldb + i ) = czero
 4502     CONTINUE
 2279   CONTINUE
*
        DO 5642 i=1, (max_bw+2)*max_bw
          work( i ) = czero
 5642   CONTINUE
*
*     Begin main code
*
*
**************************************
*
      IF ( lsame( trans, 'N' ) ) THEN
*
*       Sizes of the extra triangles communicated bewtween processors
*
        IF( mycol .GT. 0 ) THEN
*
          dl_p_m= min( bwl,
     $          numroc( n, part_size, mycol, 0, npcol ) )
          dl_p_n= min( bwl,
     $          numroc( n, part_size, mycol-1, 0, npcol ) )
*
          du_p_m= min( bwu,
     $          numroc( n, part_size, mycol-1, 0, npcol ) )
          du_p_n= min( bwu,
     $          numroc( n, part_size, mycol, 0, npcol ) )
        ENDIF
*
        IF( mycol .LT. npcol-1 ) THEN
*
          dl_n_m= min( bwl,
     $          numroc( n, part_size, mycol+1, 0, npcol ) )
          dl_n_n= min( bwl,
     $          numroc( n, part_size, mycol, 0, npcol ) )
*
          du_n_m= min( bwu,
     $          numroc( n, part_size, mycol, 0, npcol ) )
          du_n_n= min( bwu,
     $          numroc( n, part_size, mycol+1, 0, npcol ) )
        ENDIF
*
*
*       Use main partition in each processor to multiply locally
*
        CALL cgbmv( trans, numroc_size, numroc_size, bwl, bwu, cone,
     $              a( ofst+1 ), llda, b(part_offset+1), 1, czero,
     $              x( part_offset+1 ), 1 )
*
*
*
        IF ( mycol .LT. npcol-1 ) THEN
*
*         Do the multiplication of the triangle in the lower half
*
          CALL ccopy( dl_n_n,
     $                  b( numroc_size-dl_n_n+1 ),
     $                  1, work( max_bw*max_bw+1+bwl-dl_n_n ), 1 )
*
         CALL ctrmv( 'U', 'N', 'N', bwl,
     $            a( llda*( numroc_size-bwl )+1+bwu+bwl ), llda-1,
     $            work( max_bw*max_bw+1 ), 1)
*
*        Zero out extraneous elements caused by TRMV if any
*
         IF( dl_n_m .GT. dl_n_n ) THEN
        DO 10  i = dl_n_m-dl_n_n, dl_n_m
                work( max_bw*max_bw+i ) = 0
   10   CONTINUE
         ENDIF
*
*         Send the result to the neighbor
*
          CALL cgesd2d( ictxt, bwl, 1,
     $       work( max_bw*max_bw+1 ), bwl, myrow, mycol+1 )
*
        ENDIF
*
        IF ( mycol .GT. 0 ) THEN
*
        DO 20  i=1, max_bw*( max_bw+2 )
          work( i ) = czero
   20   CONTINUE
*
*         Do the multiplication of the triangle in the upper half
*
*         Copy vector to workspace
*
          CALL ccopy( du_p_n, b( 1 ), 1,
     $                  work( max_bw*max_bw+1 ), 1)
*
          CALL ctrmv(
     $     'L',
     $     'N',
     $     'N', bwu,
     $     a( 1 ), llda-1,
     $     work( max_bw*max_bw+1 ), 1 )
*
*         Zero out extraneous results from TRMV if any
*
          IF( du_p_n .GT. du_p_m ) THEN
        DO 30  i=1, du_p_n-du_p_m
              work( max_bw*max_bw+i ) = 0
   30   CONTINUE
          ENDIF
*
*         Send result back
*
          CALL cgesd2d( ictxt, bwu, 1, work(max_bw*max_bw+1 ),
     $                   bwu, myrow, mycol-1 )
*
*         Receive vector result from neighboring processor
*
          CALL cgerv2d( ictxt, bwl, 1, work( max_bw*max_bw+1 ),
     $                    bwl, myrow, mycol-1 )
*
*         Do addition of received vector
*
          CALL caxpy( bwl, cone,
     $                  work( max_bw*max_bw+1 ), 1,
     $                  x( 1 ), 1 )
*
        ENDIF
*
*
*
         IF( mycol .LT. npcol-1 ) THEN
*
*          Receive returned result
*
           CALL cgerv2d( ictxt, bwu, 1, work( max_bw*max_bw+1 ),
     $                    bwu, myrow, mycol+1 )
*
*          Do addition of received vector
*
           CALL caxpy( bwu, cone,
     $                  work( max_bw*max_bw+1 ), 1,
     $                  x( numroc_size-bwu+1 ), 1)
*
         ENDIF
*
*
      ENDIF
*
*     End of LSAME if
*
**************************************
*
      IF ( lsame( trans, 'C' ) ) THEN
*
*       Sizes of the extra triangles communicated bewtween processors
*
        IF( mycol .GT. 0 ) THEN
*
          dl_p_m= min( bwu,
     $          numroc( n, part_size, mycol, 0, npcol ) )
          dl_p_n= min( bwu,
     $          numroc( n, part_size, mycol-1, 0, npcol ) )
*
          du_p_m= min( bwl,
     $          numroc( n, part_size, mycol-1, 0, npcol ) )
          du_p_n= min( bwl,
     $          numroc( n, part_size, mycol, 0, npcol ) )
        ENDIF
*
        IF( mycol .LT. npcol-1 ) THEN
*
          dl_n_m= min( bwu,
     $          numroc( n, part_size, mycol+1, 0, npcol ) )
          dl_n_n= min( bwu,
     $          numroc( n, part_size, mycol, 0, npcol ) )
*
          du_n_m= min( bwl,
     $          numroc( n, part_size, mycol, 0, npcol ) )
          du_n_n= min( bwl,
     $          numroc( n, part_size, mycol+1, 0, npcol ) )
        ENDIF
*
*
        IF( mycol .GT. 0 ) THEN
*         ...must send triangle in lower half of matrix to left
*
*         Transpose triangle in preparation for sending
*
          CALL clatcpy( 'L', bwu, bwu, a( ofst+1 ),
     $          llda-1, work( 1 ), max_bw )
*
*         Send the triangle to neighboring processor to left
*
          CALL ctrsd2d(ictxt, 'U', 'N',
     $                  bwu, bwu,
     $                  work( 1 ),
     $                  max_bw, myrow, mycol-1 )
*
        ENDIF
*
        IF( mycol .LT. npcol-1 ) THEN
*         ...must send triangle in upper half of matrix to right
*
*         Transpose triangle in preparation for sending
*
          CALL clatcpy( 'U', bwl, bwl,
     $          a( llda*( numroc_size-bwl )+1+bwu+bwl ),
     $          llda-1, work( 1 ), max_bw )
*
*         Send the triangle to neighboring processor to right
*
          CALL ctrsd2d(ictxt, 'L', 'N',
     $                  bwl, bwl,
     $                  work( 1 ),
     $                  max_bw, myrow, mycol+1 )
*
        ENDIF
*
*       Use main partition in each processor to multiply locally
*
        CALL cgbmv( trans, numroc_size, numroc_size, bwl, bwu, cone,
     $              a( ofst+1 ), llda, b(part_offset+1), 1, czero,
     $              x( part_offset+1 ), 1 )
*
*
*
        IF ( mycol .LT. npcol-1 ) THEN
*
*         Do the multiplication of the triangle in the lower half
*
          CALL ccopy( dl_n_n,
     $                  b( numroc_size-dl_n_n+1 ),
     $                  1, work( max_bw*max_bw+1+bwu-dl_n_n ), 1 )
*
*         Receive the triangle prior to multiplying by it.
*
          CALL ctrrv2d(ictxt, 'U', 'N',
     $                  bwu, bwu,
     $                  work( 1 ), max_bw, myrow, mycol+1 )
*
         CALL ctrmv( 'U', 'N', 'N', bwu,
     $            work( 1 ), max_bw,
     $            work( max_bw*max_bw+1 ), 1)
*
*        Zero out extraneous elements caused by TRMV if any
*
         IF( dl_n_m .GT. dl_n_n ) THEN
        DO 40  i = dl_n_m-dl_n_n, dl_n_m
                work( max_bw*max_bw+i ) = 0
   40   CONTINUE
         ENDIF
*
*         Send the result to the neighbor
*
          CALL cgesd2d( ictxt, bwu, 1,
     $       work( max_bw*max_bw+1 ), bwu, myrow, mycol+1 )
*
        ENDIF
*
        IF ( mycol .GT. 0 ) THEN
*
        DO 50  i=1, max_bw*( max_bw+2 )
          work( i ) = czero
   50   CONTINUE
*
*         Do the multiplication of the triangle in the upper half
*
*         Copy vector to workspace
*
          CALL ccopy( du_p_n, b( 1 ), 1,
     $                  work( max_bw*max_bw+1 ), 1)
*
*         Receive the triangle prior to multiplying by it.
*
          CALL ctrrv2d(ictxt, 'L', 'N',
     $                  bwl, bwl,
     $                  work( 1 ), max_bw, myrow, mycol-1 )
*
          CALL ctrmv(
     $     'L',
     $     'N',
     $     'N', bwl,
     $     work( 1 ), max_bw,
     $     work( max_bw*max_bw+1 ), 1 )
*
*         Zero out extraneous results from TRMV if any
*
          IF( du_p_n .GT. du_p_m ) THEN
        DO 60  i=1, du_p_n-du_p_m
              work( max_bw*max_bw+i ) = 0
   60   CONTINUE
          ENDIF
*
*         Send result back
*
          CALL cgesd2d( ictxt, bwl, 1, work(max_bw*max_bw+1 ),
     $                   bwl, myrow, mycol-1 )
*
*         Receive vector result from neighboring processor
*
          CALL cgerv2d( ictxt, bwu, 1, work( max_bw*max_bw+1 ),
     $                    bwu, myrow, mycol-1 )
*
*         Do addition of received vector
*
          CALL caxpy( bwu, cone,
     $                  work( max_bw*max_bw+1 ), 1,
     $                  x( 1 ), 1 )
*
        ENDIF
*
*
*
         IF( mycol .LT. npcol-1 ) THEN
*
*          Receive returned result
*
           CALL cgerv2d( ictxt, bwl, 1, work( max_bw*max_bw+1 ),
     $                    bwl, myrow, mycol+1 )
*
*          Do addition of received vector
*
           CALL caxpy( bwl, cone,
     $                  work( max_bw*max_bw+1 ), 1,
     $                  x( numroc_size-bwl+1 ), 1)
*
         ENDIF
*
*
      ENDIF
*
*     End of LSAME if
*
*
*     Free BLACS space used to hold standard-form grid.
*
      IF( ictxt_save .NE. ictxt_new ) THEN
         CALL blacs_gridexit( ictxt_new )
      ENDIF
*
 1234 CONTINUE
*
*     Restore saved input parameters
*
      ictxt = ictxt_save
      np = np_save
*
*
      RETURN
*
*     End of PCBhBMV1
*
      END