LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ ssbevd()

subroutine ssbevd ( character jobz,
character uplo,
integer n,
integer kd,
real, dimension( ldab, * ) ab,
integer ldab,
real, dimension( * ) w,
real, dimension( ldz, * ) z,
integer ldz,
real, dimension( * ) work,
integer lwork,
integer, dimension( * ) iwork,
integer liwork,
integer info )

SSBEVD computes the eigenvalues and, optionally, the left and/or right eigenvectors for OTHER matrices

Download SSBEVD + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!> SSBEVD computes all the eigenvalues and, optionally, eigenvectors of
!> a real symmetric band matrix A. If eigenvectors are desired, it uses
!> a divide and conquer algorithm.
!>
!>
Parameters
[in]JOBZ
!>          JOBZ is CHARACTER*1
!>          = 'N':  Compute eigenvalues only;
!>          = 'V':  Compute eigenvalues and eigenvectors.
!>
[in]UPLO
!>          UPLO is CHARACTER*1
!>          = 'U':  Upper triangle of A is stored;
!>          = 'L':  Lower triangle of A is stored.
!>
[in]N
!>          N is INTEGER
!>          The order of the matrix A.  N >= 0.
!>
[in]KD
!>          KD is INTEGER
!>          The number of superdiagonals of the matrix A if UPLO = 'U',
!>          or the number of subdiagonals if UPLO = 'L'.  KD >= 0.
!>
[in,out]AB
!>          AB is REAL array, dimension (LDAB, N)
!>          On entry, the upper or lower triangle of the symmetric band
!>          matrix A, stored in the first KD+1 rows of the array.  The
!>          j-th column of A is stored in the j-th column of the array AB
!>          as follows:
!>          if UPLO = 'U', AB(kd+1+i-j,j) = A(i,j) for max(1,j-kd)<=i<=j;
!>          if UPLO = 'L', AB(1+i-j,j)    = A(i,j) for j<=i<=min(n,j+kd).
!>
!>          On exit, AB is overwritten by values generated during the
!>          reduction to tridiagonal form.  If UPLO = 'U', the first
!>          superdiagonal and the diagonal of the tridiagonal matrix T
!>          are returned in rows KD and KD+1 of AB, and if UPLO = 'L',
!>          the diagonal and first subdiagonal of T are returned in the
!>          first two rows of AB.
!>
[in]LDAB
!>          LDAB is INTEGER
!>          The leading dimension of the array AB.  LDAB >= KD + 1.
!>
[out]W
!>          W is REAL array, dimension (N)
!>          If INFO = 0, the eigenvalues in ascending order.
!>
[out]Z
!>          Z is REAL array, dimension (LDZ, N)
!>          If JOBZ = 'V', then if INFO = 0, Z contains the orthonormal
!>          eigenvectors of the matrix A, with the i-th column of Z
!>          holding the eigenvector associated with W(i).
!>          If JOBZ = 'N', then Z is not referenced.
!>
[in]LDZ
!>          LDZ is INTEGER
!>          The leading dimension of the array Z.  LDZ >= 1, and if
!>          JOBZ = 'V', LDZ >= max(1,N).
!>
[out]WORK
!>          WORK is REAL array,
!>                                         dimension (LWORK)
!>          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
!>
[in]LWORK
!>          LWORK is INTEGER
!>          The dimension of the array WORK.
!>          IF N <= 1,                LWORK must be at least 1.
!>          If JOBZ  = 'N' and N > 2, LWORK must be at least 2*N.
!>          If JOBZ  = 'V' and N > 2, LWORK must be at least
!>                         ( 1 + 5*N + 2*N**2 ).
!>
!>          If LWORK = -1, then a workspace query is assumed; the routine
!>          only calculates the optimal sizes of the WORK and IWORK
!>          arrays, returns these values as the first entries of the WORK
!>          and IWORK arrays, and no error message related to LWORK or
!>          LIWORK is issued by XERBLA.
!>
[out]IWORK
!>          IWORK is INTEGER array, dimension (MAX(1,LIWORK))
!>          On exit, if INFO = 0, IWORK(1) returns the optimal LIWORK.
!>
[in]LIWORK
!>          LIWORK is INTEGER
!>          The dimension of the array IWORK.
!>          If JOBZ  = 'N' or N <= 1, LIWORK must be at least 1.
!>          If JOBZ  = 'V' and N > 2, LIWORK must be at least 3 + 5*N.
!>
!>          If LIWORK = -1, then a workspace query is assumed; the
!>          routine only calculates the optimal sizes of the WORK and
!>          IWORK arrays, returns these values as the first entries of
!>          the WORK and IWORK arrays, and no error message related to
!>          LWORK or LIWORK is issued by XERBLA.
!>
[out]INFO
!>          INFO is INTEGER
!>          = 0:  successful exit
!>          < 0:  if INFO = -i, the i-th argument had an illegal value
!>          > 0:  if INFO = i, the algorithm failed to converge; i
!>                off-diagonal elements of an intermediate tridiagonal
!>                form did not converge to zero.
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 183 of file ssbevd.f.

186*
187* -- LAPACK driver routine --
188* -- LAPACK is a software package provided by Univ. of Tennessee, --
189* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
190*
191* .. Scalar Arguments ..
192 CHARACTER JOBZ, UPLO
193 INTEGER INFO, KD, LDAB, LDZ, LIWORK, LWORK, N
194* ..
195* .. Array Arguments ..
196 INTEGER IWORK( * )
197 REAL AB( LDAB, * ), W( * ), WORK( * ), Z( LDZ, * )
198* ..
199*
200* =====================================================================
201*
202* .. Parameters ..
203 REAL ZERO, ONE
204 parameter( zero = 0.0e+0, one = 1.0e+0 )
205* ..
206* .. Local Scalars ..
207 LOGICAL LOWER, LQUERY, WANTZ
208 INTEGER IINFO, INDE, INDWK2, INDWRK, ISCALE, LIWMIN,
209 $ LLWRK2, LWMIN
210 REAL ANRM, BIGNUM, EPS, RMAX, RMIN, SAFMIN, SIGMA,
211 $ SMLNUM
212* ..
213* .. External Functions ..
214 LOGICAL LSAME
215 REAL SLAMCH, SLANSB, SROUNDUP_LWORK
216 EXTERNAL lsame, slamch, slansb,
217 $ sroundup_lwork
218* ..
219* .. External Subroutines ..
220 EXTERNAL sgemm, slacpy, slascl, ssbtrd, sscal,
221 $ sstedc,
222 $ ssterf, xerbla
223* ..
224* .. Intrinsic Functions ..
225 INTRINSIC sqrt
226* ..
227* .. Executable Statements ..
228*
229* Test the input parameters.
230*
231 wantz = lsame( jobz, 'V' )
232 lower = lsame( uplo, 'L' )
233 lquery = ( lwork.EQ.-1 .OR. liwork.EQ.-1 )
234*
235 info = 0
236 IF( n.LE.1 ) THEN
237 liwmin = 1
238 lwmin = 1
239 ELSE
240 IF( wantz ) THEN
241 liwmin = 3 + 5*n
242 lwmin = 1 + 5*n + 2*n**2
243 ELSE
244 liwmin = 1
245 lwmin = 2*n
246 END IF
247 END IF
248 IF( .NOT.( wantz .OR. lsame( jobz, 'N' ) ) ) THEN
249 info = -1
250 ELSE IF( .NOT.( lower .OR. lsame( uplo, 'U' ) ) ) THEN
251 info = -2
252 ELSE IF( n.LT.0 ) THEN
253 info = -3
254 ELSE IF( kd.LT.0 ) THEN
255 info = -4
256 ELSE IF( ldab.LT.kd+1 ) THEN
257 info = -6
258 ELSE IF( ldz.LT.1 .OR. ( wantz .AND. ldz.LT.n ) ) THEN
259 info = -9
260 END IF
261*
262 IF( info.EQ.0 ) THEN
263 work( 1 ) = sroundup_lwork(lwmin)
264 iwork( 1 ) = liwmin
265*
266 IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
267 info = -11
268 ELSE IF( liwork.LT.liwmin .AND. .NOT.lquery ) THEN
269 info = -13
270 END IF
271 END IF
272*
273 IF( info.NE.0 ) THEN
274 CALL xerbla( 'SSBEVD', -info )
275 RETURN
276 ELSE IF( lquery ) THEN
277 RETURN
278 END IF
279*
280* Quick return if possible
281*
282 IF( n.EQ.0 )
283 $ RETURN
284*
285 IF( n.EQ.1 ) THEN
286 w( 1 ) = ab( 1, 1 )
287 IF( wantz )
288 $ z( 1, 1 ) = one
289 RETURN
290 END IF
291*
292* Get machine constants.
293*
294 safmin = slamch( 'Safe minimum' )
295 eps = slamch( 'Precision' )
296 smlnum = safmin / eps
297 bignum = one / smlnum
298 rmin = sqrt( smlnum )
299 rmax = sqrt( bignum )
300*
301* Scale matrix to allowable range, if necessary.
302*
303 anrm = slansb( 'M', uplo, n, kd, ab, ldab, work )
304 iscale = 0
305 IF( anrm.GT.zero .AND. anrm.LT.rmin ) THEN
306 iscale = 1
307 sigma = rmin / anrm
308 ELSE IF( anrm.GT.rmax ) THEN
309 iscale = 1
310 sigma = rmax / anrm
311 END IF
312 IF( iscale.EQ.1 ) THEN
313 IF( lower ) THEN
314 CALL slascl( 'B', kd, kd, one, sigma, n, n, ab, ldab,
315 $ info )
316 ELSE
317 CALL slascl( 'Q', kd, kd, one, sigma, n, n, ab, ldab,
318 $ info )
319 END IF
320 END IF
321*
322* Call SSBTRD to reduce symmetric band matrix to tridiagonal form.
323*
324 inde = 1
325 indwrk = inde + n
326 indwk2 = indwrk + n*n
327 llwrk2 = lwork - indwk2 + 1
328 CALL ssbtrd( jobz, uplo, n, kd, ab, ldab, w, work( inde ), z,
329 $ ldz,
330 $ work( indwrk ), iinfo )
331*
332* For eigenvalues only, call SSTERF. For eigenvectors, call SSTEDC.
333*
334 IF( .NOT.wantz ) THEN
335 CALL ssterf( n, w, work( inde ), info )
336 ELSE
337 CALL sstedc( 'I', n, w, work( inde ), work( indwrk ), n,
338 $ work( indwk2 ), llwrk2, iwork, liwork, info )
339 CALL sgemm( 'N', 'N', n, n, n, one, z, ldz, work( indwrk ),
340 $ n,
341 $ zero, work( indwk2 ), n )
342 CALL slacpy( 'A', n, n, work( indwk2 ), n, z, ldz )
343 END IF
344*
345* If matrix was scaled, then rescale eigenvalues appropriately.
346*
347 IF( iscale.EQ.1 )
348 $ CALL sscal( n, one / sigma, w, 1 )
349*
350 work( 1 ) = sroundup_lwork(lwmin)
351 iwork( 1 ) = liwmin
352 RETURN
353*
354* End of SSBEVD
355*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
sgemm
subroutine sgemm(transa, transb, m, n, k, alpha, a, lda, b, ldb, beta, c, ldc)
SGEMM
Definition sgemm.f:188
ssbtrd
subroutine ssbtrd(vect, uplo, n, kd, ab, ldab, d, e, q, ldq, work, info)
SSBTRD
Definition ssbtrd.f:161
slacpy
subroutine slacpy(uplo, m, n, a, lda, b, ldb)
SLACPY copies all or part of one two-dimensional array to another.
Definition slacpy.f:101
slamch
real function slamch(cmach)
SLAMCH
Definition slamch.f:68
slansb
real function slansb(norm, uplo, n, k, ab, ldab, work)
SLANSB returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition slansb.f:127
slascl
subroutine slascl(type, kl, ku, cfrom, cto, m, n, a, lda, info)
SLASCL multiplies a general rectangular matrix by a real scalar defined as cto/cfrom.
Definition slascl.f:142
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
sroundup_lwork
real function sroundup_lwork(lwork)
SROUNDUP_LWORK
Definition sroundup_lwork.f:59
sscal
subroutine sscal(n, sa, sx, incx)
SSCAL
Definition sscal.f:79
sstedc
subroutine sstedc(compz, n, d, e, z, ldz, work, lwork, iwork, liwork, info)
SSTEDC
Definition sstedc.f:180
ssterf
subroutine ssterf(n, d, e, info)
SSTERF
Definition ssterf.f:84
Here is the call graph for this function:
Here is the caller graph for this function: