ScaLAPACK 2.1  2.1
ScaLAPACK: Scalable Linear Algebra PACKage
pzunml2.f
Go to the documentation of this file.
1  SUBROUTINE pzunml2( SIDE, TRANS, M, N, K, A, IA, JA, DESCA, TAU,
2  $ C, IC, JC, DESCC, WORK, LWORK, INFO )
3 *
4 * -- ScaLAPACK routine (version 1.7) --
5 * University of Tennessee, Knoxville, Oak Ridge National Laboratory,
6 * and University of California, Berkeley.
7 * May 25, 2001
8 *
9 * .. Scalar Arguments ..
10  CHARACTER SIDE, TRANS
11  INTEGER IA, IC, INFO, JA, JC, K, LWORK, M, N
12 * ..
13 * .. Array Arguments ..
14  INTEGER DESCA( * ), DESCC( * )
15  COMPLEX*16 A( * ), C( * ), TAU( * ), WORK( * )
16 * ..
17 *
18 * Purpose
19 * =======
20 *
21 * PZUNML2 overwrites the general complex M-by-N distributed matrix
22 * sub( C ) = C(IC:IC+M-1,JC:JC+N-1) with
23 *
24 * SIDE = 'L' SIDE = 'R'
25 * TRANS = 'N': Q * sub( C ) sub( C ) * Q
26 * TRANS = 'C': Q**H * sub( C sub( C ) * Q**H
27 *
28 * where Q is a complex unitary distributed matrix defined as the
29 * product of K elementary reflectors
30 *
31 * Q = H(k)' . . . H(2)' H(1)'
32 *
33 * as returned by PZGELQF. Q is of order M if SIDE = 'L' and of order N
34 * if SIDE = 'R'.
35 *
36 * Notes
37 * =====
38 *
39 * Each global data object is described by an associated description
40 * vector. This vector stores the information required to establish
41 * the mapping between an object element and its corresponding process
42 * and memory location.
43 *
44 * Let A be a generic term for any 2D block cyclicly distributed array.
45 * Such a global array has an associated description vector DESCA.
46 * In the following comments, the character _ should be read as
47 * "of the global array".
48 *
49 * NOTATION STORED IN EXPLANATION
50 * --------------- -------------- --------------------------------------
51 * DTYPE_A(global) DESCA( DTYPE_ )The descriptor type. In this case,
52 * DTYPE_A = 1.
53 * CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
54 * the BLACS process grid A is distribu-
55 * ted over. The context itself is glo-
56 * bal, but the handle (the integer
57 * value) may vary.
58 * M_A (global) DESCA( M_ ) The number of rows in the global
59 * array A.
60 * N_A (global) DESCA( N_ ) The number of columns in the global
61 * array A.
62 * MB_A (global) DESCA( MB_ ) The blocking factor used to distribute
63 * the rows of the array.
64 * NB_A (global) DESCA( NB_ ) The blocking factor used to distribute
65 * the columns of the array.
66 * RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
67 * row of the array A is distributed.
68 * CSRC_A (global) DESCA( CSRC_ ) The process column over which the
69 * first column of the array A is
70 * distributed.
71 * LLD_A (local) DESCA( LLD_ ) The leading dimension of the local
72 * array. LLD_A >= MAX(1,LOCr(M_A)).
73 *
74 * Let K be the number of rows or columns of a distributed matrix,
75 * and assume that its process grid has dimension p x q.
76 * LOCr( K ) denotes the number of elements of K that a process
77 * would receive if K were distributed over the p processes of its
78 * process column.
79 * Similarly, LOCc( K ) denotes the number of elements of K that a
80 * process would receive if K were distributed over the q processes of
81 * its process row.
82 * The values of LOCr() and LOCc() may be determined via a call to the
83 * ScaLAPACK tool function, NUMROC:
84 * LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
85 * LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
86 * An upper bound for these quantities may be computed by:
87 * LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
88 * LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
89 *
90 * Arguments
91 * =========
92 *
93 * SIDE (global input) CHARACTER
94 * = 'L': apply Q or Q**H from the Left;
95 * = 'R': apply Q or Q**H from the Right.
96 *
97 * TRANS (global input) CHARACTER
98 * = 'N': No transpose, apply Q;
99 * = 'C': Conjugate transpose, apply Q**H.
100 *
101 * M (global input) INTEGER
102 * The number of rows to be operated on i.e the number of rows
103 * of the distributed submatrix sub( C ). M >= 0.
104 *
105 * N (global input) INTEGER
106 * The number of columns to be operated on i.e the number of
107 * columns of the distributed submatrix sub( C ). N >= 0.
108 *
109 * K (global input) INTEGER
110 * The number of elementary reflectors whose product defines the
111 * matrix Q. If SIDE = 'L', M >= K >= 0, if SIDE = 'R',
112 * N >= K >= 0.
113 *
114 * A (local input) COMPLEX*16 pointer into the local memory
115 * to an array of dimension (LLD_A,LOCc(JA+M-1)) if SIDE='L',
116 * and (LLD_A,LOCc(JA+N-1)) if SIDE='R', where
117 * LLD_A >= max(1,LOCr(IA+K-1)); On entry, the i-th row must
118 * contain the vector which defines the elementary reflector
119 * H(i), IA <= i <= IA+K-1, as returned by PZGELQF in the
120 * K rows of its distributed matrix argument A(IA:IA+K-1,JA:*).
121 * A(IA:IA+K-1,JA:*) is modified by the routine but restored on
122 * exit.
123 *
124 * IA (global input) INTEGER
125 * The row index in the global array A indicating the first
126 * row of sub( A ).
127 *
128 * JA (global input) INTEGER
129 * The column index in the global array A indicating the
130 * first column of sub( A ).
131 *
132 * DESCA (global and local input) INTEGER array of dimension DLEN_.
133 * The array descriptor for the distributed matrix A.
134 *
135 * TAU (local input) COMPLEX*16, array, dimension LOCc(IA+K-1).
136 * This array contains the scalar factors TAU(i) of the
137 * elementary reflectors H(i) as returned by PZGELQF.
138 * TAU is tied to the distributed matrix A.
139 *
140 * C (local input/local output) COMPLEX*16 pointer into the
141 * local memory to an array of dimension (LLD_C,LOCc(JC+N-1)).
142 * On entry, the local pieces of the distributed matrix sub(C).
143 * On exit, sub( C ) is overwritten by Q*sub( C ) or Q'*sub( C )
144 * or sub( C )*Q' or sub( C )*Q.
145 *
146 * IC (global input) INTEGER
147 * The row index in the global array C indicating the first
148 * row of sub( C ).
149 *
150 * JC (global input) INTEGER
151 * The column index in the global array C indicating the
152 * first column of sub( C ).
153 *
154 * DESCC (global and local input) INTEGER array of dimension DLEN_.
155 * The array descriptor for the distributed matrix C.
156 *
157 * WORK (local workspace/local output) COMPLEX*16 array,
158 * dimension (LWORK)
159 * On exit, WORK(1) returns the minimal and optimal LWORK.
160 *
161 * LWORK (local or global input) INTEGER
162 * The dimension of the array WORK.
163 * LWORK is local input and must be at least
164 * If SIDE = 'L', LWORK >= MpC0 + MAX( MAX( 1, NqC0 ), NUMROC(
165 * NUMROC( M+IROFFC,MB_A,0,0,NPROW ),MB_A,0,0,LCMP ) );
166 * if SIDE = 'R', LWORK >= NqC0 + MAX( 1, MpC0 );
167 *
168 * where LCMP = LCM / NPROW with LCM = ICLM( NPROW, NPCOL ),
169 *
170 * IROFFC = MOD( IC-1, MB_C ), ICOFFC = MOD( JC-1, NB_C ),
171 * ICROW = INDXG2P( IC, MB_C, MYROW, RSRC_C, NPROW ),
172 * ICCOL = INDXG2P( JC, NB_C, MYCOL, CSRC_C, NPCOL ),
173 * MpC0 = NUMROC( M+IROFFC, MB_C, MYROW, ICROW, NPROW ),
174 * NqC0 = NUMROC( N+ICOFFC, NB_C, MYCOL, ICCOL, NPCOL ),
175 *
176 * ILCM, INDXG2P and NUMROC are ScaLAPACK tool functions;
177 * MYROW, MYCOL, NPROW and NPCOL can be determined by calling
178 * the subroutine BLACS_GRIDINFO.
179 *
180 * If LWORK = -1, then LWORK is global input and a workspace
181 * query is assumed; the routine only calculates the minimum
182 * and optimal size for all work arrays. Each of these
183 * values is returned in the first entry of the corresponding
184 * work array, and no error message is issued by PXERBLA.
185 *
186 *
187 * INFO (local output) INTEGER
188 * = 0: successful exit
189 * < 0: If the i-th argument is an array and the j-entry had
190 * an illegal value, then INFO = -(i*100+j), if the i-th
191 * argument is a scalar and had an illegal value, then
192 * INFO = -i.
193 *
194 * Alignment requirements
195 * ======================
196 *
197 * The distributed submatrices A(IA:*, JA:*) and C(IC:IC+M-1,JC:JC+N-1)
198 * must verify some alignment properties, namely the following
199 * expressions should be true:
200 *
201 * If SIDE = 'L',
202 * ( NB_A.EQ.MB_C .AND. ICOFFA.EQ.IROFFC )
203 * If SIDE = 'R',
204 * ( NB_A.EQ.NB_C .AND. ICOFFA.EQ.ICOFFC .AND. IACOL.EQ.ICCOL )
205 *
206 * =====================================================================
207 *
208 * .. Parameters ..
209  INTEGER BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
210  $ lld_, mb_, m_, nb_, n_, rsrc_
211  parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
212  $ ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
213  $ rsrc_ = 7, csrc_ = 8, lld_ = 9 )
214  COMPLEX*16 ONE
215  parameter( one = ( 1.0d+0, 0.0d+0 ) )
216 * ..
217 * .. Local Scalars ..
218  LOGICAL LEFT, LQUERY, NOTRAN
219  CHARACTER COLBTOP, ROWBTOP
220  INTEGER I, I1, I2, I3, IACOL, ICC, ICCOL, ICOFFA,
221  $ icoffc, icrow, ictxt, iroffc, jcc, lcm, lcmp,
222  $ lwmin, mi, mpc0, mycol, myrow, ni, npcol,
223  $ nprow, nq, nqc0
224  COMPLEX*16 AII
225 * ..
226 * .. External Subroutines ..
227  EXTERNAL blacs_abort, blacs_gridinfo, chk1mat,
228  $ pb_topget, pb_topset, pxerbla, pzelset,
229  $ pzelset2, pzlacgv, pzlarf, pzlarfc
230 * ..
231 * .. External Functions ..
232  LOGICAL LSAME
233  INTEGER ILCM, INDXG2P, NUMROC
234  EXTERNAL ilcm, indxg2p, lsame, numroc
235 * ..
236 * .. Intrinsic Functions ..
237  INTRINSIC dble, dcmplx, max, mod
238 * ..
239 * .. Executable Statements ..
240 *
241 * Get grid parameters
242 *
243  ictxt = desca( ctxt_ )
244  CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
245 *
246 * Test the input parameters
247 *
248  info = 0
249  IF( nprow.EQ.-1 ) THEN
250  info = -(900+ctxt_)
251  ELSE
252  left = lsame( side, 'L' )
253  notran = lsame( trans, 'N' )
254 *
255 * NQ is the order of Q
256 *
257  IF( left ) THEN
258  nq = m
259  CALL chk1mat( k, 5, m, 3, ia, ja, desca, 9, info )
260  ELSE
261  nq = n
262  CALL chk1mat( k, 5, n, 4, ia, ja, desca, 9, info )
263  END IF
264  CALL chk1mat( m, 3, n, 4, ic, jc, descc, 14, info )
265  IF( info.EQ.0 ) THEN
266  icoffa = mod( ja-1, desca( nb_ ) )
267  iroffc = mod( ic-1, descc( mb_ ) )
268  icoffc = mod( jc-1, descc( nb_ ) )
269  iacol = indxg2p( ja, desca( nb_ ), mycol, desca( csrc_ ),
270  $ npcol )
271  icrow = indxg2p( ic, descc( mb_ ), myrow, descc( rsrc_ ),
272  $ nprow )
273  iccol = indxg2p( jc, descc( nb_ ), mycol, descc( csrc_ ),
274  $ npcol )
275  mpc0 = numroc( m+iroffc, descc( mb_ ), myrow, icrow, nprow )
276  nqc0 = numroc( n+icoffc, descc( nb_ ), mycol, iccol, npcol )
277 *
278  IF( left ) THEN
279  lcm = ilcm( nprow, npcol )
280  lcmp = lcm / nprow
281  lwmin = mpc0 + max( max( 1, nqc0 ), numroc( numroc(
282  $ m+iroffc, desca( mb_ ), 0, 0, nprow ),
283  $ desca( mb_ ), 0, 0, lcmp ) )
284  ELSE
285  nqc0 = numroc( n+icoffc, descc( nb_ ), mycol, iccol,
286  $ npcol )
287  mpc0 = numroc( m+iroffc, descc( mb_ ), myrow, icrow,
288  $ nprow )
289  lwmin = nqc0 + max( 1, mpc0 )
290  END IF
291 *
292  work( 1 ) = dcmplx( dble( lwmin ) )
293  lquery = ( lwork.EQ.-1 )
294  IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
295  info = -1
296  ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'C' ) ) THEN
297  info = -2
298  ELSE IF( k.LT.0 .OR. k.GT.nq ) THEN
299  info = -5
300  ELSE IF( left .AND. desca( nb_ ).NE.descc( mb_ ) ) THEN
301  info = -(900+nb_)
302  ELSE IF( left .AND. icoffa.NE.iroffc ) THEN
303  info = -12
304  ELSE IF( .NOT.left .AND. icoffa.NE.icoffc ) THEN
305  info = -13
306  ELSE IF( .NOT.left .AND. iacol.NE.iccol ) THEN
307  info = -13
308  ELSE IF( .NOT.left .AND. desca( nb_ ).NE.descc( nb_ ) ) THEN
309  info = -(1400+nb_)
310  ELSE IF( ictxt.NE.descc( ctxt_ ) ) THEN
311  info = -(1400+ctxt_)
312  ELSE IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
313  info = -16
314  END IF
315  END IF
316  END IF
317 *
318  IF( info.NE.0 ) THEN
319  CALL pxerbla( ictxt, 'PZUNML2', -info )
320  CALL blacs_abort( ictxt, 1 )
321  RETURN
322  ELSE IF( lquery ) THEN
323  RETURN
324  END IF
325 *
326 * Quick return if possible
327 *
328  IF( m.EQ.0 .OR. n.EQ.0 .OR. k.EQ.0 )
329  $ RETURN
330 *
331  CALL pb_topget( ictxt, 'Broadcast', 'Rowwise', rowbtop )
332  CALL pb_topget( ictxt, 'Broadcast', 'Columnwise', colbtop )
333 *
334  IF( ( left .AND. notran .OR. .NOT.left .AND. .NOT.notran ) ) THEN
335  i1 = ia
336  i2 = ia + k - 1
337  i3 = 1
338  ELSE
339  i1 = ia + k -1
340  i2 = ia
341  i3 = -1
342  END IF
343 *
344  IF( left ) THEN
345  ni = n
346  jcc = jc
347  ELSE
348  mi = m
349  icc = ic
350  CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', ' ' )
351  IF( notran ) THEN
352  CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', 'D-ring' )
353  ELSE
354  CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', 'I-ring' )
355  END IF
356  END IF
357 *
358  DO 10 i = i1, i2, i3
359  IF( left ) THEN
360 *
361 * H(i) or H(i)' is applied to C(i:ic+m-1,jc:jc+n-1)
362 *
363  mi = m - i + ia
364  icc = ic + i - ia
365  ELSE
366 *
367 * H(i) or H(i)' is applied to C(ic:ic+m-1,jc+i-ia:jc+n-1)
368 *
369  ni = n - i + ia
370  jcc = jc + i - ia
371  END IF
372 *
373 * Apply H(i) or H(i)'
374 *
375  IF( i-ia+1.LT.nq )
376  $ CALL pzlacgv( nq-i+ia-1, a, i, ja+i-ia+1, desca,
377  $ desca( m_ ) )
378  CALL pzelset2( aii, a, i, ja+i-ia, desca, one )
379  IF( notran ) THEN
380  CALL pzlarfc( side, mi, ni, a, i, ja+i-ia, desca,
381  $ desca( m_ ), tau, c, icc, jcc, descc, work )
382  ELSE
383  CALL pzlarf( side, mi, ni, a, i, ja+i-ia, desca,
384  $ desca( m_ ), tau, c, icc, jcc, descc, work )
385  END IF
386  CALL pzelset( a, i, ja+i-ia, desca, aii )
387  IF( i-ia+1.LT.nq )
388  $ CALL pzlacgv( nq-i+ia-1, a, i, ja+i-ia+1, desca,
389  $ desca( m_ ) )
390 *
391  10 CONTINUE
392 *
393  CALL pb_topget( ictxt, 'Broadcast', 'Rowwise', rowbtop )
394  CALL pb_topget( ictxt, 'Broadcast', 'Columnwise', colbtop )
395 *
396  work( 1 ) = dcmplx( dble( lwmin ) )
397 *
398  RETURN
399 *
400 * End of PZUNML2
401 *
402  END
max
#define max(A, B)
Definition: pcgemr.c:180
pzlarf
subroutine pzlarf(SIDE, M, N, V, IV, JV, DESCV, INCV, TAU, C, IC, JC, DESCC, WORK)
Definition: pzlarf.f:3
pzlarfc
subroutine pzlarfc(SIDE, M, N, V, IV, JV, DESCV, INCV, TAU, C, IC, JC, DESCC, WORK)
Definition: pzlarfc.f:3
pzelset2
subroutine pzelset2(ALPHA, A, IA, JA, DESCA, BETA)
Definition: pzelset2.f:2
pzlacgv
subroutine pzlacgv(N, X, IX, JX, DESCX, INCX)
Definition: pzlacgv.f:2
pzunml2
subroutine pzunml2(SIDE, TRANS, M, N, K, A, IA, JA, DESCA, TAU, C, IC, JC, DESCC, WORK, LWORK, INFO)
Definition: pzunml2.f:3
chk1mat
subroutine chk1mat(MA, MAPOS0, NA, NAPOS0, IA, JA, DESCA, DESCAPOS0, INFO)
Definition: chk1mat.f:3
pzelset
subroutine pzelset(A, IA, JA, DESCA, ALPHA)
Definition: pzelset.f:2
pxerbla
subroutine pxerbla(ICTXT, SRNAME, INFO)
Definition: pxerbla.f:2