LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ cunbdb1()

subroutine cunbdb1 ( integer m,
integer p,
integer q,
complex, dimension(ldx11,*) x11,
integer ldx11,
complex, dimension(ldx21,*) x21,
integer ldx21,
real, dimension(*) theta,
real, dimension(*) phi,
complex, dimension(*) taup1,
complex, dimension(*) taup2,
complex, dimension(*) tauq1,
complex, dimension(*) work,
integer lwork,
integer info )

CUNBDB1

Download CUNBDB1 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!> CUNBDB1 simultaneously bidiagonalizes the blocks of a tall and skinny
!> matrix X with orthonormal columns:
!>
!>                            [ B11 ]
!>      [ X11 ]   [ P1 |    ] [  0  ]
!>      [-----] = [---------] [-----] Q1**T .
!>      [ X21 ]   [    | P2 ] [ B21 ]
!>                            [  0  ]
!>
!> X11 is P-by-Q, and X21 is (M-P)-by-Q. Q must be no larger than P,
!> M-P, or M-Q. Routines CUNBDB2, CUNBDB3, and CUNBDB4 handle cases in
!> which Q is not the minimum dimension.
!>
!> The unitary matrices P1, P2, and Q1 are P-by-P, (M-P)-by-(M-P),
!> and (M-Q)-by-(M-Q), respectively. They are represented implicitly by
!> Householder vectors.
!>
!> B11 and B12 are Q-by-Q bidiagonal matrices represented implicitly by
!> angles THETA, PHI.
!>
!>
Parameters
[in]M
!>          M is INTEGER
!>           The number of rows X11 plus the number of rows in X21.
!>
[in]P
!>          P is INTEGER
!>           The number of rows in X11. 0 <= P <= M.
!>
[in]Q
!>          Q is INTEGER
!>           The number of columns in X11 and X21. 0 <= Q <=
!>           MIN(P,M-P,M-Q).
!>
[in,out]X11
!>          X11 is COMPLEX array, dimension (LDX11,Q)
!>           On entry, the top block of the matrix X to be reduced. On
!>           exit, the columns of tril(X11) specify reflectors for P1 and
!>           the rows of triu(X11,1) specify reflectors for Q1.
!>
[in]LDX11
!>          LDX11 is INTEGER
!>           The leading dimension of X11. LDX11 >= P.
!>
[in,out]X21
!>          X21 is COMPLEX array, dimension (LDX21,Q)
!>           On entry, the bottom block of the matrix X to be reduced. On
!>           exit, the columns of tril(X21) specify reflectors for P2.
!>
[in]LDX21
!>          LDX21 is INTEGER
!>           The leading dimension of X21. LDX21 >= M-P.
!>
[out]THETA
!>          THETA is REAL array, dimension (Q)
!>           The entries of the bidiagonal blocks B11, B21 are defined by
!>           THETA and PHI. See Further Details.
!>
[out]PHI
!>          PHI is REAL array, dimension (Q-1)
!>           The entries of the bidiagonal blocks B11, B21 are defined by
!>           THETA and PHI. See Further Details.
!>
[out]TAUP1
!>          TAUP1 is COMPLEX array, dimension (P)
!>           The scalar factors of the elementary reflectors that define
!>           P1.
!>
[out]TAUP2
!>          TAUP2 is COMPLEX array, dimension (M-P)
!>           The scalar factors of the elementary reflectors that define
!>           P2.
!>
[out]TAUQ1
!>          TAUQ1 is COMPLEX array, dimension (Q)
!>           The scalar factors of the elementary reflectors that define
!>           Q1.
!>
[out]WORK
!>          WORK is COMPLEX array, dimension (LWORK)
!>
[in]LWORK
!>          LWORK is INTEGER
!>           The dimension of the array WORK. LWORK >= M-Q.
!>
!>           If LWORK = -1, then a workspace query is assumed; the routine
!>           only calculates the optimal size of the WORK array, returns
!>           this value as the first entry of the WORK array, and no error
!>           message related to LWORK is issued by XERBLA.
!>
[out]INFO
!>          INFO is INTEGER
!>           = 0:  successful exit.
!>           < 0:  if INFO = -i, the i-th argument had an illegal value.
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Further Details:
!>
!>  The upper-bidiagonal blocks B11, B21 are represented implicitly by
!>  angles THETA(1), ..., THETA(Q) and PHI(1), ..., PHI(Q-1). Every entry
!>  in each bidiagonal band is a product of a sine or cosine of a THETA
!>  with a sine or cosine of a PHI. See [1] or CUNCSD for details.
!>
!>  P1, P2, and Q1 are represented as products of elementary reflectors.
!>  See CUNCSD2BY1 for details on generating P1, P2, and Q1 using CUNGQR
!>  and CUNGLQ.
!>
References:
[1] Brian D. Sutton. Computing the complete CS decomposition. Numer. Algorithms, 50(1):33-65, 2009.

Definition at line 198 of file cunbdb1.f.

