psgbtrs.f

Go to the documentation of this file.

      SUBROUTINE psgbtrs( TRANS, N, BWL, BWU, NRHS, A, JA, DESCA, IPIV,
     $                    B, IB, DESCB, AF, LAF, WORK, LWORK, INFO )
*
*  -- ScaLAPACK routine (version 2.0.2) --
*     Univ. of Tennessee, Univ. of California Berkeley, Univ. of Colorado Denver
*     May 1 2012
*
*     .. Scalar Arguments ..
      CHARACTER          TRANS
      INTEGER            BWL, BWU, IB, INFO, JA, LAF, LWORK, N, NRHS
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * ), DESCB( * ), IPIV( * )
      REAL               A( * ), AF( * ), B( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  PSGBTRS solves a system of linear equations
*
*            A(1:N, JA:JA+N-1) * X = B(IB:IB+N-1, 1:NRHS)
*                                    or
*            A(1:N, JA:JA+N-1)' * X = B(IB:IB+N-1, 1:NRHS)
*
*  where A(1:N, JA:JA+N-1) is the matrix used to produce the factors
*  stored in A(1:N,JA:JA+N-1) and AF by PSGBTRF.
*  A(1:N, JA:JA+N-1) is an N-by-N real
*  banded distributed
*  matrix with bandwidth BWL, BWU.
*
*  Routine PSGBTRF MUST be called first.
*
*  =====================================================================
*
*  Arguments
*  =========
*
*
*  TRANS   (global input) CHARACTER
*          = 'N':  Solve with A(1:N, JA:JA+N-1);
*          = 'T' or 'C':  Solve with A(1:N, JA:JA+N-1)^T;
*
*  N       (global input) INTEGER
*          The number of rows and columns to be operated on, i.e. the
*          order of the distributed submatrix A(1:N, JA:JA+N-1). N >= 0.
*
*  BWL     (global input) INTEGER
*          Number of subdiagonals. 0 <= BWL <= N-1
*
*  BWU     (global input) INTEGER
*          Number of superdiagonals. 0 <= BWU <= N-1
*
*  NRHS    (global input) INTEGER
*          The number of right hand sides, i.e., the number of columns
*          of the distributed submatrix B(IB:IB+N-1, 1:NRHS).
*          NRHS >= 0.
*
*  A       (local input/local output) REAL pointer into
*          local memory to an array with first dimension
*          LLD_A >=(2*bwl+2*bwu+1) (stored in DESCA).
*          On entry, this array contains the local pieces of the
*          N-by-N unsymmetric banded distributed Cholesky factor L or
*          L^T A(1:N, JA:JA+N-1).
*          This local portion is stored in the packed banded format
*            used in LAPACK. Please see the Notes below and the
*            ScaLAPACK manual for more detail on the format of
*            distributed matrices.
*
*  JA      (global input) INTEGER
*          The index in the global array A that points to the start of
*          the matrix to be operated on (which may be either all of A
*          or a submatrix of A).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN.
*          if 1D type (DTYPE_A=501), DLEN >= 7;
*          if 2D type (DTYPE_A=1), DLEN >= 9 .
*          The array descriptor for the distributed matrix A.
*          Contains information of mapping of A to memory. Please
*          see NOTES below for full description and options.
*
*  IPIV    (local output) INTEGER array, dimension >= DESCA( NB ).
*          Pivot indices for local factorizations.
*          Users *should not* alter the contents between
*          factorization and solve.
*
*  B       (local input/local output) REAL pointer into
*          local memory to an array of local lead dimension lld_b>=NB.
*          On entry, this array contains the
*          the local pieces of the right hand sides
*          B(IB:IB+N-1, 1:NRHS).
*          On exit, this contains the local piece of the solutions
*          distributed matrix X.
*
*  IB      (global input) INTEGER
*          The row index in the global array B that points to the first
*          row of the matrix to be operated on (which may be either
*          all of B or a submatrix of B).
*
*  DESCB   (global and local input) INTEGER array of dimension DLEN.
*          if 1D type (DTYPE_B=502), DLEN >=7;
*          if 2D type (DTYPE_B=1), DLEN >= 9.
*          The array descriptor for the distributed matrix B.
*          Contains information of mapping of B to memory. Please
*          see NOTES below for full description and options.
*
*  AF      (local output) REAL array, dimension LAF.
*          Auxiliary Fillin Space.
*          Fillin is created during the factorization routine
*          PSGBTRF and this is stored in AF. If a linear system
*          is to be solved using PSGBTRS after the factorization
*          routine, AF *must not be altered* after the factorization.
*
*  LAF     (local input) INTEGER
*          Size of user-input Auxiliary Fillin space AF. Must be >=
*          (NB+bwu)*(bwl+bwu)+6*(bwl+bwu)*(bwl+2*bwu)
*          If LAF is not large enough, an error code will be returned
*          and the minimum acceptable size will be returned in AF( 1 )
*
*  WORK    (local workspace/local output)
*          REAL temporary workspace. This space may
*          be overwritten in between calls to routines. WORK must be
*          the size given in LWORK.
*          On exit, WORK( 1 ) contains the minimal LWORK.
*
*  LWORK   (local input or global input) INTEGER
*          Size of user-input workspace WORK.
*          If LWORK is too small, the minimal acceptable size will be
*          returned in WORK(1) and an error code is returned. LWORK>=
*          NRHS*(NB+2*bwl+4*bwu)
*
*  INFO    (global output) INTEGER
*          = 0:  successful exit
*          < 0:  If the i-th argument is an array and the j-entry had
*                an illegal value, then INFO = -(i*100+j), if the i-th
*                argument is a scalar and had an illegal value, then
*                INFO = -i.
*
*  =====================================================================
*
*  Restrictions
*  ============
*
*  The following are restrictions on the input parameters. Some of these
*    are temporary and will be removed in future releases, while others
*    may reflect fundamental technical limitations.
*
*    Non-cyclic restriction: VERY IMPORTANT!
*      P*NB>= mod(JA-1,NB)+N.
*      The mapping for matrices must be blocked, reflecting the nature
*      of the divide and conquer algorithm as a task-parallel algorithm.
*      This formula in words is: no processor may have more than one
*      chunk of the matrix.
*
*    Blocksize cannot be too small:
*      If the matrix spans more than one processor, the following
*      restriction on NB, the size of each block on each processor,
*      must hold:
*      NB >= (BWL+BWU)+1
*      The bulk of parallel computation is done on the matrix of size
*      O(NB) on each processor. If this is too small, divide and conquer
*      is a poor choice of algorithm.
*
*    Submatrix reference:
*      JA = IB
*      Alignment restriction that prevents unnecessary communication.
*
*  =====================================================================
*
*  Notes
*  =====
*
*  If the factorization routine and the solve routine are to be called
*    separately (to solve various sets of righthand sides using the same
*    coefficient matrix), the auxiliary space AF *must not be altered*
*    between calls to the factorization routine and the solve routine.
*
*  The best algorithm for solving banded and tridiagonal linear systems
*    depends on a variety of parameters, especially the bandwidth.
*    Currently, only algorithms designed for the case N/P >> bw are
*    implemented. These go by many names, including Divide and Conquer,
*    Partitioning, domain decomposition-type, etc.
*
*  Algorithm description: Divide and Conquer
*
*    The Divide and Conqer algorithm assumes the matrix is narrowly
*      banded compared with the number of equations. In this situation,
*      it is best to distribute the input matrix A one-dimensionally,
*      with columns atomic and rows divided amongst the processes.
*      The basic algorithm divides the banded matrix up into
*      P pieces with one stored on each processor,
*      and then proceeds in 2 phases for the factorization or 3 for the
*      solution of a linear system.
*      1) Local Phase:
*         The individual pieces are factored independently and in
*         parallel. These factors are applied to the matrix creating
*         fillin, which is stored in a non-inspectable way in auxiliary
*         space AF. Mathematically, this is equivalent to reordering
*         the matrix A as P A P^T and then factoring the principal
*         leading submatrix of size equal to the sum of the sizes of
*         the matrices factored on each processor. The factors of
*         these submatrices overwrite the corresponding parts of A
*         in memory.
*      2) Reduced System Phase:
*         A small (max(bwl,bwu)* (P-1)) system is formed representing
*         interaction of the larger blocks, and is stored (as are its
*         factors) in the space AF. A parallel Block Cyclic Reduction
*         algorithm is used. For a linear system, a parallel front solve
*         followed by an analagous backsolve, both using the structure
*         of the factored matrix, are performed.
*      3) Backsubsitution Phase:
*         For a linear system, a local backsubstitution is performed on
*         each processor in parallel.
*
*
*  Descriptors
*  ===========
*
*  Descriptors now have *types* and differ from ScaLAPACK 1.0.
*
*  Note: banded codes can use either the old two dimensional
*    or new one-dimensional descriptors, though the processor grid in
*    both cases *must be one-dimensional*. We describe both types below.
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*
*  One-dimensional descriptors:
*
*  One-dimensional descriptors are a new addition to ScaLAPACK since
*    version 1.0. They simplify and shorten the descriptor for 1D
*    arrays.
*
*  Since ScaLAPACK supports two-dimensional arrays as the fundamental
*    object, we allow 1D arrays to be distributed either over the
*    first dimension of the array (as if the grid were P-by-1) or the
*    2nd dimension (as if the grid were 1-by-P). This choice is
*    indicated by the descriptor type (501 or 502)
*    as described below.
*
*    IMPORTANT NOTE: the actual BLACS grid represented by the
*    CTXT entry in the descriptor may be *either*  P-by-1 or 1-by-P
*    irrespective of which one-dimensional descriptor type
*    (501 or 502) is input.
*    This routine will interpret the grid properly either way.
*    ScaLAPACK routines *do not support intercontext operations* so that
*    the grid passed to a single ScaLAPACK routine *must be the same*
*    for all array descriptors passed to that routine.
*
*    NOTE: In all cases where 1D descriptors are used, 2D descriptors
*    may also be used, since a one-dimensional array is a special case
*    of a two-dimensional array with one dimension of size unity.
*    The two-dimensional array used in this case *must* be of the
*    proper orientation:
*      If the appropriate one-dimensional descriptor is DTYPEA=501
*      (1 by P type), then the two dimensional descriptor must
*      have a CTXT value that refers to a 1 by P BLACS grid;
*      If the appropriate one-dimensional descriptor is DTYPEA=502
*      (P by 1 type), then the two dimensional descriptor must
*      have a CTXT value that refers to a P by 1 BLACS grid.
*
*
*  Summary of allowed descriptors, types, and BLACS grids:
*  DTYPE           501         502         1         1
*  BLACS grid      1xP or Px1  1xP or Px1  1xP       Px1
*  -----------------------------------------------------
*  A               OK          NO          OK        NO
*  B               NO          OK          NO        OK
*
*  Note that a consequence of this chart is that it is not possible
*    for *both* DTYPE_A and DTYPE_B to be 2D_type(1), as these lead
*    to opposite requirements for the orientation of the BLACS grid,
*    and as noted before, the *same* BLACS context must be used in
*    all descriptors in a single ScaLAPACK subroutine call.
*
*  Let A be a generic term for any 1D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN  EXPLANATION
*  --------------- ---------- ------------------------------------------
*  DTYPE_A(global) DESCA( 1 ) The descriptor type. For 1D grids,
*                                TYPE_A = 501: 1-by-P grid.
*                                TYPE_A = 502: P-by-1 grid.
*  CTXT_A (global) DESCA( 2 ) The BLACS context handle, indicating
*                                the BLACS process grid A is distribu-
*                                ted over. The context itself is glo-
*                                bal, but the handle (the integer
*                                value) may vary.
*  N_A    (global) DESCA( 3 ) The size of the array dimension being
*                                distributed.
*  NB_A   (global) DESCA( 4 ) The blocking factor used to distribute
*                                the distributed dimension of the array.
*  SRC_A  (global) DESCA( 5 ) The process row or column over which the
*                                first row or column of the array
*                                is distributed.
*  LLD_A  (local)  DESCA( 6 ) The leading dimension of the local array
*                                storing the local blocks of the distri-
*                                buted array A. Minimum value of LLD_A
*                                depends on TYPE_A.
*                                TYPE_A = 501: LLD_A >=
*                                   size of undistributed dimension, 1.
*                                TYPE_A = 502: LLD_A >=NB_A, 1.
*  Reserved        DESCA( 7 ) Reserved for future use.
*
*  =====================================================================
*
*  Implemented for ScaLAPACK by:
*     Andrew J. Cleary, Livermore National Lab and University of Tenn.,
*     and Markus Hegland, Australian National University. Feb., 1997.
*  Based on code written by    : Peter Arbenz, ETH Zurich, 1996.
*  Last modified by:  Peter Arbenz, Institute of Scientific Computing,
*    ETH, Zurich.
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE
      parameter( one = 1.0e+0 )
      REAL               ZERO
      parameter( zero = 0.0e+0 )
      INTEGER            INT_ONE
      parameter( int_one = 1 )
      INTEGER            DESCMULT, BIGNUM
      parameter( descmult = 100, bignum = descmult*descmult )
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   lld_, mb_, m_, nb_, n_, rsrc_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
*     ..
*     .. Local Scalars ..
      INTEGER            APTR, BBPTR, BM, BMN, BN, BNN, BW, CSRC,
     $                   first_proc, ictxt, ictxt_new, ictxt_save,
     $                   idum2, idum3, j, ja_new, l, lbwl, lbwu, ldbb,
     $                   ldw, llda, lldb, lm, lmj, ln, lptr, mycol,
     $                   myrow, nb, neicol, np, npact, npcol, nprow,
     $                   npstr, np_save, odd_size, part_offset,
     $                   recovery_val, return_code, store_m_b,
     $                   store_n_a, work_size_min, wptr
