ScaLAPACK 2.1  2.1
ScaLAPACK: Scalable Linear Algebra PACKage
pcgeqlrv.f
Go to the documentation of this file.
1  SUBROUTINE pcgeqlrv( M, N, A, IA, JA, DESCA, TAU, WORK )
2 *
3 * -- ScaLAPACK routine (version 1.7) --
4 * University of Tennessee, Knoxville, Oak Ridge National Laboratory,
5 * and University of California, Berkeley.
6 * May 28, 2001
7 *
8 * .. Scalar Arguments ..
9  INTEGER IA, JA, M, N
10 * ..
11 * .. Array Arguments ..
12  INTEGER DESCA( * )
13  COMPLEX A( * ), TAU( * ), WORK( * )
14 * ..
15 *
16 * Purpose
17 * =======
18 *
19 * PCGEQLRV computes sub( A ) = A(IA:IA+M-1,JA:JA+N-1) from L, Q
20 * computed by PCGEQLF.
21 *
22 * Notes
23 * =====
24 *
25 * Each global data object is described by an associated description
26 * vector. This vector stores the information required to establish
27 * the mapping between an object element and its corresponding process
28 * and memory location.
29 *
30 * Let A be a generic term for any 2D block cyclicly distributed array.
31 * Such a global array has an associated description vector DESCA.
32 * In the following comments, the character _ should be read as
33 * "of the global array".
34 *
35 * NOTATION STORED IN EXPLANATION
36 * --------------- -------------- --------------------------------------
37 * DTYPE_A(global) DESCA( DTYPE_ )The descriptor type. In this case,
38 * DTYPE_A = 1.
39 * CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
40 * the BLACS process grid A is distribu-
41 * ted over. The context itself is glo-
42 * bal, but the handle (the integer
43 * value) may vary.
44 * M_A (global) DESCA( M_ ) The number of rows in the global
45 * array A.
46 * N_A (global) DESCA( N_ ) The number of columns in the global
47 * array A.
48 * MB_A (global) DESCA( MB_ ) The blocking factor used to distribute
49 * the rows of the array.
50 * NB_A (global) DESCA( NB_ ) The blocking factor used to distribute
51 * the columns of the array.
52 * RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
53 * row of the array A is distributed.
54 * CSRC_A (global) DESCA( CSRC_ ) The process column over which the
55 * first column of the array A is
56 * distributed.
57 * LLD_A (local) DESCA( LLD_ ) The leading dimension of the local
58 * array. LLD_A >= MAX(1,LOCr(M_A)).
59 *
60 * Let K be the number of rows or columns of a distributed matrix,
61 * and assume that its process grid has dimension p x q.
62 * LOCr( K ) denotes the number of elements of K that a process
63 * would receive if K were distributed over the p processes of its
64 * process column.
65 * Similarly, LOCc( K ) denotes the number of elements of K that a
66 * process would receive if K were distributed over the q processes of
67 * its process row.
68 * The values of LOCr() and LOCc() may be determined via a call to the
69 * ScaLAPACK tool function, NUMROC:
70 * LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
71 * LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
72 * An upper bound for these quantities may be computed by:
73 * LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
74 * LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
75 *
76 * Arguments
77 * =========
78 *
79 * M (global input) INTEGER
80 * The number of rows to be operated on, i.e. the number of rows
81 * of the distributed submatrix sub( A ). M >= 0.
82 *
83 * N (global input) INTEGER
84 * The number of columns to be operated on, i.e. the number of
85 * columns of the distributed submatrix sub( A ). N >= 0.
86 *
87 * A (local input/local output) COMPLEX pointer into the
88 * local memory to an array of dimension (LLD_A, LOCc(JA+N-1)).
89 * On entry, sub( A ) contains the the factors L and Q computed
90 * by PCGEQLF. On exit, the original matrix is restored.
91 *
92 * IA (global input) INTEGER
93 * The row index in the global array A indicating the first
94 * row of sub( A ).
95 *
96 * JA (global input) INTEGER
97 * The column index in the global array A indicating the
98 * first column of sub( A ).
99 *
100 * DESCA (global and local input) INTEGER array of dimension DLEN_.
101 * The array descriptor for the distributed matrix A.
102 *
103 * TAU (local input) COMPLEX, array, dimension LOCc(N_A).
104 * This array contains the scalar factors TAU of the elementary
105 * reflectors computed by PCGEQLF. TAU is tied to the dis-
106 * tributed matrix A.
107 *
108 * WORK (local workspace) COMPLEX array, dimension (LWORK)
109 * LWORK = NB_A * ( 2*Mp0 + Nq0 + NB_A ), where
110 * Mp0 = NUMROC( M+IROFF, MB_A, MYROW, IAROW, NPROW ) * NB_A,
111 * Nq0 = NUMROC( N+ICOFF, NB_A, MYCOL, IACOL, NPCOL ) * MB_A,
112 * IROFF = MOD( IA-1, MB_A ), ICOFF = MOD( JA-1, NB_A ),
113 * IAROW = INDXG2P( IA, DESCA( MB_ ), MYROW, DESCA( RSRC_ ),
114 * NPROW ),
115 * IACOL = INDXG2P( JA, DESCA( NB_ ), MYCOL, DESCA( CSRC_ ),
116 * NPCOL ),
117 * and NUMROC, INDXG2P are ScaLAPACK tool functions;
118 * MYROW, MYCOL, NPROW and NPCOL can be determined by calling
119 * the subroutine BLACS_GRIDINFO.
120 *
121 * =====================================================================
122 *
123 * .. Parameters ..
124  INTEGER BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
125  $ LLD_, MB_, M_, NB_, N_, RSRC_
126  parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
127  $ ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
128  $ rsrc_ = 7, csrc_ = 8, lld_ = 9 )
129  COMPLEX ONE, ZERO
130  parameter( one = ( 1.0e+0, 0.0e+0 ),
131  $ zero = ( 0.0e+0, 0.0e+0 ) )
132 * ..
133 * .. Local Scalars ..
134  CHARACTER COLBTOP, ROWBTOP
135  INTEGER IACOL, IAROW, ICTXT, IIA, IPT, IPV, IPW, IROFF,
136  $ IV, J, JB, JJA, JN, K, MP, MYCOL, MYROW, NPCOL,
137  $ NPROW
138 * ..
139 * .. Local Arrays ..
140  INTEGER DESCV( DLEN_ )
141 * ..
142 * .. External Subroutines ..
143  EXTERNAL blacs_gridinfo, descset, infog2l, pclacpy,
144  $ pclarfb, pclarft, pclaset, pb_topget,
145  $ pb_topset
146 * ..
147 * .. External Functions ..
148  INTEGER ICEIL, NUMROC
149  EXTERNAL iceil, numroc
150 * ..
151 * .. Intrinsic Functions ..
152  INTRINSIC max, min, mod
153 * ..
154 * .. Executable Statements ..
155 *
156 * Get grid parameters
157 *
158  ictxt = desca( ctxt_ )
159  CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
160 *
161  k = min( m, n )
162  jn = min( iceil( ja+n-k, desca( nb_ ) ) * desca( nb_ ), ja+n-1 )
163 *
164  iroff = mod( ia-1, desca( mb_ ) )
165  CALL infog2l( ia, ja+n-k, desca, nprow, npcol, myrow, mycol,
166  $ iia, jja, iarow, iacol )
167  mp = numroc( m+iroff, desca( mb_ ), myrow, iarow, nprow )
168  ipv = 1
169  ipt = ipv + mp * desca( nb_ )
170  ipw = ipt + desca( nb_ ) * desca( nb_ )
171  CALL pb_topget( ictxt, 'Broadcast', 'Rowwise', rowbtop )
172  CALL pb_topget( ictxt, 'Broadcast', 'Columnwise', colbtop )
173  CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', 'I-ring' )
174  CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', ' ' )
175 *
176  CALL descset( descv, m+iroff, desca( nb_ ), desca( mb_ ),
177  $ desca( nb_ ), iarow, iacol, ictxt, max( 1, mp ) )
178 *
179 * Handle first block separately
180 *
181  iv = 1 + m - k + iroff
182  jb = jn - ja - n + k + 1
183 *
184 * Compute upper triangular matrix T
185 *
186  CALL pclarft( 'Backward', 'Columnwise', m-n+jn-ja+1, jb, a, ia,
187  $ ja+n-k, desca, tau, work( ipt ), work( ipw ) )
188 *
189 * Copy Householder vectors into workspace
190 *
191  CALL pclacpy( 'All', m-n+jn-ja+1, jb, a, ia, ja+n-k, desca,
192  $ work( ipv ), iroff+1, 1, descv )
193  CALL pclaset( 'Lower', jb, jb, zero, one, work( ipv ), iv,
194  $ 1, descv )
195 *
196 * Zeoes the strict upper triangular part of A to get block
197 * row of L
198 *
199  CALL pclaset( 'All', m-k, jb, zero, zero, a, ia, ja+n-k,
200  $ desca )
201  CALL pclaset( 'Upper', jb, jb-1, zero, zero, a, ia+m-k,
202  $ ja+n-k+1, desca )
203 *
204 * Apply block Householder transformation
205 *
206  CALL pclarfb( 'Left', 'No transpose', 'Backward', 'Columnwise',
207  $ m-n+jn-ja+1, jn-ja+1, jb, work( ipv ), iroff+1, 1,
208  $ descv, work( ipt ), a, ia, ja, desca, work( ipw ) )
209 *
210  descv( csrc_ ) = mod( descv( csrc_ ) + 1, npcol )
211 *
212 * Loop over the remaining column blocks
213 *
214  DO 10 j = jn+1, ja+n-1, desca( nb_ )
215  jb = min( ja+n-j, desca( nb_ ) )
216  iv = 1 + m - n + j - ja + iroff
217 *
218 * Compute upper triangular matrix T
219 *
220  CALL pclarft( 'Backward', 'Columnwise', m-n+j+jb-ja, jb, a, ia,
221  $ j, desca, tau, work( ipt ), work( ipw ) )
222 *
223 * Copy Householder vectors into workspace
224 *
225  CALL pclacpy( 'All', m-n+j+jb-ja, jb, a, ia, j, desca,
226  $ work( ipv ), iroff+1, 1, descv )
227  CALL pclaset( 'Lower', jb, jb, zero, one, work( ipv ), iv,
228  $ 1, descv )
229 *
230 * Zeoes the strict upper triangular part of sub( A ) to get
231 * block row of L
232 *
233  CALL pclaset( 'All', m-n+j-ja, jb, zero, zero, a, ia, j,
234  $ desca )
235  CALL pclaset( 'Upper', jb, jb-1, zero, zero, a, ia+m-n+j-ja,
236  $ j+1, desca )
237 *
238 * Apply block Householder transformation
239 *
240  CALL pclarfb( 'Left', 'No transpose', 'Backward', 'Columnwise',
241  $ m-n+j+jb-ja, j+jb-ja, jb, work( ipv ), iroff+1,
242  $ 1, descv, work( ipt ), a, ia, ja, desca,
243  $ work( ipw ) )
244 *
245  descv( csrc_ ) = mod( descv( csrc_ ) + 1, npcol )
246 *
247  10 CONTINUE
248 *
249  CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', rowbtop )
250  CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', colbtop )
251 *
252  RETURN
253 *
254 * End of PCGEQLRV
255 *
256  END
max
#define max(A, B)
Definition: pcgemr.c:180
infog2l
subroutine infog2l(GRINDX, GCINDX, DESC, NPROW, NPCOL, MYROW, MYCOL, LRINDX, LCINDX, RSRC, CSRC)
Definition: infog2l.f:3
pclarfb
subroutine pclarfb(SIDE, TRANS, DIRECT, STOREV, M, N, K, V, IV, JV, DESCV, T, C, IC, JC, DESCC, WORK)
Definition: pclarfb.f:3
descset
subroutine descset(DESC, M, N, MB, NB, IRSRC, ICSRC, ICTXT, LLD)
Definition: descset.f:3
pclaset
subroutine pclaset(UPLO, M, N, ALPHA, BETA, A, IA, JA, DESCA)
Definition: pcblastst.f:7508
pclacpy
subroutine pclacpy(UPLO, M, N, A, IA, JA, DESCA, B, IB, JB, DESCB)
Definition: pclacpy.f:3
pcgeqlrv
subroutine pcgeqlrv(M, N, A, IA, JA, DESCA, TAU, WORK)
Definition: pcgeqlrv.f:2
pclarft
subroutine pclarft(DIRECT, STOREV, N, K, V, IV, JV, DESCV, TAU, T, WORK)
Definition: pclarft.f:3
min
#define min(A, B)
Definition: pcgemr.c:181