pclange()

real function pclange	(	character	norm,
		integer	m,
		integer	n,
		complex, dimension( * )	a,
		integer	ia,
		integer	ja,
		integer, dimension( * )	desca,
		real, dimension( * )	work
	)

Definition at line 1 of file pclange.f.

      IMPLICIT NONE
*
*  -- ScaLAPACK auxiliary routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      CHARACTER          NORM
      INTEGER            IA, JA, M, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * )
      REAL               WORK( * )
      COMPLEX            A( * )
*     ..
*
*  Purpose
*  =======
*
*  PCLANGE returns the value of the one norm, or the Frobenius norm,
*  or the infinity norm, or the element of largest absolute value of a
*  distributed matrix sub( A ) = A(IA:IA+M-1, JA:JA+N-1).
*
*  PCLANGE returns the value
*
*     ( max(abs(A(i,j))),  NORM = 'M' or 'm' with IA <= i <= IA+M-1,
*     (                                      and  JA <= j <= JA+N-1,
*     (
*     ( norm1( sub( A ) ), NORM = '1', 'O' or 'o'
*     (
*     ( normI( sub( A ) ), NORM = 'I' or 'i'
*     (
*     ( normF( sub( A ) ), NORM = 'F', 'f', 'E' or 'e'
*
*  where norm1 denotes the  one norm of a matrix (maximum column sum),
*  normI denotes the  infinity norm  of a matrix  (maximum row sum) and
*  normF denotes the  Frobenius norm of a matrix (square root of sum of
*  squares).  Note that  max(abs(A(i,j)))  is not a  matrix norm.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  NORM    (global input) CHARACTER
*          Specifies the value to be returned in PCLANGE as described
*          above.
*
*  M       (global input) INTEGER
*          The number of rows to be operated on i.e the number of rows
*          of the distributed submatrix sub( A ). When M = 0, PCLANGE
*          is set to zero. M >= 0.
*
*  N       (global input) INTEGER
*          The number of columns to be operated on i.e the number of
*          columns of the distributed submatrix sub( A ). When N = 0,
*          PCLANGE is set to zero. N >= 0.
*
*  A       (local input) COMPLEX pointer into the local memory
*          to an array of dimension (LLD_A, LOCc(JA+N-1)) containing the
*          local pieces of the distributed matrix sub( A ).
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  WORK    (local workspace) REAL array dimension (LWORK)
*          LWORK >=   0 if NORM = 'M' or 'm' (not referenced),
*                   Nq0 if NORM = '1', 'O' or 'o',
*                   Mp0 if NORM = 'I' or 'i',
*                     0 if NORM = 'F', 'f', 'E' or 'e' (not referenced),
*          where
*
*          IROFFA = MOD( IA-1, MB_A ), ICOFFA = MOD( JA-1, NB_A ),
*          IAROW = INDXG2P( IA, MB_A, MYROW, RSRC_A, NPROW ),
*          IACOL = INDXG2P( JA, NB_A, MYCOL, CSRC_A, NPCOL ),
*          Mp0 = NUMROC( M+IROFFA, MB_A, MYROW, IAROW, NPROW ),
*          Nq0 = NUMROC( N+ICOFFA, NB_A, MYCOL, IACOL, NPCOL ),
*
*          INDXG2P and NUMROC are ScaLAPACK tool functions; MYROW,
*          MYCOL, NPROW and NPCOL can be determined by calling the
*          subroutine BLACS_GRIDINFO.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      REAL               ONE, ZERO
      parameter( one = 1.0e+0, zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IACOL, IAROW, ICTXT, II, ICOFF, IOFFA,
     $                   IROFF, J, JJ, LDA, MP, MYCOL, MYROW, NPCOL,
     $                   NPROW, NQ
      REAL               SUM, VALUE
*     ..
*     .. Local Arrays ..
      REAL               SSQ( 2 ), COLSSQ( 2 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, classq, infog2l, scombssq,
     $                   sgebr2d, sgebs2d, sgamx2d, sgsum2d,
     $                   pstreecomb
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ISAMAX, NUMROC
      EXTERNAL           lsame, isamax, numroc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min, mod, sqrt
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters.
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
      CALL infog2l( ia, ja, desca, nprow, npcol, myrow, mycol, ii, jj,
     $              iarow, iacol )
      iroff = mod( ia-1, desca( mb_ ) )
      icoff = mod( ja-1, desca( nb_ ) )
      mp = numroc( m+iroff, desca( mb_ ), myrow, iarow, nprow )
      nq = numroc( n+icoff, desca( nb_ ), mycol, iacol, npcol )
      IF( myrow.EQ.iarow )
     $   mp = mp - iroff
      IF( mycol.EQ.iacol )
     $   nq = nq - icoff
      lda = desca( lld_ )
*
      IF( min( m, n ).EQ.0 ) THEN
*
         VALUE = zero
*
************************************************************************
* max norm
*
      ELSE IF( lsame( norm, 'M' ) ) THEN
*
*        Find max(abs(A(i,j))).
*
         VALUE = zero
         IF( nq.GT.0 .AND. mp.GT.0 ) THEN
            ioffa = (jj-1)*lda
            DO 20 j = jj, jj+nq-1
               DO 10 i = ii, mp+ii-1
                  VALUE = max( VALUE, abs( a( ioffa+i ) ) )
   10          CONTINUE
               ioffa = ioffa + lda
   20       CONTINUE
         END IF
         CALL sgamx2d( ictxt, 'All', ' ', 1, 1, VALUE, 1, i, j, -1,
     $                 0, 0 )
*
************************************************************************
* one norm
*
      ELSE IF( lsame( norm, 'O' ) .OR. norm.EQ.'1' ) THEN
*
*        Find norm1( sub( A ) ).
*
         IF( nq.GT.0 ) THEN
            ioffa = ( jj - 1 ) * lda
            DO 40 j = jj, jj+nq-1
               sum = zero
               IF( mp.GT.0 ) THEN
                  DO 30 i = ii, mp+ii-1
                     sum = sum + abs( a( ioffa+i ) )
   30             CONTINUE
               END IF
               ioffa = ioffa + lda
               work( j-jj+1 ) = sum
   40       CONTINUE
         END IF
*
*        Find sum of global matrix columns and store on row 0 of
*        process grid
*
         CALL sgsum2d( ictxt, 'Columnwise', ' ', 1, nq, work, 1,
     $                 0, mycol )
*
*        Find maximum sum of columns for 1-norm
*
         IF( myrow.EQ.0 ) THEN
            IF( nq.GT.0 ) THEN
               VALUE = work( isamax( nq, work, 1 ) )
            ELSE
               VALUE = zero
            END IF
            CALL sgamx2d( ictxt, 'Rowwise', ' ', 1, 1, VALUE, 1, i, j,
     $                    -1, 0, 0 )
         END IF
*
************************************************************************
* inf norm
*
      ELSE IF( lsame( norm, 'I' ) ) THEN
*
*        Find normI( sub( A ) ).
*
         IF( mp.GT.0 ) THEN
            ioffa = ii + ( jj - 1 ) * lda
            DO 60 i = ii, ii+mp-1
               sum = zero
               IF( nq.GT.0 ) THEN
                  DO 50 j = ioffa, ioffa + nq*lda - 1, lda
                     sum = sum + abs( a( j ) )
   50             CONTINUE
               END IF
               work( i-ii+1 ) = sum
               ioffa = ioffa + 1
   60       CONTINUE
         END IF
*
*        Find sum of global matrix rows and store on column 0 of
*        process grid
*
         CALL sgsum2d( ictxt, 'Rowwise', ' ', mp, 1, work, max( 1, mp ),
     $                 myrow, 0 )
*
*        Find maximum sum of rows for supnorm
*
         IF( mycol.EQ.0 ) THEN
            IF( mp.GT.0 ) THEN
               VALUE = work( isamax( mp, work, 1 ) )
            ELSE
               VALUE = zero
            END IF
            CALL sgamx2d( ictxt, 'Columnwise', ' ', 1, 1, VALUE, 1, i,
     $                    j, -1, 0, 0 )
         END IF
*
************************************************************************
* Frobenius norm
* SSQ(1) is scale
* SSQ(2) is sum-of-squares
*
      ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
*
*        Find normF( sub( A ) ).
*
         ssq(1) = zero
         ssq(2) = one
         ioffa = ii + ( jj - 1 ) * lda
         IF( nq.GT.0 ) THEN
             DO 70 j = ioffa, ioffa + nq*lda - 1, lda
                colssq(1) = zero
                colssq(2) = one
                CALL classq( mp, a( j ), 1, colssq(1), colssq(2) )
                CALL scombssq( ssq, colssq )
   70        CONTINUE
         END IF
*
*        Perform the global scaled sum
*
         CALL pstreecomb( ictxt, 'All', 2, ssq, 0, 0, scombssq )
         VALUE = ssq( 1 ) * sqrt( ssq( 2 ) )
*
      END IF
*
      IF( myrow.EQ.0 .AND. mycol.EQ.0 ) THEN
         CALL sgebs2d( ictxt, 'All', ' ', 1, 1, VALUE, 1 )
      ELSE
         CALL sgebr2d( ictxt, 'All', ' ', 1, 1, VALUE, 1, 0, 0 )
      END IF
*
      pclange = VALUE
*
      RETURN
*
*     End of PCLANGE
*

Here is the call graph for this function:

Here is the caller graph for this function: