pclacon.f

Go to the documentation of this file.

      SUBROUTINE pclacon( N, V, IV, JV, DESCV, X, IX, JX, DESCX, EST,
     $                    KASE )
*
*  -- ScaLAPACK auxiliary routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      INTEGER            IV, IX, JV, JX, KASE, N
      REAL               EST
*     ..
*     .. Array Arguments ..
      INTEGER            DESCV( * ), DESCX( * )
      COMPLEX            V( * ), X( * )
*     ..
*
*  Purpose
*  =======
*
*  PCLACON estimates the 1-norm of a square, complex distributed matrix
*  A. Reverse communication is used for evaluating matrix-vector
*  products. X and V are aligned with the distributed matrix A, this
*  information is implicitly contained within IV, IX, DESCV, and DESCX.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  N       (global input) INTEGER
*          The length of the distributed vectors V and X.  N >= 0.
*
*  V       (local workspace) COMPLEX pointer into the local
*          memory to an array of dimension LOCr(N+MOD(IV-1,MB_V)). On
*          the final return, V = A*W, where EST = norm(V)/norm(W)
*          (W is not returned).
*
*  IV      (global input) INTEGER
*          The row index in the global array V indicating the first
*          row of sub( V ).
*
*  JV      (global input) INTEGER
*          The column index in the global array V indicating the
*          first column of sub( V ).
*
*  DESCV   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix V.
*
*  X       (local input/local output) COMPLEX pointer into the
*          local memory to an array of dimension
*          LOCr(N+MOD(IX-1,MB_X)). On an intermediate return, X
*          should be overwritten by
*                A * X,   if KASE=1,
*                A' * X,  if KASE=2,
*          where A' is the conjugate transpose of A, and PCLACON must
*          be re-called with all the other parameters unchanged.
*
*  IX      (global input) INTEGER
*          The row index in the global array X indicating the first
*          row of sub( X ).
*
*  JX      (global input) INTEGER
*          The column index in the global array X indicating the
*          first column of sub( X ).
*
*  DESCX   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix X.
*
*
*  EST     (global output) REAL
*          An estimate (a lower bound) for norm(A).
*
*  KASE    (local input/local output) INTEGER
*          On the initial call to PCLACON, KASE should be 0.
*          On an intermediate return, KASE will be 1 or 2, indicating
*          whether X should be overwritten by A * X  or A' * X.
*          On the final return from PCLACON, KASE will again be 0.
*
*  Further Details
*  ===============
*
*  The serial version CLACON has been contributed by Nick Higham,
*  University of Manchester. It was originally named SONEST, dated
*  March 16, 1988.
*
*  Reference: N.J. Higham, "FORTRAN codes for estimating the one-norm of
*  a real or complex matrix, with applications to condition estimation",
*  ACM Trans. Math. Soft., vol. 14, no. 4, pp. 381-396, December 1988.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   lld_, mb_, m_, nb_, n_, rsrc_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      INTEGER            ITMAX
      parameter( itmax = 5 )
      REAL               ONE, TWO
      parameter( one = 1.0e+0, two = 2.0e+0 )
      COMPLEX            CZERO, CONE
      parameter( czero = ( 0.0e+0, 0.0e+0 ),
     $                   cone = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            I, ICTXT, IIVX, IMAXROW, IOFFVX, IROFF, ITER,
     $                   ivxcol, ivxrow, j, jlast, jjvx, jump, k,
     $                   mycol, myrow, np, npcol, nprow
      REAL               ALTSGN, ESTOLD, SAFMIN, TEMP
      COMPLEX            JLMAX, XMAX
*     ..
*     .. Local Arrays ..
      COMPLEX            WORK( 2 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, ccopy, cgebr2d, cgebs2d,
     $                   infog2l, pcelget, pcmax1,
     $                   pscsum1, sgebr2d, sgebs2d
*     ..
*     .. External Functions ..
      INTEGER            INDXG2L, INDXG2P, INDXL2G, NUMROC
      REAL               PSLAMCH
      EXTERNAL           indxg2l, indxg2p, indxl2g, numroc, pslamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, cmplx, real
*     ..
*     .. Save statement ..
      SAVE
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters.
*
      ictxt = descx( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
      CALL infog2l( ix, jx, descx, nprow, npcol, myrow, mycol,
     $              iivx, jjvx, ivxrow, ivxcol )
      IF( mycol.NE.ivxcol )
     $   RETURN
      iroff = mod( ix-1, descx( mb_ ) )
      np = numroc( n+iroff, descx( mb_ ), myrow, ivxrow, nprow )
      IF( myrow.EQ.ivxrow )
     $   np = np - iroff
      ioffvx = iivx + (jjvx-1)*descx( lld_ )
*
      safmin = pslamch( ictxt, 'Safe minimum' )
      IF( kase.EQ.0 ) THEN
         DO 10 i = ioffvx, ioffvx+np-1
            x( i ) = cmplx( one / real( n ) )
   10    CONTINUE
         kase = 1
         jump = 1
         RETURN
      END IF
*
      GO TO ( 20, 40, 70, 90, 120 )jump
*
*     ................ ENTRY   (JUMP = 1)
*     FIRST ITERATION.  X HAS BEEN OVERWRITTEN BY A*X
*
   20 CONTINUE
      IF( n.EQ.1 ) THEN
         IF( myrow.EQ.ivxrow ) THEN
            v( ioffvx ) = x( ioffvx )
            est = abs( v( ioffvx ) )
            CALL sgebs2d( ictxt, 'Columnwise', ' ', 1, 1, est, 1 )
         ELSE
            CALL sgebr2d( ictxt, 'Columnwise', ' ', 1, 1, est, 1,
     $                    ivxrow, mycol )
         END IF
*        ... QUIT
         GO TO 130
      END IF
      CALL pscsum1( n, est, x, ix, jx, descx, 1 )
      IF( descx( m_ ).EQ.1 .AND. n.EQ.1 ) THEN
         IF( myrow.EQ.ivxrow ) THEN
            CALL sgebs2d( ictxt, 'Columnwise', ' ', 1, 1, est, 1 )
         ELSE
            CALL sgebr2d( ictxt, 'Columnwise', ' ', 1, 1, est, 1,
     $                    ivxrow, mycol )
         END IF
      END IF
*
      DO 30 i = ioffvx, ioffvx+np-1
         IF( abs( x( i ) ).GT.safmin ) THEN
            x( i ) = x( i ) / cmplx( abs( x( i ) ) )
         ELSE
            x( i ) = cone
         END IF
   30 CONTINUE
      kase = 2
      jump = 2
      RETURN
*
*     ................ ENTRY   (JUMP = 2)
*     FIRST ITERATION.  X HAS BEEN OVERWRITTEN BY CTRANS(A)*X
*
   40 CONTINUE
      CALL pcmax1( n, xmax, j, x, ix, jx, descx, 1 )
      IF( descx( m_ ).EQ.1 .AND. n.EQ.1 ) THEN
         IF( myrow.EQ.ivxrow ) THEN
            work( 1 ) = xmax
            work( 2 ) = cmplx( real( j ) )
            CALL cgebs2d( ictxt, 'Columnwise', ' ', 2, 1, work, 2 )
         ELSE
            CALL cgebr2d( ictxt, 'Columnwise', ' ', 2, 1, work, 2,
     $                    ivxrow, mycol )
            xmax = work( 1 )
            j = nint( real( work( 2 ) ) )
         END IF
      END IF
      iter = 2
*
*     MAIN LOOP - ITERATIONS 2, 3,...,ITMAX
*
   50 CONTINUE
      DO 60 i = ioffvx, ioffvx+np-1
         x( i ) = czero
   60 CONTINUE
      imaxrow = indxg2p( j, descx( mb_ ), myrow, descx( rsrc_ ), nprow )
      IF( myrow.EQ.imaxrow ) THEN
         i = indxg2l( j, descx( mb_ ), myrow, descx( rsrc_ ), nprow )
         x( i ) = cone
      END IF
      kase = 1
      jump = 3
      RETURN
*
*     ................ ENTRY   (JUMP = 3)
*     X HAS BEEN OVERWRITTEN BY A*X
*
   70 CONTINUE
      CALL ccopy( np, x( ioffvx ), 1, v( ioffvx ), 1 )
      estold = est
      CALL pscsum1( n, est, v, iv, jv, descv, 1 )
      IF( descv( m_ ).EQ.1 .AND. n.EQ.1 ) THEN
         IF( myrow.EQ.ivxrow ) THEN
            CALL sgebs2d( ictxt, 'Columnwise', ' ', 1, 1, est, 1 )
         ELSE
            CALL sgebr2d( ictxt, 'Columnwise', ' ', 1, 1, est, 1,
     $                    ivxrow, mycol )
         END IF
      END IF
*
*     TEST FOR CYCLING
      IF( est.LE.estold )
     $   GO TO 100
*
      DO 80 i = ioffvx, ioffvx+np-1
         IF( abs( x( i ) ).GT.safmin ) THEN
            x( i ) = x( i ) / cmplx( abs( x( i ) ) )
         ELSE
            x( i ) = cone
         END IF
   80 CONTINUE
      kase = 2
      jump = 4
      RETURN
*
*     ................ ENTRY   (JUMP = 4)
*     X HAS BEEN OVERWRITTEN BY CTRANS(A)*X
*
   90 CONTINUE
      jlast = j
      CALL pcmax1( n, xmax, j, x, ix, jx, descx, 1 )
      IF( descx( m_ ).EQ.1 .AND. n.EQ.1 ) THEN
         IF( myrow.EQ.ivxrow ) THEN
            work( 1 ) = xmax
            work( 2 ) = cmplx( real( j ) )
            CALL cgebs2d( ictxt, 'Columnwise', ' ', 2, 1, work, 2 )
         ELSE
            CALL cgebr2d( ictxt, 'Columnwise', ' ', 2, 1, work, 2,
     $                    ivxrow, mycol )
            xmax = work( 1 )
            j = nint( real( work( 2 ) ) )
         END IF
      END IF
      CALL pcelget( 'Columnwise', ' ', jlmax, x, jlast, jx, descx )
      IF( ( real( jlmax ).NE.abs( real( xmax ) ) ).AND.
     $    ( iter.LT.itmax                        ) ) THEN
         iter = iter + 1
         GO TO 50
      END IF
*
*     ITERATION COMPLETE.  FINAL STAGE.
*
  100 CONTINUE
      DO 110 i = ioffvx, ioffvx+np-1
         k = indxl2g( i-ioffvx+iivx, descx( mb_ ), myrow,
     $                descx( rsrc_ ), nprow )-ix+1
         IF( mod( k, 2 ).EQ.0 ) THEN
            altsgn = -one
         ELSE
            altsgn = one
         END IF
         x( i ) = cmplx( altsgn*( one+real( k-1 ) / real( n-1 ) ) )
  110 CONTINUE
      kase = 1
      jump = 5
      RETURN
*
*     ................ ENTRY   (JUMP = 5)
*     X HAS BEEN OVERWRITTEN BY A*X
*
  120 CONTINUE
      CALL pscsum1( n, temp, x, ix, jx, descx, 1 )
      IF( descx( m_ ).EQ.1 .AND. n.EQ.1 ) THEN
         IF( myrow.EQ.ivxrow ) THEN
            CALL sgebs2d( ictxt, 'Columnwise', ' ', 1, 1, temp, 1 )
         ELSE
            CALL sgebr2d( ictxt, 'Columnwise', ' ', 1, 1, temp, 1,
     $                    ivxrow, mycol )
         END IF
      END IF
      temp = two*( temp / real( 3*n ) )
      IF( temp.GT.est ) THEN
         CALL ccopy( np, x( ioffvx ), 1, v( ioffvx ), 1 )
         est = temp
      END IF
*
  130 CONTINUE
      kase = 0
*
      RETURN
*
*     End of PCLACON
*
      END