*     ..
*     .. Local Arrays ..
      INTEGER            DESCA_1XP( 7 ), DESCB_PX1( 7 ),
     $                   param_check( 17, 3 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridexit, blacs_gridinfo, scopy,
     $                   desc_convert, sgemm, sgemv, sger, sgerv2d,
     $                   sgesd2d, sgetrs, slamov, slaswp, sscal, sswap,
     $                   strsm, globchk, pxerbla, reshape
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            NUMROC
      EXTERNAL           lsame, numroc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          ichar, max, min, mod
*     ..
*     .. Executable Statements ..
*
*
*     Test the input parameters
*
      info = 0
*
*     Convert descriptor into standard form for easy access to
*        parameters, check that grid is of right shape.
*
      desca_1xp( 1 ) = 501
      descb_px1( 1 ) = 502
*
      CALL desc_convert( desca, desca_1xp, return_code )
*
      IF( return_code.NE.0 ) THEN
         info = -( 8*100+2 )
      END IF
*
      CALL desc_convert( descb, descb_px1, return_code )
*
      IF( return_code.NE.0 ) THEN
         info = -( 11*100+2 )
      END IF
*
*     Consistency checks for DESCA and DESCB.
*
*     Context must be the same
      IF( desca_1xp( 2 ).NE.descb_px1( 2 ) ) THEN
         info = -( 11*100+2 )
      END IF
*
*        These are alignment restrictions that may or may not be removed
*        in future releases. -Andy Cleary, April 14, 1996.
*
*     Block sizes must be the same
      IF( desca_1xp( 4 ).NE.descb_px1( 4 ) ) THEN
         info = -( 11*100+4 )
      END IF
*
*     Source processor must be the same
*
      IF( desca_1xp( 5 ).NE.descb_px1( 5 ) ) THEN
         info = -( 11*100+5 )
      END IF
*
*     Get values out of descriptor for use in code.
*
      ictxt = desca_1xp( 2 )
      csrc = desca_1xp( 5 )
      nb = desca_1xp( 4 )
      llda = desca_1xp( 6 )
      store_n_a = desca_1xp( 3 )
      lldb = descb_px1( 6 )
      store_m_b = descb_px1( 3 )
*
*     Get grid parameters
*
*
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
      np = nprow*npcol
*
*
*
      IF( lsame( trans, 'N' ) ) THEN
         idum2 = ichar( 'N' )
      ELSE IF( lsame( trans, 'T' ) ) THEN
         idum2 = ichar( 'T' )
      ELSE IF( lsame( trans, 'C' ) ) THEN
         idum2 = ichar( 'T' )
      ELSE
         info = -1
      END IF
*
      IF( lwork.LT.-1 ) THEN
         info = -16
      ELSE IF( lwork.EQ.-1 ) THEN
         idum3 = -1
      ELSE
         idum3 = 1
      END IF
*
      IF( n.LT.0 ) THEN
         info = -2
      END IF
*
      IF( n+ja-1.GT.store_n_a ) THEN
         info = -( 8*100+6 )
      END IF
*
      IF( ( bwl.GT.n-1 ) .OR. ( bwl.LT.0 ) ) THEN
         info = -3
      END IF
*
      IF( ( bwu.GT.n-1 ) .OR. ( bwu.LT.0 ) ) THEN
         info = -4
      END IF
*
      IF( llda.LT.( 2*bwl+2*bwu+1 ) ) THEN
         info = -( 8*100+6 )
      END IF
*
      IF( nb.LE.0 ) THEN
         info = -( 8*100+4 )
      END IF
*
      bw = bwu + bwl
*
      IF( n+ib-1.GT.store_m_b ) THEN
         info = -( 11*100+3 )
      END IF
*
      IF( lldb.LT.nb ) THEN
         info = -( 11*100+6 )
      END IF
*
      IF( nrhs.LT.0 ) THEN
         info = -5
      END IF
*
*     Current alignment restriction
*
      IF( ja.NE.ib ) THEN
         info = -7
      END IF
*
*     Argument checking that is specific to Divide & Conquer routine
*
      IF( nprow.NE.1 ) THEN
         info = -( 8*100+2 )
      END IF
*
      IF( n.GT.np*nb-mod( ja-1, nb ) ) THEN
         info = -( 2 )
         CALL pxerbla( ictxt, 'PSGBTRS, D&C alg.: only 1 block per proc'
     $                 , -info )
         RETURN
      END IF
*
      IF( ( ja+n-1.GT.nb ) .AND. ( nb.LT.( bwl+bwu+1 ) ) ) THEN
         info = -( 8*100+4 )
         CALL pxerbla( ictxt, 'PSGBTRS, D&C alg.: NB too small', -info )
         RETURN
      END IF
*
*
*     Check worksize
*
      work_size_min = nrhs*( nb+2*bwl+4*bwu )
*
      work( 1 ) = work_size_min
*
      IF( lwork.LT.work_size_min ) THEN
         IF( lwork.NE.-1 ) THEN
            info = -16
            CALL pxerbla( ictxt, 'PSGBTRS: worksize error ', -info )
         END IF
         RETURN
      END IF
*
*     Pack params and positions into arrays for global consistency check
*
      param_check( 17, 1 ) = descb( 5 )
      param_check( 16, 1 ) = descb( 4 )
      param_check( 15, 1 ) = descb( 3 )
      param_check( 14, 1 ) = descb( 2 )
      param_check( 13, 1 ) = descb( 1 )
      param_check( 12, 1 ) = ib
      param_check( 11, 1 ) = desca( 5 )
      param_check( 10, 1 ) = desca( 4 )
      param_check( 9, 1 ) = desca( 3 )
      param_check( 8, 1 ) = desca( 1 )
      param_check( 7, 1 ) = ja
      param_check( 6, 1 ) = nrhs
      param_check( 5, 1 ) = bwu
      param_check( 4, 1 ) = bwl
      param_check( 3, 1 ) = n
      param_check( 2, 1 ) = idum3
      param_check( 1, 1 ) = idum2
*
      param_check( 17, 2 ) = 1105
      param_check( 16, 2 ) = 1104
      param_check( 15, 2 ) = 1103
      param_check( 14, 2 ) = 1102
      param_check( 13, 2 ) = 1101
      param_check( 12, 2 ) = 10
      param_check( 11, 2 ) = 805
      param_check( 10, 2 ) = 804
      param_check( 9, 2 ) = 803
      param_check( 8, 2 ) = 801
      param_check( 7, 2 ) = 7
      param_check( 6, 2 ) = 5
      param_check( 5, 2 ) = 4
      param_check( 4, 2 ) = 3
      param_check( 3, 2 ) = 2
      param_check( 2, 2 ) = 16
      param_check( 1, 2 ) = 1
*
*     Want to find errors with MIN( ), so if no error, set it to a big
*     number. If there already is an error, multiply by the the
*     descriptor multiplier.
*
      IF( info.GE.0 ) THEN
         info = bignum
      ELSE IF( info.LT.-descmult ) THEN
         info = -info
      ELSE
         info = -info*descmult
      END IF
*
*     Check consistency across processors
*
      CALL globchk( ictxt, 17, param_check, 17, param_check( 1, 3 ),
     $              info )
*
*     Prepare output: set info = 0 if no error, and divide by DESCMULT
*     if error is not in a descriptor entry.
*
      IF( info.EQ.bignum ) THEN
         info = 0
      ELSE IF( mod( info, descmult ).EQ.0 ) THEN
         info = -info / descmult
      ELSE
         info = -info
      END IF
*
      IF( info.LT.0 ) THEN
         CALL pxerbla( ictxt, 'PSGBTRS', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
      IF( nrhs.EQ.0 )
     $   RETURN
*
*
*     Adjust addressing into matrix space to properly get into
*        the beginning part of the relevant data
*
      part_offset = nb*( ( ja-1 ) / ( npcol*nb ) )
*
      IF( ( mycol-csrc ).LT.( ja-part_offset-1 ) / nb ) THEN
         part_offset = part_offset + nb
      END IF
*
      IF( mycol.LT.csrc ) THEN
         part_offset = part_offset - nb
      END IF
*
*     Form a new BLACS grid (the "standard form" grid) with only procs
*        holding part of the matrix, of size 1xNP where NP is adjusted,
*        starting at csrc=0, with JA modified to reflect dropped procs.
*
*     First processor to hold part of the matrix:
*
      first_proc = mod( ( ja-1 ) / nb+csrc, npcol )
*
*     Calculate new JA one while dropping off unused processors.
*
      ja_new = mod( ja-1, nb ) + 1
*
*     Save and compute new value of NP
*
      np_save = np
      np = ( ja_new+n-2 ) / nb + 1
*
*     Call utility routine that forms "standard-form" grid
*
      CALL reshape( ictxt, int_one, ictxt_new, int_one, first_proc,
     $              int_one, np )
*
*     Use new context from standard grid as context.
*
      ictxt_save = ictxt
      ictxt = ictxt_new
      desca_1xp( 2 ) = ictxt_new
      descb_px1( 2 ) = ictxt_new
*
*     Get information about new grid.
*
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Drop out processors that do not have part of the matrix.
*
      IF( myrow.LT.0 ) THEN
         GO TO 100
      END IF
*
*
*
*     Begin main code
*
*     Move data into workspace - communicate/copy (overlap)
*
      IF( mycol.LT.npcol-1 ) THEN
         CALL sgesd2d( ictxt, bwu, nrhs, b( nb-bwu+1 ), lldb, 0,
     $                 mycol+1 )
      END IF
*
      IF( mycol.LT.npcol-1 ) THEN
         lm = nb - bwu
      ELSE
         lm = nb
      END IF
*
      IF( mycol.GT.0 ) THEN
         wptr = bwu + 1
      ELSE
         wptr = 1
      END IF
*
      ldw = nb + bwu + 2*bw + bwu
*
      CALL slamov( 'G', lm, nrhs, b( 1 ), lldb, work( wptr ), ldw )
*
*     Zero out rest of work
*
      DO 20 j = 1, nrhs
         DO 10 l = wptr + lm, ldw
            work( ( j-1 )*ldw+l ) = zero
   10    CONTINUE
   20 CONTINUE
*
      IF( mycol.GT.0 ) THEN
         CALL sgerv2d( ictxt, bwu, nrhs, work( 1 ), ldw, 0, mycol-1 )
      END IF
*
********************************************************************
*       PHASE 1: Local computation phase -- Solve L*X = B
********************************************************************
*
*     Size of main (or odd) partition in each processor
*
      odd_size = numroc( n, nb, mycol, 0, npcol )
*
      IF( mycol.NE.0 ) THEN
         lbwl = bw
         lbwu = 0
         aptr = 1
      ELSE
         lbwl = bwl
         lbwu = bwu
         aptr = 1 + bwu
      END IF
*
      IF( mycol.NE.npcol-1 ) THEN
         lm = nb - lbwu
         ln = nb - bw
      ELSE IF( mycol.NE.0 ) THEN
         lm = odd_size + bwu
         ln = max( odd_size-bw, 0 )
      ELSE
         lm = n
         ln = max( n-bw, 0 )
      END IF
*
      DO 30 j = 1, ln
*
         lmj = min( lbwl, lm-j )
         l = ipiv( j )
*
         IF( l.NE.j ) THEN
            CALL sswap( nrhs, work( l ), ldw, work( j ), ldw )
         END IF
*
         lptr = bw + 1 + ( j-1 )*llda + aptr
*
         CALL sger( lmj, nrhs, -one, a( lptr ), 1, work( j ), ldw,
     $              work( j+1 ), ldw )
*
   30 CONTINUE
*
********************************************************************
*       PHASE 2: Global computation phase -- Solve L*X = B
********************************************************************
*
*     Define the initial dimensions of the diagonal blocks
*     The offdiagonal blocks (for MYCOL > 0) are of size BM by BW
*
      IF( mycol.NE.npcol-1 ) THEN
         bm = bw - lbwu
         bn = bw
      ELSE
         bm = min( bw, odd_size ) + bwu
         bn = min( bw, odd_size )
      END IF
*
*     Pointer to first element of block bidiagonal matrix in AF
*     Leading dimension of block bidiagonal system
*
      bbptr = ( nb+bwu )*bw + 1
      ldbb = 2*bw + bwu
*
      IF( npcol.EQ.1 ) THEN
*
*        In this case the loop over the levels will not be
*        performed.
         CALL sgetrs( 'N', n-ln, nrhs, af( bbptr+bw*ldbb ), ldbb,
     $                ipiv( ln+1 ), work( ln+1 ), ldw, info )
*
      END IF
*
* Loop over levels ...
*
*     The two integers NPACT (nu. of active processors) and NPSTR
*     (stride between active processors) is used to control the
*     loop.
*
      npact = npcol
      npstr = 1
*
*     Begin loop over levels
   40 CONTINUE
      IF( npact.LE.1 )
     $   GO TO 50
*
*     Test if processor is active
      IF( mod( mycol, npstr ).EQ.0 ) THEN
*
*   Send/Receive blocks
*
         IF( mod( mycol, 2*npstr ).EQ.0 ) THEN
*
            neicol = mycol + npstr
*
            IF( neicol / npstr.LE.npact-1 ) THEN
*
               IF( neicol / npstr.LT.npact-1 ) THEN
                  bmn = bw
               ELSE
                  bmn = min( bw, numroc( n, nb, neicol, 0, npcol ) ) +
     $                  bwu
               END IF
*
               CALL sgesd2d( ictxt, bm, nrhs, work( ln+1 ), ldw, 0,
     $                       neicol )
*
               IF( npact.NE.2 ) THEN
*
*                     Receive answers back from partner processor
*
                  CALL sgerv2d( ictxt, bm+bmn-bw, nrhs, work( ln+1 ),
     $                          ldw, 0, neicol )
*
                  bm = bm + bmn - bw
*
               END IF
*
            END IF
*
         ELSE
*
            neicol = mycol - npstr
*
            IF( neicol.EQ.0 ) THEN
               bmn = bw - bwu
            ELSE
               bmn = bw
            END IF
*
            CALL slamov( 'G', bm, nrhs, work( ln+1 ), ldw,
     $                   work( nb+bwu+bmn+1 ), ldw )
*
            CALL sgerv2d( ictxt, bmn, nrhs, work( nb+bwu+1 ), ldw, 0,
     $                    neicol )
*
*               and do the permutations and eliminations
*
            IF( npact.NE.2 ) THEN
*
*                  Solve locally for BW variables
*
               CALL slaswp( nrhs, work( nb+bwu+1 ), ldw, 1, bw,
     $                      ipiv( ln+1 ), 1 )
*
               CALL strsm( 'L', 'L', 'N', 'U', bw, nrhs, one,
     $                     af( bbptr+bw*ldbb ), ldbb, work( nb+bwu+1 ),
     $                     ldw )
*
*                  Use soln just calculated to update RHS
*
               CALL sgemm( 'N', 'N', bm+bmn-bw, nrhs, bw, -one,
     $                     af( bbptr+bw*ldbb+bw ), ldbb,
     $                     work( nb+bwu+1 ), ldw, one,
     $                     work( nb+bwu+1+bw ), ldw )
*
*                  Give answers back to partner processor
*
               CALL sgesd2d( ictxt, bm+bmn-bw, nrhs,
     $                       work( nb+bwu+1+bw ), ldw, 0, neicol )
*
            ELSE
*
*                  Finish up calculations for final level
*
               CALL slaswp( nrhs, work( nb+bwu+1 ), ldw, 1, bm+bmn,
     $                      ipiv( ln+1 ), 1 )
*
               CALL strsm( 'L', 'L', 'N', 'U', bm+bmn, nrhs, one,
     $                     af( bbptr+bw*ldbb ), ldbb, work( nb+bwu+1 ),
     $                     ldw )
            END IF
*
         END IF
*
         npact = ( npact+1 ) / 2
         npstr = npstr*2
         GO TO 40
*
      END IF
*
   50 CONTINUE
*
*
**************************************
*     BACKSOLVE
********************************************************************
*       PHASE 2: Global computation phase -- Solve U*Y = X
********************************************************************
*
      IF( npcol.EQ.1 ) THEN
*
*        In this case the loop over the levels will not be
*        performed.
*        In fact, the backsolve portion was done in the call to
*          SGETRS in the frontsolve.
*
      END IF
*
*     Compute variable needed to reverse loop structure in
*        reduced system.
*
      recovery_val = npact*npstr - npcol
*
*     Loop over levels
*      Terminal values of NPACT and NPSTR from frontsolve are used
*
   60 CONTINUE
      IF( npact.GE.npcol )
     $   GO TO 80
*
      npstr = npstr / 2
*
      npact = npact*2
*
*        Have to adjust npact for non-power-of-2
*
      npact = npact - mod( ( recovery_val / npstr ), 2 )
*
*        Find size of submatrix in this proc at this level
*
      IF( mycol / npstr.LT.npact-1 ) THEN
         bn = bw
      ELSE
         bn = min( bw, numroc( n, nb, npcol-1, 0, npcol ) )
      END IF
*
*        If this processor is even in this level...
*
      IF( mod( mycol, 2*npstr ).EQ.0 ) THEN
*
         neicol = mycol + npstr
*
         IF( neicol / npstr.LE.npact-1 ) THEN
*
            IF( neicol / npstr.LT.npact-1 ) THEN
               bmn = bw
               bnn = bw
            ELSE
               bmn = min( bw, numroc( n, nb, neicol, 0, npcol ) ) + bwu
               bnn = min( bw, numroc( n, nb, neicol, 0, npcol ) )
            END IF
*
            IF( npact.GT.2 ) THEN
*
               CALL sgesd2d( ictxt, 2*bw, nrhs, work( ln+1 ), ldw, 0,
     $                       neicol )
*
               CALL sgerv2d( ictxt, bw, nrhs, work( ln+1 ), ldw, 0,
     $                       neicol )
*
            ELSE
*
               CALL sgerv2d( ictxt, bw, nrhs, work( ln+1 ), ldw, 0,
     $                       neicol )
*
            END IF
*
         END IF
*
      ELSE
*           This processor is odd on this level
*
         neicol = mycol - npstr
*
         IF( neicol.EQ.0 ) THEN
            bmn = bw - bwu
         ELSE
            bmn = bw
         END IF
*
         IF( neicol.LT.npcol-1 ) THEN
            bnn = bw
         ELSE
            bnn = min( bw, numroc( n, nb, neicol, 0, npcol ) )
         END IF
*
         IF( npact.GT.2 ) THEN
*
*              Move RHS to make room for received solutions
*
            CALL slamov( 'G', bw, nrhs, work( nb+bwu+1 ), ldw,
     $                   work( nb+bwu+bw+1 ), ldw )
*
            CALL sgerv2d( ictxt, 2*bw, nrhs, work( ln+1 ), ldw, 0,
     $                    neicol )
*
            CALL sgemm( 'N', 'N', bw, nrhs, bn, -one, af( bbptr ), ldbb,
     $                  work( ln+1 ), ldw, one, work( nb+bwu+bw+1 ),
     $                  ldw )
*
*
            IF( mycol.GT.npstr ) THEN
*
               CALL sgemm( 'N', 'N', bw, nrhs, bw, -one,
     $                     af( bbptr+2*bw*ldbb ), ldbb, work( ln+bw+1 ),
     $                     ldw, one, work( nb+bwu+bw+1 ), ldw )
*
            END IF
*
            CALL strsm( 'L', 'U', 'N', 'N', bw, nrhs, one,
     $                  af( bbptr+bw*ldbb ), ldbb, work( nb+bwu+bw+1 ),
     $                  ldw )
*
*              Send new solution to neighbor
*
            CALL sgesd2d( ictxt, bw, nrhs, work( nb+bwu+bw+1 ), ldw, 0,
     $                    neicol )
*
*              Copy new solution into expected place
*
            CALL slamov( 'G', bw, nrhs, work( nb+bwu+1+bw ), ldw,
     $                   work( ln+bw+1 ), ldw )
*
         ELSE
*
*              Solve with local diagonal block
*
            CALL strsm( 'L', 'U', 'N', 'N', bn+bnn, nrhs, one,
     $                  af( bbptr+bw*ldbb ), ldbb, work( nb+bwu+1 ),
     $                  ldw )
*
*              Send new solution to neighbor
*
            CALL sgesd2d( ictxt, bw, nrhs, work( nb+bwu+1 ), ldw, 0,
     $                    neicol )
*
*              Shift solutions into expected positions
*
            CALL slamov( 'G', bnn+bn-bw, nrhs, work( nb+bwu+1+bw ), ldw,
     $                   work( ln+1 ), ldw )
*
*
            IF( ( nb+bwu+1 ).NE.( ln+1+bw ) ) THEN
*
*                 Copy one row at a time since spaces may overlap
*
               DO 70 j = 1, bw
                  CALL scopy( nrhs, work( nb+bwu+j ), ldw,
     $                        work( ln+bw+j ), ldw )
   70          CONTINUE
*
            END IF
*
         END IF
*
      END IF
*
      GO TO 60
*
   80 CONTINUE
*     End of loop over levels
*
********************************************************************
*       PHASE 1: (Almost) Local computation phase -- Solve U*Y = X
********************************************************************
*
*     Reset BM to value it had before reduced system frontsolve...
*
      IF( mycol.NE.npcol-1 ) THEN
         bm = bw - lbwu
      ELSE
         bm = min( bw, odd_size ) + bwu
      END IF
*
*     First metastep is to account for the fillin blocks AF
*
      IF( mycol.LT.npcol-1 ) THEN
*
         CALL sgesd2d( ictxt, bw, nrhs, work( nb-bw+1 ), ldw, 0,
     $                 mycol+1 )
*
      END IF
*
      IF( mycol.GT.0 ) THEN
*
         CALL sgerv2d( ictxt, bw, nrhs, work( nb+bwu+1 ), ldw, 0,
     $                 mycol-1 )
*
*        Modify local right hand sides with received rhs's
*
         CALL sgemm( 'T', 'N', lm-bm, nrhs, bw, -one, af( 1 ), bw,
     $               work( nb+bwu+1 ), ldw, one, work( 1 ), ldw )
*
      END IF
*
      DO 90 j = ln, 1, -1
*
         lmj = min( bw, odd_size-1 )
*
         lptr = bw - 1 + j*llda + aptr
*
*        In the following, the TRANS=T option is used to reverse
*           the order of multiplication, not as a true transpose
*
         CALL sgemv( 'T', lmj, nrhs, -one, work( j+1 ), ldw, a( lptr ),
     $               llda-1, one, work( j ), ldw )
*
*        Divide by diagonal element
*
         CALL sscal( nrhs, one / a( lptr-llda+1 ), work( j ), ldw )
   90 CONTINUE
*
*
*
      CALL slamov( 'G', odd_size, nrhs, work( 1 ), ldw, b( 1 ), lldb )
*
*     Free BLACS space used to hold standard-form grid.
*
      ictxt = ictxt_save
      IF( ictxt.NE.ictxt_new ) THEN
         CALL blacs_gridexit( ictxt_new )
      END IF
*
  100 CONTINUE
*
*     Restore saved input parameters
*
      np = np_save
*
*     Output worksize
*
      work( 1 ) = work_size_min
*
      RETURN
*
*     End of PSGBTRS
*
      END