201*
202* -- LAPACK computational routine --
203* -- LAPACK is a software package provided by Univ. of Tennessee, --
204* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
205*
206* .. Scalar Arguments ..
207 INTEGER INFO, LWORK, M, P, Q, LDX11, LDX21
208* ..
209* .. Array Arguments ..
210 REAL PHI(*), THETA(*)
211 COMPLEX TAUP1(*), TAUP2(*), TAUQ1(*), WORK(*),
212 $ X11(LDX11,*), X21(LDX21,*)
213* ..
214*
215* ====================================================================
216*
217* .. Local Scalars ..
218 REAL C, S
219 INTEGER CHILDINFO, I, ILARF, IORBDB5, LLARF, LORBDB5,
220 $ LWORKMIN, LWORKOPT
221 LOGICAL LQUERY
222* ..
223* .. External Subroutines ..
224 EXTERNAL clarf1f, clarfgp, cunbdb5, csrot,
225 $ xerbla
226 EXTERNAL clacgv
227* ..
228* .. External Functions ..
229 REAL SCNRM2, SROUNDUP_LWORK
230 EXTERNAL scnrm2, sroundup_lwork
231* ..
232* .. Intrinsic Function ..
233 INTRINSIC atan2, cos, max, sin, sqrt
234* ..
235* .. Executable Statements ..
236*
237* Test input arguments
238*
239 info = 0
240 lquery = lwork .EQ. -1
241*
242 IF( m .LT. 0 ) THEN
243 info = -1
244 ELSE IF( p .LT. q .OR. m-p .LT. q ) THEN
245 info = -2
246 ELSE IF( q .LT. 0 .OR. m-q .LT. q ) THEN
247 info = -3
248 ELSE IF( ldx11 .LT. max( 1, p ) ) THEN
249 info = -5
250 ELSE IF( ldx21 .LT. max( 1, m-p ) ) THEN
251 info = -7
252 END IF
253*
254* Compute workspace
255*
256 IF( info .EQ. 0 ) THEN
257 ilarf = 2
258 llarf = max( p-1, m-p-1, q-1 )
259 iorbdb5 = 2
260 lorbdb5 = q-2
261 lworkopt = max( ilarf+llarf-1, iorbdb5+lorbdb5-1 )
262 lworkmin = lworkopt
263 work(1) = sroundup_lwork(lworkopt)
264 IF( lwork .LT. lworkmin .AND. .NOT.lquery ) THEN
265 info = -14
266 END IF
267 END IF
268 IF( info .NE. 0 ) THEN
269 CALL xerbla( 'CUNBDB1', -info )
270 RETURN
271 ELSE IF( lquery ) THEN
272 RETURN
273 END IF
274*
275* Reduce columns 1, ..., Q of X11 and X21
276*
277 DO i = 1, q
278*
279 CALL clarfgp( p-i+1, x11(i,i), x11(i+1,i), 1, taup1(i) )
280 CALL clarfgp( m-p-i+1, x21(i,i), x21(i+1,i), 1, taup2(i) )
281 theta(i) = atan2( real( x21(i,i) ), real( x11(i,i) ) )
282 c = cos( theta(i) )
283 s = sin( theta(i) )
284 CALL clarf1f( 'L', p-i+1, q-i, x11(i,i), 1, conjg(taup1(i)),
285 $ x11(i,i+1), ldx11, work(ilarf) )
286 CALL clarf1f( 'L', m-p-i+1, q-i, x21(i,i), 1,
287 $ conjg(taup2(i)), x21(i,i+1), ldx21,
288 $ work(ilarf) )
289*
290 IF( i .LT. q ) THEN
291 CALL csrot( q-i, x11(i,i+1), ldx11, x21(i,i+1), ldx21, c,
292 $ s )
293 CALL clacgv( q-i, x21(i,i+1), ldx21 )
294 CALL clarfgp( q-i, x21(i,i+1), x21(i,i+2), ldx21,
295 $ tauq1(i) )
296 s = real( x21(i,i+1) )
297 CALL clarf1f( 'R', p-i, q-i, x21(i,i+1), ldx21, tauq1(i),
298 $ x11(i+1,i+1), ldx11, work(ilarf) )
299 CALL clarf1f( 'R', m-p-i, q-i, x21(i,i+1), ldx21,
300 $ tauq1(i), x21(i+1,i+1), ldx21,
301 $ work(ilarf) )
302 CALL clacgv( q-i, x21(i,i+1), ldx21 )
303 c = sqrt( scnrm2( p-i, x11(i+1,i+1), 1 )**2
304 $ + scnrm2( m-p-i, x21(i+1,i+1), 1 )**2 )
305 phi(i) = atan2( s, c )
306 CALL cunbdb5( p-i, m-p-i, q-i-1, x11(i+1,i+1), 1,
307 $ x21(i+1,i+1), 1, x11(i+1,i+2), ldx11,
308 $ x21(i+1,i+2), ldx21, work(iorbdb5), lorbdb5,
309 $ childinfo )
310 END IF
311*
312 END DO
313*
314 RETURN
315*
316* End of CUNBDB1
317*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
clarf1f
subroutine clarf1f(side, m, n, v, incv, tau, c, ldc, work)
CLARF1F applies an elementary reflector to a general rectangular
Definition clarf1f.f:126
clacgv
subroutine clacgv(n, x, incx)
CLACGV conjugates a complex vector.
Definition clacgv.f:72
clarfgp
subroutine clarfgp(n, alpha, x, incx, tau)
CLARFGP generates an elementary reflector (Householder matrix) with non-negative beta.
Definition clarfgp.f:102
scnrm2
real(wp) function scnrm2(n, x, incx)
SCNRM2
Definition scnrm2.f90:90
csrot
subroutine csrot(n, cx, incx, cy, incy, c, s)
CSROT
Definition csrot.f:98
sroundup_lwork
real function sroundup_lwork(lwork)
SROUNDUP_LWORK
Definition sroundup_lwork.f:59
cunbdb5
subroutine cunbdb5(m1, m2, n, x1, incx1, x2, incx2, q1, ldq1, q2, ldq2, work, lwork, info)
CUNBDB5
Definition cunbdb5.f:155
Here is the call graph for this function:
Here is the caller graph for this function: