pcheevd.f

Go to the documentation of this file.

      SUBROUTINE pcheevd( JOBZ, UPLO, N, A, IA, JA, DESCA, W, Z, IZ, JZ,
     $                    DESCZ, WORK, LWORK, RWORK, LRWORK, IWORK,
     $                    LIWORK, INFO )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     March 25, 2002
*
*     .. Scalar Arguments ..
      CHARACTER          JOBZ, UPLO
      INTEGER            IA, INFO, IZ, JA, JZ, LIWORK, LRWORK, LWORK, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * ), DESCZ( * ), IWORK( * )
      REAL               RWORK( * ), W( * )
      COMPLEX            A( * ), WORK( * ), Z( * )
*     ..
*
*  Purpose
*  =======
*
*  PCHEEVD computes all the eigenvalues and eigenvectors of a Hermitian
*  matrix A by using a divide and conquer algorithm.
*
*  Arguments
*  =========
*
*     NP = the number of rows local to a given process.
*     NQ = the number of columns local to a given process.
*
*  JOBZ    (input) CHARACTER*1
*          = 'N':  Compute eigenvalues only;    (NOT IMPLEMENTED YET)
*          = 'V':  Compute eigenvalues and eigenvectors.
*
*  UPLO    (global input) CHARACTER*1
*          Specifies whether the upper or lower triangular part of the
*          symmetric matrix A is stored:
*          = 'U':  Upper triangular
*          = 'L':  Lower triangular
*
*  N       (global input) INTEGER
*          The number of rows and columns of the matrix A.  N >= 0.
*
*  A       (local input/workspace) block cyclic COMPLEX array,
*          global dimension (N, N), local dimension ( LLD_A,
*          LOCc(JA+N-1) )
*
*          On entry, the symmetric matrix A.  If UPLO = 'U', only the
*          upper triangular part of A is used to define the elements of
*          the symmetric matrix.  If UPLO = 'L', only the lower
*          triangular part of A is used to define the elements of the
*          symmetric matrix.
*
*          On exit, the lower triangle (if UPLO='L') or the upper
*          triangle (if UPLO='U') of A, including the diagonal, is
*          destroyed.
*
*  IA      (global input) INTEGER
*          A's global row index, which points to the beginning of the
*          submatrix which is to be operated on.
*
*  JA      (global input) INTEGER
*          A's global column index, which points to the beginning of
*          the submatrix which is to be operated on.
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*          If DESCA( CTXT_ ) is incorrect, PCHEEVD cannot guarantee
*          correct error reporting.
*
*  W       (global output) REAL array, dimension (N)
*          If INFO=0, the eigenvalues in ascending order.
*
*  Z       (local output) COMPLEX array,
*          global dimension (N, N),
*          local dimension ( LLD_Z, LOCc(JZ+N-1) )
*          Z contains the orthonormal eigenvectors of the matrix A.
*
*  IZ      (global input) INTEGER
*          Z's global row index, which points to the beginning of the
*          submatrix which is to be operated on.
*
*  JZ      (global input) INTEGER
*          Z's global column index, which points to the beginning of
*          the submatrix which is to be operated on.
*
*  DESCZ   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix Z.
*          DESCZ( CTXT_ ) must equal DESCA( CTXT_ )
*
*  WORK    (local workspace/output) COMPLEX array,
*          dimension (LWORK)
*          On output, WORK(1) returns the workspace needed for the
*          computation.
*
*  LWORK   (local input) INTEGER
*          If eigenvectors are requested:
*            LWORK = N + ( NP0 + MQ0 + NB ) * NB,
*          with  NP0 = NUMROC( MAX( N, NB, 2 ), NB, 0, 0, NPROW )
*                MQ0 = NUMROC( MAX( N, NB, 2 ), NB, 0, 0, NPCOL )
*
*          If LWORK = -1, then LWORK is global input and a workspace
*          query is assumed; the routine calculates the size for all
*          work arrays. Each of these values is returned in the first
*          entry of the corresponding work array, and no error message
*          is issued by PXERBLA.
*
*  RWORK   (local workspace/output) REAL array,
*          dimension (LRWORK)
*          On output RWORK(1) returns the real workspace needed to
*          guarantee completion.  If the input parameters are incorrect,
*          RWORK(1) may also be incorrect.
*
*  LRWORK  (local input) INTEGER
*          Size of RWORK array.
*          LRWORK >= 1 + 9*N + 3*NP*NQ,
*          NP = NUMROC( N, NB, MYROW, IAROW, NPROW )
*          NQ = NUMROC( N, NB, MYCOL, IACOL, NPCOL )
*
*  IWORK   (local workspace/output) INTEGER array, dimension (LIWORK)
*          On output IWORK(1) returns the integer workspace needed.
*
*  LIWORK  (input) INTEGER
*          The dimension of the array IWORK.
*          LIWORK = 7*N + 8*NPCOL + 2
*
*  INFO    (global output) INTEGER
*          = 0:  successful exit
*          < 0:  If the i-th argument is an array and the j-entry had
*                an illegal value, then INFO = -(i*100+j), if the i-th
*                argument is a scalar and had an illegal value, then
*                INFO = -i.
*          > 0:  If INFO = 1 through N, the i(th) eigenvalue did not
*                converge in PSLAED3.
*
*  Alignment requirements
*  ======================
*
*  The distributed submatrices sub( A ), sub( Z ) must verify
*  some alignment properties, namely the following expression
*  should be true:
*  ( MB_A.EQ.NB_A.EQ.MB_Z.EQ.NB_Z .AND. IROFFA.EQ.ICOFFA .AND.
*    IROFFA.EQ.0 .AND.IROFFA.EQ.IROFFZ. AND. IAROW.EQ.IZROW)
*    with IROFFA = MOD( IA-1, MB_A )
*     and ICOFFA = MOD( JA-1, NB_A ).
*
*  Further Details
*  ======= =======
*
*  Contributed by Francoise Tisseur, University of Manchester.
*
*  Reference:  F. Tisseur and J. Dongarra, "A Parallel Divide and
*              Conquer Algorithm for the Symmetric Eigenvalue Problem
*              on Distributed Memory Architectures",
*              SIAM J. Sci. Comput., 6:20 (1999), pp. 2223--2236.
*              (see also LAPACK Working Note 132)
*                http://www.netlib.org/lapack/lawns/lawn132.ps
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, DLEN_, DTYPE_, CTXT_, M_, N_,
     $                   MB_, NB_, RSRC_, CSRC_, LLD_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                   ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                   rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      REAL               ZERO, ONE
      PARAMETER          ( ZERO = 0.0e+0, one = 1.0e+0 )
      COMPLEX            CZERO, CONE
      parameter( czero = ( 0.0e+0, 0.0e+0 ),
     $                   cone = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            LOWER, LQUERY
      INTEGER            CSRC_A, I, IACOL, IAROW, ICOFFA, IINFO, IIZ,
     $                   indd, inde, inde2, indrwork, indtau, indwork,
     $                   indz, ipr, ipz, iroffa, iroffz, iscale, izcol,
     $                   izrow, j, jjz, ldr, ldz, liwmin, llrwork,
     $                   llwork, lrwmin, lwmin, mb_a, mycol, myrow, nb,
     $                   nb_a, nn, np0, npcol, nprow, nq, nq0, offset,
     $                   rsrc_a
      REAL               ANRM, BIGNUM, EPS, RMAX, RMIN, SAFMIN, SIGMA,
     $                   SMLNUM
*     ..
*     .. Local Arrays ..
      INTEGER            DESCRZ( 9 ), IDUM1( 2 ), IDUM2( 2 )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            INDXG2L, INDXG2P, NUMROC
      REAL               PCLANHE, PSLAMCH
      EXTERNAL           lsame, indxg2l, indxg2p, numroc, pclanhe,
     $                   pslamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, chk1mat, descinit, infog2l,
     $                   pcelget, pchetrd, pchk2mat, pclascl, pclaset,
     $                   pcunmtr, pslared1d, pslaset, psstedc, pxerbla,
     $                   sscal
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, ichar, max, min, mod, real, sqrt
*     ..
*     .. Executable Statements ..
*       This is just to keep ftnchek and toolpack/1 happy
      IF( block_cyclic_2d*csrc_*ctxt_*dlen_*dtype_*lld_*mb_*m_*nb_*n_*
     $    rsrc_.LT.0 )RETURN
*
      info = 0
*
*     Quick return
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Test the input arguments.
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
      IF( nprow.EQ.-1 ) THEN
         info = -( 700+ctxt_ )
      ELSE
         CALL chk1mat( n, 3, n, 3, ia, ja, desca, 7, info )
         CALL chk1mat( n, 3, n, 3, iz, jz, descz, 12, info )
         IF( info.EQ.0 ) THEN
            lower = lsame( uplo, 'L' )
            nb_a = desca( nb_ )
            mb_a = desca( mb_ )
            nb = nb_a
            rsrc_a = desca( rsrc_ )
            csrc_a = desca( csrc_ )
            iroffa = mod( ia-1, mb_a )
            icoffa = mod( ja-1, nb_a )
            iarow = indxg2p( ia, nb_a, myrow, rsrc_a, nprow )
            iacol = indxg2p( ja, mb_a, mycol, csrc_a, npcol )
            np0 = numroc( n, nb, myrow, iarow, nprow )
            nq0 = numroc( n, nb, mycol, iacol, npcol )
            iroffz = mod( iz-1, mb_a )
            CALL infog2l( iz, jz, descz, nprow, npcol, myrow, mycol,
     $                    iiz, jjz, izrow, izcol )
            lquery = ( lwork.EQ.-1 .OR. liwork.EQ.-1 .OR. lrwork.EQ.-1 )
*
*           Compute the total amount of space needed
*
            nn = max( n, nb, 2 )
            nq = numroc( nn, nb, 0, 0, npcol )
            lwmin = n + ( np0+nq+nb )*nb
            lrwmin = 1 + 9*n + 3*np0*nq0
            liwmin = 7*n + 8*npcol + 2
            work( 1 ) = cmplx( lwmin )
            rwork( 1 ) = real( lrwmin )
            iwork( 1 ) = liwmin
            IF( .NOT.lsame( jobz, 'V' ) ) THEN
               info = -1
            ELSE IF( .NOT.( lower .OR. lsame( uplo, 'U' ) ) ) THEN
               info = -2
            ELSE IF( lwork.LT.lwmin .AND. lwork.NE.-1 ) THEN
               info = -14
            ELSE IF( lrwork.LT.lrwmin .AND. lrwork.NE.-1 ) THEN
               info = -16
            ELSE IF( iroffa.NE.0 ) THEN
               info = -4
            ELSE IF( desca( mb_ ).NE.desca( nb_ ) ) THEN
               info = -( 700+nb_ )
            ELSE IF( iroffa.NE.iroffz ) THEN
               info = -10
            ELSE IF( iarow.NE.izrow ) THEN
               info = -10
            ELSE IF( desca( m_ ).NE.descz( m_ ) ) THEN
               info = -( 1200+m_ )
            ELSE IF( desca( n_ ).NE.descz( n_ ) ) THEN
               info = -( 1200+n_ )
            ELSE IF( desca( mb_ ).NE.descz( mb_ ) ) THEN
               info = -( 1200+mb_ )
            ELSE IF( desca( nb_ ).NE.descz( nb_ ) ) THEN
               info = -( 1200+nb_ )
            ELSE IF( desca( rsrc_ ).NE.descz( rsrc_ ) ) THEN
               info = -( 1200+rsrc_ )
            ELSE IF( desca( ctxt_ ).NE.descz( ctxt_ ) ) THEN
               info = -( 1200+ctxt_ )
            END IF
         END IF
         IF( lower ) THEN
            idum1( 1 ) = ichar( 'L' )
         ELSE
            idum1( 1 ) = ichar( 'U' )
         END IF
         idum2( 1 ) = 2
         IF( lwork.EQ.-1 ) THEN
            idum1( 2 ) = -1
         ELSE
            idum1( 2 ) = 1
         END IF
         idum2( 2 ) = 14
         CALL pchk2mat( n, 3, n, 3, ia, ja, desca, 7, n, 3, n, 3, iz,
     $                  jz, descz, 12, 2, idum1, idum2, info )
      END IF
*
      IF( info.NE.0 ) THEN
         CALL pxerbla( desca( ctxt_ ), 'PCHEEVD', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Get machine constants.
*
      safmin = pslamch( desca( ctxt_ ), 'Safe minimum' )
      eps = pslamch( desca( ctxt_ ), 'Precision' )
      smlnum = safmin / eps
      bignum = one / smlnum
      rmin = sqrt( smlnum )
      rmax = min( sqrt( bignum ), one / sqrt( sqrt( safmin ) ) )
*
*     Set up pointers into the WORK array
*
      indtau = 1
      indwork = indtau + n
      llwork = lwork - indwork + 1
*
*     Set up pointers into the RWORK array
*
      inde = 1
      indd = inde + n
      inde2 = indd + n
      indrwork = inde2 + n
      llrwork = lrwork - indrwork + 1
*
*     Scale matrix to allowable range, if necessary.
*
      iscale = 0
*
      anrm = pclanhe( 'M', uplo, n, a, ia, ja, desca,
     $       rwork( indrwork ) )
*
*
      IF( anrm.GT.zero .AND. anrm.LT.rmin ) THEN
         iscale = 1
         sigma = rmin / anrm
      ELSE IF( anrm.GT.rmax ) THEN
         iscale = 1
         sigma = rmax / anrm
      END IF
*
      IF( iscale.EQ.1 ) THEN
         CALL pclascl( uplo, one, sigma, n, n, a, ia, ja, desca, iinfo )
      END IF
*
*     Reduce Hermitian matrix to tridiagonal form.
*
      CALL pchetrd( uplo, n, a, ia, ja, desca, rwork( indd ),
     $              rwork( inde2 ), work( indtau ), work( indwork ),
     $              llwork, iinfo )
*
*     Copy the values of D, E to all processes
*
*     Here PxLARED1D is used to redistribute the tridiagonal matrix.
*     PxLARED1D, however, doesn't yet work with arbritary matrix
*     distributions so we have PxELGET as a backup.
*
      offset = 0
      IF( ia.EQ.1 .AND. ja.EQ.1 .AND. rsrc_a.EQ.0 .AND. csrc_a.EQ.0 )
     $     THEN
         CALL pslared1d( n, ia, ja, desca, rwork( indd ), w,
     $                   rwork( indrwork ), llrwork )
*
         CALL pslared1d( n, ia, ja, desca, rwork( inde2 ),
     $                   rwork( inde ), rwork( indrwork ), llrwork )
         IF( .NOT.lower )
     $      offset = 1
      ELSE
         DO 10 i = 1, n
            CALL pcelget( 'A', ' ', work( indwork ), a, i+ia-1, i+ja-1,
     $                    desca )
            w( i ) = real( work( indwork ) )
   10    CONTINUE
         IF( lsame( uplo, 'U' ) ) THEN
            DO 20 i = 1, n - 1
               CALL pcelget( 'A', ' ', work( indwork ), a, i+ia-1, i+ja,
     $                       desca )
               rwork( inde+i-1 ) = real( work( indwork ) )
   20       CONTINUE
         ELSE
            DO 30 i = 1, n - 1
               CALL pcelget( 'A', ' ', work( indwork ), a, i+ia, i+ja-1,
     $                       desca )
               rwork( inde+i-1 ) = real( work( indwork ) )
   30       CONTINUE
         END IF
      END IF
*
*     Call PSSTEDC to compute eigenvalues and eigenvectors.
*
      indz = inde + n
      indrwork = indz + np0*nq0
      llrwork = lrwork - indrwork + 1
      ldr = max( 1, np0 )
      CALL descinit( descrz, descz( m_ ), descz( n_ ), descz( mb_ ),
     $               descz( nb_ ), descz( rsrc_ ), descz( csrc_ ),
     $               descz( ctxt_ ), ldr, info )
      CALL pclaset( 'Full', n, n, czero, cone, z, iz, jz, descz )
      CALL pslaset( 'Full', n, n, zero, one, rwork( indz ), 1, 1,
     $              descrz )
      CALL psstedc( 'I', n, w, rwork( inde+offset ), rwork( indz ), iz,
     $              jz, descrz, rwork( indrwork ), llrwork, iwork,
     $              liwork, iinfo )
*
      ldz = descz( lld_ )
      ldr = descrz( lld_ )
      iiz = indxg2l( iz, nb, myrow, myrow, nprow )
      jjz = indxg2l( jz, nb, mycol, mycol, npcol )
      ipz = iiz + ( jjz-1 )*ldz
      ipr = indz - 1 + iiz + ( jjz-1 )*ldr
      DO 50 j = 0, nq0 - 1
         DO 40 i = 0, np0 - 1
            z( ipz+i+j*ldz ) = rwork( ipr+i+j*ldr )
   40    CONTINUE
   50 CONTINUE
*
*     Z = Q * Z
*
      CALL pcunmtr( 'L', uplo, 'N', n, n, a, ia, ja, desca,
     $              work( indtau ), z, iz, jz, descz, work( indwork ),
     $              llwork, iinfo )
*
*     If matrix was scaled, then rescale eigenvalues appropriately.
*
      IF( iscale.EQ.1 ) THEN
         CALL sscal( n, one / sigma, w, 1 )
      END IF
*
      work( 1 ) = cmplx( lwmin )
      rwork( 1 ) = real( lrwmin )
      iwork( 1 ) = liwmin
*
      RETURN
*
*     End of PCHEEVD
*
      END