pcmax1.f

Go to the documentation of this file.

      SUBROUTINE pcmax1( N, AMAX, INDX, X, IX, JX, DESCX, INCX )
*
*  -- ScaLAPACK auxiliary routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 25, 2001
*
*     .. Scalar Arguments ..
      INTEGER            INDX, INCX, IX, JX, N
      COMPLEX            AMAX
*     ..
*     .. Array Arguments ..
      INTEGER            DESCX( * )
      COMPLEX            X( * )
*     ..
*
*  Purpose
*  =======
*
*  PCMAX1 computes the global index of the maximum element in absolute
*  value of a distributed vector sub( X ). The global index is returned
*  in INDX and the value is returned in AMAX,
*
*  where sub( X ) denotes X(IX:IX+N-1,JX) if INCX = 1,
*                         X(IX,JX:JX+N-1) if INCX = M_X.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Because vectors may be viewed as a subclass of matrices, a
*  distributed vector is considered to be a distributed matrix.
*
*  When the result of a vector-oriented PBLAS call is a scalar, it will
*  be made available only within the scope which owns the vector(s)
*  being operated on.  Let X be a generic term for the input vector(s).
*  Then, the processes which receive the answer will be (note that if
*  an operation involves more than one vector, the processes which re-
*  ceive the result will be the union of the following calculation for
*  each vector):
*
*  If N = 1, M_X = 1 and INCX = 1, then one can't determine if a process
*  row or process column owns the vector operand, therefore only the
*  process of coordinate {RSRC_X, CSRC_X} receives the result;
*
*  If INCX = M_X, then sub( X ) is a vector distributed over a process
*  row. Each process part of this row receives the result;
*
*  If INCX = 1, then sub( X ) is a vector distributed over a process
*  column. Each process part of this column receives the result;
*
*  Based on PCAMAX from Level 1 PBLAS. The change is to use the
*  'genuine' absolute value.
*
*  The serial version was contributed to LAPACK by Nick Higham for use
*  with CLACON.
*
*  Arguments
*  =========
*
*  N       (global input) pointer to INTEGER
*          The number of components of the distributed vector sub( X ).
*          N >= 0.
*
*  AMAX    (global output) pointer to REAL
*          The absolute value of the largest entry of the distributed
*          vector sub( X ) only in the scope of sub( X ).
*
*  INDX    (global output) pointer to INTEGER
*          The global index of the element of the distributed vector
*          sub( X ) whose real part has maximum absolute value.
*
*  X       (local input) COMPLEX array containing the local
*          pieces of a distributed matrix of dimension of at least
*              ( (JX-1)*M_X + IX + ( N - 1 )*abs( INCX ) )
*          This array contains the entries of the distributed vector
*          sub( X ).
*
*  IX      (global input) INTEGER
*          The row index in the global array X indicating the first
*          row of sub( X ).
*
*  JX      (global input) INTEGER
*          The column index in the global array X indicating the
*          first column of sub( X ).
*
*  DESCX   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix X.
*
*  INCX    (global input) INTEGER
*          The global increment for the elements of X. Only two values
*          of INCX are supported in this version, namely 1 and M_X.
*          INCX must not be zero.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      COMPLEX            ZERO
      parameter( zero = ( 0.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      CHARACTER          CBTOP, CCTOP, RBTOP, RCTOP
      INTEGER            ICOFF, ICTXT, IDUMM, IIX, IROFF, IXCOL, IXROW,
     $                   JJX, LCINDX, LDX, MAXPOS, MYCOL, MYROW, NP,
     $                   NPCOL, NPROW, NQ
*     ..
*     .. Local Arrays ..
      COMPLEX            WORK( 2 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, ccombamax1, cgamx2d,
     $                   igebr2d, igebs2d, infog2l, pctreecomb,
     $                   pb_topget
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ICMAX1, INDXL2G, NUMROC
      EXTERNAL           icmax1, indxl2g, numroc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, cmplx, mod, nint, real
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters
*
      ictxt = descx( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Quick return if possible.
*
      indx = 0
      amax = zero
      IF( n.LE.0 )
     $   RETURN
*
*     Retrieve local information for vector X.
*
      ldx = descx( lld_ )
      CALL infog2l( ix, jx, descx, nprow, npcol, myrow, mycol, iix, jjx,
     $              ixrow, ixcol )
*
      IF( incx.EQ.1 .AND. descx( m_ ).EQ.1 .AND. n.EQ.1 ) THEN
         indx = jx
         amax = x( iix+(jjx-1)*ldx )
         RETURN
      END IF
*
*     Find the maximum value and its index
*
      IF( incx.EQ.descx( m_ ) ) THEN
*
         IF( myrow.EQ.ixrow ) THEN
*
            icoff = mod( jx-1, descx( nb_ ) )
            nq = numroc( n+icoff, descx( nb_ ), mycol, ixcol, npcol )
            IF( mycol.EQ.ixcol )
     $         nq = nq-icoff
*
            CALL pb_topget( ictxt, 'Broadcast', 'Rowwise', rbtop )
*
            IF( lsame( rbtop, ' ' ) ) THEN
*
               IF( nq.GT.0 ) THEN
                  lcindx = jjx-1+icmax1( nq, x( iix+(jjx-1)*ldx ), ldx )
                  work( 1 ) = x( iix+(lcindx-1)*ldx )
                  work( 2 ) = cmplx( real( indxl2g( lcindx,
     $              descx( nb_ ), mycol, descx( csrc_ ), npcol ) ) )
               ELSE
                  work( 1 ) = zero
                  work( 2 ) = zero
               END IF
*
               CALL pctreecomb( ictxt, 'Row', 2, work, -1, mycol,
     $                          ccombamax1 )
*
               amax = work( 1 )
               IF( amax.EQ.zero ) THEN
                  indx = jx
               ELSE
                  indx = nint( real( work( 2 ) ) )
               END IF
*
            ELSE
*
               CALL pb_topget( ictxt, 'Combine', 'Rowwise', rctop )
*
               IF( nq.GT.0 ) THEN
                  lcindx = jjx-1+icmax1( nq, x( iix+(jjx-1)*ldx ), ldx )
                  amax = x( iix + (lcindx-1)*ldx )
               ELSE
                  amax = zero
               END IF
*
*              Find the maximum value
*
               CALL cgamx2d( ictxt, 'Rowwise', rctop, 1, 1, amax, 1,
     $                       idumm, maxpos, 1, -1, myrow )
*
               IF( amax.NE.zero ) THEN
*
*                 Broadcast corresponding global index
*
                  IF( mycol.EQ.maxpos ) THEN
                     indx = indxl2g( lcindx, descx( nb_ ), mycol,
     $                               descx( csrc_ ), npcol )
                     CALL igebs2d( ictxt, 'Rowwise', rbtop, 1, 1, indx,
     $                             1 )
                  ELSE
                     CALL igebr2d( ictxt, 'Rowwise', rbtop, 1, 1, indx,
     $                             1, myrow, maxpos )
                  END IF
*
               ELSE
*
                  indx = jx
*
               END IF
*
            END IF
*
         END IF
*
      ELSE
*
         IF( mycol.EQ.ixcol ) THEN
*
            iroff = mod( ix-1, descx( mb_ ) )
            np = numroc( n+iroff, descx( mb_ ), myrow, ixrow, nprow )
            IF( myrow.EQ.ixrow )
     $         np = np-iroff
*
            CALL pb_topget( ictxt, 'Broadcast', 'Columnwise', cbtop )
*
            IF( lsame( cbtop, ' ' ) ) THEN
*
               IF( np.GT.0 ) THEN
                  lcindx = iix-1+icmax1( np, x( iix+(jjx-1)*ldx ), 1 )
                  work( 1 ) = x( lcindx + (jjx-1)*ldx )
                  work( 2 ) = cmplx( real( indxl2g( lcindx,
     $              descx( mb_ ), myrow, descx( rsrc_ ), nprow ) ) )
               ELSE
                  work( 1 ) = zero
                  work( 2 ) = zero
               END IF
*
               CALL pctreecomb( ictxt, 'Column', 2, work, -1, mycol,
     $                          ccombamax1 )
*
               amax = work( 1 )
               IF( amax.EQ.zero ) THEN
                  indx = ix
               ELSE
                  indx = nint( real( work( 2 ) ) )
               END IF
*
            ELSE
*
               CALL pb_topget( ictxt, 'Combine', 'Columnwise', cctop )
*
               IF( np.GT.0 ) THEN
                  lcindx = iix-1+icmax1( np, x( iix+(jjx-1)*ldx ), 1 )
                  amax = x( lcindx + (jjx-1)*ldx )
               ELSE
                  amax = zero
               END IF
*
*              Find the maximum value
*
               CALL cgamx2d( ictxt, 'Columnwise', cctop, 1, 1, amax, 1,
     $                       maxpos, idumm, 1, -1, mycol )
*
               IF( amax.NE.zero ) THEN
*
*                 Broadcast corresponding global index
*
                  IF( myrow.EQ.maxpos ) THEN
                     indx = indxl2g( lcindx, descx( mb_ ), myrow,
     $                               descx( rsrc_ ), nprow )
                     CALL igebs2d( ictxt, 'Columnwise', cbtop, 1, 1,
     $                             indx, 1 )
                  ELSE
                     CALL igebr2d( ictxt, 'Columnwise', cbtop, 1, 1,
     $                             indx, 1, maxpos, mycol )
                  END IF
*
               ELSE
*
                  indx = ix
*
               END IF
*
            END IF
*
         END IF
*
      END IF
*
      RETURN
*
*     End of PCMAX1
*
      END
*
      SUBROUTINE ccombamax1 ( V1, V2 )
*
*  -- ScaLAPACK auxiliary routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Array Arguments ..
      COMPLEX            V1( 2 ), V2( 2 )
*     ..
*
*  Purpose
*  =======
*
*  CCOMBAMAX1 finds the element having maximum real part absolute
*  value as well as its corresponding globl index.
*
*  Arguments
*  =========
*
*  V1        (local input/local output) COMPLEX array of
*            dimension 2.  The first maximum absolute value element and
*            its global index. V1(1) = AMAX, V1(2) = INDX.
*
*  V2        (local input) COMPLEX array of dimension 2.
*            The second maximum absolute value element and its global
*            index. V2(1) = AMAX, V2(2) = INDX.
*
*  =====================================================================
*
*     .. Intrinsic Functions ..
      INTRINSIC          abs, real
*     ..
*     .. Executable Statements ..
*
      IF( abs( real( v1( 1 ) ) ).LT.abs( real( v2( 1 ) ) ) ) THEN
         v1( 1 ) = v2( 1 )
         v1( 2 ) = v2( 2 )
      END IF
*
      RETURN
*
*     End of CCOMBAMAX1
*
      END