LAPACK 3.12.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
dlatsqr.f
Go to the documentation of this file.
1*> \brief \b DLATSQR
2*
3* Definition:
4* ===========
5*
6* SUBROUTINE DLATSQR( M, N, MB, NB, A, LDA, T, LDT, WORK,
7* LWORK, INFO)
8*
9* .. Scalar Arguments ..
10* INTEGER INFO, LDA, M, N, MB, NB, LDT, LWORK
11* ..
12* .. Array Arguments ..
13* DOUBLE PRECISION A( LDA, * ), T( LDT, * ), WORK( * )
14* ..
15*
16*
17*> \par Purpose:
18* =============
19*>
20*> \verbatim
21*>
22*> DLATSQR computes a blocked Tall-Skinny QR factorization of
23*> a real M-by-N matrix A for M >= N:
24*>
25*> A = Q * ( R ),
26*> ( 0 )
27*>
28*> where:
29*>
30*> Q is a M-by-M orthogonal matrix, stored on exit in an implicit
31*> form in the elements below the diagonal of the array A and in
32*> the elements of the array T;
33*>
34*> R is an upper-triangular N-by-N matrix, stored on exit in
35*> the elements on and above the diagonal of the array A.
36*>
37*> 0 is a (M-N)-by-N zero matrix, and is not stored.
38*>
39*> \endverbatim
40*
41* Arguments:
42* ==========
43*
44*> \param[in] M
45*> \verbatim
46*> M is INTEGER
47*> The number of rows of the matrix A. M >= 0.
48*> \endverbatim
49*>
50*> \param[in] N
51*> \verbatim
52*> N is INTEGER
53*> The number of columns of the matrix A. M >= N >= 0.
54*> \endverbatim
55*>
56*> \param[in] MB
57*> \verbatim
58*> MB is INTEGER
59*> The row block size to be used in the blocked QR.
60*> MB > 0.
61*> \endverbatim
62*>
63*> \param[in] NB
64*> \verbatim
65*> NB is INTEGER
66*> The column block size to be used in the blocked QR.
67*> N >= NB >= 1.
68*> \endverbatim
69*>
70*> \param[in,out] A
71*> \verbatim
72*> A is DOUBLE PRECISION array, dimension (LDA,N)
73*> On entry, the M-by-N matrix A.
74*> On exit, the elements on and above the diagonal
75*> of the array contain the N-by-N upper triangular matrix R;
76*> the elements below the diagonal represent Q by the columns
77*> of blocked V (see Further Details).
78*> \endverbatim
79*>
80*> \param[in] LDA
81*> \verbatim
82*> LDA is INTEGER
83*> The leading dimension of the array A. LDA >= max(1,M).
84*> \endverbatim
85*>
86*> \param[out] T
87*> \verbatim
88*> T is DOUBLE PRECISION array,
89*> dimension (LDT, N * Number_of_row_blocks)
90*> where Number_of_row_blocks = CEIL((M-N)/(MB-N))
91*> The blocked upper triangular block reflectors stored in compact form
92*> as a sequence of upper triangular blocks.
93*> See Further Details below.
94*> \endverbatim
95*>
96*> \param[in] LDT
97*> \verbatim
98*> LDT is INTEGER
99*> The leading dimension of the array T. LDT >= NB.
100*> \endverbatim
101*>
102*> \param[out] WORK
103*> \verbatim
104*> (workspace) DOUBLE PRECISION array, dimension (MAX(1,LWORK))
105*> \endverbatim
106*>
107*> \param[in] LWORK
108*> \verbatim
109*> LWORK is INTEGER
110*> The dimension of the array WORK. LWORK >= NB*N.
111*> If LWORK = -1, then a workspace query is assumed; the routine
112*> only calculates the optimal size of the WORK array, returns
113*> this value as the first entry of the WORK array, and no error
114*> message related to LWORK is issued by XERBLA.
115*> \endverbatim
116*>
117*> \param[out] INFO
118*> \verbatim
119*> INFO is INTEGER
120*> = 0: successful exit
121*> < 0: if INFO = -i, the i-th argument had an illegal value
122*> \endverbatim
123*
124* Authors:
125* ========
126*
127*> \author Univ. of Tennessee
128*> \author Univ. of California Berkeley
129*> \author Univ. of Colorado Denver
130*> \author NAG Ltd.
131*
132*> \par Further Details:
133* =====================
134*>
135*> \verbatim
136*> Tall-Skinny QR (TSQR) performs QR by a sequence of orthogonal transformations,
137*> representing Q as a product of other orthogonal matrices
138*> Q = Q(1) * Q(2) * . . . * Q(k)
139*> where each Q(i) zeros out subdiagonal entries of a block of MB rows of A:
140*> Q(1) zeros out the subdiagonal entries of rows 1:MB of A
141*> Q(2) zeros out the bottom MB-N rows of rows [1:N,MB+1:2*MB-N] of A
142*> Q(3) zeros out the bottom MB-N rows of rows [1:N,2*MB-N+1:3*MB-2*N] of A
143*> . . .
144*>
145*> Q(1) is computed by GEQRT, which represents Q(1) by Householder vectors
146*> stored under the diagonal of rows 1:MB of A, and by upper triangular
147*> block reflectors, stored in array T(1:LDT,1:N).
148*> For more information see Further Details in GEQRT.
149*>
150*> Q(i) for i>1 is computed by TPQRT, which represents Q(i) by Householder vectors
151*> stored in rows [(i-1)*(MB-N)+N+1:i*(MB-N)+N] of A, and by upper triangular
152*> block reflectors, stored in array T(1:LDT,(i-1)*N+1:i*N).
153*> The last Q(k) may use fewer rows.
154*> For more information see Further Details in TPQRT.
155*>
156*> For more details of the overall algorithm, see the description of
157*> Sequential TSQR in Section 2.2 of [1].
158*>
159*> [1] “Communication-Optimal Parallel and Sequential QR and LU Factorizations,”
160*> J. Demmel, L. Grigori, M. Hoemmen, J. Langou,
161*> SIAM J. Sci. Comput, vol. 34, no. 1, 2012
162*> \endverbatim
163*>
164*> \ingroup latsqr
165*>
166* =====================================================================
167 SUBROUTINE dlatsqr( M, N, MB, NB, A, LDA, T, LDT, WORK,
168 $ LWORK, INFO)
169*
170* -- LAPACK computational routine --
171* -- LAPACK is a software package provided by Univ. of Tennessee, --
172* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd. --
173*
174* .. Scalar Arguments ..
175 INTEGER INFO, LDA, M, N, MB, NB, LDT, LWORK
176* ..
177* .. Array Arguments ..
178 DOUBLE PRECISION A( LDA, * ), WORK( * ), T(LDT, *)
179* ..
180*
181* =====================================================================
182*
183* ..
184* .. Local Scalars ..
185 LOGICAL LQUERY
186 INTEGER I, II, KK, CTR
187* ..
188* .. EXTERNAL FUNCTIONS ..
189 LOGICAL LSAME
190 EXTERNAL lsame
191* .. EXTERNAL SUBROUTINES ..
192 EXTERNAL dgeqrt, dtpqrt, xerbla
193* .. INTRINSIC FUNCTIONS ..
194 INTRINSIC max, min, mod
195* ..
196* .. EXECUTABLE STATEMENTS ..
197*
198* TEST THE INPUT ARGUMENTS
199*
200 info = 0
201*
202 lquery = ( lwork.EQ.-1 )
203*
204 IF( m.LT.0 ) THEN
205 info = -1
206 ELSE IF( n.LT.0 .OR. m.LT.n ) THEN
207 info = -2
208 ELSE IF( mb.LT.1 ) THEN
209 info = -3
210 ELSE IF( nb.LT.1 .OR. ( nb.GT.n .AND. n.GT.0 )) THEN
211 info = -4
212 ELSE IF( lda.LT.max( 1, m ) ) THEN
213 info = -6
214 ELSE IF( ldt.LT.nb ) THEN
215 info = -8
216 ELSE IF( lwork.LT.(n*nb) .AND. (.NOT.lquery) ) THEN
217 info = -10
218 END IF
219 IF( info.EQ.0) THEN
220 work(1) = nb*n
221 END IF
222 IF( info.NE.0 ) THEN
223 CALL xerbla( 'DLATSQR', -info )
224 RETURN
225 ELSE IF (lquery) THEN
226 RETURN
227 END IF
228*
229* Quick return if possible
230*
231 IF( min(m,n).EQ.0 ) THEN
232 RETURN
233 END IF
234*
235* The QR Decomposition
236*
237 IF ((mb.LE.n).OR.(mb.GE.m)) THEN
238 CALL dgeqrt( m, n, nb, a, lda, t, ldt, work, info)
239 RETURN
240 END IF
241*
242 kk = mod((m-n),(mb-n))
243 ii=m-kk+1
244*
245* Compute the QR factorization of the first block A(1:MB,1:N)
246*
247 CALL dgeqrt( mb, n, nb, a(1,1), lda, t, ldt, work, info )
248*
249 ctr = 1
250 DO i = mb+1, ii-mb+n , (mb-n)
251*
252* Compute the QR factorization of the current block A(I:I+MB-N,1:N)
253*
254 CALL dtpqrt( mb-n, n, 0, nb, a(1,1), lda, a( i, 1 ), lda,
255 $ t(1, ctr * n + 1),
256 $ ldt, work, info )
257 ctr = ctr + 1
258 END DO
259*
260* Compute the QR factorization of the last block A(II:M,1:N)
261*
262 IF (ii.LE.m) THEN
263 CALL dtpqrt( kk, n, 0, nb, a(1,1), lda, a( ii, 1 ), lda,
264 $ t(1, ctr * n + 1), ldt,
265 $ work, info )
266 END IF
267*
268 work( 1 ) = n*nb
269 RETURN
270*
271* End of DLATSQR
272*
273 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine dgeqrt(m, n, nb, a, lda, t, ldt, work, info)
DGEQRT
Definition dgeqrt.f:141
subroutine dlatsqr(m, n, mb, nb, a, lda, t, ldt, work, lwork, info)
DLATSQR
Definition dlatsqr.f:169
subroutine dtpqrt(m, n, l, nb, a, lda, b, ldb, t, ldt, work, info)
DTPQRT
Definition dtpqrt.f:189