csrot()

subroutine csrot	(	integer	n,
		complex, dimension( * )	cx,
		integer	incx,
		complex, dimension( * )	cy,
		integer	incy,
		real	c,
		real	s )

CSROT

Purpose:

!>
!> CSROT applies a plane rotation, where the cos and sin (c and s) are real
!> and the vectors cx and cy are complex.
!> jack dongarra, linpack, 3/11/78.
!> 

Parameters

[in]	N	!> N is INTEGER !> On entry, N specifies the order of the vectors cx and cy. !> N must be at least zero. !>
[in,out]	CX	!> CX is COMPLEX array, dimension at least !> ( 1 + ( N - 1 )*abs( INCX ) ). !> Before entry, the incremented array CX must contain the n !> element vector cx. On exit, CX is overwritten by the updated !> vector cx. !>
[in]	INCX	!> INCX is INTEGER !> On entry, INCX specifies the increment for the elements of !> CX. INCX must not be zero. !>
[in,out]	CY	!> CY is COMPLEX array, dimension at least !> ( 1 + ( N - 1 )*abs( INCY ) ). !> Before entry, the incremented array CY must contain the n !> element vector cy. On exit, CY is overwritten by the updated !> vector cy. !>
[in]	INCY	!> INCY is INTEGER !> On entry, INCY specifies the increment for the elements of !> CY. INCY must not be zero. !>
[in]	C	!> C is REAL !> On entry, C specifies the cosine, cos. !>
[in]	S	!> S is REAL !> On entry, S specifies the sine, sin. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 97 of file csrot.f.

*
*  -- Reference BLAS level1 routine --
*  -- Reference BLAS is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER           INCX, INCY, N
      REAL              C, S
*     ..
*     .. Array Arguments ..
      COMPLEX           CX( * ), CY( * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER           I, IX, IY
      COMPLEX           CTEMP
*     ..
*     .. Executable Statements ..
*
      IF( n.LE.0 )
     $   RETURN
      IF( incx.EQ.1 .AND. incy.EQ.1 ) THEN
*
*        code for both increments equal to 1
*
         DO i = 1, n
            ctemp = c*cx( i ) + s*cy( i )
            cy( i ) = c*cy( i ) - s*cx( i )
            cx( i ) = ctemp
         END DO
      ELSE
*
*        code for unequal increments or equal increments not equal
*          to 1
*
         ix = 1
         iy = 1
         IF( incx.LT.0 )
     $      ix = ( -n+1 )*incx + 1
         IF( incy.LT.0 )
     $      iy = ( -n+1 )*incy + 1
         DO i = 1, n
            ctemp = c*cx( ix ) + s*cy( iy )
            cy( iy ) = c*cy( iy ) - s*cx( ix )
            cx( ix ) = ctemp
            ix = ix + incx
            iy = iy + incy
         END DO
      END IF
      RETURN
*
*     End of CSROT
*

Here is the caller graph for this function: