pcqrt17.f

Go to the documentation of this file.

      REAL             function pcqrt17( trans, iresid, m, n, nrhs, a,
     $                                   ia, ja, desca, x, ix, jx,
     $                                   descx, b, ib, jb, descb, work,
     $                                   rwork )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      CHARACTER          trans
      INTEGER            ia, ib, iresid, ix, ja, jb, jx, m, n, nrhs
*     ..
*     .. Array Arguments ..
      INTEGER            desca( * ), descb( * ), descx( * )
      COMPLEX            a( * ), b( * ), work( * ), x( * )
      REAL               rwork( * )
*     ..
*
*  Purpose
*  =======
*
*  PCQRT17 computes the ratio
*
*     || R'*op( sub( A ) ) ||/(||sub( A )||*alpha*max(M,N,NRHS)*eps)
*
*  where R = op( sub( A ) )*sub( X ) - B, op(A) is A or A', and
*
*     alpha = ||B|| if IRESID = 1 (zero-residual problem)
*     alpha = ||R|| if IRESID = 2 (otherwise).
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  TRANS   (global input) CHARACTER*1
*          Specifies whether or not the transpose of sub( A ) is used.
*          = 'N':  No transpose, op( sub( A ) ) = sub( A ).
*          = 'C':  Conjugate transpose, op( sub( A ) ) = sub( A' ).
*
*  IRESID  (global input) INTEGER
*          IRESID = 1 indicates zero-residual problem.
*          IRESID = 2 indicates non-zero residual.
*
*  M       (global input) INTEGER
*          The number of rows to be operated on, i.e. the number of rows
*          of the distributed submatrix sub( A ). M >= 0.
*          If TRANS = 'N', the number of rows of the distributed
*          submatrix sub( B ).
*          If TRANS = 'C', the number of rows of the distributed
*          submatrix sub( X ).
*
*  N       (global input) INTEGER
*          The number of columns to be operated on, i.e. the number of
*          columns of the distributed submatrix sub( A ). N >= 0.
*          If TRANS = 'N', the number of rows of the distributed
*          submatrix sub( X ). Otherwise N is the number of rows of
*          the distributed submatrix sub( B ).
*
*  NRHS    (global input) INTEGER
*          The number of right hand sides, i.e., the number of columns
*          of the distributed submatrices sub( X ) and sub( B ).
*          NRHS >= 0.
*
*  A       (local input) COMPLEX pointer into the local memory
*          to an array of dimension (LLD_A,LOCc(JA+N-1)). This array
*          contains the local pieces of the distributed M-by-N
*          submatrix sub( A ).
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  X       (local input) COMPLEX pointer into the local
*          memory to an array of dimension (LLD_X,LOCc(JX+NRHS-1)).
*          If TRANS = 'N', this array contains the local pieces of the
*          N-by-NRHS distributed submatrix sub( X ). Otherwise, this
*          array contains the local pieces of the M-by-NRHS distributed
*          submatrix sub( X ).
*
*  IX      (global input) INTEGER
*          The row index in the global array X indicating the first
*          row of sub( X ).
*
*  JX      (global input) INTEGER
*          The column index in the global array X indicating the
*          first column of sub( X ).
*
*  DESCX   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix X.
*
*  B       (local input) COMPLEX pointer into the local memory
*          to an array of dimension (LLD_B,LOCc(JB+NRHS-1)).
*          If TRANS='N', this array contains the local pieces of the
*          distributed M-by-NRHS submatrix operand sub( B ). Otherwise,
*          this array contains the local pieces of the distributed
*          N-by-NRHS submatrix operand sub( B ).
*
*  IB      (global input) INTEGER
*          The row index in the global array B indicating the first
*          row of sub( B ).
*
*  JB      (global input) INTEGER
*          The column index in the global array B indicating the
*          first column of sub( B ).
*
*  DESCB   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix B.
*
*  WORK    (local workspace) COMPLEX array, dimension (LWORK)
*          If TRANS = 'N', LWORK >= Mp0 * NRHSq0 + NRHSp0 * Nq0
*          otherwise       LWORK >= Np0 * NRHSq0 + NRHSp0 * Mq0
*
*  RWORK   (local workspace) REAL array, dimension (LRWORK)
*          LRWORK >= Nq0, if TRANS = 'N', and LRWORK >= Mp0 otherwise.
*
*          where
*
*          IROFFA = MOD( IA-1, MB_A ), ICOFFA = MOD( JA-1, NB_A ),
*          IAROW = INDXG2P( IA, MB_A, MYROW, RSRC_A, NPROW ),
*          IACOL = INDXG2P( JA, NB_A, MYCOL, CSRC_A, NPCOL ),
*          Mp0 = NUMROC( M+IROFFA, MB_A, MYROW, IAROW, NPROW ),
*          Np0 = NUMROC( N+ICOFFA, NB_A, MYROW, IAROW, NPROW ),
*          Mq0 = NUMROC( M+IROFFA, NB_A, MYCOL, IACOL, NPCOL ),
*          Nq0 = NUMROC( N+ICOFFA, NB_A, MYCOL, IACOL, NPCOL ),
*
*          IROFFB = MOD( IB-1, MB_B ), ICOFFB = MOD( JB-1, NB_B ),
*          IBROW = INDXG2P( IB, MB_B, MYROW, RSRC_B, NPROW ),
*          IBCOL = INDXG2P( JB, NB_B, MYCOL, CSRC_B, NPCOL ),
*          NRHSp0 = NUMROC( NRHS+ICOFFB, NB_B, MYROW, IBROW, NPROW ),
*          NRHSq0 = NUMROC( NRHS+ICOFFB, NB_B, MYCOL, IBCOL, NPCOL ).
*
*          INDXG2P and NUMROC are ScaLAPACK tool functions; MYROW,
*          MYCOL, NPROW and NPCOL can be determined by calling the
*          subroutine BLACS_GRIDINFO.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            block_cyclic_2d, csrc_, ctxt_, dlen_, dtype_,
     $                   lld_, mb_, m_, nb_, n_, rsrc_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      REAL               zero, one
      parameter( zero = 0.0e0, one = 1.0e0 )
*     ..
*     .. Local Scalars ..
      INTEGER            iacol, ibcol, ibrow, icoffb, ictxt, info,
     $                   ioffa, iroffb, iscl, iw, iw2, jw, jw2, mycol,
     $                   nrhsq, nrhsp, myrow, ncols, npcol, nprow,
     $                   nrows, nrowsp
      REAL               err, norma, normb, normrs, normx, smlnum
*     ..
*     .. Local Arrays ..
      INTEGER            descw( dlen_ ), descw2( dlen_ )
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      INTEGER            indxg2p, numroc
      REAL               pclange, pslamch
      EXTERNAL           indxg2p, lsame, numroc, pclange, pslamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, descset, pcgemm, pclacpy,
     $                   pclascl, pxerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, max, real
*     ..
*     .. Executable Statements ..
*
      pcqrt17 = zero
*
*     Get grid parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
      info = 0
      IF( lsame( trans, 'N' ) ) THEN
         nrows = m
         ncols = n
         ioffa = mod( ja-1, desca( nb_ ) )
      ELSE IF( lsame( trans, 'C' ) ) THEN
         nrows = n
         ncols = m
         ioffa = mod( ia-1, desca( mb_ ) )
      ELSE
         CALL pxerbla( ictxt, 'PCQRT17', -1 )
         RETURN
      END IF
*
      IF( m.LE.0 .OR. n.LE.0 .OR. nrhs.LE.0 )
     $   RETURN
*
      iroffb = mod( ia-1, desca( mb_ ) )
      icoffb = mod( ja-1, desca( nb_ ) )
      ibrow = indxg2p( ib, descb( mb_ ), myrow, descb( rsrc_ ),
     $                 nprow )
      iacol = indxg2p( ja, desca( nb_ ), mycol, desca( csrc_ ),
     $                 npcol )
      ibcol = indxg2p( jb, descb( nb_ ), mycol, descb( csrc_ ),
     $                 npcol )
*
      nrhsq = numroc( nrhs+icoffb, descb( nb_ ), mycol, ibcol, npcol )
      nrhsp = numroc( nrhs+iroffb, descb( nb_ ), myrow, ibrow, nprow )
      nrowsp = numroc( nrows+iroffb, desca( mb_ ), myrow, ibrow, nprow )
*
*     Assign array descriptor DESCW for workspace WORK, where DESCW
*     holds a copy of the distributed submatrix sub( B )
*
      CALL descset( descw, nrows+iroffb, nrhs+icoffb, descb( mb_ ),
     $              descb( nb_ ), ibrow, ibcol, ictxt, max( 1,
     $              nrowsp ) )
*
*     Assign array descriptor DESCW2 for workspace WORK, where DESCW2
*     holds a copy of the distributed submatrix sub( X**T )
*
      CALL descset( descw2, nrhs+icoffb, ncols+ioffa, descx( nb_ ),
     $              descx( mb_ ), ibrow, iacol, ictxt, max( 1,
     $              nrhsp ) )
*
      norma = pclange( 'One-norm', m, n, a, ia, ja, desca, rwork )
      smlnum = pslamch( ictxt, 'Safe minimum' )
      smlnum = smlnum / pslamch( ictxt, 'Precision' )
      iscl = 0
*
*     compute residual and scale it
*
      iw = 1 + iroffb
      jw = 1 + icoffb
      CALL pclacpy( 'All', nrows, nrhs, b, ib, jb, descb, work, iw, jw,
     $              descw )
      CALL pcgemm( trans, 'No transpose', nrows, nrhs, ncols,
     $             cmplx( -one ), a, ia, ja, desca, x, ix, jx, descx,
     $             cmplx( one ), work, iw, jw, descw )
      normrs = pclange( 'Max', nrows, nrhs, work, iw, jw, descw,
     $                  rwork )
      IF( normrs.GT.smlnum ) THEN
         iscl = 1
         CALL pclascl( 'General', normrs, one, nrows, nrhs, work,
     $                 iw, jw, descw, info )
      END IF
*
*     compute R'*sub( A )
*
      iw2 = 1 + icoffb
      jw2 = 1 + ioffa
      CALL pcgemm( 'Conjugate transpose', trans, nrhs, ncols, nrows,
     $             cmplx( one ), work, iw, jw, descw, a, ia, ja, desca,
     $             cmplx( zero ), work( nrowsp*nrhsq+1 ), iw2, jw2,
     $             descw2 )
*
*     compute and properly scale error
*
      err = pclange( 'One-norm', nrhs, ncols, work( nrowsp*nrhsq+1 ),
     $               iw2, jw2, descw2, rwork )
      IF( norma.NE.zero )
     $   err = err / norma
*
      IF( iscl.EQ.1 )
     $   err = err*normrs
*
      IF( iresid.EQ.1 ) THEN
         normb = pclange( 'One-norm', nrows, nrhs, b, ib, jb, descb,
     $                    rwork )
         IF( normb.NE.zero )
     $      err = err / normb
      ELSE
         normx = pclange( 'One-norm', ncols, nrhs, x, ix, jx, descx,
     $                    rwork )
         IF( normx.NE.zero )
     $      err = err / normx
      END IF
*
      pcqrt17 = err / ( pslamch( ictxt, 'Epsilon' ) *
     $                  real( max( m, n, nrhs ) ) )
*
      RETURN
*
*     End of PCQRT17
*
      END