globchk()

subroutine globchk	(	integer	ictxt,
		integer	n,
		integer, dimension( ldx, 2 )	x,
		integer	ldx,
		integer, dimension( n )	iwork,
		integer	info
	)

Definition at line 402 of file pchkxmat.f.

*
*  -- ScaLAPACK tools routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      INTEGER            ICTXT, INFO, LDX, N
*     ..
*     .. Array Arguments ..
      INTEGER            IWORK( N ), X( LDX, 2 )
*     ..
*
*  Purpose
*  =======
*
*  GLOBCHK checks that values in X(i,1) are the same on all processes
*  in the process grid indicated by ICTXT.
*
*  Arguments
*  =========
*
*  ICTXT   (global input) INTEGER
*          The BLACS context handle indicating the context over which
*          the values are to be the same.
*
*  N       (global input) INTEGER
*          The number of values to be compared.
*
*  X       (local input) INTEGER array, dimension (N,2)
*          The 1st column contains the values which should be the same
*          on all processes.  The 2nd column indicates where in the
*          calling routine's parameter list the corresponding value
*          from column 1 came from.
*
*  LDX     (local input) INTEGER
*          The leading dimension of the array X. LDX >= MAX(1,N).
*
*  IWORK   (local workspace) INTEGER array, dimension (N)
*          Used to receive other processes' values for comparing with X.
*
*  INFO    (local input/global output) INTEGER
*          On entry, the smallest error flag so far generated, or BIGNUM
*          for no error. On exit:
*          = BIGNUM : no error
*          < 0: if INFO = -i*100, the i-th argument had an illegal
*               value, or was different between processes.
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            K, MYROW, MYCOL
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, igamn2d, igebr2d, igebs2d
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          min
*     ..
*     .. Executable Statements ..
*
      CALL blacs_gridinfo( ictxt, iwork, k, myrow, mycol )
*
      IF( myrow.EQ.0 .AND. mycol.EQ.0 ) THEN
         CALL igebs2d( ictxt, 'All', ' ', n, 1, x, n )
      ELSE
         CALL igebr2d( ictxt, 'All', ' ', n, 1, iwork, n, 0, 0 )
         DO 10 k = 1, n
            IF( x( k, 1 ).NE.iwork( k ) )
     $         info = min( info, x( k, 2 ) )
   10    CONTINUE
      END IF
*
      CALL igamn2d( ictxt, 'All', ' ', 1, 1, info, 1, k, k, -1, -1, 0 )
*
      RETURN
*
*     End GLOBCHK
*