pzdbtrf.f

Go to the documentation of this file.

      SUBROUTINE pzdbtrf( N, BWL, BWU, A, JA, DESCA, AF, LAF, WORK,
     $                    LWORK, INFO )
*
*  -- ScaLAPACK routine (version 2.0.2) --
*     Univ. of Tennessee, Univ. of California Berkeley, Univ. of Colorado Denver
*     May 1 2012
*
*     .. Scalar Arguments ..
      INTEGER            BWL, BWU, INFO, JA, LAF, LWORK, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * )
      COMPLEX*16         A( * ), AF( * ), WORK( * )
*     ..
*
*
*  Purpose
*  =======
*
*  PZDBTRF computes a LU factorization
*  of an N-by-N complex banded
*  diagonally dominant-like distributed matrix
*  with bandwidth BWL, BWU: A(1:N, JA:JA+N-1).
*  Reordering is used to increase parallelism in the factorization.
*  This reordering results in factors that are DIFFERENT from those
*  produced by equivalent sequential codes. These factors cannot
*  be used directly by users; however, they can be used in
*  subsequent calls to PZDBTRS to solve linear systems.
*
*  The factorization has the form
*
*          P A(1:N, JA:JA+N-1) P^T = L U
*
*  where U is a banded upper triangular matrix and L is banded
*  lower triangular, and P is a permutation matrix.
*
*  =====================================================================
*
*  Arguments
*  =========
*
*
*  N       (global input) INTEGER
*          The number of rows and columns to be operated on, i.e. the
*          order of the distributed submatrix A(1:N, JA:JA+N-1). N >= 0.
*
*  BWL     (global input) INTEGER
*          Number of subdiagonals. 0 <= BWL <= N-1
*
*  BWU     (global input) INTEGER
*          Number of superdiagonals. 0 <= BWU <= N-1
*
*  A       (local input/local output) COMPLEX*16 pointer into
*          local memory to an array with first dimension
*          LLD_A >=(bwl+bwu+1) (stored in DESCA).
*          On entry, this array contains the local pieces of the
*          N-by-N unsymmetric banded distributed matrix
*          A(1:N, JA:JA+N-1) to be factored.
*          This local portion is stored in the packed banded format
*            used in LAPACK. Please see the Notes below and the
*            ScaLAPACK manual for more detail on the format of
*            distributed matrices.
*          On exit, this array contains information containing details
*            of the factorization.
*          Note that permutations are performed on the matrix, so that
*            the factors returned are different from those returned
*            by LAPACK.
*
*  JA      (global input) INTEGER
*          The index in the global array A that points to the start of
*          the matrix to be operated on (which may be either all of A
*          or a submatrix of A).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN.
*          if 1D type (DTYPE_A=501), DLEN >= 7;
*          if 2D type (DTYPE_A=1), DLEN >= 9 .
*          The array descriptor for the distributed matrix A.
*          Contains information of mapping of A to memory. Please
*          see NOTES below for full description and options.
*
*  AF      (local output) COMPLEX*16 array, dimension LAF.
*          Auxiliary Fillin Space.
*          Fillin is created during the factorization routine
*          PZDBTRF and this is stored in AF. If a linear system
*          is to be solved using PZDBTRS after the factorization
*          routine, AF *must not be altered* after the factorization.
*
*  LAF     (local input) INTEGER
*          Size of user-input Auxiliary Fillin space AF. Must be >=
*          NB*(bwl+bwu)+6*max(bwl,bwu)*max(bwl,bwu)
*          If LAF is not large enough, an error code will be returned
*          and the minimum acceptable size will be returned in AF( 1 )
*
*  WORK    (local workspace/local output)
*          COMPLEX*16 temporary workspace. This space may
*          be overwritten in between calls to routines. WORK must be
*          the size given in LWORK.
*          On exit, WORK( 1 ) contains the minimal LWORK.
*
*  LWORK   (local input or global input) INTEGER
*          Size of user-input workspace WORK.
*          If LWORK is too small, the minimal acceptable size will be
*          returned in WORK(1) and an error code is returned. LWORK>=
*          max(bwl,bwu)*max(bwl,bwu)
*
*  INFO    (global output) INTEGER
*          = 0:  successful exit
*          < 0:  If the i-th argument is an array and the j-entry had
*                an illegal value, then INFO = -(i*100+j), if the i-th
*                argument is a scalar and had an illegal value, then
*                INFO = -i.
*          > 0:  If INFO = K<=NPROCS, the submatrix stored on processor
*                INFO and factored locally was not
*                diagonally dominant-like,  and
*                the factorization was not completed.
*                If INFO = K>NPROCS, the submatrix stored on processor
*                INFO-NPROCS representing interactions with other
*                processors was not
*                stably factorable wo/interchanges,
*                and the factorization was not completed.
*
*  =====================================================================
*
*
*  Restrictions
*  ============
*
*  The following are restrictions on the input parameters. Some of these
*    are temporary and will be removed in future releases, while others
*    may reflect fundamental technical limitations.
*
*    Non-cyclic restriction: VERY IMPORTANT!
*      P*NB>= mod(JA-1,NB)+N.
*      The mapping for matrices must be blocked, reflecting the nature
*      of the divide and conquer algorithm as a task-parallel algorithm.
*      This formula in words is: no processor may have more than one
*      chunk of the matrix.
*
*    Blocksize cannot be too small:
*      If the matrix spans more than one processor, the following
*      restriction on NB, the size of each block on each processor,
*      must hold:
*      NB >= 2*MAX(BWL,BWU)
*      The bulk of parallel computation is done on the matrix of size
*      O(NB) on each processor. If this is too small, divide and conquer
*      is a poor choice of algorithm.
*
*    Submatrix reference:
*      JA = IB
*      Alignment restriction that prevents unnecessary communication.
*
*
*  =====================================================================
*
*
*  Notes
*  =====
*
*  If the factorization routine and the solve routine are to be called
*    separately (to solve various sets of righthand sides using the same
*    coefficient matrix), the auxiliary space AF *must not be altered*
*    between calls to the factorization routine and the solve routine.
*
*  The best algorithm for solving banded and tridiagonal linear systems
*    depends on a variety of parameters, especially the bandwidth.
*    Currently, only algorithms designed for the case N/P >> bw are
*    implemented. These go by many names, including Divide and Conquer,
*    Partitioning, domain decomposition-type, etc.
*
*  Algorithm description: Divide and Conquer
*
*    The Divide and Conqer algorithm assumes the matrix is narrowly
*      banded compared with the number of equations. In this situation,
*      it is best to distribute the input matrix A one-dimensionally,
*      with columns atomic and rows divided amongst the processes.
*      The basic algorithm divides the banded matrix up into
*      P pieces with one stored on each processor,
*      and then proceeds in 2 phases for the factorization or 3 for the
*      solution of a linear system.
*      1) Local Phase:
*         The individual pieces are factored independently and in
*         parallel. These factors are applied to the matrix creating
*         fillin, which is stored in a non-inspectable way in auxiliary
*         space AF. Mathematically, this is equivalent to reordering
*         the matrix A as P A P^T and then factoring the principal
*         leading submatrix of size equal to the sum of the sizes of
*         the matrices factored on each processor. The factors of
*         these submatrices overwrite the corresponding parts of A
*         in memory.
*      2) Reduced System Phase:
*         A small (max(bwl,bwu)* (P-1)) system is formed representing
*         interaction of the larger blocks, and is stored (as are its
*         factors) in the space AF. A parallel Block Cyclic Reduction
*         algorithm is used. For a linear system, a parallel front solve
*         followed by an analagous backsolve, both using the structure
*         of the factored matrix, are performed.
*      3) Backsubsitution Phase:
*         For a linear system, a local backsubstitution is performed on
*         each processor in parallel.
*
*
*  Descriptors
*  ===========
*
*  Descriptors now have *types* and differ from ScaLAPACK 1.0.
*
*  Note: banded codes can use either the old two dimensional
*    or new one-dimensional descriptors, though the processor grid in
*    both cases *must be one-dimensional*. We describe both types below.
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*
*  One-dimensional descriptors:
*
*  One-dimensional descriptors are a new addition to ScaLAPACK since
*    version 1.0. They simplify and shorten the descriptor for 1D
*    arrays.
*
*  Since ScaLAPACK supports two-dimensional arrays as the fundamental
*    object, we allow 1D arrays to be distributed either over the
*    first dimension of the array (as if the grid were P-by-1) or the
*    2nd dimension (as if the grid were 1-by-P). This choice is
*    indicated by the descriptor type (501 or 502)
*    as described below.
*
*    IMPORTANT NOTE: the actual BLACS grid represented by the
*    CTXT entry in the descriptor may be *either*  P-by-1 or 1-by-P
*    irrespective of which one-dimensional descriptor type
*    (501 or 502) is input.
*    This routine will interpret the grid properly either way.
*    ScaLAPACK routines *do not support intercontext operations* so that
*    the grid passed to a single ScaLAPACK routine *must be the same*
*    for all array descriptors passed to that routine.
*
*    NOTE: In all cases where 1D descriptors are used, 2D descriptors
*    may also be used, since a one-dimensional array is a special case
*    of a two-dimensional array with one dimension of size unity.
*    The two-dimensional array used in this case *must* be of the
*    proper orientation:
*      If the appropriate one-dimensional descriptor is DTYPEA=501
*      (1 by P type), then the two dimensional descriptor must
*      have a CTXT value that refers to a 1 by P BLACS grid;
*      If the appropriate one-dimensional descriptor is DTYPEA=502
*      (P by 1 type), then the two dimensional descriptor must
*      have a CTXT value that refers to a P by 1 BLACS grid.
*
*
*  Summary of allowed descriptors, types, and BLACS grids:
*  DTYPE           501         502         1         1
*  BLACS grid      1xP or Px1  1xP or Px1  1xP       Px1
*  -----------------------------------------------------
*  A               OK          NO          OK        NO
*  B               NO          OK          NO        OK
*
*  Let A be a generic term for any 1D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN  EXPLANATION
*  --------------- ---------- ------------------------------------------
*  DTYPE_A(global) DESCA( 1 ) The descriptor type. For 1D grids,
*                                TYPE_A = 501: 1-by-P grid.
*                                TYPE_A = 502: P-by-1 grid.
*  CTXT_A (global) DESCA( 2 ) The BLACS context handle, indicating
*                                the BLACS process grid A is distribu-
*                                ted over. The context itself is glo-
*                                bal, but the handle (the integer
*                                value) may vary.
*  N_A    (global) DESCA( 3 ) The size of the array dimension being
*                                distributed.
*  NB_A   (global) DESCA( 4 ) The blocking factor used to distribute
*                                the distributed dimension of the array.
*  SRC_A  (global) DESCA( 5 ) The process row or column over which the
*                                first row or column of the array
*                                is distributed.
*  LLD_A  (local)  DESCA( 6 ) The leading dimension of the local array
*                                storing the local blocks of the distri-
*                                buted array A. Minimum value of LLD_A
*                                depends on TYPE_A.
*                                TYPE_A = 501: LLD_A >=
*                                   size of undistributed dimension, 1.
*                                TYPE_A = 502: LLD_A >=NB_A, 1.
*  Reserved        DESCA( 7 ) Reserved for future use.
*
*
*
*  =====================================================================
*
*  Code Developer: Andrew J. Cleary, University of Tennessee.
*    Current address: Lawrence Livermore National Labs.
*  This version released: August, 2001.
*
*  =====================================================================
*
*     ..
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0 )
      parameter( zero = 0.0d+0 )
      COMPLEX*16         CONE, CZERO
      parameter( cone = ( 1.0d+0, 0.0d+0 ) )
      parameter( czero = ( 0.0d+0, 0.0d+0 ) )
      INTEGER            INT_ONE
      parameter( int_one = 1 )
      INTEGER            DESCMULT, BIGNUM
      parameter(descmult = 100, bignum = descmult * descmult)
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   lld_, mb_, m_, nb_, n_, rsrc_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
*     ..
*     .. Local Scalars ..
      INTEGER            COMM_PROC, CSRC, FIRST_PROC, I, ICTXT,
     $                   ictxt_new, ictxt_save, idum3, ja_new, laf_min,
     $                   level_dist, llda, max_bw, mbw2, mycol, myrow,
     $                   my_num_cols, nb, next_tri_size_m,
     $                   next_tri_size_n, np, npcol, nprow, np_save,
     $                   odd_size, ofst, part_offset, part_size,
     $                   prev_tri_size_m, prev_tri_size_n, return_code,
     $                   store_n_a, up_prev_tri_size_m,
     $                   up_prev_tri_size_n, work_size_min, work_u
