dgeqrt()

subroutine dgeqrt	(	integer	m,
		integer	n,
		integer	nb,
		double precision, dimension( lda, * )	a,
		integer	lda,
		double precision, dimension( ldt, * )	t,
		integer	ldt,
		double precision, dimension( * )	work,
		integer	info )

DGEQRT

Download DGEQRT + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> DGEQRT computes a blocked QR factorization of a real M-by-N matrix A
!> using the compact WY representation of Q.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrix A. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix A. N >= 0. !>
[in]	NB	!> NB is INTEGER !> The block size to be used in the blocked QR. MIN(M,N) >= NB >= 1. !>
[in,out]	A	!> A is DOUBLE PRECISION array, dimension (LDA,N) !> On entry, the M-by-N matrix A. !> On exit, the elements on and above the diagonal of the array !> contain the min(M,N)-by-N upper trapezoidal matrix R (R is !> upper triangular if M >= N); the elements below the diagonal !> are the columns of V. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,M). !>
[out]	T	!> T is DOUBLE PRECISION array, dimension (LDT,MIN(M,N)) !> The upper triangular block reflectors stored in compact form !> as a sequence of upper triangular blocks. See below !> for further details. !>
[in]	LDT	!> LDT is INTEGER !> The leading dimension of the array T. LDT >= NB. !>
[out]	WORK	!> WORK is DOUBLE PRECISION array, dimension (NB*N) !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>  The matrix V stores the elementary reflectors H(i) in the i-th column
!>  below the diagonal. For example, if M=5 and N=3, the matrix V is
!>
!>               V = (  1       )
!>                   ( v1  1    )
!>                   ( v1 v2  1 )
!>                   ( v1 v2 v3 )
!>                   ( v1 v2 v3 )
!>
!>  where the vi's represent the vectors which define H(i), which are returned
!>  in the matrix A.  The 1's along the diagonal of V are not stored in A.
!>
!>  Let K=MIN(M,N).  The number of blocks is B = ceiling(K/NB), where each
!>  block is of order NB except for the last block, which is of order
!>  IB = K - (B-1)*NB.  For each of the B blocks, a upper triangular block
!>  reflector factor is computed: T1, T2, ..., TB.  The NB-by-NB (and IB-by-IB
!>  for the last block) T's are stored in the NB-by-K matrix T as
!>
!>               T = (T1 T2 ... TB).
!> 

Definition at line 138 of file dgeqrt.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER INFO, LDA, LDT, M, N, NB
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION A( LDA, * ), T( LDT, * ), WORK( * )
*     ..
*
* =====================================================================
*
*     ..
*     .. Local Scalars ..
      INTEGER    I, IB, IINFO, K
      LOGICAL    USE_RECURSIVE_QR
      parameter( use_recursive_qr=.true. )
*     ..
*     .. External Subroutines ..
      EXTERNAL   dgeqrt2, dgeqrt3, dlarfb, xerbla
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( nb.LT.1 .OR. ( nb.GT.min(m,n) .AND. min(m,n).GT.0 ) )THEN
         info = -3
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -5
      ELSE IF( ldt.LT.nb ) THEN
         info = -7
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DGEQRT', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      k = min( m, n )
      IF( k.EQ.0 ) RETURN
*
*     Blocked loop of length K
*
      DO i = 1, k,  nb
         ib = min( k-i+1, nb )
*
*     Compute the QR factorization of the current block A(I:M,I:I+IB-1)
*
         IF( use_recursive_qr ) THEN
            CALL dgeqrt3( m-i+1, ib, a(i,i), lda, t(1,i), ldt,
     $                    iinfo )
         ELSE
            CALL dgeqrt2( m-i+1, ib, a(i,i), lda, t(1,i), ldt,
     $                    iinfo )
         END IF
         IF( i+ib.LE.n ) THEN
*
*     Update by applying H**T to A(I:M,I+IB:N) from the left
*
            CALL dlarfb( 'L', 'T', 'F', 'C', m-i+1, n-i-ib+1, ib,
     $                   a( i, i ), lda, t( 1, i ), ldt,
     $                   a( i, i+ib ), lda, work , n-i-ib+1 )
         END IF
      END DO
      RETURN
*
*     End of DGEQRT
*

Here is the call graph for this function:

Here is the caller graph for this function: