ScaLAPACK 2.1  2.1
ScaLAPACK: Scalable Linear Algebra PACKage
pcdblaschk.f
Go to the documentation of this file.
1  SUBROUTINE pcdblaschk( SYMM, UPLO, TRANS, N, BWL, BWU, NRHS, X,
2  $ IX, JX, DESCX, IASEED, A, IA, JA, DESCA,
3  $ IBSEED, ANORM, RESID, WORK, WORKSIZ )
4 *
5 *
6 * -- ScaLAPACK routine (version 1.7) --
7 * University of Tennessee, Knoxville, Oak Ridge National Laboratory,
8 * and University of California, Berkeley.
9 * November 15, 1997
10 *
11 * .. Scalar Arguments ..
12  CHARACTER SYMM, TRANS, UPLO
13  INTEGER BWL, BWU, IA, IASEED, IBSEED,
14  $ ix, ja, jx, n, nrhs, worksiz
15  REAL ANORM, RESID
16 * ..
17 * .. Array Arguments ..
18  INTEGER DESCA( * ), DESCX( * )
19  COMPLEX A( * ), WORK( * ), X( * )
20 * .. External Functions ..
21  LOGICAL LSAME
22 * ..
23 *
24 * Purpose
25 * =======
26 *
27 * PCDBLASCHK computes the residual
28 * || sub( A )*sub( X ) - B || / (|| sub( A ) ||*|| sub( X ) ||*eps*N)
29 * to check the accuracy of the factorization and solve steps in the
30 * LU and Cholesky decompositions, where sub( A ) denotes
31 * A(IA:IA+N-1,JA,JA+N-1), sub( X ) denotes X(IX:IX+N-1, JX:JX+NRHS-1).
32 *
33 * Notes
34 * =====
35 *
36 * Each global data object is described by an associated description
37 * vector. This vector stores the information required to establish
38 * the mapping between an object element and its corresponding process
39 * and memory location.
40 *
41 * Let A be a generic term for any 2D block cyclicly distributed array.
42 * Such a global array has an associated description vector DESCA.
43 * In the following comments, the character _ should be read as
44 * "of the global array".
45 *
46 * NOTATION STORED IN EXPLANATION
47 * --------------- -------------- --------------------------------------
48 * DTYPE_A(global) DESCA( DTYPE_ )The descriptor type. In this case,
49 * DTYPE_A = 1.
50 * CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
51 * the BLACS process grid A is distribu-
52 * ted over. The context itself is glo-
53 * bal, but the handle (the integer
54 * value) may vary.
55 * M_A (global) DESCA( M_ ) The number of rows in the global
56 * array A.
57 * N_A (global) DESCA( N_ ) The number of columns in the global
58 * array A.
59 * MB_A (global) DESCA( MB_ ) The blocking factor used to distribute
60 * the rows of the array.
61 * NB_A (global) DESCA( NB_ ) The blocking factor used to distribute
62 * the columns of the array.
63 * RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
64 * row of the array A is distributed.
65 * CSRC_A (global) DESCA( CSRC_ ) The process column over which the
66 * first column of the array A is
67 * distributed.
68 * LLD_A (local) DESCA( LLD_ ) The leading dimension of the local
69 * array. LLD_A >= MAX(1,LOCr(M_A)).
70 *
71 * Let K be the number of rows or columns of a distributed matrix,
72 * and assume that its process grid has dimension p x q.
73 * LOCr( K ) denotes the number of elements of K that a process
74 * would receive if K were distributed over the p processes of its
75 * process column.
76 * Similarly, LOCc( K ) denotes the number of elements of K that a
77 * process would receive if K were distributed over the q processes of
78 * its process row.
79 * The values of LOCr() and LOCc() may be determined via a call to the
80 * ScaLAPACK tool function, NUMROC:
81 * LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
82 * LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
83 * An upper bound for these quantities may be computed by:
84 * LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
85 * LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
86 *
87 * Arguments
88 * =========
89 *
90 * SYMM (global input) CHARACTER
91 * if SYMM = 'H', sub( A ) is a hermitian distributed band
92 * matrix, otherwise sub( A ) is a general distributed matrix.
93 *
94 * UPLO (global input) CHARACTER
95 * if SYMM = 'H', then
96 * if UPLO = 'L', the lower half of the matrix is stored
97 * if UPLO = 'U', the upper half of the matrix is stored
98 * if SYMM != 'S' or 'H', then
99 * if UPLO = 'D', the matrix is stable during factorization
100 * without interchanges
101 * if UPLO != 'D', the matrix is general
102 *
103 * TRANS if TRANS= 'C', A 'Conjugate transpose' is used as the
104 * coefficient matrix in the solve.
105 *
106 * N (global input) INTEGER
107 * The number of columns to be operated on, i.e. the number of
108 * columns of the distributed submatrix sub( A ). N >= 0.
109 *
110 * NRHS (global input) INTEGER
111 * The number of right-hand-sides, i.e the number of columns
112 * of the distributed matrix sub( X ). NRHS >= 1.
113 *
114 * X (local input) COMPLEX pointer into the local memory
115 * to an array of dimension (LLD_X,LOCq(JX+NRHS-1). This array
116 * contains the local pieces of the answer vector(s) sub( X ) of
117 * sub( A ) sub( X ) - B, split up over a column of processes.
118 *
119 * IX (global input) INTEGER
120 * The row index in the global array X indicating the first
121 * row of sub( X ).
122 *
123 * DESCX (global and local input) INTEGER array of dimension DLEN_.
124 * The array descriptor for the distributed matrix X.
125 *
126 * IASEED (global input) INTEGER
127 * The seed number to generate the original matrix Ao.
128 *
129 * JA (global input) INTEGER
130 * The column index in the global array A indicating the
131 * first column of sub( A ).
132 *
133 * DESCA (global and local input) INTEGER array of dimension DLEN_.
134 * The array descriptor for the distributed matrix A.
135 *
136 * IBSEED (global input) INTEGER
137 * The seed number to generate the original matrix B.
138 *
139 * ANORM (global input) REAL
140 * The 1-norm or infinity norm of the distributed matrix
141 * sub( A ).
142 *
143 * RESID (global output) REAL
144 * The residual error:
145 * ||sub( A )*sub( X )-B|| / (||sub( A )||*||sub( X )||*eps*N).
146 *
147 * WORK (local workspace) COMPLEX array, dimension (LWORK)
148 * IF SYMM='S'
149 * LWORK >= max(5,max(max(bwl,bwu)*(max(bwl,bwu)+2),NB))+2*NB
150 * IF SYMM!='S' or 'H'
151 * LWORK >= max(5,max(max(bwl,bwu)*(max(bwl,bwu)+2),NB))+2*NB
152 *
153 * WORKSIZ (local input) size of WORK.
154 *
155 * =====================================================================
156 *
157 * Code Developer: Andrew J. Cleary, University of Tennessee.
158 * Current address: Lawrence Livermore National Labs.
159 * This version released: August, 2001.
160 *
161 * =====================================================================
162 *
163 * .. Parameters ..
164  COMPLEX ZERO, ONE
165  PARAMETER ( ONE = ( 1.0e+0, 0.0e+0 ),
166  $ zero = ( 0.0e+0, 0.0e+0 ) )
167  INTEGER BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
168  $ LLD_, MB_, M_, NB_, N_, RSRC_
169  parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
170  $ ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
171  $ rsrc_ = 7, csrc_ = 8, lld_ = 9 )
172  INTEGER INT_ONE
173  PARAMETER ( INT_ONE = 1 )
174 * ..
175 * .. Local Scalars ..
176  INTEGER IACOL, IAROW, ICTXT,
177  $ IIA, IIX, IPB, IPW,
178  $ ixcol, ixrow, j, jja, jjx, lda,
179  $ mycol, myrow, nb, np, npcol, nprow, nq
180  INTEGER BW, INFO, IPPRODUCT, WORK_MIN
181  REAL DIVISOR, EPS, RESID1, NORMX
182 * ..
183 * .. Local Arrays ..
184 * ..
185 * .. External Subroutines ..
186  EXTERNAL blacs_gridinfo, cgamx2d, cgemm, cgsum2d,
187  $ claset, pbctran, pcmatgen, sgebr2d,
188  $ sgebs2d, sgerv2d, sgesd2d
189 * ..
190 * .. External Functions ..
191  INTEGER ICAMAX, NUMROC
192  REAL PSLAMCH
193  EXTERNAL icamax, numroc, pslamch
194 * ..
195 * .. Intrinsic Functions ..
196  INTRINSIC abs, max, min, mod, real
197 * ..
198 * .. Executable Statements ..
199 *
200 * Get needed initial parameters
201 *
202  ictxt = desca( ctxt_ )
203  nb = desca( nb_ )
204 *
205  IF( lsame( symm, 'H' ) ) THEN
206  bw = bwl
207  work_min = max(5,max(max(bwl,bwu)*(max(bwl,bwu)+2),nb))+2*nb
208  ELSE
209  bw = max(bwl, bwu)
210  work_min = max(5,max(max(bwl,bwu)*(max(bwl,bwu)+2),nb))+2*nb
211  ENDIF
212 *
213  IF ( worksiz .LT. work_min ) THEN
214  CALL pxerbla( ictxt, 'PCBLASCHK', -18 )
215  RETURN
216  END IF
217 *
218  CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
219 *
220  eps = pslamch( ictxt, 'eps' )
221  resid = 0.0e+0
222  divisor = anorm * eps * real( n )
223 *
224  CALL infog2l( ia, ja, desca, nprow, npcol, myrow, mycol, iia, jja,
225  $ iarow, iacol )
226  CALL infog2l( ix, jx, descx, nprow, npcol, myrow, mycol, iix, jjx,
227  $ ixrow, ixcol )
228  np = numroc( (bwl+bwu+1), desca( mb_ ), myrow, 0, nprow )
229  nq = numroc( n, desca( nb_ ), mycol, 0, npcol )
230 *
231  ipb = 1
232  ipproduct = 1 + desca( nb_ )
233  ipw = 1 + 2*desca( nb_ )
234 *
235  lda = desca( lld_ )
236 *
237 * Regenerate A
238 *
239  IF( lsame( symm, 'H' )) THEN
240  CALL pcbmatgen( ictxt, uplo, 'D', bw, bw, n, bw+1,
241  $ desca( nb_ ), a, desca( lld_ ), 0, 0,
242  $ iaseed, myrow, mycol, nprow, npcol )
243  ELSE
244 *
245  CALL pcbmatgen( ictxt, 'N', uplo, bwl, bwu, n,
246  $ desca( mb_ ), desca( nb_ ), a,
247  $ desca( lld_ ), 0, 0, iaseed, myrow,
248  $ mycol, nprow, npcol )
249  ENDIF
250 *
251 * Loop over the rhs
252 *
253  resid = 0.0
254 *
255  DO 40 j = 1, nrhs
256 *
257 * Multiply A * current column of X
258 *
259 *
260  CALL pcgbdcmv( bwl+bwu+1, bwl, bwu, trans, n, a, 1, desca,
261  $ 1, x( 1 + (j-1)*descx( lld_ )), 1, descx,
262  $ work( ipproduct ), work( ipw ),
263  $ (max(bwl,bwu)+2)*max(bwl,bwu), info )
264 *
265 *
266 * Regenerate column of B
267 *
268  CALL pcmatgen( descx( ctxt_ ), 'No', 'No', descx( m_ ),
269  $ descx( n_ ), descx( mb_ ), descx( nb_ ),
270  $ work( ipb ), descx( lld_ ), descx( rsrc_ ),
271  $ descx( csrc_ ), ibseed, 0, nq, j-1, 1, mycol,
272  $ myrow, npcol, nprow )
273 *
274 * Figure || A * X - B || & || X ||
275 *
276  CALL pcaxpy( n, -one, work( ipproduct ), 1, 1, descx, 1,
277  $ work( ipb ), 1, 1, descx, 1 )
278 *
279  CALL pscnrm2( n, normx,
280  $ x, 1, j, descx, 1 )
281 *
282  CALL pscnrm2( n, resid1,
283  $ work( ipb ), 1, 1, descx, 1 )
284 *
285 *
286 * Calculate residual = ||Ax-b|| / (||x||*||A||*eps*N)
287 *
288  resid1 = resid1 / ( normx*divisor )
289 *
290  resid = max( resid, resid1 )
291 *
292  40 CONTINUE
293 *
294  RETURN
295 *
296 * End of PCBLASCHK
297 *
298  END
max
#define max(A, B)
Definition: pcgemr.c:180
pcgbdcmv
subroutine pcgbdcmv(LDBW, BWL, BWU, TRANS, N, A, JA, DESCA, NRHS, B, IB, DESCB, X, WORK, LWORK, INFO)
Definition: pcdbmv1.f:3
pcbmatgen
subroutine pcbmatgen(ICTXT, AFORM, AFORM2, BWL, BWU, N, MB, NB, A, LDA, IAROW, IACOL, ISEED, MYROW, MYCOL, NPROW, NPCOL)
Definition: pcbmatgen.f:5
infog2l
subroutine infog2l(GRINDX, GCINDX, DESC, NPROW, NPCOL, MYROW, MYCOL, LRINDX, LCINDX, RSRC, CSRC)
Definition: infog2l.f:3
pcmatgen
subroutine pcmatgen(ICTXT, AFORM, DIAG, M, N, MB, NB, A, LDA, IAROW, IACOL, ISEED, IROFF, IRNUM, ICOFF, ICNUM, MYROW, MYCOL, NPROW, NPCOL)
Definition: pcmatgen.f:4
pbctran
subroutine pbctran(ICONTXT, ADIST, TRANS, M, N, NB, A, LDA, BETA, C, LDC, IAROW, IACOL, ICROW, ICCOL, WORK)
Definition: pbctran.f:3
pxerbla
subroutine pxerbla(ICTXT, SRNAME, INFO)
Definition: pxerbla.f:2
min
#define min(A, B)
Definition: pcgemr.c:181
pcdblaschk
subroutine pcdblaschk(SYMM, UPLO, TRANS, N, BWL, BWU, NRHS, X, IX, JX, DESCX, IASEED, A, IA, JA, DESCA, IBSEED, ANORM, RESID, WORK, WORKSIZ)
Definition: pcdblaschk.f:4