*     ..
*     .. Local Arrays ..
      INTEGER            DESCA_1XP( 7 ), PARAM_CHECK( 9, 3 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_get, blacs_gridexit, blacs_gridinfo,
     $                   desc_convert, globchk, pxerbla, reshape, zaxpy,
     $                   zgemm, zgerv2d, zgesd2d, zlamov, zlatcpy,
     $                   zpbtrf, zpotrf, zsyrk, ztbtrs, ztrmm, ztrrv2d,
     $                   ztrsd2d, ztrsm, ztrtrs
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            NUMROC
      EXTERNAL           lsame, numroc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          ichar, min, mod
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters
*
      info = 0
*
*     Convert descriptor into standard form for easy access to
*        parameters, check that grid is of right shape.
*
      desca_1xp( 1 ) = 501
*
      CALL desc_convert( desca, desca_1xp, return_code )
*
      IF( return_code .NE. 0) THEN
         info = -( 6*100 + 2 )
      ENDIF
*
*     Get values out of descriptor for use in code.
*
      ictxt = desca_1xp( 2 )
      csrc = desca_1xp( 5 )
      nb = desca_1xp( 4 )
      llda = desca_1xp( 6 )
      store_n_a = desca_1xp( 3 )
*
*     Get grid parameters
*
*
*     Size of separator blocks is maximum of bandwidths
*
      max_bw = max(bwl,bwu)
      mbw2 = max_bw * max_bw
*
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
      np = nprow * npcol
*
*
*
      IF( lwork .LT. -1) THEN
         info = -10
      ELSE IF ( lwork .EQ. -1 ) THEN
         idum3 = -1
      ELSE
         idum3 = 1
      ENDIF
*
      IF( n .LT. 0 ) THEN
         info = -1
      ENDIF
*
      IF( n+ja-1 .GT. store_n_a ) THEN
         info = -( 6*100 + 6 )
      ENDIF
*
      IF(( bwl .GT. n-1 ) .OR.
     $   ( bwl .LT. 0 ) ) THEN
         info = -2
      ENDIF
*
      IF(( bwu .GT. n-1 ) .OR.
     $   ( bwu .LT. 0 ) ) THEN
         info = -3
      ENDIF
*
      IF( llda .LT. (bwl+bwu+1) ) THEN
         info = -( 6*100 + 6 )
      ENDIF
*
      IF( nb .LE. 0 ) THEN
         info = -( 6*100 + 4 )
      ENDIF
*
*     Argument checking that is specific to Divide & Conquer routine
*
      IF( nprow .NE. 1 ) THEN
         info = -( 6*100+2 )
      ENDIF
*
      IF( n .GT. np*nb-mod( ja-1, nb )) THEN
         info = -( 1 )
         CALL pxerbla( ictxt,
     $      'PZDBTRF, D&C alg.: only 1 block per proc',
     $      -info )
         RETURN
      ENDIF
*
      IF((ja+n-1.GT.nb) .AND. ( nb.LT.2*max(bwl,bwu) )) THEN
         info = -( 6*100+4 )
         CALL pxerbla( ictxt,
     $      'PZDBTRF, D&C alg.: NB too small',
     $      -info )
         RETURN
      ENDIF
*
*
*     Check auxiliary storage size
*
      laf_min = nb*(bwl+bwu)+6*max(bwl,bwu)*max(bwl,bwu)
*
      IF( laf .LT. laf_min ) THEN
         info = -8
*        put minimum value of laf into AF( 1 )
         af( 1 ) = laf_min
         CALL pxerbla( ictxt,
     $      'PZDBTRF: auxiliary storage error ',
     $      -info )
         RETURN
      ENDIF
*
*     Check worksize
*
      work_size_min = max(bwl,bwu)*max(bwl,bwu)
*
      work( 1 ) = work_size_min
*
      IF( lwork .LT. work_size_min ) THEN
         IF( lwork .NE. -1 ) THEN
           info = -10
           CALL pxerbla( ictxt,
     $      'PZDBTRF: worksize error ',
     $      -info )
         ENDIF
         RETURN
      ENDIF
*
*     Pack params and positions into arrays for global consistency check
*
      param_check(  9, 1 ) = desca(5)
      param_check(  8, 1 ) = desca(4)
      param_check(  7, 1 ) = desca(3)
      param_check(  6, 1 ) = desca(1)
      param_check(  5, 1 ) = ja
      param_check(  4, 1 ) = bwu
      param_check(  3, 1 ) = bwl
      param_check(  2, 1 ) = n
      param_check(  1, 1 ) = idum3
*
      param_check(  9, 2 ) = 605
      param_check(  8, 2 ) = 604
      param_check(  7, 2 ) = 603
      param_check(  6, 2 ) = 601
      param_check(  5, 2 ) = 5
      param_check(  4, 2 ) = 3
      param_check(  3, 2 ) = 2
      param_check(  2, 2 ) = 1
      param_check(  1, 2 ) = 10
*
*     Want to find errors with MIN( ), so if no error, set it to a big
*     number. If there already is an error, multiply by the the
*     descriptor multiplier.
*
      IF( info.GE.0 ) THEN
         info = bignum
      ELSE IF( info.LT.-descmult ) THEN
         info = -info
      ELSE
         info = -info * descmult
      END IF
*
*     Check consistency across processors
*
      CALL globchk( ictxt, 9, param_check, 9,
     $              param_check( 1, 3 ), info )
*
*     Prepare output: set info = 0 if no error, and divide by DESCMULT
*     if error is not in a descriptor entry.
*
      IF( info.EQ.bignum ) THEN
         info = 0
      ELSE IF( mod( info, descmult ) .EQ. 0 ) THEN
         info = -info / descmult
      ELSE
         info = -info
      END IF
*
      IF( info.LT.0 ) THEN
         CALL pxerbla( ictxt, 'PZDBTRF', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*
*     Adjust addressing into matrix space to properly get into
*        the beginning part of the relevant data
*
      part_offset = nb*( (ja-1)/(npcol*nb) )
*
      IF ( (mycol-csrc) .LT. (ja-part_offset-1)/nb ) THEN
         part_offset = part_offset + nb
      ENDIF
*
      IF ( mycol .LT. csrc ) THEN
         part_offset = part_offset - nb
      ENDIF
*
*     Form a new BLACS grid (the "standard form" grid) with only procs
*        holding part of the matrix, of size 1xNP where NP is adjusted,
*        starting at csrc=0, with JA modified to reflect dropped procs.
*
*     First processor to hold part of the matrix:
*
      first_proc = mod( ( ja-1 )/nb+csrc, npcol )
*
*     Calculate new JA one while dropping off unused processors.
*
      ja_new = mod( ja-1, nb ) + 1
*
*     Save and compute new value of NP
*
      np_save = np
      np = ( ja_new+n-2 )/nb + 1
*
*     Call utility routine that forms "standard-form" grid
*
      CALL reshape( ictxt, int_one, ictxt_new, int_one,
     $              first_proc, int_one, np )
*
*     Use new context from standard grid as context.
*
      ictxt_save = ictxt
      ictxt = ictxt_new
      desca_1xp( 2 ) = ictxt_new
*
*     Get information about new grid.
*
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Drop out processors that do not have part of the matrix.
*
      IF( myrow .LT. 0 ) THEN
         GOTO 1234
      ENDIF
*
*     ********************************
*     Values reused throughout routine
*
*     User-input value of partition size
*
      part_size = nb
*
*     Number of columns in each processor
*
      my_num_cols = numroc( n, part_size, mycol, 0, npcol )
*
*     Offset in columns to beginning of main partition in each proc
*
      IF ( mycol .EQ. 0 ) THEN
        part_offset = part_offset+mod( ja_new-1, part_size )
        my_num_cols = my_num_cols - mod(ja_new-1, part_size )
      ENDIF
*
*     Offset in elements
*
      ofst = part_offset*llda
*
*     Size of main (or odd) partition in each processor
*
      odd_size = my_num_cols
      IF ( mycol .LT. np-1 ) THEN
         odd_size = odd_size - max_bw
      ENDIF
*
*     Offset to workspace for Upper triangular factor
*
      work_u = bwu*odd_size + 3*mbw2
*
*
*       Zero out space for fillin
*
        DO 10  i=1, laf_min
          af( i ) = czero
   10   CONTINUE
*
*       Zero out space for work
*
        DO 20  i=1, work_size_min
          work( i ) = czero
   20   CONTINUE
*
*     Begin main code
*
*
********************************************************************
*       PHASE 1: Local computation phase.
********************************************************************
*
*
*       Sizes of the extra triangles communicated bewtween processors
*
        IF( mycol .GT. 0 ) THEN
          prev_tri_size_m= min( bwl,
     $          numroc( n, part_size, mycol, 0, npcol ) )
          prev_tri_size_n=min( bwl,
     $          numroc( n, part_size, mycol-1, 0, npcol ) )
        ENDIF
*
        IF( mycol .GT. 0 ) THEN
          up_prev_tri_size_m= min( bwu,
     $          numroc( n, part_size, mycol, 0, npcol ) )
          up_prev_tri_size_n=min( bwu,
     $          numroc( n, part_size, mycol-1, 0, npcol ) )
        ENDIF
*
        IF( mycol .LT. npcol-1 ) THEN
          next_tri_size_m=min( bwl,
     $          numroc( n, part_size, mycol+1, 0, npcol ) )
          next_tri_size_n= min( bwl,
     $          numroc( n, part_size, mycol, 0, npcol ) )
        ENDIF
*
        IF ( mycol .LT. np-1 ) THEN
*         Transfer last triangle D_i of local matrix to next processor
*         which needs it to calculate fillin due to factorization of
*         its main (odd) block A_i.
*         Overlap the send with the factorization of A_i.
*
          CALL ztrsd2d( ictxt, 'U', 'N', next_tri_size_m,
     $                  next_tri_size_n,
     $                  a( ofst+(my_num_cols-bwl)*llda+(bwl+bwu+1) ),
     $                  llda-1, 0, mycol+1 )
*
        ENDIF
*
*
*       Factor main partition A_i = L_i {U_i} in each processor
*
        CALL zdbtrf( odd_size, odd_size, bwl, bwu, a( ofst + 1),
     $                    llda, info )
*
        IF( info.NE.0 ) THEN
           info = mycol+1
           GOTO 1500
        ENDIF
*
*
        IF ( mycol .LT. np-1 ) THEN
*
*         Apply factorization to lower connection block BL_i
*         conjugate transpose the connection block in preparation.
*         Apply factorization to upper connection block BU_i
*         Move the connection block in preparation.
*
          CALL zlatcpy( 'U', bwl, bwl,
     $                  a(( ofst+(bwl+bwu+1)+(odd_size-bwl)*llda )),
     $                  llda-1, af( odd_size*bwu+2*mbw2+1+max_bw-bwl ),
     $                  max_bw )
          CALL zlamov( 'L', bwu, bwu, a( ( ofst+1+odd_size*llda ) ),
     $                 llda-1,
     $                 af( work_u+odd_size*bwl+2*mbw2+1+max_bw-bwu ),
     $                 max_bw )
*
*         Perform the triangular system solve {L_i}{{BU'}_i} = {B_i}
*
          CALL ztbtrs( 'L', 'N', 'U', bwu, bwl, bwu,
     $                 a( ofst+bwu+1+(odd_size-bwu )*llda ), llda,
     $                 af( work_u+odd_size*bwl+2*mbw2+1+max_bw-bwu ),
     $                 max_bw, info )
*
*         Perform the triangular solve {U_i}^C{BL'}_i^C = {BL_i}^C
*
          CALL ztbtrs( 'U', 'C', 'N', bwl, bwu, bwl,
     $                 a( ofst+1+(odd_size-bwl)*llda ), llda,
     $                 af( odd_size*bwu+2*mbw2+1+max_bw-bwl ), max_bw,
     $                 info )
*
*         conjugate transpose resulting block to its location
*           in main storage.
*
          CALL zlatcpy( 'L', bwl, bwl,
     $                  af( odd_size*bwu+2*mbw2+1+max_bw-bwl ), max_bw,
     $                  a(( ofst+(bwl+bwu+1)+(odd_size-bwl)*llda )),
     $                  llda-1 )
*
*         Move the resulting block back to its location in main storage.
*
          CALL zlamov( 'L', bwu, bwu,
     $                 af( work_u+odd_size*bwl+2*mbw2+1+max_bw-bwu ),
     $                 max_bw, a(( ofst+1+odd_size*llda )), llda-1 )
*
*
*         Compute contribution to diagonal block(s) of reduced system.
*          {C'}_i = {C_i}-{{BL'}_i}{{BU'}_i}
*
*         The following method uses more flops than necessary but
*           does not necessitate the writing of a new BLAS routine.
*
*
          CALL zgemm( 'C', 'N', max_bw, max_bw, max_bw, -cone ,
     $         af( odd_size*bwu+2*mbw2+1), max_bw,
     $         af( work_u+odd_size*bwl+2*mbw2+1), max_bw, cone,
     $         a( ofst+odd_size*llda+1+bwu ), llda-1 )
*
        ENDIF
*       End of "if ( MYCOL .lt. NP-1 )..." loop
*
*
 1500   CONTINUE
*       If the processor could not locally factor, it jumps here.
*
        IF ( mycol .NE. 0 ) THEN
*         Discard temporary matrix stored beginning in
*           AF( (odd_size+2*bwl, bwu)*bwl, bwu+1 ) and use for
*           off_diagonal block of reduced system.
*
*         Receive previously transmitted matrix section, which forms
*         the right-hand-side for the triangular solve that calculates
*         the "spike" fillin.
*
*
          CALL ztrrv2d( ictxt, 'U', 'N', prev_tri_size_m,
     $                  prev_tri_size_n, af( work_u+1 ), odd_size, 0,
     $                  mycol-1 )
*
          IF (info.EQ.0) THEN
*
*         Calculate the "spike" fillin, ${L_i} {{GU}_i} = {DL_i}$ .
*
          CALL ztbtrs( 'L', 'N', 'U', odd_size, bwl, bwl,
     $                 a( ofst + bwu+1 ), llda, af( work_u+1 ),
     $                 odd_size, info )
*
*
*         Calculate the "spike" fillin, ${U_i}^C {{GL}_i}^C = {DU_i}^C$
*
*
*         Copy D block into AF storage for solve.
*
          CALL zlatcpy( 'L', up_prev_tri_size_n, up_prev_tri_size_m,
     $                  a( ofst+1 ), llda-1, af( 1 ), odd_size )
*
          CALL ztbtrs( 'U', 'C', 'N', odd_size, bwu, bwu,
     $                    a( ofst + 1 ), llda,
     $                    af( 1 ), odd_size, info )
*
*
*         Calculate the update block for previous proc, E_i = GL_i{GU_i}
*
*
*         Zero out space in case result is smaller than storage block
*
        DO 30  i=1, mbw2
            af( odd_size*bwu+2*mbw2+i ) = czero
   30   CONTINUE
*
          CALL zgemm( 'C', 'N', bwu, bwl, odd_size,
     $                    -cone, af( 1 ), odd_size,
     $                    af( work_u+1 ), odd_size, czero,
     $                    af( 1+max(0,bwl-bwu)+odd_size*bwu+
     $                      (2*max_bw+max(0,bwu-bwl))*max_bw),
     $                    max_bw )
*
*
*         Initiate send of E_i to previous processor to overlap
*           with next computation.
*
          CALL zgesd2d( ictxt, max_bw, max_bw,
     $                  af( odd_size*bwu+2*mbw2+1 ), max_bw, 0,
     $                  mycol-1 )
*
*
          IF ( mycol .LT. np-1 ) THEN
*
*           Calculate off-diagonal block(s) of reduced system.
*           Note: for ease of use in solution of reduced system, store
*           L's off-diagonal block in conjugate transpose form.
*
*           Copy matrix HU_i (the last bwl rows of GU_i) to AFL storage
*             as per requirements of BLAS routine ZTRMM.
*             Since we have GU_i stored,
*             conjugate transpose HU_i to HU_i^C.
*
            CALL zlatcpy( 'N', bwl, bwl,
     $               af( work_u+odd_size-bwl+1 ), odd_size,
     $        af( (odd_size)*bwu+1+(max_bw-bwl) ),
     $               max_bw  )
*
            CALL ztrmm( 'R', 'U', 'C', 'N', bwl, bwl, -cone,
     $                  a( ( ofst+(bwl+bwu+1)+(odd_size-bwl)*llda ) ),
     $                  llda-1, af( (odd_size)*bwu+1+(max_bw-bwl) ),
     $                  max_bw )
*
*
*           Copy matrix HL_i (the last bwu rows of GL_i^C) to AFU store
*             as per requirements of BLAS routine ZTRMM.
*             Since we have GL_i^C stored,
*             conjugate transpose HL_i^C to HL_i.
*
            CALL zlatcpy( 'N', bwu, bwu,
     $               af( odd_size-bwu+1 ), odd_size,
     $               af( work_u+(odd_size)*bwl+1+max_bw-bwu ),
     $               max_bw  )
*
            CALL ztrmm( 'R', 'L', 'N', 'N', bwu, bwu, -cone,
     $                  a( ( ofst+1+odd_size*llda ) ), llda-1,
     $                  af( work_u+(odd_size)*bwl+1+max_bw-bwu ),
     $                  max_bw )
*
          ENDIF
*
        ENDIF
*       End of "if ( MYCOL .ne. 0 )..."
*
        ENDIF
*       End of "if (info.eq.0) then"
*
*
*       Check to make sure no processors have found errors
*
        CALL igamx2d( ictxt, 'A', ' ', 1, 1, info, 1, info, info,
     $              -1, 0, 0 )
*
        IF( mycol.EQ.0 ) THEN
           CALL igebs2d( ictxt, 'A', ' ', 1, 1, info, 1 )
        ELSE
           CALL igebr2d( ictxt, 'A', ' ', 1, 1, info, 1, 0, 0 )
        ENDIF
*
        IF ( info.NE.0 ) THEN
           GOTO 1000
        ENDIF
*       No errors found, continue
*
*
********************************************************************
*       PHASE 2: Formation and factorization of Reduced System.
********************************************************************
*
*       Gather up local sections of reduced system
*
*
*     The last processor does not participate in the factorization of
*       the reduced system, having sent its E_i already.
      IF( mycol .EQ. npcol-1 ) THEN
        GOTO 14
      ENDIF
*
*       Initiate send of off-diag block(s) to overlap with next part.
*       Off-diagonal block needed on neighboring processor to start
*       algorithm.
*
        IF( (mod( mycol+1, 2 ) .EQ. 0) .AND. ( mycol .GT. 0 ) ) THEN
*
          CALL zgesd2d( ictxt, max_bw, max_bw,
     $                       af( odd_size*bwu+1 ),
     $                       max_bw, 0, mycol-1 )
*
          CALL zgesd2d( ictxt, max_bw, max_bw,
     $                       af( work_u+odd_size*bwl+1 ),
     $                       max_bw, 0, mycol-1 )
*
        ENDIF
*
*       Copy last diagonal block into AF storage for subsequent
*         operations.
*
        CALL zlamov( 'N', max_bw, max_bw,
     $                    a( ofst+odd_size*llda+bwu+1 ),
     $                    llda-1, af( odd_size*bwu+mbw2+1 ),
     $                    max_bw )
*
*       Receive cont. to diagonal block that is stored on this proc.
*
        IF( mycol.LT. npcol-1 ) THEN
*
           CALL zgerv2d( ictxt, max_bw, max_bw,
     $               af( odd_size*bwu+2*mbw2+1 ),
     $               max_bw, 0,
     $               mycol+1 )
*
*          Add contribution to diagonal block
*
           CALL zaxpy( mbw2, cone,
     $               af( odd_size*bwu+2*mbw2+1 ),
     $               1, af( odd_size*bwu+mbw2+1 ), 1 )
*
        ENDIF
*
*
*       *************************************
*       Modification Loop
*
*       The distance for sending and receiving for each level starts
*         at 1 for the first level.
        level_dist = 1
*
*       Do until this proc is needed to modify other procs' equations
*
   12   CONTINUE
        IF( mod( (mycol+1)/level_dist, 2) .NE. 0 ) GOTO 11
*
*         Receive and add contribution to diagonal block from the left
*
          IF( mycol-level_dist .GE. 0 ) THEN
            CALL zgerv2d( ictxt, max_bw, max_bw, work( 1 ),
     $                     max_bw, 0, mycol-level_dist )
*
            CALL zaxpy( mbw2, cone, work( 1 ), 1,
     $               af( odd_size*bwu+mbw2+1 ), 1 )
*
          ENDIF
*
*         Receive and add contribution to diagonal block from the right
*
          IF( mycol+level_dist .LT. npcol-1 ) THEN
            CALL zgerv2d( ictxt, max_bw, max_bw, work( 1 ),
     $                        max_bw, 0, mycol+level_dist )
*
            CALL zaxpy( mbw2, cone, work( 1 ), 1,
     $               af( odd_size*bwu+mbw2+1 ), 1 )
*
          ENDIF
*
          level_dist = level_dist*2
*
        GOTO 12
   11   CONTINUE
*       [End of GOTO Loop]
*
*
*       *********************************
*       Calculate and use this proc's blocks to modify other procs'...
*
*       Factor diagonal block
*
       CALL zdbtrf( max_bw, max_bw, min( max_bw-1, bwl ),
     $              min( max_bw-1, bwu ), af( odd_size*bwu+mbw2+1
     $              -( min( max_bw-1, bwu ))), max_bw+1, info )
*
        IF( info.NE.0 ) THEN
               info = npcol + mycol
        ENDIF
*
*       ****************************************************************
*       Receive offdiagonal block from processor to right.
*         If this is the first group of processors, the receive comes
*         from a different processor than otherwise.
*
        IF( level_dist .EQ. 1 )THEN
          comm_proc = mycol + 1
*
*           Move block into place that it will be expected to be for
*             calcs.
*
          CALL zlamov( 'N', max_bw, max_bw, af( odd_size*bwu+1 ),
     $                 max_bw, af( work_u+odd_size*bwl+2*mbw2+1 ),
     $                 max_bw )
*
          CALL zlamov( 'N', max_bw, max_bw, af( work_u+odd_size*bwl+1 ),
     $                 max_bw, af( odd_size*bwu+2*mbw2+1 ), max_bw )
*
        ELSE
          comm_proc = mycol + level_dist/2
        ENDIF
*
        IF( mycol/level_dist .LE. (npcol-1)/level_dist-2 )THEN
*
          CALL zgerv2d( ictxt, max_bw, max_bw,
     $        af( odd_size*bwu+1 ),
     $                       max_bw, 0, comm_proc )
*
          CALL zgerv2d( ictxt, max_bw, max_bw,
     $        af( work_u+odd_size*bwl+1 ),
     $                       max_bw, 0, comm_proc )
*
          IF( info .EQ. 0 ) THEN
*
*
*         Modify upper off_diagonal block with diagonal block
*
*
          CALL ztbtrs(
     $     'L', 'N', 'U', bwu, min( bwl, bwu-1 ), bwu,
     $     af( odd_size*bwu+
     $     mbw2+1+(max_bw+1)*(max_bw-bwu)), max_bw+1,
     $     af( work_u+odd_size*bwl+1+max_bw-bwu), max_bw, info )
*
*         Modify lower off_diagonal block with diagonal block
*
*
          CALL ztbtrs(
     $     'U', 'C', 'N', bwl, min( bwu, bwl-1 ), bwl,
     $     af( odd_size*bwu+
     $     mbw2+1-min( bwu, bwl-1 )+(max_bw+1)*(max_bw-bwl)), max_bw+1,
     $     af( odd_size*bwu+1+max_bw-bwl), max_bw, info )
*
          ENDIF
*         End of "if ( info.eq.0 ) then"
*
*         Calculate contribution from this block to next diagonal block
*
          CALL zgemm( 'C', 'N', max_bw, max_bw, max_bw, -cone,
     $                af( (odd_size)*bwu+1 ), max_bw,
     $                af( work_u+(odd_size)*bwl+1 ), max_bw, czero,
     $                work( 1 ), max_bw )
*
*         Send contribution to diagonal block's owning processor.
*
          CALL zgesd2d( ictxt, max_bw, max_bw, work( 1 ), max_bw,
     $                     0, mycol+level_dist )
*
        ENDIF
*       End of "if( mycol/level_dist .le. (npcol-1)/level_dist-2 )..."
*
*
*       ****************************************************************
*       Receive off_diagonal block from left and use to finish with this
*         processor.
*
        IF( (mycol/level_dist .GT. 0 ).AND.
     $      ( mycol/level_dist .LE. (npcol-1)/level_dist-1 ) ) THEN
*
          IF( level_dist .GT. 1)THEN
*
*           Receive offdiagonal block(s) from proc level_dist/2 to the
*           left
*
           CALL zgerv2d( ictxt, max_bw, max_bw,
     $            af( work_u+odd_size*bwl+2*mbw2+1 ),
     $            max_bw, 0, mycol-level_dist/2 )
*
*           Receive offdiagonal block(s) from proc level_dist/2 to the
*           left
*
           CALL zgerv2d( ictxt, max_bw, max_bw,
     $            af( odd_size*bwu+2*mbw2+1 ),
     $            max_bw, 0, mycol-level_dist/2 )
*
          ENDIF
*
*
          IF( info.EQ.0 ) THEN
*
*         Use diagonal block(s) to modify this offdiagonal block
*
*
*         Since ZTBTRS has no "left-right" option, we must transpose
*
          CALL zlatcpy( 'N', max_bw, max_bw, af( work_u+odd_size*bwl+
     $      2*mbw2+1), max_bw, work( 1 ), max_bw )
*
          CALL ztbtrs(
     $          'L', 'N', 'U', max_bw, min( bwl, max_bw-1 ), bwl,
     $          af( odd_size*bwu+mbw2+1), max_bw+1,
     $          work( 1+max_bw*(max_bw-bwl) ), max_bw, info )
*
*         Transpose back
*
          CALL zlatcpy(
     $         'N', max_bw, max_bw, work( 1 ), max_bw,
     $         af( work_u+odd_size*bwl+
     $      2*mbw2+1), max_bw )
*
*
*
*         Since ZTBTRS has no "left-right" option, we must transpose
*
          CALL zlatcpy( 'N', max_bw, max_bw, af( odd_size*bwu+
     $      2*mbw2+1), max_bw, work( 1 ), max_bw )
*
          CALL ztbtrs(
     $          'U', 'C', 'N', max_bw, min( bwu, max_bw-1 ), bwu,
     $          af( odd_size*bwu+mbw2+1-min( bwu, max_bw-1 )), max_bw+1,
     $          work( 1+max_bw*(max_bw-bwu) ), max_bw, info )
*
*         Transpose back
*
          CALL zlatcpy(
     $         'N', max_bw, max_bw, work( 1 ), max_bw,
     $         af( odd_size*bwu+
     $      2*mbw2+1), max_bw )
*
*
          ENDIF
*         End of "if( info.eq.0 ) then"
*
*         Use offdiag block(s) to calculate modification to diag block
*           of processor to the left
*
          CALL zgemm( 'N', 'C', max_bw, max_bw, max_bw, -cone,
     $                af( (odd_size)*bwu+2*mbw2+1 ), max_bw,
     $                af( work_u+(odd_size)*bwl+2*mbw2+1 ), max_bw,
     $                czero, work( 1 ), max_bw )
*
*         Send contribution to diagonal block's owning processor.
*
          CALL zgesd2d( ictxt, max_bw, max_bw, work( 1 ), max_bw,
     $                     0, mycol-level_dist )
*
*         *******************************************************
*
          IF( mycol/level_dist .LE. (npcol-1)/level_dist-2 ) THEN
*
*           Decide which processor offdiagonal block(s) goes to
*
            IF( ( mod( mycol/( 2*level_dist ),2 )) .EQ.0 ) THEN
              comm_proc = mycol + level_dist
            ELSE
              comm_proc = mycol - level_dist
            ENDIF
*
*           Use offdiagonal blocks to calculate offdiag
*             block to send to neighboring processor. Depending
*             on circumstances, may need to transpose the matrix.
*
              CALL zgemm( 'N', 'N', max_bw, max_bw, max_bw, -cone,
     $                    af( work_u+odd_size*bwl+2*mbw2+1 ), max_bw,
     $                    af( odd_size*bwu+1 ), max_bw, czero,
     $                    work( 1 ), max_bw )
*
*           Send contribution to offdiagonal block's owning processor.
*
            CALL zgesd2d( ictxt, max_bw, max_bw, work( 1 ), max_bw,
     $                         0, comm_proc )
*
              CALL zgemm( 'N', 'N', max_bw, max_bw, max_bw, -cone,
     $                    af( odd_size*bwu+2*mbw2+1 ), max_bw,
     $                    af( work_u+odd_size*bwl+1 ), max_bw, czero,
     $                    work( 1 ), max_bw )
*
*           Send contribution to offdiagonal block's owning processor.
*
            CALL zgesd2d( ictxt, max_bw, max_bw, work( 1 ), max_bw,
     $                         0, comm_proc )
*
          ENDIF
*
        ENDIF
*       End of "if( mycol/level_dist.le. (npcol-1)/level_dist -1 )..."
*
   14   CONTINUE
*
*
 1000 CONTINUE
*
*
*     Free BLACS space used to hold standard-form grid.
*
      IF( ictxt_save .NE. ictxt_new ) THEN
         CALL blacs_gridexit( ictxt_new )
      ENDIF
*
 1234 CONTINUE
*
*     Restore saved input parameters
*
      ictxt = ictxt_save
      np = np_save
*
*     Output minimum worksize
*
      work( 1 ) = work_size_min
*
*         Make INFO consistent across processors
*
          CALL igamx2d( ictxt, 'A', ' ', 1, 1, info, 1, info, info,
     $              -1, 0, 0 )
*
          IF( mycol.EQ.0 ) THEN
             CALL igebs2d( ictxt, 'A', ' ', 1, 1, info, 1 )
          ELSE
             CALL igebr2d( ictxt, 'A', ' ', 1, 1, info, 1, 0, 0 )
          ENDIF
*
*
      RETURN
*
*     End of PZDBTRF
*
      END